src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007 Free Software Foundation,
   4    Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software; you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation; either version 2 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program; if not, write to the Free Software
  20    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21    02110-1301  USA
  22 */
  23
  24 #include <config.h>
  25 #include "system.h"
  26
  27 #include <strverscmp.h>
  28
  29 #include "complain.h"
  30 #include "conflicts.h"
  31 #include "files.h"
  32 #include "getargs.h"
  33 #include "gram.h"
  34 #include "muscle_tab.h"
  35 #include "quotearg.h"
  36 #include "reader.h"
  37 #include "symlist.h"
  38 #include "scan-gram.h"
  39 #include "scan-code.h"
  40
  41 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  42 static YYLTYPE lloc_default (YYLTYPE const *, int);
  43
  44 #define YY_LOCATION_PRINT(File, Loc) \
  45           location_print (File, Loc)
  46
  47 static void version_check (location const *loc, char const *version);
  48
  49 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  50    FIXME: depends on the undocumented availability of YYLLOC.  */
  51 #undef  yyerror
  52 #define yyerror(Msg) \
  53         gram_error (&yylloc, Msg)
  54 static void gram_error (location const *, char const *);
  55
  56 static char const *char_name (char);
  57
  58 /** Add a lex-param or a parse-param.
  59  *
  60  * \param type  \a lex_param or \a parse_param
  61  * \param decl  the formal argument
  62  * \param loc   the location in the source.
  63  */
  64 static void add_param (char const *type, char *decl, location loc);
  65
  66
  67 static symbol_class current_class = unknown_sym;
  68 static uniqstr current_type = NULL;
  69 static symbol *current_lhs;
  70 static location current_lhs_location;
  71 static int current_prec = 0;
  72
  73 #define YYTYPE_INT16 int_fast16_t
  74 #define YYTYPE_INT8 int_fast8_t
  75 #define YYTYPE_UINT16 uint_fast16_t
  76 #define YYTYPE_UINT8 uint_fast8_t
  77 %}
  78
  79 %debug
  80 %verbose
  81 %defines
  82 %locations
  83 %pure-parser
  84 %error-verbose
  85 %name-prefix="gram_"
  86 %expect 0
  87
  88 %initial-action
  89 {
  90   /* Bison's grammar can initial empty locations, hence a default
  91      location is needed. */
  92   boundary_set (&@$.start, current_file, 1, 1);
  93   boundary_set (&@$.end, current_file, 1, 1);
  94 }
  95
  96 %union
  97 {
  98   symbol *symbol;
  99   symbol_list *list;
 100   int integer;
 101   char const *chars;
 102   char *code;
 103   assoc assoc;
 104   uniqstr uniqstr;
 105   unsigned char character;
 106 };
 107
 108 /* Define the tokens together with their human representation.  */
 109 %token GRAM_EOF 0 "end of file"
 110 %token STRING     "string"
 111 %token INT        "integer"
 112
 113 %token PERCENT_TOKEN       "%token"
 114 %token PERCENT_NTERM       "%nterm"
 115
 116 %token PERCENT_TYPE        "%type"
 117 %token PERCENT_DESTRUCTOR  "%destructor"
 118 %token PERCENT_PRINTER     "%printer"
 119
 120 %token PERCENT_LEFT        "%left"
 121 %token PERCENT_RIGHT       "%right"
 122 %token PERCENT_NONASSOC    "%nonassoc"
 123
 124 %token PERCENT_PREC          "%prec"
 125 %token PERCENT_DPREC         "%dprec"
 126 %token PERCENT_MERGE         "%merge"
 127
 128
 129 /*----------------------.
 130 | Global Declarations.  |
 131 `----------------------*/
 132
 133 %token
 134   PERCENT_CODE            "%code"
 135   PERCENT_DEBUG           "%debug"
 136   PERCENT_DEFAULT_PREC    "%default-prec"
 137   PERCENT_DEFINE          "%define"
 138   PERCENT_DEFINES         "%defines"
 139   PERCENT_ERROR_VERBOSE   "%error-verbose"
 140   PERCENT_EXPECT          "%expect"
 141   PERCENT_EXPECT_RR       "%expect-rr"
 142   PERCENT_FILE_PREFIX     "%file-prefix"
 143   PERCENT_GLR_PARSER      "%glr-parser"
 144   PERCENT_INITIAL_ACTION  "%initial-action"
 145   PERCENT_LANGUAGE        "%language"
 146   PERCENT_LEX_PARAM       "%lex-param"
 147   PERCENT_LOCATIONS       "%locations"
 148   PERCENT_NAME_PREFIX     "%name-prefix"
 149   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 150   PERCENT_NO_LINES        "%no-lines"
 151   PERCENT_NONDETERMINISTIC_PARSER
 152                           "%nondeterministic-parser"
 153   PERCENT_OUTPUT          "%output"
 154   PERCENT_PARSE_PARAM     "%parse-param"
 155   PERCENT_PURE_PARSER     "%pure-parser"
 156   PERCENT_PUSH_PARSER     "%push-parser"
 157   PERCENT_PUSH_PULL_PARSER
 158                           "%push-pull-parser"
 159   PERCENT_REQUIRE         "%require"
 160   PERCENT_SKELETON        "%skeleton"
 161   PERCENT_START           "%start"
 162   PERCENT_TOKEN_TABLE     "%token-table"
 163   PERCENT_VERBOSE         "%verbose"
 164   PERCENT_YACC            "%yacc"
 165 ;
 166
 167 %token BRACED_CODE     "{...}"
 168 %token CHAR            "char"
 169 %token EPILOGUE        "epilogue"
 170 %token EQUAL           "="
 171 %token ID              "identifier"
 172 %token ID_COLON        "identifier:"
 173 %token PERCENT_PERCENT "%%"
 174 %token PIPE            "|"
 175 %token PROLOGUE        "%{...%}"
 176 %token SEMICOLON       ";"
 177 %token TYPE            "type"
 178 %token TYPE_TAG_ANY    "<*>"
 179 %token TYPE_TAG_NONE   "<>"
 180
 181 %type <character> CHAR
 182 %printer { fputs (char_name ($$), stderr); } CHAR
 183
 184 /* braceless is not to be used for rule or symbol actions, as it
 185    calls code_props_plain_init.  */
 186 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 187 %type <code> "{...}"
 188 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 189          STRING
 190 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 191          braceless content.opt "{...}" "%{...%}" EPILOGUE
 192
 193 %type <uniqstr> TYPE ID ID_COLON variable
 194 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 195 %printer { fputs ($$, stderr); } ID variable
 196 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 197
 198 %type <integer> INT
 199 %printer { fprintf (stderr, "%d", $$); } INT
 200
 201 %type <symbol> id id_colon symbol string_as_id
 202 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 203 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 204
 205 %type <assoc> precedence_declarator
 206 %type <list>  symbols.1 generic_symlist generic_symlist_item
 207 %%
 208
 209 input:
 210   prologue_declarations "%%" grammar epilogue.opt
 211 ;
 212
 213
 214         /*------------------------------------.
 215         | Declarations: before the first %%.  |
 216         `------------------------------------*/
 217
 218 prologue_declarations:
 219   /* Nothing */
 220 | prologue_declarations prologue_declaration
 221 ;
 222
 223 prologue_declaration:
 224   grammar_declaration
 225 | "%{...%}"
 226     {
 227       code_props plain_code;
 228       code_props_plain_init (&plain_code, $1, @1);
 229       code_props_translate_code (&plain_code);
 230       gram_scanner_last_string_free ();
 231       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 232                         plain_code.code, @1);
 233       code_scanner_last_string_free ();
 234     }
 235 | "%debug"                         { debug_flag = true; }
 236 | "%define" variable content.opt
 237     {
 238       char const name_prefix[] = "percent_define_";
 239       char *name = xmalloc (sizeof name_prefix + strlen ($2));
 240       strcpy (name, name_prefix);
 241       strcpy (name + sizeof name_prefix - 1, $2);
 242       if (muscle_find_const (name))
 243         warn_at (@2, _("%s `%s' redefined"), "%define variable", $2);
 244       MUSCLE_INSERT_STRING (uniqstr_new (name), $3);
 245       free (name);
 246       muscle_grow_user_name_list ("user_percent_define_variables", $2, @2);
 247     }
 248 | "%defines"                       { defines_flag = true; }
 249 | "%defines" STRING
 250     {
 251       defines_flag = true;
 252       spec_defines_file = xstrdup ($2);
 253     }
 254 | "%error-verbose"                 { error_verbose = true; }
 255 | "%expect" INT                    { expected_sr_conflicts = $2; }
 256 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 257 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 258 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 259 | "%glr-parser"
 260     {
 261       nondeterministic_parser = true;
 262       glr_parser = true;
 263     }
 264 | "%initial-action" "{...}"
 265     {
 266       code_props action;
 267       code_props_symbol_action_init (&action, $2, @2);
 268       code_props_translate_code (&action);
 269       gram_scanner_last_string_free ();
 270       muscle_code_grow ("initial_action", action.code, @2);
 271       code_scanner_last_string_free ();
 272     }
 273 | "%language" STRING            { language_argmatch ($2, 1, &@1); }
 274 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 275 | "%locations"                  { locations_flag = true; }
 276 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 277 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 278 | "%no-lines"                   { no_lines_flag = true; }
 279 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 280 | "%output" STRING              { spec_outfile = $2; }
 281 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 282 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 283 | "%pure-parser"                { pure_parser = true; }
 284 | "%push-parser"                { push_parser = true; pull_parser = false; }
 285 | "%push-pull-parser"           { push_parser = true; pull_parser = true; }
 286 | "%require" STRING             { version_check (&@2, $2); }
 287 | "%skeleton" STRING            { skeleton_arg ($2, 1, &@1); }
 288 | "%token-table"                { token_table_flag = true; }
 289 | "%verbose"                    { report_flag = report_states; }
 290 | "%yacc"                       { yacc_flag = true; }
 291 | /*FIXME: Err?  What is this horror doing here? */ ";"
 292 ;
 293
 294 grammar_declaration:
 295   precedence_declaration
 296 | symbol_declaration
 297 | "%start" symbol
 298     {
 299       grammar_start_symbol_set ($2, @2);
 300     }
 301 | "%destructor" "{...}" generic_symlist
 302     {
 303       symbol_list *list;
 304       for (list = $3; list; list = list->next)
 305         symbol_list_destructor_set (list, $2, @2);
 306       symbol_list_free ($3);
 307     }
 308 | "%printer" "{...}" generic_symlist
 309     {
 310       symbol_list *list;
 311       for (list = $3; list; list = list->next)
 312         symbol_list_printer_set (list, $2, @2);
 313       symbol_list_free ($3);
 314     }
 315 | "%default-prec"
 316     {
 317       default_prec = true;
 318     }
 319 | "%no-default-prec"
 320     {
 321       default_prec = false;
 322     }
 323 | "%code" braceless
 324     {
 325       muscle_code_grow ("percent_code", $2, @2);
 326       code_scanner_last_string_free ();
 327     }
 328 | "%code" ID braceless
 329     {
 330       char const name_prefix[] = "percent_code_";
 331       char *name = xmalloc (sizeof name_prefix + strlen ($2));
 332       strcpy (name, name_prefix);
 333       strcpy (name + sizeof name_prefix - 1, $2);
 334       muscle_code_grow (uniqstr_new (name), $3, @3);
 335       free (name);
 336       code_scanner_last_string_free ();
 337       muscle_grow_user_name_list ("user_percent_code_qualifiers", $2, @2);
 338     }
 339 ;
 340
 341
 342 /*----------*
 343  | %union.  |
 344  *----------*/
 345
 346 %token PERCENT_UNION "%union";
 347
 348 union_name:
 349   /* Nothing. */ {}
 350 | ID             { muscle_code_grow ("union_name", $1, @1); }
 351 ;
 352
 353 grammar_declaration:
 354   "%union" union_name braceless
 355     {
 356       union_seen = true;
 357       muscle_code_grow ("stype", $3, @3);
 358       code_scanner_last_string_free ();
 359     }
 360 ;
 361
 362
 363
 364
 365 symbol_declaration:
 366   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 367     {
 368       current_class = unknown_sym;
 369       current_type = NULL;
 370     }
 371 | "%token" { current_class = token_sym; } symbol_defs.1
 372     {
 373       current_class = unknown_sym;
 374       current_type = NULL;
 375     }
 376 | "%type" TYPE symbols.1
 377     {
 378       symbol_list *list;
 379       tag_seen = true;
 380       for (list = $3; list; list = list->next)
 381         symbol_type_set (list->content.sym, $2, @2);
 382       symbol_list_free ($3);
 383     }
 384 ;
 385
 386 precedence_declaration:
 387   precedence_declarator type.opt symbols.1
 388     {
 389       symbol_list *list;
 390       ++current_prec;
 391       for (list = $3; list; list = list->next)
 392         {
 393           symbol_type_set (list->content.sym, current_type, @2);
 394           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 395         }
 396       symbol_list_free ($3);
 397       current_type = NULL;
 398     }
 399 ;
 400
 401 precedence_declarator:
 402   "%left"     { $$ = left_assoc; }
 403 | "%right"    { $$ = right_assoc; }
 404 | "%nonassoc" { $$ = non_assoc; }
 405 ;
 406
 407 type.opt:
 408   /* Nothing. */ { current_type = NULL; }
 409 | TYPE           { current_type = $1; tag_seen = true; }
 410 ;
 411
 412 /* One or more symbols to be %typed. */
 413 symbols.1:
 414   symbol
 415     { $$ = symbol_list_sym_new ($1, @1); }
 416 | symbols.1 symbol
 417     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 418 ;
 419
 420 generic_symlist:
 421   generic_symlist_item { $$ = $1; }
 422 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 423 ;
 424
 425 generic_symlist_item:
 426   symbol            { $$ = symbol_list_sym_new ($1, @1); }
 427 | TYPE              { $$ = symbol_list_type_new ($1, @1); }
 428 | "<*>"             { $$ = symbol_list_default_tagged_new (@1); }
 429 | "<>"             { $$ = symbol_list_default_tagless_new (@1); }
 430 ;
 431
 432 /* One token definition.  */
 433 symbol_def:
 434   TYPE
 435      {
 436        current_type = $1;
 437        tag_seen = true;
 438      }
 439 | id
 440      {
 441        symbol_class_set ($1, current_class, @1, true);
 442        symbol_type_set ($1, current_type, @1);
 443      }
 444 | id INT
 445     {
 446       symbol_class_set ($1, current_class, @1, true);
 447       symbol_type_set ($1, current_type, @1);
 448       symbol_user_token_number_set ($1, $2, @2);
 449     }
 450 | id string_as_id
 451     {
 452       symbol_class_set ($1, current_class, @1, true);
 453       symbol_type_set ($1, current_type, @1);
 454       symbol_make_alias ($1, $2, @$);
 455     }
 456 | id INT string_as_id
 457     {
 458       symbol_class_set ($1, current_class, @1, true);
 459       symbol_type_set ($1, current_type, @1);
 460       symbol_user_token_number_set ($1, $2, @2);
 461       symbol_make_alias ($1, $3, @$);
 462     }
 463 ;
 464
 465 /* One or more symbol definitions. */
 466 symbol_defs.1:
 467   symbol_def
 468 | symbol_defs.1 symbol_def
 469 ;
 470
 471
 472         /*------------------------------------------.
 473         | The grammar section: between the two %%.  |
 474         `------------------------------------------*/
 475
 476 grammar:
 477   rules_or_grammar_declaration
 478 | grammar rules_or_grammar_declaration
 479 ;
 480
 481 /* As a Bison extension, one can use the grammar declarations in the
 482    body of the grammar.  */
 483 rules_or_grammar_declaration:
 484   rules
 485 | grammar_declaration ";"
 486 | error ";"
 487     {
 488       yyerrok;
 489     }
 490 ;
 491
 492 rules:
 493   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 494 ;
 495
 496 rhses.1:
 497   rhs                { grammar_current_rule_end (@1); }
 498 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 499 | rhses.1 ";"
 500 ;
 501
 502 rhs:
 503   /* Nothing.  */
 504     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 505 | rhs symbol
 506     { grammar_current_rule_symbol_append ($2, @2); }
 507 | rhs "{...}"
 508     { grammar_current_rule_action_append ($2, @2); }
 509 | rhs "%prec" symbol
 510     { grammar_current_rule_prec_set ($3, @3); }
 511 | rhs "%dprec" INT
 512     { grammar_current_rule_dprec_set ($3, @3); }
 513 | rhs "%merge" TYPE
 514     { grammar_current_rule_merge_set ($3, @3); }
 515 ;
 516
 517
 518 /*----------------------------*
 519  | variable and content.opt.  |
 520  *---------------------------*/
 521
 522 variable:
 523   ID
 524   | STRING { $$ = uniqstr_new ($1); } /* deprecated and not M4-friendly */
 525   ;
 526
 527 /* Some content or "1" by default. */
 528 content.opt:
 529   /* Nothing. */
 530     {
 531       static char one[] = "1";
 532       $$ = one;
 533     }
 534 | STRING
 535 ;
 536
 537
 538 /*-------------*
 539  | braceless.  |
 540  *-------------*/
 541
 542 braceless:
 543   "{...}"
 544     {
 545       code_props plain_code;
 546       $1[strlen ($1) - 1] = '\n';
 547       code_props_plain_init (&plain_code, $1+1, @1);
 548       code_props_translate_code (&plain_code);
 549       gram_scanner_last_string_free ();
 550       $$ = plain_code.code;
 551     }
 552 ;
 553
 554
 555 /*---------------*
 556  | Identifiers.  |
 557  *---------------*/
 558
 559 /* Identifiers are returned as uniqstr values by the scanner.
 560    Depending on their use, we may need to make them genuine symbols.  */
 561
 562 id:
 563   ID
 564     { $$ = symbol_from_uniqstr ($1, @1); }
 565 | CHAR
 566     {
 567       $$ = symbol_get (char_name ($1), @1);
 568       symbol_class_set ($$, token_sym, @1, false);
 569       symbol_user_token_number_set ($$, $1, @1);
 570     }
 571 ;
 572
 573 id_colon:
 574   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 575 ;
 576
 577
 578 symbol:
 579   id
 580 | string_as_id
 581 ;
 582
 583 /* A string used as an ID: quote it.  */
 584 string_as_id:
 585   STRING
 586     {
 587       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 588       symbol_class_set ($$, token_sym, @1, false);
 589     }
 590 ;
 591
 592 epilogue.opt:
 593   /* Nothing.  */
 594 | "%%" EPILOGUE
 595     {
 596       code_props plain_code;
 597       code_props_plain_init (&plain_code, $2, @2);
 598       code_props_translate_code (&plain_code);
 599       gram_scanner_last_string_free ();
 600       muscle_code_grow ("epilogue", plain_code.code, @2);
 601       code_scanner_last_string_free ();
 602     }
 603 ;
 604
 605 %%
 606
 607
 608 /* Return the location of the left-hand side of a rule whose
 609    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 610    the right-hand side, and return an empty location equal to the end
 611    boundary of RHS[0] if the right-hand side is empty.  */
 612
 613 static YYLTYPE
 614 lloc_default (YYLTYPE const *rhs, int n)
 615 {
 616   int i;
 617   YYLTYPE loc;
 618
 619   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 620      The bug is fixed in 7.4.2m, but play it safe for now.  */
 621   loc.start = rhs[n].end;
 622   loc.end = rhs[n].end;
 623
 624   /* Ignore empty nonterminals the start of the the right-hand side.
 625      Do not bother to ignore them at the end of the right-hand side,
 626      since empty nonterminals have the same end as their predecessors.  */
 627   for (i = 1; i <= n; i++)
 628     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 629       {
 630         loc.start = rhs[i].start;
 631         break;
 632       }
 633
 634   return loc;
 635 }
 636
 637
 638 /* Add a lex-param or a parse-param (depending on TYPE) with
 639    declaration DECL and location LOC.  */
 640
 641 static void
 642 add_param (char const *type, char *decl, location loc)
 643 {
 644   static char const alphanum[26 + 26 + 1 + 10] =
 645     "abcdefghijklmnopqrstuvwxyz"
 646     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 647     "_"
 648     "0123456789";
 649   char const *name_start = NULL;
 650   char *p;
 651
 652   /* Stop on last actual character.  */
 653   for (p = decl; p[1]; p++)
 654     if ((p == decl
 655          || ! memchr (alphanum, p[-1], sizeof alphanum))
 656         && memchr (alphanum, p[0], sizeof alphanum - 10))
 657       name_start = p;
 658
 659   /* Strip the surrounding '{' and '}', and any blanks just inside
 660      the braces.  */
 661   while (*--p == ' ' || *p == '\t')
 662     continue;
 663   p[1] = '\0';
 664   while (*++decl == ' ' || *decl == '\t')
 665     continue;
 666
 667   if (! name_start)
 668     complain_at (loc, _("missing identifier in parameter declaration"));
 669   else
 670     {
 671       char *name;
 672       size_t name_len;
 673
 674       for (name_len = 1;
 675            memchr (alphanum, name_start[name_len], sizeof alphanum);
 676            name_len++)
 677         continue;
 678
 679       name = xmalloc (name_len + 1);
 680       memcpy (name, name_start, name_len);
 681       name[name_len] = '\0';
 682       muscle_pair_list_grow (type, decl, name);
 683       free (name);
 684     }
 685
 686   gram_scanner_last_string_free ();
 687 }
 688
 689
 690 static void
 691 version_check (location const *loc, char const *version)
 692 {
 693   if (strverscmp (version, PACKAGE_VERSION) > 0)
 694     {
 695       complain_at (*loc, "require bison %s, but have %s",
 696                    version, PACKAGE_VERSION);
 697       exit (63);
 698     }
 699 }
 700
 701 static void
 702 gram_error (location const *loc, char const *msg)
 703 {
 704   complain_at (*loc, "%s", msg);
 705 }
 706
 707 char const *
 708 token_name (int type)
 709 {
 710   return yytname[YYTRANSLATE (type)];
 711 }
 712
 713 static char const *
 714 char_name (char c)
 715 {
 716   if (c == '\'')
 717     return "'\\''";
 718   else
 719     {
 720       char buf[4];
 721       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 722       return quotearg_style (escape_quoting_style, buf);
 723     }
 724 }