src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002-2013 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software: you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation, either version 3 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  19
  20 #include <config.h>
  21 #include "system.h"
  22
  23 #include "c-ctype.h"
  24 #include "complain.h"
  25 #include "conflicts.h"
  26 #include "files.h"
  27 #include "getargs.h"
  28 #include "gram.h"
  29 #include "muscle-tab.h"
  30 #include "named-ref.h"
  31 #include "quotearg.h"
  32 #include "reader.h"
  33 #include "symlist.h"
  34 #include "symtab.h"
  35 #include "scan-gram.h"
  36 #include "scan-code.h"
  37 #include "xmemdup0.h"
  38
  39 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  40 static YYLTYPE lloc_default (YYLTYPE const *, int);
  41
  42 #define YY_LOCATION_PRINT(File, Loc) \
  43           location_print (Loc, File)
  44
  45 static void version_check (location const *loc, char const *version);
  46
  47 static void gram_error (location const *, char const *);
  48
  49 /* A string that describes a char (e.g., 'a' -> "'a'").  */
  50 static char const *char_name (char);
  51 %}
  52
  53 %code
  54 {
  55   static int current_prec = 0;
  56   static location current_lhs_location;
  57   static named_ref *current_lhs_named_ref;
  58   static symbol *current_lhs_symbol;
  59   static symbol_class current_class = unknown_sym;
  60   static uniqstr current_type = NULL;
  61
  62   /** Set the new current left-hand side symbol, possibly common
  63    * to several right-hand side parts of rule.
  64    */
  65   static
  66   void
  67   current_lhs (symbol *sym, location loc, named_ref *ref)
  68   {
  69     current_lhs_symbol = sym;
  70     current_lhs_location = loc;
  71     /* In order to simplify memory management, named references for lhs
  72        are always assigned by deep copy into the current symbol_list
  73        node.  This is because a single named-ref in the grammar may
  74        result in several uses when the user factors lhs between several
  75        rules using "|".  Therefore free the parser's original copy.  */
  76     free (current_lhs_named_ref);
  77     current_lhs_named_ref = ref;
  78   }
  79
  80   #define YYTYPE_INT16 int_fast16_t
  81   #define YYTYPE_INT8 int_fast8_t
  82   #define YYTYPE_UINT16 uint_fast16_t
  83   #define YYTYPE_UINT8 uint_fast8_t
  84 }
  85
  86 %define api.prefix "gram_"
  87 %define api.pure full
  88 %define locations
  89 %define parse.error verbose
  90 %define parse.lac full
  91 %define parse.trace
  92 %defines
  93 %expect 0
  94 %verbose
  95
  96 %initial-action
  97 {
  98   /* Bison's grammar can initial empty locations, hence a default
  99      location is needed. */
 100   boundary_set (&@$.start, current_file, 1, 1);
 101   boundary_set (&@$.end, current_file, 1, 1);
 102 }
 103
 104 %union
 105 {
 106   assoc assoc;
 107   char *code;
 108   char const *chars;
 109   int integer;
 110   named_ref *named_ref;
 111   symbol *symbol;
 112   symbol_list *list;
 113   uniqstr uniqstr;
 114   unsigned char character;
 115 };
 116
 117 /* Define the tokens together with their human representation.  */
 118 %token GRAM_EOF 0 "end of file"
 119 %token STRING     "string"
 120 %token INT        "integer"
 121
 122 %token PERCENT_TOKEN       "%token"
 123 %token PERCENT_NTERM       "%nterm"
 124
 125 %token PERCENT_TYPE        "%type"
 126 %token PERCENT_DESTRUCTOR  "%destructor"
 127 %token PERCENT_PRINTER     "%printer"
 128
 129 %token PERCENT_LEFT        "%left"
 130 %token PERCENT_RIGHT       "%right"
 131 %token PERCENT_NONASSOC    "%nonassoc"
 132 %token PERCENT_PRECEDENCE  "%precedence"
 133
 134 %token PERCENT_PREC          "%prec"
 135 %token PERCENT_DPREC         "%dprec"
 136 %token PERCENT_MERGE         "%merge"
 137
 138 /*----------------------.
 139 | Global Declarations.  |
 140 `----------------------*/
 141
 142 %token
 143   PERCENT_CODE            "%code"
 144   PERCENT_DEFAULT_PREC    "%default-prec"
 145   PERCENT_DEFINE          "%define"
 146   PERCENT_DEFINES         "%defines"
 147   PERCENT_ERROR_VERBOSE   "%error-verbose"
 148   PERCENT_EXPECT          "%expect"
 149   PERCENT_EXPECT_RR       "%expect-rr"
 150   PERCENT_FLAG            "%<flag>"
 151   PERCENT_FILE_PREFIX     "%file-prefix"
 152   PERCENT_GLR_PARSER      "%glr-parser"
 153   PERCENT_INITIAL_ACTION  "%initial-action"
 154   PERCENT_LANGUAGE        "%language"
 155   PERCENT_NAME_PREFIX     "%name-prefix"
 156   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 157   PERCENT_NO_LINES        "%no-lines"
 158   PERCENT_NONDETERMINISTIC_PARSER
 159                           "%nondeterministic-parser"
 160   PERCENT_OUTPUT          "%output"
 161   PERCENT_REQUIRE         "%require"
 162   PERCENT_SKELETON        "%skeleton"
 163   PERCENT_START           "%start"
 164   PERCENT_TOKEN_TABLE     "%token-table"
 165   PERCENT_VERBOSE         "%verbose"
 166   PERCENT_YACC            "%yacc"
 167 ;
 168
 169 %token BRACED_CODE     "{...}"
 170 %token BRACED_PREDICATE "%?{...}"
 171 %token BRACKETED_ID    "[identifier]"
 172 %token CHAR            "char"
 173 %token EPILOGUE        "epilogue"
 174 %token EQUAL           "="
 175 %token ID              "identifier"
 176 %token ID_COLON        "identifier:"
 177 %token PERCENT_PERCENT "%%"
 178 %token PIPE            "|"
 179 %token PROLOGUE        "%{...%}"
 180 %token SEMICOLON       ";"
 181 %token TAG             "<tag>"
 182 %token TAG_ANY         "<*>"
 183 %token TAG_NONE        "<>"
 184
 185 %type <character> CHAR
 186 %printer { fputs (char_name ($$), yyo); } CHAR
 187
 188 /* braceless is not to be used for rule or symbol actions, as it
 189    calls code_props_plain_init.  */
 190 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 191 %type <code> "{...}" "%?{...}"
 192 %printer { fputs (quotearg_style (c_quoting_style, $$), yyo); }
 193          STRING
 194 %printer { fprintf (yyo, "{\n%s\n}", $$); }
 195          braceless content.opt "{...}" "%{...%}" EPILOGUE
 196
 197 %type <uniqstr> BRACKETED_ID ID ID_COLON PERCENT_FLAG TAG tag variable
 198 %printer { fputs ($$, yyo); } <uniqstr>
 199 %printer { fprintf (yyo, "[%s]", $$); } BRACKETED_ID
 200 %printer { fprintf (yyo, "%s:", $$); } ID_COLON
 201 %printer { fprintf (yyo, "%%%s", $$); } PERCENT_FLAG
 202 %printer { fprintf (yyo, "<%s>", $$); } TAG tag
 203
 204 %type <integer> INT
 205 %printer { fprintf (yyo, "%d", $$); } <integer>
 206
 207 %type <symbol> id id_colon string_as_id symbol symbol.prec
 208 %printer { fprintf (yyo, "%s", $$->tag); } <symbol>
 209 %printer { fprintf (yyo, "%s:", $$->tag); } id_colon
 210
 211 %type <assoc> precedence_declarator
 212 %type <list>  symbols.1 symbols.prec generic_symlist generic_symlist_item
 213 %type <named_ref> named_ref.opt
 214
 215 /*---------.
 216 | %param.  |
 217 `---------*/
 218 %code requires
 219 {
 220 # ifndef PARAM_TYPE
 221 #  define PARAM_TYPE
 222   typedef enum
 223   {
 224     param_none   = 0,
 225     param_lex    = 1 << 0,
 226     param_parse  = 1 << 1,
 227     param_both   = param_lex | param_parse
 228   } param_type;
 229 # endif
 230 };
 231 %code
 232 {
 233   /** Add a lex-param and/or a parse-param.
 234    *
 235    * \param type  where to push this formal argument.
 236    * \param decl  the formal argument.  Destroyed.
 237    * \param loc   the location in the source.
 238    */
 239   static void add_param (param_type type, char *decl, location loc);
 240   static param_type current_param = param_none;
 241 };
 242 %union
 243 {
 244   param_type param;
 245 }
 246 %token <param> PERCENT_PARAM "%param";
 247 %printer
 248 {
 249   switch ($$)
 250     {
 251 #define CASE(In, Out)                                           \
 252       case param_ ## In: fputs ("%" #Out, stderr); break
 253       CASE (lex,   lex-param);
 254       CASE (parse, parse-param);
 255       CASE (both,  param);
 256 #undef CASE
 257       case param_none: aver (false); break;
 258     }
 259 } <param>;
 260
 261
 262                      /*==========\
 263                      | Grammar.  |
 264                      \==========*/
 265 %%
 266
 267 input:
 268   prologue_declarations "%%" grammar epilogue.opt
 269 ;
 270
 271
 272         /*------------------------------------.
 273         | Declarations: before the first %%.  |
 274         `------------------------------------*/
 275
 276 prologue_declarations:
 277   /* Nothing */
 278 | prologue_declarations prologue_declaration
 279 ;
 280
 281 prologue_declaration:
 282   grammar_declaration
 283 | "%{...%}"
 284     {
 285       code_props plain_code;
 286       code_props_plain_init (&plain_code, $1, @1);
 287       code_props_translate_code (&plain_code);
 288       gram_scanner_last_string_free ();
 289       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 290                         plain_code.code, @1);
 291       code_scanner_last_string_free ();
 292     }
 293 | "%<flag>"
 294     {
 295       muscle_percent_define_ensure ($1, @1, true);
 296     }
 297 | "%define" variable content.opt
 298     {
 299       muscle_percent_define_insert ($2, @2, $3,
 300                                     MUSCLE_PERCENT_DEFINE_GRAMMAR_FILE);
 301     }
 302 | "%defines"                       { defines_flag = true; }
 303 | "%defines" STRING
 304     {
 305       defines_flag = true;
 306       spec_defines_file = xstrdup ($2);
 307     }
 308 | "%error-verbose"
 309     {
 310       muscle_percent_define_insert ("parse.error", @1, "verbose",
 311                                     MUSCLE_PERCENT_DEFINE_GRAMMAR_FILE);
 312     }
 313 | "%expect" INT                    { expected_sr_conflicts = $2; }
 314 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 315 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 316 | "%glr-parser"
 317     {
 318       nondeterministic_parser = true;
 319       glr_parser = true;
 320     }
 321 | "%initial-action" "{...}"
 322     {
 323       code_props action;
 324       code_props_symbol_action_init (&action, $2, @2);
 325       code_props_translate_code (&action);
 326       gram_scanner_last_string_free ();
 327       muscle_code_grow ("initial_action", action.code, @2);
 328       code_scanner_last_string_free ();
 329     }
 330 | "%language" STRING            { language_argmatch ($2, grammar_prio, @1); }
 331 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 332 | "%no-lines"                   { no_lines_flag = true; }
 333 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 334 | "%output" STRING              { spec_outfile = $2; }
 335 | "%param" { current_param = $1; } params { current_param = param_none; }
 336 | "%require" STRING             { version_check (&@2, $2); }
 337 | "%skeleton" STRING
 338     {
 339       char const *skeleton_user = $2;
 340       if (strchr (skeleton_user, '/'))
 341         {
 342           size_t dir_length = strlen (current_file);
 343           char *skeleton_build;
 344           while (dir_length && current_file[dir_length - 1] != '/')
 345             --dir_length;
 346           while (dir_length && current_file[dir_length - 1] == '/')
 347             --dir_length;
 348           skeleton_build =
 349             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 350           if (dir_length > 0)
 351             {
 352               memcpy (skeleton_build, current_file, dir_length);
 353               skeleton_build[dir_length++] = '/';
 354             }
 355           strcpy (skeleton_build + dir_length, skeleton_user);
 356           skeleton_user = uniqstr_new (skeleton_build);
 357           free (skeleton_build);
 358         }
 359       skeleton_arg (skeleton_user, grammar_prio, @1);
 360     }
 361 | "%token-table"                { token_table_flag = true; }
 362 | "%verbose"                    { report_flag |= report_states; }
 363 | "%yacc"                       { yacc_flag = true; }
 364 | /*FIXME: Err?  What is this horror doing here? */ ";"
 365 ;
 366
 367 params:
 368    params "{...}"  { add_param (current_param, $2, @2); }
 369 | "{...}"          { add_param (current_param, $1, @1); }
 370 ;
 371
 372
 373 /*----------------------.
 374 | grammar_declaration.  |
 375 `----------------------*/
 376
 377 grammar_declaration:
 378   precedence_declaration
 379 | symbol_declaration
 380 | "%start" symbol
 381     {
 382       grammar_start_symbol_set ($2, @2);
 383     }
 384 | code_props_type "{...}" generic_symlist
 385     {
 386       code_props code;
 387       code_props_symbol_action_init (&code, $2, @2);
 388       code_props_translate_code (&code);
 389       {
 390         symbol_list *list;
 391         for (list = $3; list; list = list->next)
 392           symbol_list_code_props_set (list, $1, &code);
 393         symbol_list_free ($3);
 394       }
 395     }
 396 | "%default-prec"
 397     {
 398       default_prec = true;
 399     }
 400 | "%no-default-prec"
 401     {
 402       default_prec = false;
 403     }
 404 | "%code" braceless
 405     {
 406       /* Do not invoke muscle_percent_code_grow here since it invokes
 407          muscle_user_name_list_grow.  */
 408       muscle_code_grow ("percent_code()", $2, @2);
 409       code_scanner_last_string_free ();
 410     }
 411 | "%code" ID braceless
 412     {
 413       muscle_percent_code_grow ($2, @2, $3, @3);
 414       code_scanner_last_string_free ();
 415     }
 416 ;
 417
 418 %type <code_type> code_props_type;
 419 %union {code_props_type code_type;};
 420 %printer { fprintf (yyo, "%s", code_props_type_string ($$)); } <code_type>;
 421 code_props_type:
 422   "%destructor"  { $$ = destructor; }
 423 | "%printer"     { $$ = printer; }
 424 ;
 425
 426 /*---------.
 427 | %union.  |
 428 `---------*/
 429
 430 %token PERCENT_UNION "%union";
 431
 432 union_name:
 433   /* Nothing. */ {}
 434 | ID             { muscle_code_grow ("union_name", $1, @1); }
 435 ;
 436
 437 grammar_declaration:
 438   "%union" union_name braceless
 439     {
 440       union_seen = true;
 441       muscle_code_grow ("union_members", $3, @3);
 442       code_scanner_last_string_free ();
 443     }
 444 ;
 445
 446
 447
 448
 449 symbol_declaration:
 450   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 451     {
 452       current_class = unknown_sym;
 453       current_type = NULL;
 454     }
 455 | "%token" { current_class = token_sym; } symbol_defs.1
 456     {
 457       current_class = unknown_sym;
 458       current_type = NULL;
 459     }
 460 | "%type" TAG symbols.1
 461     {
 462       symbol_list *list;
 463       tag_seen = true;
 464       for (list = $3; list; list = list->next)
 465         symbol_type_set (list->content.sym, $2, @2);
 466       symbol_list_free ($3);
 467     }
 468 ;
 469
 470 precedence_declaration:
 471   precedence_declarator tag.opt symbols.prec
 472     {
 473       symbol_list *list;
 474       ++current_prec;
 475       for (list = $3; list; list = list->next)
 476         {
 477           symbol_type_set (list->content.sym, current_type, @2);
 478           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 479         }
 480       symbol_list_free ($3);
 481       current_type = NULL;
 482     }
 483 ;
 484
 485 precedence_declarator:
 486   "%left"       { $$ = left_assoc; }
 487 | "%right"      { $$ = right_assoc; }
 488 | "%nonassoc"   { $$ = non_assoc; }
 489 | "%precedence" { $$ = precedence_assoc; }
 490 ;
 491
 492 tag.opt:
 493   /* Nothing. */ { current_type = NULL; }
 494 | TAG            { current_type = $1; tag_seen = true; }
 495 ;
 496
 497 /* Just like symbols.1 but accept INT for the sake of POSIX.  */
 498 symbols.prec:
 499   symbol.prec
 500     { $$ = symbol_list_sym_new ($1, @1); }
 501 | symbols.prec symbol.prec
 502     { $$ = symbol_list_append ($1, symbol_list_sym_new ($2, @2)); }
 503 ;
 504
 505 symbol.prec:
 506   symbol     { $$ = $1; }
 507 | symbol INT { $$ = $1; symbol_user_token_number_set ($1, $2, @2); }
 508 ;
 509
 510 /* One or more symbols to be %typed. */
 511 symbols.1:
 512   symbol
 513     { $$ = symbol_list_sym_new ($1, @1); }
 514 | symbols.1 symbol
 515     { $$ = symbol_list_append ($1, symbol_list_sym_new ($2, @2)); }
 516 ;
 517
 518 generic_symlist:
 519   generic_symlist_item { $$ = $1; }
 520 | generic_symlist generic_symlist_item { $$ = symbol_list_append ($1, $2); }
 521 ;
 522
 523 generic_symlist_item:
 524   symbol    { $$ = symbol_list_sym_new ($1, @1); }
 525 | tag       { $$ = symbol_list_type_new ($1, @1); }
 526 ;
 527
 528 tag:
 529   TAG
 530 | "<*>" { $$ = uniqstr_new ("*"); }
 531 | "<>"  { $$ = uniqstr_new (""); }
 532 ;
 533
 534 /* One token definition.  */
 535 symbol_def:
 536   TAG
 537     {
 538       current_type = $1;
 539       tag_seen = true;
 540     }
 541 | id
 542     {
 543       symbol_class_set ($1, current_class, @1, true);
 544       symbol_type_set ($1, current_type, @1);
 545     }
 546 | id INT
 547     {
 548       symbol_class_set ($1, current_class, @1, true);
 549       symbol_type_set ($1, current_type, @1);
 550       symbol_user_token_number_set ($1, $2, @2);
 551     }
 552 | id string_as_id
 553     {
 554       symbol_class_set ($1, current_class, @1, true);
 555       symbol_type_set ($1, current_type, @1);
 556       symbol_make_alias ($1, $2, @$);
 557     }
 558 | id INT string_as_id
 559     {
 560       symbol_class_set ($1, current_class, @1, true);
 561       symbol_type_set ($1, current_type, @1);
 562       symbol_user_token_number_set ($1, $2, @2);
 563       symbol_make_alias ($1, $3, @$);
 564     }
 565 ;
 566
 567 /* One or more symbol definitions. */
 568 symbol_defs.1:
 569   symbol_def
 570 | symbol_defs.1 symbol_def
 571 ;
 572
 573
 574         /*------------------------------------------.
 575         | The grammar section: between the two %%.  |
 576         `------------------------------------------*/
 577
 578 grammar:
 579   rules_or_grammar_declaration
 580 | grammar rules_or_grammar_declaration
 581 ;
 582
 583 /* As a Bison extension, one can use the grammar declarations in the
 584    body of the grammar.  */
 585 rules_or_grammar_declaration:
 586   rules
 587 | grammar_declaration ";"
 588 | error ";"
 589     {
 590       yyerrok;
 591     }
 592 ;
 593
 594 rules:
 595   id_colon named_ref.opt { current_lhs ($1, @1, $2); } rhses.1
 596   {
 597     /* Free the current lhs. */
 598     current_lhs (0, @1, 0);
 599   }
 600 ;
 601
 602 rhses.1:
 603   rhs                { grammar_current_rule_end (@1); }
 604 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 605 | rhses.1 ";"
 606 ;
 607
 608 %token PERCENT_EMPTY "%empty";
 609 rhs:
 610   /* Nothing.  */
 611     { grammar_current_rule_begin (current_lhs_symbol, current_lhs_location,
 612                                   current_lhs_named_ref); }
 613 | rhs symbol named_ref.opt
 614     { grammar_current_rule_symbol_append ($2, @2, $3); }
 615 | rhs "{...}" named_ref.opt
 616     { grammar_current_rule_action_append ($2, @2, $3, false); }
 617 | rhs "%?{...}"
 618     { grammar_current_rule_action_append ($2, @2, NULL, true); }
 619 | rhs "%empty"
 620     { grammar_current_rule_empty_set (@2); }
 621 | rhs "%prec" symbol
 622     { grammar_current_rule_prec_set ($3, @3); }
 623 | rhs "%dprec" INT
 624     { grammar_current_rule_dprec_set ($3, @3); }
 625 | rhs "%merge" TAG
 626     { grammar_current_rule_merge_set ($3, @3); }
 627 ;
 628
 629 named_ref.opt:
 630   /* Nothing. */ { $$ = 0; }
 631 |
 632   BRACKETED_ID   { $$ = named_ref_new ($1, @1); }
 633 ;
 634
 635 /*---------------------------.
 636 | variable and content.opt.  |
 637 `---------------------------*/
 638
 639 /* The STRING form of variable is deprecated and is not M4-friendly.
 640    For example, M4 fails for `%define "[" "value"'.  */
 641 variable:
 642   ID
 643 | STRING { $$ = uniqstr_new ($1); }
 644 ;
 645
 646 /* Some content or empty by default. */
 647 content.opt:
 648   /* Nothing. */   { $$ = ""; }
 649 | ID { $$ = $1; }
 650 | STRING
 651 ;
 652
 653
 654 /*------------.
 655 | braceless.  |
 656 `------------*/
 657
 658 braceless:
 659   "{...}"
 660     {
 661       code_props plain_code;
 662       $1[strlen ($1) - 1] = '\n';
 663       code_props_plain_init (&plain_code, $1+1, @1);
 664       code_props_translate_code (&plain_code);
 665       gram_scanner_last_string_free ();
 666       $$ = plain_code.code;
 667     }
 668 ;
 669
 670
 671 /*--------------.
 672 | Identifiers.  |
 673 `--------------*/
 674
 675 /* Identifiers are returned as uniqstr values by the scanner.
 676    Depending on their use, we may need to make them genuine symbols.  */
 677
 678 id:
 679   ID
 680     { $$ = symbol_from_uniqstr ($1, @1); }
 681 | CHAR
 682     {
 683       $$ = symbol_get (char_name ($1), @1);
 684       symbol_class_set ($$, token_sym, @1, false);
 685       symbol_user_token_number_set ($$, $1, @1);
 686     }
 687 ;
 688
 689 id_colon:
 690   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 691 ;
 692
 693
 694 symbol:
 695   id
 696 | string_as_id
 697 ;
 698
 699 /* A string used as an ID: quote it.  */
 700 string_as_id:
 701   STRING
 702     {
 703       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 704       symbol_class_set ($$, token_sym, @1, false);
 705     }
 706 ;
 707
 708 epilogue.opt:
 709   /* Nothing.  */
 710 | "%%" EPILOGUE
 711     {
 712       code_props plain_code;
 713       code_props_plain_init (&plain_code, $2, @2);
 714       code_props_translate_code (&plain_code);
 715       gram_scanner_last_string_free ();
 716       muscle_code_grow ("epilogue", plain_code.code, @2);
 717       code_scanner_last_string_free ();
 718     }
 719 ;
 720
 721 %%
 722
 723 /* Return the location of the left-hand side of a rule whose
 724    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 725    the right-hand side, and return an empty location equal to the end
 726    boundary of RHS[0] if the right-hand side is empty.  */
 727
 728 static YYLTYPE
 729 lloc_default (YYLTYPE const *rhs, int n)
 730 {
 731   int i;
 732   YYLTYPE loc;
 733
 734   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 735      The bug is fixed in 7.4.2m, but play it safe for now.  */
 736   loc.start = rhs[n].end;
 737   loc.end = rhs[n].end;
 738
 739   /* Ignore empty nonterminals the start of the right-hand side.
 740      Do not bother to ignore them at the end of the right-hand side,
 741      since empty nonterminals have the same end as their predecessors.  */
 742   for (i = 1; i <= n; i++)
 743     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 744       {
 745         loc.start = rhs[i].start;
 746         break;
 747       }
 748
 749   return loc;
 750 }
 751
 752
 753 static void
 754 add_param (param_type type, char *decl, location loc)
 755 {
 756   static char const alphanum[26 + 26 + 1 + 10] =
 757     "abcdefghijklmnopqrstuvwxyz"
 758     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 759     "_"
 760     "0123456789";
 761
 762   char const *name_start = NULL;
 763   {
 764     char *p;
 765     /* Stop on last actual character.  */
 766     for (p = decl; p[1]; p++)
 767       if ((p == decl
 768            || ! memchr (alphanum, p[-1], sizeof alphanum))
 769           && memchr (alphanum, p[0], sizeof alphanum - 10))
 770         name_start = p;
 771
 772     /* Strip the surrounding '{' and '}', and any blanks just inside
 773        the braces.  */
 774     --p;
 775   while (c_isspace ((unsigned char) *p))
 776       --p;
 777     p[1] = '\0';
 778     ++decl;
 779   while (c_isspace ((unsigned char) *decl))
 780       ++decl;
 781   }
 782
 783   if (! name_start)
 784     complain (&loc, complaint, _("missing identifier in parameter declaration"));
 785   else
 786     {
 787       char *name = xmemdup0 (name_start, strspn (name_start, alphanum));
 788       if (type & param_lex)
 789         muscle_pair_list_grow ("lex_param", decl, name);
 790       if (type & param_parse)
 791         muscle_pair_list_grow ("parse_param", decl, name);
 792       free (name);
 793     }
 794
 795   gram_scanner_last_string_free ();
 796 }
 797
 798
 799 static void
 800 version_check (location const *loc, char const *version)
 801 {
 802   if (strverscmp (version, PACKAGE_VERSION) > 0)
 803     {
 804       complain (loc, complaint, "require bison %s, but have %s",
 805                 version, PACKAGE_VERSION);
 806       exit (EX_MISMATCH);
 807     }
 808 }
 809
 810 static void
 811 gram_error (location const *loc, char const *msg)
 812 {
 813   complain (loc, complaint, "%s", msg);
 814 }
 815
 816 char const *
 817 token_name (int type)
 818 {
 819   return yytname[YYTRANSLATE (type)];
 820 }
 821
 822 static char const *
 823 char_name (char c)
 824 {
 825   if (c == '\'')
 826     return "'\\''";
 827   else
 828     {
 829       char buf[4];
 830       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 831       return quotearg_style (escape_quoting_style, buf);
 832     }
 833 }