src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software
   4    Foundation, Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software: you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation, either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  20
  21 #include <config.h>
  22 #include "system.h"
  23
  24 #include "complain.h"
  25 #include "conflicts.h"
  26 #include "files.h"
  27 #include "getargs.h"
  28 #include "gram.h"
  29 #include "muscle-tab.h"
  30 #include "quotearg.h"
  31 #include "reader.h"
  32 #include "symlist.h"
  33 #include "scan-gram.h"
  34 #include "scan-code.h"
  35
  36 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  37 static YYLTYPE lloc_default (YYLTYPE const *, int);
  38
  39 #define YY_LOCATION_PRINT(File, Loc) \
  40           location_print (File, Loc)
  41
  42 static void version_check (location const *loc, char const *version);
  43
  44 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  45    FIXME: depends on the undocumented availability of YYLLOC.  */
  46 #undef  yyerror
  47 #define yyerror(Msg) \
  48         gram_error (&yylloc, Msg)
  49 static void gram_error (location const *, char const *);
  50
  51 static char const *char_name (char);
  52
  53 /** Add a lex-param or a parse-param.
  54  *
  55  * \param type  \a lex_param or \a parse_param
  56  * \param decl  the formal argument
  57  * \param loc   the location in the source.
  58  */
  59 static void add_param (char const *type, char *decl, location loc);
  60
  61
  62 static symbol_class current_class = unknown_sym;
  63 static uniqstr current_type = NULL;
  64 static symbol *current_lhs;
  65 static location current_lhs_location;
  66 static int current_prec = 0;
  67
  68 #define YYTYPE_INT16 int_fast16_t
  69 #define YYTYPE_INT8 int_fast8_t
  70 #define YYTYPE_UINT16 uint_fast16_t
  71 #define YYTYPE_UINT8 uint_fast8_t
  72 %}
  73
  74 %debug
  75 %verbose
  76 %defines
  77 %locations
  78 %pure-parser
  79 %error-verbose
  80 %name-prefix="gram_"
  81 %expect 0
  82
  83 %initial-action
  84 {
  85   /* Bison's grammar can initial empty locations, hence a default
  86      location is needed. */
  87   boundary_set (&@$.start, current_file, 1, 1);
  88   boundary_set (&@$.end, current_file, 1, 1);
  89 }
  90
  91 %union
  92 {
  93   symbol *symbol;
  94   symbol_list *list;
  95   int integer;
  96   char const *chars;
  97   char *code;
  98   assoc assoc;
  99   uniqstr uniqstr;
 100   unsigned char character;
 101 };
 102
 103 /* Define the tokens together with their human representation.  */
 104 %token GRAM_EOF 0 "end of file"
 105 %token STRING     "string"
 106 %token INT        "integer"
 107
 108 %token PERCENT_TOKEN       "%token"
 109 %token PERCENT_NTERM       "%nterm"
 110
 111 %token PERCENT_TYPE        "%type"
 112 %token PERCENT_DESTRUCTOR  "%destructor"
 113 %token PERCENT_PRINTER     "%printer"
 114
 115 %token PERCENT_LEFT        "%left"
 116 %token PERCENT_RIGHT       "%right"
 117 %token PERCENT_NONASSOC    "%nonassoc"
 118 %token PERCENT_PRECEDENCE  "%precedence"
 119
 120 %token PERCENT_PREC          "%prec"
 121 %token PERCENT_DPREC         "%dprec"
 122 %token PERCENT_MERGE         "%merge"
 123
 124
 125 /*----------------------.
 126 | Global Declarations.  |
 127 `----------------------*/
 128
 129 %token
 130   PERCENT_CODE            "%code"
 131   PERCENT_DEFAULT_PREC    "%default-prec"
 132   PERCENT_DEFINE          "%define"
 133   PERCENT_DEFINES         "%defines"
 134   PERCENT_EXPECT          "%expect"
 135   PERCENT_EXPECT_RR       "%expect-rr"
 136   PERCENT_FLAG            "%<flag>"
 137   PERCENT_FILE_PREFIX     "%file-prefix"
 138   PERCENT_GLR_PARSER      "%glr-parser"
 139   PERCENT_INITIAL_ACTION  "%initial-action"
 140   PERCENT_LANGUAGE        "%language"
 141   PERCENT_LEX_PARAM       "%lex-param"
 142   PERCENT_NAME_PREFIX     "%name-prefix"
 143   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 144   PERCENT_NO_LINES        "%no-lines"
 145   PERCENT_NONDETERMINISTIC_PARSER
 146                           "%nondeterministic-parser"
 147   PERCENT_OUTPUT          "%output"
 148   PERCENT_PARSE_PARAM     "%parse-param"
 149   PERCENT_REQUIRE         "%require"
 150   PERCENT_SKELETON        "%skeleton"
 151   PERCENT_START           "%start"
 152   PERCENT_TOKEN_TABLE     "%token-table"
 153   PERCENT_VERBOSE         "%verbose"
 154   PERCENT_YACC            "%yacc"
 155 ;
 156
 157 %token BRACED_CODE     "{...}"
 158 %token CHAR            "char"
 159 %token EPILOGUE        "epilogue"
 160 %token EQUAL           "="
 161 %token ID              "identifier"
 162 %token ID_COLON        "identifier:"
 163 %token PERCENT_PERCENT "%%"
 164 %token PIPE            "|"
 165 %token PROLOGUE        "%{...%}"
 166 %token SEMICOLON       ";"
 167 %token TAG             "<tag>"
 168 %token TAG_ANY         "<*>"
 169 %token TAG_NONE        "<>"
 170
 171 %type <character> CHAR
 172 %printer { fputs (char_name ($$), stderr); } CHAR
 173
 174 /* braceless is not to be used for rule or symbol actions, as it
 175    calls code_props_plain_init.  */
 176 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 177 %type <code> "{...}"
 178 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 179          STRING
 180 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 181          braceless content.opt "{...}" "%{...%}" EPILOGUE
 182
 183 %type <uniqstr> TAG ID ID_COLON PERCENT_FLAG variable
 184 %printer { fputs ($$, stderr); } ID variable
 185 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 186 %printer { fprintf (stderr, "%%%s", $$); } PERCENT_FLAG
 187 %printer { fprintf (stderr, "<%s>", $$); } TAG
 188
 189 %type <integer> INT
 190 %printer { fprintf (stderr, "%d", $$); } INT
 191
 192 %type <symbol> id id_colon symbol symbol.prec string_as_id
 193 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 194 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 195
 196 %type <assoc> precedence_declarator
 197 %type <list>  symbols.1 symbols.prec generic_symlist generic_symlist_item
 198 %%
 199
 200 input:
 201   prologue_declarations "%%" grammar epilogue.opt
 202 ;
 203
 204
 205         /*------------------------------------.
 206         | Declarations: before the first %%.  |
 207         `------------------------------------*/
 208
 209 prologue_declarations:
 210   /* Nothing */
 211 | prologue_declarations prologue_declaration
 212 ;
 213
 214 prologue_declaration:
 215   grammar_declaration
 216 | "%{...%}"
 217     {
 218       code_props plain_code;
 219       code_props_plain_init (&plain_code, $1, @1);
 220       code_props_translate_code (&plain_code);
 221       gram_scanner_last_string_free ();
 222       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 223                         plain_code.code, @1);
 224       code_scanner_last_string_free ();
 225     }
 226 | "%<flag>"
 227     {
 228       muscle_percent_define_ensure ($1, @1, true);
 229     }
 230 | "%define" variable content.opt
 231     {
 232       muscle_percent_define_insert ($2, @2, $3,
 233                                     MUSCLE_PERCENT_DEFINE_GRAMMAR_FILE);
 234     }
 235 | "%defines"                       { defines_flag = true; }
 236 | "%defines" STRING
 237     {
 238       defines_flag = true;
 239       spec_defines_file = xstrdup ($2);
 240     }
 241 | "%expect" INT                    { expected_sr_conflicts = $2; }
 242 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 243 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 244 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 245 | "%glr-parser"
 246     {
 247       nondeterministic_parser = true;
 248       glr_parser = true;
 249     }
 250 | "%initial-action" "{...}"
 251     {
 252       code_props action;
 253       code_props_symbol_action_init (&action, $2, @2);
 254       code_props_translate_code (&action);
 255       gram_scanner_last_string_free ();
 256       muscle_code_grow ("initial_action", action.code, @2);
 257       code_scanner_last_string_free ();
 258     }
 259 | "%language" STRING            { language_argmatch ($2, grammar_prio, @1); }
 260 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 261 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 262 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 263 | "%no-lines"                   { no_lines_flag = true; }
 264 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 265 | "%output" STRING              { spec_outfile = $2; }
 266 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 267 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 268 | "%require" STRING             { version_check (&@2, $2); }
 269 | "%skeleton" STRING
 270     {
 271       char const *skeleton_user = $2;
 272       if (strchr (skeleton_user, '/'))
 273         {
 274           size_t dir_length = strlen (current_file);
 275           char *skeleton_build;
 276           while (dir_length && current_file[dir_length - 1] != '/')
 277             --dir_length;
 278           while (dir_length && current_file[dir_length - 1] == '/')
 279             --dir_length;
 280           skeleton_build =
 281             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 282           if (dir_length > 0)
 283             {
 284               strncpy (skeleton_build, current_file, dir_length);
 285               skeleton_build[dir_length++] = '/';
 286             }
 287           strcpy (skeleton_build + dir_length, skeleton_user);
 288           skeleton_user = uniqstr_new (skeleton_build);
 289           free (skeleton_build);
 290         }
 291       skeleton_arg (skeleton_user, grammar_prio, @1);
 292     }
 293 | "%token-table"                { token_table_flag = true; }
 294 | "%verbose"                    { report_flag |= report_states; }
 295 | "%yacc"                       { yacc_flag = true; }
 296 | /*FIXME: Err?  What is this horror doing here? */ ";"
 297 ;
 298
 299 grammar_declaration:
 300   precedence_declaration
 301 | symbol_declaration
 302 | "%start" symbol
 303     {
 304       grammar_start_symbol_set ($2, @2);
 305     }
 306 | "%destructor" "{...}" generic_symlist
 307     {
 308       symbol_list *list;
 309       for (list = $3; list; list = list->next)
 310         symbol_list_destructor_set (list, $2, @2);
 311       symbol_list_free ($3);
 312     }
 313 | "%printer" "{...}" generic_symlist
 314     {
 315       symbol_list *list;
 316       for (list = $3; list; list = list->next)
 317         symbol_list_printer_set (list, $2, @2);
 318       symbol_list_free ($3);
 319     }
 320 | "%default-prec"
 321     {
 322       default_prec = true;
 323     }
 324 | "%no-default-prec"
 325     {
 326       default_prec = false;
 327     }
 328 | "%code" braceless
 329     {
 330       /* Do not invoke muscle_percent_code_grow here since it invokes
 331          muscle_user_name_list_grow.  */
 332       muscle_code_grow ("percent_code()", $2, @2);
 333       code_scanner_last_string_free ();
 334     }
 335 | "%code" ID braceless
 336     {
 337       muscle_percent_code_grow ($2, @2, $3, @3);
 338       code_scanner_last_string_free ();
 339     }
 340 ;
 341
 342
 343 /*---------.
 344 | %union.  |
 345 `---------*/
 346
 347 %token PERCENT_UNION "%union";
 348
 349 union_name:
 350   /* Nothing. */ {}
 351 | ID             { muscle_code_grow ("union_name", $1, @1); }
 352 ;
 353
 354 grammar_declaration:
 355   "%union" union_name braceless
 356     {
 357       union_seen = true;
 358       muscle_code_grow ("stype", $3, @3);
 359       code_scanner_last_string_free ();
 360     }
 361 ;
 362
 363
 364
 365
 366 symbol_declaration:
 367   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 368     {
 369       current_class = unknown_sym;
 370       current_type = NULL;
 371     }
 372 | "%token" { current_class = token_sym; } symbol_defs.1
 373     {
 374       current_class = unknown_sym;
 375       current_type = NULL;
 376     }
 377 | "%type" TAG symbols.1
 378     {
 379       symbol_list *list;
 380       tag_seen = true;
 381       for (list = $3; list; list = list->next)
 382         symbol_type_set (list->content.sym, $2, @2);
 383       symbol_list_free ($3);
 384     }
 385 ;
 386
 387 precedence_declaration:
 388   precedence_declarator tag.opt symbols.prec
 389     {
 390       symbol_list *list;
 391       ++current_prec;
 392       for (list = $3; list; list = list->next)
 393         {
 394           symbol_type_set (list->content.sym, current_type, @2);
 395           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 396         }
 397       symbol_list_free ($3);
 398       current_type = NULL;
 399     }
 400 ;
 401
 402 precedence_declarator:
 403   "%left"       { $$ = left_assoc; }
 404 | "%right"      { $$ = right_assoc; }
 405 | "%nonassoc"   { $$ = non_assoc; }
 406 | "%precedence" { $$ = precedence_assoc; }
 407 ;
 408
 409 tag.opt:
 410   /* Nothing. */ { current_type = NULL; }
 411 | TAG            { current_type = $1; tag_seen = true; }
 412 ;
 413
 414 /* Just like symbols.1 but accept INT for the sake of POSIX.  */
 415 symbols.prec:
 416   symbol.prec
 417     { $$ = symbol_list_sym_new ($1, @1); }
 418 | symbols.prec symbol.prec
 419     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 420 ;
 421
 422 symbol.prec:
 423     symbol { $$ = $1; }
 424   | symbol INT { $$ = $1; symbol_user_token_number_set ($1, $2, @2); }
 425   ;
 426
 427 /* One or more symbols to be %typed. */
 428 symbols.1:
 429   symbol
 430     { $$ = symbol_list_sym_new ($1, @1); }
 431 | symbols.1 symbol
 432     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 433 ;
 434
 435 generic_symlist:
 436   generic_symlist_item { $$ = $1; }
 437 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 438 ;
 439
 440 generic_symlist_item:
 441   symbol    { $$ = symbol_list_sym_new ($1, @1); }
 442 | TAG       { $$ = symbol_list_type_new ($1, @1); }
 443 | "<*>"     { $$ = symbol_list_default_tagged_new (@1); }
 444 | "<>"      { $$ = symbol_list_default_tagless_new (@1); }
 445 ;
 446
 447 /* One token definition.  */
 448 symbol_def:
 449   TAG
 450      {
 451        current_type = $1;
 452        tag_seen = true;
 453      }
 454 | id
 455      {
 456        symbol_class_set ($1, current_class, @1, true);
 457        symbol_type_set ($1, current_type, @1);
 458      }
 459 | id INT
 460     {
 461       symbol_class_set ($1, current_class, @1, true);
 462       symbol_type_set ($1, current_type, @1);
 463       symbol_user_token_number_set ($1, $2, @2);
 464     }
 465 | id string_as_id
 466     {
 467       symbol_class_set ($1, current_class, @1, true);
 468       symbol_type_set ($1, current_type, @1);
 469       symbol_make_alias ($1, $2, @$);
 470     }
 471 | id INT string_as_id
 472     {
 473       symbol_class_set ($1, current_class, @1, true);
 474       symbol_type_set ($1, current_type, @1);
 475       symbol_user_token_number_set ($1, $2, @2);
 476       symbol_make_alias ($1, $3, @$);
 477     }
 478 ;
 479
 480 /* One or more symbol definitions. */
 481 symbol_defs.1:
 482   symbol_def
 483 | symbol_defs.1 symbol_def
 484 ;
 485
 486
 487         /*------------------------------------------.
 488         | The grammar section: between the two %%.  |
 489         `------------------------------------------*/
 490
 491 grammar:
 492   rules_or_grammar_declaration
 493 | grammar rules_or_grammar_declaration
 494 ;
 495
 496 /* As a Bison extension, one can use the grammar declarations in the
 497    body of the grammar.  */
 498 rules_or_grammar_declaration:
 499   rules
 500 | grammar_declaration ";"
 501 | error ";"
 502     {
 503       yyerrok;
 504     }
 505 ;
 506
 507 rules:
 508   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 509 ;
 510
 511 rhses.1:
 512   rhs                { grammar_current_rule_end (@1); }
 513 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 514 | rhses.1 ";"
 515 ;
 516
 517 rhs:
 518   /* Nothing.  */
 519     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 520 | rhs symbol
 521     { grammar_current_rule_symbol_append ($2, @2); }
 522 | rhs "{...}"
 523     { grammar_current_rule_action_append ($2, @2); }
 524 | rhs "%prec" symbol
 525     { grammar_current_rule_prec_set ($3, @3); }
 526 | rhs "%dprec" INT
 527     { grammar_current_rule_dprec_set ($3, @3); }
 528 | rhs "%merge" TAG
 529     { grammar_current_rule_merge_set ($3, @3); }
 530 ;
 531
 532
 533 /*---------------------------.
 534 | variable and content.opt.  |
 535 `---------------------------*/
 536
 537 /* The STRING form of variable is deprecated and is not M4-friendly.
 538    For example, M4 fails for `%define "[" "value"'.  */
 539 variable:
 540   ID
 541 | STRING { $$ = uniqstr_new ($1); }
 542 ;
 543
 544 /* Some content or empty by default. */
 545 content.opt:
 546   /* Nothing. */   { $$ = ""; }
 547 | STRING
 548 ;
 549
 550
 551 /*------------.
 552 | braceless.  |
 553 `------------*/
 554
 555 braceless:
 556   "{...}"
 557     {
 558       code_props plain_code;
 559       $1[strlen ($1) - 1] = '\n';
 560       code_props_plain_init (&plain_code, $1+1, @1);
 561       code_props_translate_code (&plain_code);
 562       gram_scanner_last_string_free ();
 563       $$ = plain_code.code;
 564     }
 565 ;
 566
 567
 568 /*--------------.
 569 | Identifiers.  |
 570 `--------------*/
 571
 572 /* Identifiers are returned as uniqstr values by the scanner.
 573    Depending on their use, we may need to make them genuine symbols.  */
 574
 575 id:
 576   ID
 577     { $$ = symbol_from_uniqstr ($1, @1); }
 578 | CHAR
 579     {
 580       $$ = symbol_get (char_name ($1), @1);
 581       symbol_class_set ($$, token_sym, @1, false);
 582       symbol_user_token_number_set ($$, $1, @1);
 583     }
 584 ;
 585
 586 id_colon:
 587   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 588 ;
 589
 590
 591 symbol:
 592   id
 593 | string_as_id
 594 ;
 595
 596 /* A string used as an ID: quote it.  */
 597 string_as_id:
 598   STRING
 599     {
 600       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 601       symbol_class_set ($$, token_sym, @1, false);
 602     }
 603 ;
 604
 605 epilogue.opt:
 606   /* Nothing.  */
 607 | "%%" EPILOGUE
 608     {
 609       code_props plain_code;
 610       code_props_plain_init (&plain_code, $2, @2);
 611       code_props_translate_code (&plain_code);
 612       gram_scanner_last_string_free ();
 613       muscle_code_grow ("epilogue", plain_code.code, @2);
 614       code_scanner_last_string_free ();
 615     }
 616 ;
 617
 618 %%
 619
 620
 621 /* Return the location of the left-hand side of a rule whose
 622    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 623    the right-hand side, and return an empty location equal to the end
 624    boundary of RHS[0] if the right-hand side is empty.  */
 625
 626 static YYLTYPE
 627 lloc_default (YYLTYPE const *rhs, int n)
 628 {
 629   int i;
 630   YYLTYPE loc;
 631
 632   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 633      The bug is fixed in 7.4.2m, but play it safe for now.  */
 634   loc.start = rhs[n].end;
 635   loc.end = rhs[n].end;
 636
 637   /* Ignore empty nonterminals the start of the the right-hand side.
 638      Do not bother to ignore them at the end of the right-hand side,
 639      since empty nonterminals have the same end as their predecessors.  */
 640   for (i = 1; i <= n; i++)
 641     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 642       {
 643         loc.start = rhs[i].start;
 644         break;
 645       }
 646
 647   return loc;
 648 }
 649
 650
 651 /* Add a lex-param or a parse-param (depending on TYPE) with
 652    declaration DECL and location LOC.  */
 653
 654 static void
 655 add_param (char const *type, char *decl, location loc)
 656 {
 657   static char const alphanum[26 + 26 + 1 + 10] =
 658     "abcdefghijklmnopqrstuvwxyz"
 659     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 660     "_"
 661     "0123456789";
 662   char const *name_start = NULL;
 663   char *p;
 664
 665   /* Stop on last actual character.  */
 666   for (p = decl; p[1]; p++)
 667     if ((p == decl
 668          || ! memchr (alphanum, p[-1], sizeof alphanum))
 669         && memchr (alphanum, p[0], sizeof alphanum - 10))
 670       name_start = p;
 671
 672   /* Strip the surrounding '{' and '}', and any blanks just inside
 673      the braces.  */
 674   while (*--p == ' ' || *p == '\t')
 675     continue;
 676   p[1] = '\0';
 677   while (*++decl == ' ' || *decl == '\t')
 678     continue;
 679
 680   if (! name_start)
 681     complain_at (loc, _("missing identifier in parameter declaration"));
 682   else
 683     {
 684       char *name;
 685       size_t name_len;
 686
 687       for (name_len = 1;
 688            memchr (alphanum, name_start[name_len], sizeof alphanum);
 689            name_len++)
 690         continue;
 691
 692       name = xmalloc (name_len + 1);
 693       memcpy (name, name_start, name_len);
 694       name[name_len] = '\0';
 695       muscle_pair_list_grow (type, decl, name);
 696       free (name);
 697     }
 698
 699   gram_scanner_last_string_free ();
 700 }
 701
 702
 703 static void
 704 version_check (location const *loc, char const *version)
 705 {
 706   if (strverscmp (version, PACKAGE_VERSION) > 0)
 707     {
 708       complain_at (*loc, "require bison %s, but have %s",
 709                    version, PACKAGE_VERSION);
 710       exit (63);
 711     }
 712 }
 713
 714 static void
 715 gram_error (location const *loc, char const *msg)
 716 {
 717   complain_at (*loc, "%s", msg);
 718 }
 719
 720 char const *
 721 token_name (int type)
 722 {
 723   return yytname[YYTRANSLATE (type)];
 724 }
 725
 726 static char const *
 727 char_name (char c)
 728 {
 729   if (c == '\'')
 730     return "'\\''";
 731   else
 732     {
 733       char buf[4];
 734       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 735       return quotearg_style (escape_quoting_style, buf);
 736     }
 737 }