data/bison.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Language-independent M4 Macros for Bison.
   4 # Copyright (C) 2002, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  19 # 02110-1301  USA
  20
  21
  22 ## ---------------- ##
  23 ## Identification.  ##
  24 ## ---------------- ##
  25
  26 # b4_copyright(TITLE, YEARS)
  27 # --------------------------
  28 m4_define([b4_copyright],
  29 [b4_comment([A Bison parser, made by GNU Bison b4_version.])
  30
  31 b4_comment([$1
  32
  33 m4_text_wrap([Copyright (C) $2 Free Software Foundation, Inc.], [   ])
  34
  35 This program is free software; you can redistribute it and/or modify
  36 it under the terms of the GNU General Public License as published by
  37 the Free Software Foundation; either version 2, or (at your option)
  38 any later version.
  39
  40 This program is distributed in the hope that it will be useful,
  41 but WITHOUT ANY WARRANTY; without even the implied warranty of
  42 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  43 GNU General Public License for more details.
  44
  45 You should have received a copy of the GNU General Public License
  46 along with this program; if not, write to the Free Software
  47 Foundation, Inc., 51 Franklin Street, Fifth Floor,
  48 Boston, MA 02110-1301, USA.])
  49
  50 b4_comment([As a special exception, you may create a larger work that contains
  51 part or all of the Bison parser skeleton and distribute that work
  52 under terms of your choice, so long as that work isn't itself a
  53 parser generator using the skeleton or a modified version thereof
  54 as a parser skeleton.  Alternatively, if you modify or redistribute
  55 the parser skeleton itself, you may (at your option) remove this
  56 special exception, which will cause the skeleton and the resulting
  57 Bison output files to be licensed under the GNU General Public
  58 License without this special exception.
  59
  60 This special exception was added by the Free Software Foundation in
  61 version 2.2 of Bison.])])
  62
  63
  64 ## ---------------- ##
  65 ## Error handling.  ##
  66 ## ---------------- ##
  67
  68 # b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
  69 # -------------------------------------------
  70 # Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
  71 m4_define([b4_error],
  72 [m4_divert_push(0)[@]$1[(]$2[]m4_if([$#], [2], [],
  73 [m4_foreach([b4_arg],
  74             m4_dquote(m4_shift(m4_shift($@))),
  75             [[@,]b4_arg])])[@)]m4_divert_pop(0)])
  76
  77 # b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
  78 # ----------------------------------------------------------
  79 # Write @KIND(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
  80 m4_define([b4_error_at],
  81 [m4_divert_push(0)[@]$1[_at(]$2[@,]$3[@,]$4[]m4_if([$#], [4], [],
  82 [m4_foreach([b4_arg],
  83             m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
  84             [[@,]b4_arg])])[@)]m4_divert_pop(0)])
  85
  86 # b4_warn(FORMAT, [ARG1], [ARG2], ...)
  87 # ------------------------------------
  88 # Write @warn(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
  89 #
  90 # As a simple test suite, this:
  91 #
  92 #   m4_define([asdf], [ASDF])
  93 #   m4_define([fsa], [FSA])
  94 #   m4_define([fdsa], [FDSA])
  95 #   b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
  96 #   m4_divert(0)
  97 #   b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
  98 #   m4_divert(0)
  99 #   b4_warn([asdf), asdf], [fsa), fsa], [fdsa), fdsa])
 100 #   m4_divert(0)
 101 #   b4_warn()
 102 #   m4_divert(0)
 103 #   b4_warn(1)
 104 #   m4_divert(0)
 105 #   b4_warn(1, 2)
 106 #
 107 # Should produce this:
 108 #
 109 #   @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
 110 #   @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
 111 #   @warn(ASDF), ASDF@,FSA), FSA@,FDSA), FDSA@)
 112 #   @warn(@)
 113 #   @warn(1@)
 114 #   @warn(1@,2@)
 115 m4_define([b4_warn],
 116 [b4_error([[warn]], $@)])
 117
 118 # b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 119 # ---------------------------------------------------
 120 # Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
 121 m4_define([b4_warn_at],
 122 [b4_error_at([[warn]], $@)])
 123
 124 # b4_complain(FORMAT, [ARG1], [ARG2], ...)
 125 # ----------------------------------------
 126 # Write @complain(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
 127 #
 128 # See the test suite for b4_warn above.
 129 m4_define([b4_complain],
 130 [b4_error([[complain]], $@)])
 131
 132 # b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 133 # -------------------------------------------------------
 134 # Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
 135 m4_define([b4_complain_at],
 136 [b4_error_at([[complain]], $@)])
 137
 138 # b4_fatal(FORMAT, [ARG1], [ARG2], ...)
 139 # -------------------------------------
 140 # Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
 141 #
 142 # See the test suite for b4_warn above.
 143 m4_define([b4_fatal],
 144 [b4_error([[fatal]], $@)])
 145
 146 # b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 147 # ----------------------------------------------------
 148 # Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
 149 m4_define([b4_fatal_at],
 150 [b4_error_at([[fatal]], $@)])
 151
 152
 153 ## ---------------- ##
 154 ## Default values.  ##
 155 ## ---------------- ##
 156
 157 # m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
 158 m4_define_default([b4_epilogue], [])
 159 m4_define_default([b4_parse_param], [])
 160
 161 # The initial column and line.
 162 m4_define_default([b4_location_initial_column], [1])
 163 m4_define_default([b4_location_initial_line],   [1])
 164
 165
 166 ## ------------ ##
 167 ## Data Types.  ##
 168 ## ------------ ##
 169
 170 # b4_ints_in(INT1, INT2, LOW, HIGH)
 171 # ---------------------------------
 172 # Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
 173 m4_define([b4_ints_in],
 174 [m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
 175
 176
 177
 178 ## ------------------ ##
 179 ## Decoding options.  ##
 180 ## ------------------ ##
 181
 182 # b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
 183 # -----------------------------------
 184 # Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
 185 m4_define([b4_flag_if],
 186 [m4_case(b4_$1_flag,
 187          [0], [$3],
 188          [1], [$2],
 189          [m4_fatal([invalid $1 value: ]$1)])])
 190
 191
 192 # b4_define_flag_if(FLAG)
 193 # -----------------------
 194 # Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
 195 # value of the Boolean FLAG.
 196 m4_define([b4_define_flag_if],
 197 [_b4_define_flag_if($[1], $[2], [$1])])
 198
 199 # _b4_define_flag_if($1, $2, FLAG)
 200 # --------------------------------
 201 # This macro works around the impossibility to define macros
 202 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 203 # This sucks hard, GNU M4 should really provide M5 like $$1.
 204 m4_define([_b4_define_flag_if],
 205 [m4_if([$1$2], $[1]$[2], [],
 206        [m4_fatal([$0: Invalid arguments: $@])])dnl
 207 m4_define([b4_$3_if],
 208           [b4_flag_if([$3], [$1], [$2])])])
 209
 210
 211 # b4_FLAG_if(IF-TRUE, IF-FALSE)
 212 # -----------------------------
 213 # Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
 214 b4_define_flag_if([defines])            # Whether headers are requested.
 215 b4_define_flag_if([error_verbose])      # Whether error are verbose.
 216 b4_define_flag_if([glr])                # Whether a GLR parser is requested.
 217 b4_define_flag_if([locations])          # Whether locations are tracked.
 218 b4_define_flag_if([nondeterministic])   # Whether conflicts should be handled.
 219 b4_define_flag_if([pull])               # Whether pull parsing is requested.
 220 b4_define_flag_if([pure])               # Whether the interface is pure.
 221 b4_define_flag_if([push])               # Whether push parsing is requested.
 222 b4_define_flag_if([use_push_for_pull])  # Whether push parsing should be used
 223                                         # in place of pull parsing (where
 224                                         # available) for the sake of the test
 225                                         # suite.
 226 b4_define_flag_if([yacc])               # Whether POSIX Yacc is emulated.
 227
 228
 229 ## ------------------------- ##
 230 ## Assigning token numbers.  ##
 231 ## ------------------------- ##
 232
 233
 234 ## ----------- ##
 235 ## Synclines.  ##
 236 ## ----------- ##
 237
 238 # b4_basename(NAME)
 239 # -----------------
 240 # Similar to POSIX basename; the differences don't matter here.
 241 # Beware that NAME is not evaluated.
 242 m4_define([b4_basename],
 243 [m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
 244
 245
 246 # b4_syncline(LINE, FILE)
 247 # -----------------------
 248 m4_define([b4_syncline],
 249 [b4_flag_if([synclines], [
 250 b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
 251 b4_sync_start([$1], [$2])])])
 252
 253 m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
 254 m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
 255
 256 # b4_user_code(USER-CODE)
 257 # -----------------------
 258 # Emit code from the user, ending it with synclines.
 259 m4_define([b4_user_code],
 260 [$1
 261 b4_syncline([@oline@], [@ofile@])])
 262
 263
 264 # b4_define_user_code(MACRO)
 265 # --------------------------
 266 # From b4_MACRO, build b4_user_MACRO that includes the synclines.
 267 m4_define([b4_define_user_code],
 268 [m4_define([b4_user_$1],
 269 [b4_user_code([b4_$1])])])
 270
 271
 272 # b4_user_actions
 273 # b4_user_initial_action
 274 # b4_user_post_prologue
 275 # b4_user_pre_prologue
 276 # b4_user_stype
 277 # ----------------------
 278 # Macros that issue user code, ending with synclines.
 279 b4_define_user_code([actions])
 280 b4_define_user_code([initial_action])
 281 b4_define_user_code([post_prologue])
 282 b4_define_user_code([pre_prologue])
 283 b4_define_user_code([stype])
 284
 285
 286 # b4_check_for_unrecognized_names(WHAT, LIST, [VALID_NAME], [VALID_NAME])
 287 # -----------------------------------------------------------------------
 288 # Complain if any name of type WHAT is used in the grammar (as recorded in
 289 # LIST) but is not a VALID_NAME.
 290 #
 291 # LIST must expand to a list specifying all grammar occurrences of all names of
 292 # type WHAT.   Each item in the list is a triplet specifying one occurrence:
 293 # name, start boundary, and end boundary.  Empty string names are fine.  An
 294 # empty list is fine.
 295 #
 296 # For example, to define b4_foo_list to be used for LIST with three name
 297 # occurrences and with correct quoting:
 298 #
 299 #   m4_define([b4_foo_list],
 300 #             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
 301 #               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
 302 #               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
 303 #
 304 # Each VALID_NAME must expand to a valid name of type WHAT.  Multiple
 305 # occurrences of the same valid name are fine.  A VALID_NAME that expands to
 306 # the empty string will correctly define the empty string as a valid name, but
 307 # it would be ugly for a Bison skeleton to actually use that.
 308 #
 309 # For example, to invoke b4_check_for_unrecognized_names with TYPE foo, with
 310 # LIST b4_foo_list, with two valid names, and with correct quoting:
 311 #
 312 #   b4_check_for_unrecognized_names([[foo]], [b4_foo_list],
 313 #                                   [[bar]], [[baz]])
 314 #
 315 # Names and valid names must not contain the character `,'.
 316 m4_define([b4_check_for_unrecognized_names],
 317 [m4_foreach([b4_occurrence],
 318             $2,
 319             [m4_pushdef([b4_occurrence], b4_occurrence)
 320              m4_pushdef([b4_name], m4_car(b4_occurrence))
 321              m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))
 322              m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))
 323              m4_if(m4_index(m4_if($#, 2, [],
 324                                   [[,]m4_quote(m4_shift(m4_shift($*)))[,]]),
 325                             [,]b4_name[,]),
 326                    [-1],
 327                    [b4_complain_at([b4_start], [b4_end],
 328                                    [[`%s' is not a recognized %s]],
 329                                    [b4_name], [$1])
 330                    ])
 331              m4_popdef([b4_occurrence])
 332              m4_popdef([b4_name])
 333              m4_popdef([b4_start])
 334              m4_popdef([b4_end])
 335             ])
 336 ])
 337
 338 # b4_check_percent_define_variables([VAILD_VARIABLE], [VALID_VARIABLE], ...)
 339 # --------------------------------------------------------------------------
 340 # Wrapper around b4_check_for_unrecognized_names for %define variables.
 341 #
 342 # b4_used_percent_define_variables must contain a list of all %define variables
 343 # used in the grammar similar to b4_foo_list from the
 344 # b4_check_for_unrecognized_names documentation's example.  If
 345 # b4_used_percent_define_variables is undefined, it's treated the same as an
 346 # empty list.
 347 #
 348 # Invoking b4_check_percent_define_variables with empty parens specifies one
 349 # valid variable that is an empty string.  Invoke it without parens to specify
 350 # that there are no valid variables.
 351 m4_define([b4_check_percent_define_variables],
 352 [m4_ifdef([b4_used_percent_define_variables],
 353 [b4_check_for_unrecognized_names([[%define variable]],
 354 [b4_used_percent_define_variables]m4_if([$#], [0], [], [, $@]))])])
 355
 356 # b4_check_percent_code_qualifiers([VAILD_QUALIFIER], [VALID_QUALIFIER], ...)
 357 # ---------------------------------------------------------------------------
 358 # Same as b4_check_percent_define_variables but for %code qualifiers using
 359 # b4_used_percent_code_qualifiers.
 360 m4_define([b4_check_percent_code_qualifiers],
 361 [m4_ifdef([b4_used_percent_code_qualifiers],
 362 [b4_check_for_unrecognized_names([[%code qualifier]],
 363 [b4_used_percent_code_qualifiers]m4_if([$#], [0], [], [, $@]))])])