data/bison.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Language-independent M4 Macros for Bison.
   4
   5 # Copyright (C) 2002, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free
   6 # Software Foundation, Inc.
   7
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21
  22 ## ---------------- ##
  23 ## Identification.  ##
  24 ## ---------------- ##
  25
  26 # b4_copyright(TITLE, YEARS)
  27 # --------------------------
  28 m4_define([b4_copyright],
  29 [b4_comment([A Bison parser, made by GNU Bison b4_version.])
  30
  31 b4_comment([$1
  32
  33 m4_text_wrap([Copyright (C) $2 Free Software Foundation, Inc.], [   ])
  34
  35 This program is free software: you can redistribute it and/or modify
  36 it under the terms of the GNU General Public License as published by
  37 the Free Software Foundation, either version 3 of the License, or
  38 (at your option) any later version.
  39
  40 This program is distributed in the hope that it will be useful,
  41 but WITHOUT ANY WARRANTY; without even the implied warranty of
  42 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  43 GNU General Public License for more details.
  44
  45 You should have received a copy of the GNU General Public License
  46 along with this program.  If not, see <http://www.gnu.org/licenses/>.])
  47
  48 b4_comment([As a special exception, you may create a larger work that contains
  49 part or all of the Bison parser skeleton and distribute that work
  50 under terms of your choice, so long as that work isn't itself a
  51 parser generator using the skeleton or a modified version thereof
  52 as a parser skeleton.  Alternatively, if you modify or redistribute
  53 the parser skeleton itself, you may (at your option) remove this
  54 special exception, which will cause the skeleton and the resulting
  55 Bison output files to be licensed under the GNU General Public
  56 License without this special exception.
  57
  58 This special exception was added by the Free Software Foundation in
  59 version 2.2 of Bison.])])
  60
  61
  62 ## ---------------- ##
  63 ## Error handling.  ##
  64 ## ---------------- ##
  65
  66 # The following error handling macros print error directives that should not
  67 # become arguments of other macro invocations since they would likely then be
  68 # mangled.  Thus, they print to stdout directly.
  69
  70 # b4_cat(TEXT)
  71 # ------------
  72 # Write TEXT to stdout.  Precede the final newline with an @ so that it's
  73 # escaped.  For example:
  74 #
  75 #   b4_cat([[@complain(invalid input@)]])
  76 m4_define([b4_cat],
  77 [m4_syscmd([cat <<'_m4eof'
  78 ]m4_bpatsubst(m4_dquote($1), [_m4eof], [_m4@`eof])[@
  79 _m4eof
  80 ])dnl
  81 m4_if(m4_sysval, [0], [], [m4_fatal([$0: cannot write to stdout])])])
  82
  83 # b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
  84 # -------------------------------------------
  85 # Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to stdout.
  86 #
  87 # For example:
  88 #
  89 #   b4_error([[warn]], [[invalid value for `%s': %s]], [[foo]], [[3]])
  90 m4_define([b4_error],
  91 [b4_cat([[@]$1[(]$2[]]dnl
  92 [m4_if([$#], [2], [],
  93        [m4_foreach([b4_arg],
  94                    m4_dquote(m4_shift(m4_shift($@))),
  95                    [[@,]b4_arg])])[@)]])])
  96
  97 # b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
  98 # ----------------------------------------------------------
  99 # Write @KIND_at(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 100 #
 101 # For example:
 102 #
 103 #   b4_error_at([[complain]], [[input.y:2.3]], [[input.y:5.4]],
 104 #               [[invalid %s]], [[foo]])
 105 m4_define([b4_error_at],
 106 [b4_cat([[@]$1[_at(]$2[@,]$3[@,]$4[]]dnl
 107 [m4_if([$#], [4], [],
 108        [m4_foreach([b4_arg],
 109                    m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
 110                    [[@,]b4_arg])])[@)]])])
 111
 112 # b4_warn(FORMAT, [ARG1], [ARG2], ...)
 113 # ------------------------------------
 114 # Write @warn(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 115 #
 116 # For example:
 117 #
 118 #   b4_warn([[invalid value for `%s': %s]], [[foo]], [[3]])
 119 #
 120 # As a simple test suite, this:
 121 #
 122 #   m4_divert(-1)
 123 #   m4_define([asdf], [ASDF])
 124 #   m4_define([fsa], [FSA])
 125 #   m4_define([fdsa], [FDSA])
 126 #   b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
 127 #   b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
 128 #   b4_warn()
 129 #   b4_warn(1)
 130 #   b4_warn(1, 2)
 131 #
 132 # Should produce this without newlines:
 133 #
 134 #   @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
 135 #   @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
 136 #   @warn(@)
 137 #   @warn(1@)
 138 #   @warn(1@,2@)
 139 m4_define([b4_warn],
 140 [b4_error([[warn]], $@)])
 141
 142 # b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 143 # ---------------------------------------------------
 144 # Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 145 #
 146 # For example:
 147 #
 148 #   b4_warn_at([[input.y:2.3]], [[input.y:5.4]], [[invalid %s]], [[foo]])
 149 m4_define([b4_warn_at],
 150 [b4_error_at([[warn]], $@)])
 151
 152 # b4_complain(FORMAT, [ARG1], [ARG2], ...)
 153 # ----------------------------------------
 154 # Write @complain(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 155 #
 156 # See b4_warn example.
 157 m4_define([b4_complain],
 158 [b4_error([[complain]], $@)])
 159
 160 # b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 161 # -------------------------------------------------------
 162 # Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 163 #
 164 # See b4_warn_at example.
 165 m4_define([b4_complain_at],
 166 [b4_error_at([[complain]], $@)])
 167
 168 # b4_fatal(FORMAT, [ARG1], [ARG2], ...)
 169 # -------------------------------------
 170 # Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 171 #
 172 # See b4_warn example.
 173 m4_define([b4_fatal],
 174 [b4_error([[fatal]], $@)dnl
 175 m4_exit(1)])
 176
 177 # b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 178 # ----------------------------------------------------
 179 # Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 180 #
 181 # See b4_warn_at example.
 182 m4_define([b4_fatal_at],
 183 [b4_error_at([[fatal]], $@)dnl
 184 m4_exit(1)])
 185
 186
 187 ## ---------------- ##
 188 ## Default values.  ##
 189 ## ---------------- ##
 190
 191 # m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
 192 m4_define_default([b4_pre_prologue], [])
 193 m4_define_default([b4_post_prologue], [])
 194 m4_define_default([b4_epilogue], [])
 195 m4_define_default([b4_parse_param], [])
 196
 197 # The initial column and line.
 198 m4_define_default([b4_location_initial_column], [1])
 199 m4_define_default([b4_location_initial_line],   [1])
 200
 201
 202 ## ------------ ##
 203 ## Data Types.  ##
 204 ## ------------ ##
 205
 206 # b4_ints_in(INT1, INT2, LOW, HIGH)
 207 # ---------------------------------
 208 # Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
 209 m4_define([b4_ints_in],
 210 [m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
 211
 212
 213
 214 ## ------------------ ##
 215 ## Decoding options.  ##
 216 ## ------------------ ##
 217
 218 # b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
 219 # -----------------------------------
 220 # Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
 221 m4_define([b4_flag_if],
 222 [m4_case(b4_$1_flag,
 223          [0], [$3],
 224          [1], [$2],
 225          [m4_fatal([invalid $1 value: ]$1)])])
 226
 227
 228 # b4_define_flag_if(FLAG)
 229 # -----------------------
 230 # Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
 231 # value of the Boolean FLAG.
 232 m4_define([b4_define_flag_if],
 233 [_b4_define_flag_if($[1], $[2], [$1])])
 234
 235 # _b4_define_flag_if($1, $2, FLAG)
 236 # --------------------------------
 237 # This macro works around the impossibility to define macros
 238 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 239 # This sucks hard, GNU M4 should really provide M5 like $$1.
 240 m4_define([_b4_define_flag_if],
 241 [m4_if([$1$2], $[1]$[2], [],
 242        [m4_fatal([$0: Invalid arguments: $@])])dnl
 243 m4_define([b4_$3_if],
 244           [b4_flag_if([$3], [$1], [$2])])])
 245
 246
 247 # b4_FLAG_if(IF-TRUE, IF-FALSE)
 248 # -----------------------------
 249 # Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
 250 b4_define_flag_if([defines])            # Whether headers are requested.
 251 b4_define_flag_if([error_verbose])      # Whether error are verbose.
 252 b4_define_flag_if([glr])                # Whether a GLR parser is requested.
 253 b4_define_flag_if([locations])          # Whether locations are tracked.
 254 b4_define_flag_if([nondeterministic])   # Whether conflicts should be handled.
 255 b4_define_flag_if([yacc])               # Whether POSIX Yacc is emulated.
 256
 257
 258 ## ------------------------- ##
 259 ## Assigning token numbers.  ##
 260 ## ------------------------- ##
 261
 262
 263 ## ----------- ##
 264 ## Synclines.  ##
 265 ## ----------- ##
 266
 267 # b4_basename(NAME)
 268 # -----------------
 269 # Similar to POSIX basename; the differences don't matter here.
 270 # Beware that NAME is not evaluated.
 271 m4_define([b4_basename],
 272 [m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
 273
 274
 275 # b4_syncline(LINE, FILE)
 276 # -----------------------
 277 m4_define([b4_syncline],
 278 [b4_flag_if([synclines], [
 279 b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
 280 b4_sync_start([$1], [$2])])])
 281
 282 m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
 283 m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
 284
 285 # b4_user_code(USER-CODE)
 286 # -----------------------
 287 # Emit code from the user, ending it with synclines.
 288 m4_define([b4_user_code],
 289 [$1
 290 b4_syncline([@oline@], [@ofile@])])
 291
 292
 293 # b4_define_user_code(MACRO)
 294 # --------------------------
 295 # From b4_MACRO, build b4_user_MACRO that includes the synclines.
 296 m4_define([b4_define_user_code],
 297 [m4_define([b4_user_$1],
 298 [b4_user_code([b4_$1])])])
 299
 300
 301 # b4_user_actions
 302 # b4_user_initial_action
 303 # b4_user_post_prologue
 304 # b4_user_pre_prologue
 305 # b4_user_stype
 306 # ----------------------
 307 # Macros that issue user code, ending with synclines.
 308 b4_define_user_code([actions])
 309 b4_define_user_code([initial_action])
 310 b4_define_user_code([post_prologue])
 311 b4_define_user_code([pre_prologue])
 312 b4_define_user_code([stype])
 313
 314
 315 # b4_check_user_names(WHAT, USER-LIST, BISON-NAMESPACE)
 316 # -----------------------------------------------------
 317 # Complain if any name of type WHAT is used by the user (as recorded in
 318 # USER-LIST) but is not used by Bison (as recorded by macros in the
 319 # namespace BISON-NAMESPACE).
 320 #
 321 # USER-LIST must expand to a list specifying all user occurrences of all names
 322 # of type WHAT.   Each item in the list must be a triplet specifying one
 323 # occurrence: name, start boundary, and end boundary.  Empty string names are
 324 # fine.  An empty list is fine.
 325 #
 326 # For example, to define b4_foo_user_names to be used for USER-LIST with three
 327 # name occurrences and with correct quoting:
 328 #
 329 #   m4_define([b4_foo_user_names],
 330 #             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
 331 #               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
 332 #               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
 333 #
 334 # The macro BISON-NAMESPACE(bar) must be defined iff the name bar of type WHAT
 335 # is used by Bison (in the front-end or in the skeleton).  Empty string names
 336 # are fine, but it would be ugly for Bison to actually use one.
 337 #
 338 # For example, to use b4_foo_bison_names for BISON-NAMESPACE and define that
 339 # the names bar and baz are used by Bison:
 340 #
 341 #   m4_define([b4_foo_bison_names(bar)])
 342 #   m4_define([b4_foo_bison_names(baz)])
 343 #
 344 # To invoke b4_check_user_names with TYPE foo, with USER-LIST
 345 # b4_foo_user_names, with BISON-NAMESPACE b4_foo_bison_names, and with correct
 346 # quoting:
 347 #
 348 #   b4_check_user_names([[foo]], [b4_foo_user_names],
 349 #                       [[b4_foo_bison_names]])
 350 m4_define([b4_check_user_names],
 351 [m4_foreach([b4_occurrence], $2,
 352 [m4_pushdef([b4_occurrence], b4_occurrence)dnl
 353 m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
 354 m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
 355 m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
 356 m4_ifndef($3[(]m4_quote(b4_user_name)[)],
 357           [b4_complain_at([b4_start], [b4_end],
 358                           [[%s `%s' is not used]],
 359                           [$1], [b4_user_name])])[]dnl
 360 m4_popdef([b4_occurrence])dnl
 361 m4_popdef([b4_user_name])dnl
 362 m4_popdef([b4_start])dnl
 363 m4_popdef([b4_end])dnl
 364 ])])
 365
 366
 367
 368
 369 ## --------------------- ##
 370 ## b4_percent_define_*.  ##
 371 ## --------------------- ##
 372
 373
 374 # b4_percent_define_use(VARIABLE)
 375 # -------------------------------
 376 # Declare that VARIABLE was used.
 377 m4_define([b4_percent_define_use],
 378 [m4_define([b4_percent_define_bison_variables(]$1[)])dnl
 379 ])
 380
 381 # b4_percent_define_get(VARIABLE, [DEFAULT])
 382 # ------------------------------------------
 383 # Mimic muscle_percent_define_get in ../src/muscle-tab.h.  That is, if
 384 # the %define variable VARIABLE is defined, emit its value.  Contrary
 385 # to its C counterpart, return DEFAULT otherwise.  Also, record
 386 # Bison's usage of VARIABLE by defining
 387 # b4_percent_define_bison_variables(VARIABLE).
 388 #
 389 # For example:
 390 #
 391 #   b4_percent_define_get([[foo]])
 392 m4_define([b4_percent_define_get],
 393 [b4_percent_define_use([$1])dnl
 394 m4_ifdef([b4_percent_define(]$1[)],
 395          [m4_indir([b4_percent_define(]$1[)])],
 396          [$2])])
 397
 398
 399 # b4_percent_define_get_loc(VARIABLE)
 400 # -----------------------------------
 401 # Mimic muscle_percent_define_get_loc in ../src/muscle-tab.h exactly.  That is,
 402 # if the %define variable VARIABLE is undefined, complain fatally since that's
 403 # a Bison or skeleton error.  Otherwise, return its definition location in a
 404 # form approriate for the first two arguments of b4_warn_at, b4_complain_at, or
 405 # b4_fatal_at.  Don't record this as a Bison usage of VARIABLE as there's no
 406 # reason to suspect that the user-supplied value has yet influenced the output.
 407 #
 408 # For example:
 409 #
 410 #   b4_complain_at(b4_percent_define_get_loc([[foo]]), [[invalid foo]])
 411 m4_define([b4_percent_define_get_loc],
 412 [m4_ifdef([b4_percent_define_loc(]$1[)],
 413           [m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
 414 b4_loc[]dnl
 415 m4_popdef([b4_loc])],
 416           [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_get_loc]], [$1])])])
 417
 418 # b4_percent_define_get_syncline(VARIABLE)
 419 # ----------------------------------------
 420 # Mimic muscle_percent_define_get_syncline in ../src/muscle-tab.h exactly.
 421 # That is, if the %define variable VARIABLE is undefined, complain fatally
 422 # since that's a Bison or skeleton error.  Otherwise, return its definition
 423 # location as a b4_syncline invocation.  Don't record this as a Bison usage of
 424 # VARIABLE as there's no reason to suspect that the user-supplied value has yet
 425 # influenced the output.
 426 #
 427 # For example:
 428 #
 429 #   b4_percent_define_get_syncline([[foo]])
 430 m4_define([b4_percent_define_get_syncline],
 431 [m4_ifdef([b4_percent_define_syncline(]$1[)],
 432           [m4_indir([b4_percent_define_syncline(]$1[)])],
 433           [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_get_syncline]], [$1])])])
 434
 435 # b4_percent_define_ifdef(VARIABLE, IF-TRUE, [IF-FALSE])
 436 # ------------------------------------------------------
 437 # Mimic muscle_percent_define_ifdef in ../src/muscle-tab.h exactly.  That is,
 438 # if the %define variable VARIABLE is defined, expand IF-TRUE, else expand
 439 # IF-FALSE.  Also, record Bison's usage of VARIABLE by defining
 440 # b4_percent_define_bison_variables(VARIABLE).
 441 #
 442 # For example:
 443 #
 444 #   b4_percent_define_ifdef([[foo]], [[it's defined]], [[it's undefined]])
 445 m4_define([b4_percent_define_ifdef],
 446 [m4_ifdef([b4_percent_define(]$1[)],
 447           [m4_define([b4_percent_define_bison_variables(]$1[)])$2],
 448           [$3])])
 449
 450 # b4_percent_define_flag_if(VARIABLE, IF-TRUE, [IF-FALSE])
 451 # --------------------------------------------------------
 452 # Mimic muscle_percent_define_flag_if in ../src/muscle-tab.h exactly.  That is,
 453 # if the %define variable VARIABLE is defined to "" or "true", expand IF-TRUE.
 454 # If it is defined to "false", expand IF-FALSE.  Complain if it is undefined
 455 # (a Bison or skeleton error since the default value should have been set
 456 # already) or defined to any other value (possibly a user error).  Also, record
 457 # Bison's usage of VARIABLE by defining
 458 # b4_percent_define_bison_variables(VARIABLE).
 459 #
 460 # For example:
 461 #
 462 #   b4_percent_define_flag_if([[foo]], [[it's true]], [[it's false]])
 463 m4_define([b4_percent_define_flag_if],
 464 [b4_percent_define_ifdef([$1],
 465   [m4_case(b4_percent_define_get([$1]),
 466            [], [$2], [true], [$2], [false], [$3],
 467            [m4_expand_once([b4_complain_at(b4_percent_define_get_loc([$1]),
 468                                            [[invalid value for %%define Boolean variable `%s']],
 469                                            [$1])],
 470                            [[b4_percent_define_flag_if($1)]])])],
 471   [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_flag_if]], [$1])])])
 472
 473 # b4_percent_define_default(VARIABLE, DEFAULT)
 474 # --------------------------------------------
 475 # Mimic muscle_percent_define_default in ../src/muscle-tab.h exactly.  That is,
 476 # if the %define variable VARIABLE is undefined, set its value to DEFAULT.
 477 # Don't record this as a Bison usage of VARIABLE as there's no reason to
 478 # suspect that the value has yet influenced the output.
 479 #
 480 # For example:
 481 #
 482 #   b4_percent_define_default([[foo]], [[default value]])
 483 m4_define([b4_percent_define_default],
 484 [m4_ifndef([b4_percent_define(]$1[)],
 485            [m4_define([b4_percent_define(]$1[)], [$2])dnl
 486             m4_define([b4_percent_define_loc(]$1[)],
 487                       [[[[<skeleton default value>:-1.-1]],
 488                         [[<skeleton default value>:-1.-1]]]])dnl
 489             m4_define([b4_percent_define_syncline(]$1[)], [[]])])])
 490
 491 # b4_percent_define_check_values(VALUES)
 492 # --------------------------------------
 493 # Mimic muscle_percent_define_check_values in ../src/muscle-tab.h exactly
 494 # except that the VALUES structure is more appropriate for M4.  That is, VALUES
 495 # is a list of sublists of strings.  For each sublist, the first string is the
 496 # name of a %define variable, and all remaining strings in that sublist are the
 497 # valid values for that variable.  Complain if such a variable is undefined (a
 498 # Bison error since the default value should have been set already) or defined
 499 # to any other value (possibly a user error).  Don't record this as a Bison
 500 # usage of the variable as there's no reason to suspect that the value has yet
 501 # influenced the output.
 502 #
 503 # For example:
 504 #
 505 #   b4_percent_define_check_values([[[[foo]], [[foo-value1]], [[foo-value2]]]],
 506 #                                  [[[[bar]], [[bar-value1]]]])
 507 m4_define([b4_percent_define_check_values],
 508 [m4_foreach([b4_sublist], m4_quote($@),
 509             [_b4_percent_define_check_values(b4_sublist)])])
 510
 511 m4_define([_b4_percent_define_check_values],
 512 [m4_ifdef([b4_percent_define(]$1[)],
 513   [m4_pushdef([b4_good_value], [0])dnl
 514    m4_if($#, 1, [],
 515          [m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 516                      [m4_if(m4_indir([b4_percent_define(]$1[)]), b4_value,
 517                             [m4_define([b4_good_value], [1])])])])dnl
 518    m4_if(b4_good_value, [0],
 519          [b4_complain_at(b4_percent_define_get_loc([$1]),
 520                          [[invalid value for %%define variable `%s': `%s']],
 521                          [$1],
 522                          m4_dquote(m4_indir([b4_percent_define(]$1[)])))
 523           m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 524                      [b4_complain_at(b4_percent_define_get_loc([$1]),
 525                                      [[accepted value: `%s']],
 526                                      m4_dquote(b4_value))])])dnl
 527    m4_popdef([b4_good_value])],
 528   [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_check_values]], [$1])])])
 529
 530 # b4_percent_code_get([QUALIFIER])
 531 # --------------------------------
 532 # If any %code blocks for QUALIFIER are defined, emit them beginning with a
 533 # comment and ending with synclines and a newline.  If QUALIFIER is not
 534 # specified or empty, do this for the unqualified %code blocks.  Also, record
 535 # Bison's usage of QUALIFIER (if specified) by defining
 536 # b4_percent_code_bison_qualifiers(QUALIFIER).
 537 #
 538 # For example, to emit any unqualified %code blocks followed by any %code
 539 # blocks for the qualifier foo:
 540 #
 541 #   b4_percent_code_get
 542 #   b4_percent_code_get([[foo]])
 543 m4_define([b4_percent_code_get],
 544 [m4_pushdef([b4_macro_name], [[b4_percent_code(]$1[)]])dnl
 545 m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])dnl
 546 m4_ifdef(b4_macro_name,
 547 [b4_comment([m4_if([$#], [0], [[Unqualified %code]],
 548                    [["%code ]$1["]])[ blocks.]])
 549 b4_user_code([m4_indir(b4_macro_name)])
 550 ])dnl
 551 m4_popdef([b4_macro_name])])
 552
 553 # b4_percent_code_ifdef(QUALIFIER, IF-TRUE, [IF-FALSE])
 554 # -----------------------------------------------------
 555 # If any %code blocks for QUALIFIER (or unqualified %code blocks if
 556 # QUALIFIER is empty) are defined, expand IF-TRUE, else expand IF-FALSE.
 557 # Also, record Bison's usage of QUALIFIER (if specified) by defining
 558 # b4_percent_code_bison_qualifiers(QUALIFIER).
 559 m4_define([b4_percent_code_ifdef],
 560 [m4_ifdef([b4_percent_code(]$1[)],
 561           [m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])$2],
 562           [$3])])
 563
 564
 565 ## ----------------------------------------------------------- ##
 566 ## After processing the skeletons, check that all the user's   ##
 567 ## %define variables and %code qualifiers were used by Bison.  ##
 568 ## ----------------------------------------------------------- ##
 569
 570 m4_define([b4_check_user_names_wrap],
 571 [m4_ifdef([b4_percent_]$1[_user_]$2[s],
 572           [b4_check_user_names([[%]$1 $2],
 573                                [b4_percent_]$1[_user_]$2[s],
 574                                [[b4_percent_]$1[_bison_]$2[s]])])])
 575
 576 m4_wrap_lifo([
 577 b4_check_user_names_wrap([[define]], [[variable]])
 578 b4_check_user_names_wrap([[code]], [[qualifier]])
 579 ])