src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007 Free Software Foundation,
   4    Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software; you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation; either version 2 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program; if not, write to the Free Software
  20    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21    02110-1301  USA
  22 */
  23
  24 #include <config.h>
  25 #include "system.h"
  26
  27 #include <strverscmp.h>
  28
  29 #include "complain.h"
  30 #include "conflicts.h"
  31 #include "files.h"
  32 #include "getargs.h"
  33 #include "gram.h"
  34 #include "muscle_tab.h"
  35 #include "quotearg.h"
  36 #include "reader.h"
  37 #include "symlist.h"
  38 #include "scan-gram.h"
  39 #include "scan-code.h"
  40
  41 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  42 static YYLTYPE lloc_default (YYLTYPE const *, int);
  43
  44 #define YY_LOCATION_PRINT(File, Loc) \
  45           location_print (File, Loc)
  46
  47 static void version_check (location const *loc, char const *version);
  48
  49 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  50    FIXME: depends on the undocumented availability of YYLLOC.  */
  51 #undef  yyerror
  52 #define yyerror(Msg) \
  53         gram_error (&yylloc, Msg)
  54 static void gram_error (location const *, char const *);
  55
  56 static char const *char_name (char);
  57
  58 /** Add a lex-param or a parse-param.
  59  *
  60  * \param type  \a lex_param or \a parse_param
  61  * \param decl  the formal argument
  62  * \param loc   the location in the source.
  63  */
  64 static void add_param (char const *type, char *decl, location loc);
  65
  66
  67 static symbol_class current_class = unknown_sym;
  68 static uniqstr current_type = NULL;
  69 static symbol *current_lhs;
  70 static location current_lhs_location;
  71 static int current_prec = 0;
  72
  73 #define YYTYPE_INT16 int_fast16_t
  74 #define YYTYPE_INT8 int_fast8_t
  75 #define YYTYPE_UINT16 uint_fast16_t
  76 #define YYTYPE_UINT8 uint_fast8_t
  77 %}
  78
  79 %debug
  80 %verbose
  81 %defines
  82 %locations
  83 %pure-parser
  84 %error-verbose
  85 %name-prefix="gram_"
  86 %expect 0
  87
  88 %initial-action
  89 {
  90   /* Bison's grammar can initial empty locations, hence a default
  91      location is needed. */
  92   boundary_set (&@$.start, current_file, 1, 1);
  93   boundary_set (&@$.end, current_file, 1, 1);
  94 }
  95
  96 %union
  97 {
  98   symbol *symbol;
  99   symbol_list *list;
 100   int integer;
 101   char const *chars;
 102   char *code;
 103   assoc assoc;
 104   uniqstr uniqstr;
 105   unsigned char character;
 106 };
 107
 108 /* Define the tokens together with their human representation.  */
 109 %token GRAM_EOF 0 "end of file"
 110 %token STRING     "string"
 111 %token INT        "integer"
 112
 113 %token PERCENT_TOKEN       "%token"
 114 %token PERCENT_NTERM       "%nterm"
 115
 116 %token PERCENT_TYPE        "%type"
 117 %token PERCENT_DESTRUCTOR  "%destructor"
 118 %token PERCENT_PRINTER     "%printer"
 119
 120 %token PERCENT_LEFT        "%left"
 121 %token PERCENT_RIGHT       "%right"
 122 %token PERCENT_NONASSOC    "%nonassoc"
 123
 124 %token PERCENT_PREC          "%prec"
 125 %token PERCENT_DPREC         "%dprec"
 126 %token PERCENT_MERGE         "%merge"
 127
 128
 129 /*----------------------.
 130 | Global Declarations.  |
 131 `----------------------*/
 132
 133 %token
 134   PERCENT_CODE            "%code"
 135   PERCENT_DEBUG           "%debug"
 136   PERCENT_DEFAULT_PREC    "%default-prec"
 137   PERCENT_DEFINE          "%define"
 138   PERCENT_DEFINES         "%defines"
 139   PERCENT_ERROR_VERBOSE   "%error-verbose"
 140   PERCENT_EXPECT          "%expect"
 141   PERCENT_EXPECT_RR       "%expect-rr"
 142   PERCENT_FILE_PREFIX     "%file-prefix"
 143   PERCENT_GLR_PARSER      "%glr-parser"
 144   PERCENT_INITIAL_ACTION  "%initial-action"
 145   PERCENT_LANGUAGE        "%language"
 146   PERCENT_LEX_PARAM       "%lex-param"
 147   PERCENT_LOCATIONS       "%locations"
 148   PERCENT_NAME_PREFIX     "%name-prefix"
 149   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 150   PERCENT_NO_LINES        "%no-lines"
 151   PERCENT_NONDETERMINISTIC_PARSER
 152                           "%nondeterministic-parser"
 153   PERCENT_OUTPUT          "%output"
 154   PERCENT_PARSE_PARAM     "%parse-param"
 155   PERCENT_PURE_PARSER     "%pure-parser"
 156   PERCENT_PUSH_PARSER     "%push-parser"
 157   PERCENT_PUSH_PULL_PARSER
 158                           "%push-pull-parser"
 159   PERCENT_REQUIRE         "%require"
 160   PERCENT_SKELETON        "%skeleton"
 161   PERCENT_START           "%start"
 162   PERCENT_TOKEN_TABLE     "%token-table"
 163   PERCENT_VERBOSE         "%verbose"
 164   PERCENT_YACC            "%yacc"
 165 ;
 166
 167 %token BRACED_CODE     "{...}"
 168 %token CHAR            "char"
 169 %token EPILOGUE        "epilogue"
 170 %token EQUAL           "="
 171 %token ID              "identifier"
 172 %token ID_COLON        "identifier:"
 173 %token PERCENT_PERCENT "%%"
 174 %token PIPE            "|"
 175 %token PROLOGUE        "%{...%}"
 176 %token SEMICOLON       ";"
 177 %token TYPE            "type"
 178 %token TYPE_TAG_ANY    "<*>"
 179 %token TYPE_TAG_NONE   "<>"
 180
 181 %type <character> CHAR
 182 %printer { fputs (char_name ($$), stderr); } CHAR
 183
 184 /* braceless is not to be used for rule or symbol actions, as it
 185    calls code_props_plain_init.  */
 186 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 187 %type <code> "{...}"
 188 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 189          STRING
 190 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 191          braceless content.opt "{...}" "%{...%}" EPILOGUE
 192
 193 %type <uniqstr> TYPE ID ID_COLON variable
 194 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 195 %printer { fputs ($$, stderr); } ID variable
 196 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 197
 198 %type <integer> INT
 199 %printer { fprintf (stderr, "%d", $$); } INT
 200
 201 %type <symbol> id id_colon symbol string_as_id
 202 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 203 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 204
 205 %type <assoc> precedence_declarator
 206 %type <list>  symbols.1 generic_symlist generic_symlist_item
 207 %%
 208
 209 input:
 210   prologue_declarations "%%" grammar epilogue.opt
 211 ;
 212
 213
 214         /*------------------------------------.
 215         | Declarations: before the first %%.  |
 216         `------------------------------------*/
 217
 218 prologue_declarations:
 219   /* Nothing */
 220 | prologue_declarations prologue_declaration
 221 ;
 222
 223 prologue_declaration:
 224   grammar_declaration
 225 | "%{...%}"
 226     {
 227       code_props plain_code;
 228       code_props_plain_init (&plain_code, $1, @1);
 229       code_props_translate_code (&plain_code);
 230       gram_scanner_last_string_free ();
 231       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 232                         plain_code.code, @1);
 233       code_scanner_last_string_free ();
 234     }
 235 | "%debug"                         { debug_flag = true; }
 236 | "%define" variable content.opt
 237     {
 238       char const name_prefix[] = "percent_define(";
 239       size_t length = strlen ($2);
 240       char *name = xmalloc (sizeof name_prefix + length + 1);
 241       strcpy (name, name_prefix);
 242       strcpy (name + sizeof name_prefix - 1, $2);
 243       strcpy (name + sizeof name_prefix - 1 + length, ")");
 244       if (muscle_find_const (name))
 245         warn_at (@2, _("%s `%s' redefined"), "%define variable", $2);
 246       MUSCLE_INSERT_STRING (uniqstr_new (name), $3);
 247       free (name);
 248       muscle_grow_user_name_list ("percent_define_user_variables", $2, @2);
 249     }
 250 | "%defines"                       { defines_flag = true; }
 251 | "%defines" STRING
 252     {
 253       defines_flag = true;
 254       spec_defines_file = xstrdup ($2);
 255     }
 256 | "%error-verbose"                 { error_verbose = true; }
 257 | "%expect" INT                    { expected_sr_conflicts = $2; }
 258 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 259 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 260 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 261 | "%glr-parser"
 262     {
 263       nondeterministic_parser = true;
 264       glr_parser = true;
 265     }
 266 | "%initial-action" "{...}"
 267     {
 268       code_props action;
 269       code_props_symbol_action_init (&action, $2, @2);
 270       code_props_translate_code (&action);
 271       gram_scanner_last_string_free ();
 272       muscle_code_grow ("initial_action", action.code, @2);
 273       code_scanner_last_string_free ();
 274     }
 275 | "%language" STRING            { language_argmatch ($2, 1, &@1); }
 276 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 277 | "%locations"                  { locations_flag = true; }
 278 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 279 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 280 | "%no-lines"                   { no_lines_flag = true; }
 281 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 282 | "%output" STRING              { spec_outfile = $2; }
 283 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 284 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 285 | "%pure-parser"                { pure_parser = true; }
 286 | "%push-parser"                { push_parser = true; pull_parser = false; }
 287 | "%push-pull-parser"           { push_parser = true; pull_parser = true; }
 288 | "%require" STRING             { version_check (&@2, $2); }
 289 | "%skeleton" STRING
 290     {
 291       char const *skeleton_user = $2;
 292       if (strchr (skeleton_user, '/'))
 293         {
 294           size_t dir_length = strlen (current_file);
 295           char *skeleton_build;
 296           while (dir_length && current_file[dir_length - 1] != '/')
 297             --dir_length;
 298           while (dir_length && current_file[dir_length - 1] == '/')
 299             --dir_length;
 300           skeleton_build =
 301             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 302           if (dir_length > 0)
 303             {
 304               strncpy (skeleton_build, current_file, dir_length);
 305               skeleton_build[dir_length++] = '/';
 306             }
 307           strcpy (skeleton_build + dir_length, skeleton_user);
 308           skeleton_user = uniqstr_new (skeleton_build);
 309           free (skeleton_build);
 310         }
 311       skeleton_arg (skeleton_user, 1, &@1);
 312     }
 313 | "%token-table"                { token_table_flag = true; }
 314 | "%verbose"                    { report_flag = report_states; }
 315 | "%yacc"                       { yacc_flag = true; }
 316 | /*FIXME: Err?  What is this horror doing here? */ ";"
 317 ;
 318
 319 grammar_declaration:
 320   precedence_declaration
 321 | symbol_declaration
 322 | "%start" symbol
 323     {
 324       grammar_start_symbol_set ($2, @2);
 325     }
 326 | "%destructor" "{...}" generic_symlist
 327     {
 328       symbol_list *list;
 329       for (list = $3; list; list = list->next)
 330         symbol_list_destructor_set (list, $2, @2);
 331       symbol_list_free ($3);
 332     }
 333 | "%printer" "{...}" generic_symlist
 334     {
 335       symbol_list *list;
 336       for (list = $3; list; list = list->next)
 337         symbol_list_printer_set (list, $2, @2);
 338       symbol_list_free ($3);
 339     }
 340 | "%default-prec"
 341     {
 342       default_prec = true;
 343     }
 344 | "%no-default-prec"
 345     {
 346       default_prec = false;
 347     }
 348 | "%code" braceless
 349     {
 350       muscle_code_grow ("percent_code()", $2, @2);
 351       code_scanner_last_string_free ();
 352     }
 353 | "%code" ID braceless
 354     {
 355       char const name_prefix[] = "percent_code(";
 356       size_t length = strlen ($2);
 357       char *name = xmalloc (sizeof name_prefix + length + 1);
 358       strcpy (name, name_prefix);
 359       strcpy (name + sizeof name_prefix - 1, $2);
 360       strcpy (name + sizeof name_prefix - 1 + length, ")");
 361       muscle_code_grow (uniqstr_new (name), $3, @3);
 362       free (name);
 363       code_scanner_last_string_free ();
 364       muscle_grow_user_name_list ("percent_code_user_qualifiers", $2, @2);
 365     }
 366 ;
 367
 368
 369 /*----------*
 370  | %union.  |
 371  *----------*/
 372
 373 %token PERCENT_UNION "%union";
 374
 375 union_name:
 376   /* Nothing. */ {}
 377 | ID             { muscle_code_grow ("union_name", $1, @1); }
 378 ;
 379
 380 grammar_declaration:
 381   "%union" union_name braceless
 382     {
 383       union_seen = true;
 384       muscle_code_grow ("stype", $3, @3);
 385       code_scanner_last_string_free ();
 386     }
 387 ;
 388
 389
 390
 391
 392 symbol_declaration:
 393   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 394     {
 395       current_class = unknown_sym;
 396       current_type = NULL;
 397     }
 398 | "%token" { current_class = token_sym; } symbol_defs.1
 399     {
 400       current_class = unknown_sym;
 401       current_type = NULL;
 402     }
 403 | "%type" TYPE symbols.1
 404     {
 405       symbol_list *list;
 406       tag_seen = true;
 407       for (list = $3; list; list = list->next)
 408         symbol_type_set (list->content.sym, $2, @2);
 409       symbol_list_free ($3);
 410     }
 411 ;
 412
 413 precedence_declaration:
 414   precedence_declarator type.opt symbols.1
 415     {
 416       symbol_list *list;
 417       ++current_prec;
 418       for (list = $3; list; list = list->next)
 419         {
 420           symbol_type_set (list->content.sym, current_type, @2);
 421           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 422         }
 423       symbol_list_free ($3);
 424       current_type = NULL;
 425     }
 426 ;
 427
 428 precedence_declarator:
 429   "%left"     { $$ = left_assoc; }
 430 | "%right"    { $$ = right_assoc; }
 431 | "%nonassoc" { $$ = non_assoc; }
 432 ;
 433
 434 type.opt:
 435   /* Nothing. */ { current_type = NULL; }
 436 | TYPE           { current_type = $1; tag_seen = true; }
 437 ;
 438
 439 /* One or more symbols to be %typed. */
 440 symbols.1:
 441   symbol
 442     { $$ = symbol_list_sym_new ($1, @1); }
 443 | symbols.1 symbol
 444     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 445 ;
 446
 447 generic_symlist:
 448   generic_symlist_item { $$ = $1; }
 449 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 450 ;
 451
 452 generic_symlist_item:
 453   symbol            { $$ = symbol_list_sym_new ($1, @1); }
 454 | TYPE              { $$ = symbol_list_type_new ($1, @1); }
 455 | "<*>"             { $$ = symbol_list_default_tagged_new (@1); }
 456 | "<>"             { $$ = symbol_list_default_tagless_new (@1); }
 457 ;
 458
 459 /* One token definition.  */
 460 symbol_def:
 461   TYPE
 462      {
 463        current_type = $1;
 464        tag_seen = true;
 465      }
 466 | id
 467      {
 468        symbol_class_set ($1, current_class, @1, true);
 469        symbol_type_set ($1, current_type, @1);
 470      }
 471 | id INT
 472     {
 473       symbol_class_set ($1, current_class, @1, true);
 474       symbol_type_set ($1, current_type, @1);
 475       symbol_user_token_number_set ($1, $2, @2);
 476     }
 477 | id string_as_id
 478     {
 479       symbol_class_set ($1, current_class, @1, true);
 480       symbol_type_set ($1, current_type, @1);
 481       symbol_make_alias ($1, $2, @$);
 482     }
 483 | id INT string_as_id
 484     {
 485       symbol_class_set ($1, current_class, @1, true);
 486       symbol_type_set ($1, current_type, @1);
 487       symbol_user_token_number_set ($1, $2, @2);
 488       symbol_make_alias ($1, $3, @$);
 489     }
 490 ;
 491
 492 /* One or more symbol definitions. */
 493 symbol_defs.1:
 494   symbol_def
 495 | symbol_defs.1 symbol_def
 496 ;
 497
 498
 499         /*------------------------------------------.
 500         | The grammar section: between the two %%.  |
 501         `------------------------------------------*/
 502
 503 grammar:
 504   rules_or_grammar_declaration
 505 | grammar rules_or_grammar_declaration
 506 ;
 507
 508 /* As a Bison extension, one can use the grammar declarations in the
 509    body of the grammar.  */
 510 rules_or_grammar_declaration:
 511   rules
 512 | grammar_declaration ";"
 513 | error ";"
 514     {
 515       yyerrok;
 516     }
 517 ;
 518
 519 rules:
 520   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 521 ;
 522
 523 rhses.1:
 524   rhs                { grammar_current_rule_end (@1); }
 525 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 526 | rhses.1 ";"
 527 ;
 528
 529 rhs:
 530   /* Nothing.  */
 531     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 532 | rhs symbol
 533     { grammar_current_rule_symbol_append ($2, @2); }
 534 | rhs "{...}"
 535     { grammar_current_rule_action_append ($2, @2); }
 536 | rhs "%prec" symbol
 537     { grammar_current_rule_prec_set ($3, @3); }
 538 | rhs "%dprec" INT
 539     { grammar_current_rule_dprec_set ($3, @3); }
 540 | rhs "%merge" TYPE
 541     { grammar_current_rule_merge_set ($3, @3); }
 542 ;
 543
 544
 545 /*----------------------------*
 546  | variable and content.opt.  |
 547  *---------------------------*/
 548
 549 variable:
 550   ID
 551   | STRING { $$ = uniqstr_new ($1); } /* deprecated and not M4-friendly */
 552   ;
 553
 554 /* Some content or empty by default. */
 555 content.opt:
 556   /* Nothing. */
 557     {
 558       $$ = "";
 559     }
 560 | STRING
 561 ;
 562
 563
 564 /*-------------*
 565  | braceless.  |
 566  *-------------*/
 567
 568 braceless:
 569   "{...}"
 570     {
 571       code_props plain_code;
 572       $1[strlen ($1) - 1] = '\n';
 573       code_props_plain_init (&plain_code, $1+1, @1);
 574       code_props_translate_code (&plain_code);
 575       gram_scanner_last_string_free ();
 576       $$ = plain_code.code;
 577     }
 578 ;
 579
 580
 581 /*---------------*
 582  | Identifiers.  |
 583  *---------------*/
 584
 585 /* Identifiers are returned as uniqstr values by the scanner.
 586    Depending on their use, we may need to make them genuine symbols.  */
 587
 588 id:
 589   ID
 590     { $$ = symbol_from_uniqstr ($1, @1); }
 591 | CHAR
 592     {
 593       $$ = symbol_get (char_name ($1), @1);
 594       symbol_class_set ($$, token_sym, @1, false);
 595       symbol_user_token_number_set ($$, $1, @1);
 596     }
 597 ;
 598
 599 id_colon:
 600   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 601 ;
 602
 603
 604 symbol:
 605   id
 606 | string_as_id
 607 ;
 608
 609 /* A string used as an ID: quote it.  */
 610 string_as_id:
 611   STRING
 612     {
 613       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 614       symbol_class_set ($$, token_sym, @1, false);
 615     }
 616 ;
 617
 618 epilogue.opt:
 619   /* Nothing.  */
 620 | "%%" EPILOGUE
 621     {
 622       code_props plain_code;
 623       code_props_plain_init (&plain_code, $2, @2);
 624       code_props_translate_code (&plain_code);
 625       gram_scanner_last_string_free ();
 626       muscle_code_grow ("epilogue", plain_code.code, @2);
 627       code_scanner_last_string_free ();
 628     }
 629 ;
 630
 631 %%
 632
 633
 634 /* Return the location of the left-hand side of a rule whose
 635    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 636    the right-hand side, and return an empty location equal to the end
 637    boundary of RHS[0] if the right-hand side is empty.  */
 638
 639 static YYLTYPE
 640 lloc_default (YYLTYPE const *rhs, int n)
 641 {
 642   int i;
 643   YYLTYPE loc;
 644
 645   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 646      The bug is fixed in 7.4.2m, but play it safe for now.  */
 647   loc.start = rhs[n].end;
 648   loc.end = rhs[n].end;
 649
 650   /* Ignore empty nonterminals the start of the the right-hand side.
 651      Do not bother to ignore them at the end of the right-hand side,
 652      since empty nonterminals have the same end as their predecessors.  */
 653   for (i = 1; i <= n; i++)
 654     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 655       {
 656         loc.start = rhs[i].start;
 657         break;
 658       }
 659
 660   return loc;
 661 }
 662
 663
 664 /* Add a lex-param or a parse-param (depending on TYPE) with
 665    declaration DECL and location LOC.  */
 666
 667 static void
 668 add_param (char const *type, char *decl, location loc)
 669 {
 670   static char const alphanum[26 + 26 + 1 + 10] =
 671     "abcdefghijklmnopqrstuvwxyz"
 672     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 673     "_"
 674     "0123456789";
 675   char const *name_start = NULL;
 676   char *p;
 677
 678   /* Stop on last actual character.  */
 679   for (p = decl; p[1]; p++)
 680     if ((p == decl
 681          || ! memchr (alphanum, p[-1], sizeof alphanum))
 682         && memchr (alphanum, p[0], sizeof alphanum - 10))
 683       name_start = p;
 684
 685   /* Strip the surrounding '{' and '}', and any blanks just inside
 686      the braces.  */
 687   while (*--p == ' ' || *p == '\t')
 688     continue;
 689   p[1] = '\0';
 690   while (*++decl == ' ' || *decl == '\t')
 691     continue;
 692
 693   if (! name_start)
 694     complain_at (loc, _("missing identifier in parameter declaration"));
 695   else
 696     {
 697       char *name;
 698       size_t name_len;
 699
 700       for (name_len = 1;
 701            memchr (alphanum, name_start[name_len], sizeof alphanum);
 702            name_len++)
 703         continue;
 704
 705       name = xmalloc (name_len + 1);
 706       memcpy (name, name_start, name_len);
 707       name[name_len] = '\0';
 708       muscle_pair_list_grow (type, decl, name);
 709       free (name);
 710     }
 711
 712   gram_scanner_last_string_free ();
 713 }
 714
 715
 716 static void
 717 version_check (location const *loc, char const *version)
 718 {
 719   if (strverscmp (version, PACKAGE_VERSION) > 0)
 720     {
 721       complain_at (*loc, "require bison %s, but have %s",
 722                    version, PACKAGE_VERSION);
 723       exit (63);
 724     }
 725 }
 726
 727 static void
 728 gram_error (location const *loc, char const *msg)
 729 {
 730   complain_at (*loc, "%s", msg);
 731 }
 732
 733 char const *
 734 token_name (int type)
 735 {
 736   return yytname[YYTRANSLATE (type)];
 737 }
 738
 739 static char const *
 740 char_name (char c)
 741 {
 742   if (c == '\'')
 743     return "'\\''";
 744   else
 745     {
 746       char buf[4];
 747       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 748       return quotearg_style (escape_quoting_style, buf);
 749     }
 750 }