tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4 # Copyright (C) 2003-2010 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 # We want a recent Autotest.
  20 m4_version_prereq([2.58])
  21
  22
  23 ## ------------- ##
  24 ## Basic tests.  ##
  25 ## ------------- ##
  26
  27 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  28 # ------------------------------------------
  29 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  30 # taken in "slurp" mode, i.e., one can match end-of-lines.
  31 m4_define([AT_MATCHES_CHECK],
  32 [AT_CHECK([perl -0777 -ne '
  33 my $count = 0;
  34 s{$2}{ ++$count; "" }gem;
  35 printf "$count\n";' $1], [0], [$3
  36 ])])
  37
  38
  39 ## ------------------------------- ##
  40 ## Macros decoding Bison options.  ##
  41 ## ------------------------------- ##
  42
  43 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  44 # ----------------------------------------------------------------
  45 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  46 m4_define([AT_LOC_PUSHDEF],
  47 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  48 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  49 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  50 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  51
  52 # AT_LOC_POPDEF
  53 # -------------
  54 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  55 m4_define([AT_LOC_POPDEF],
  56 [m4_popdef([AT_LOC_FIRST_LINE])
  57 m4_popdef([AT_LOC_FIRST_COLUMN])
  58 m4_popdef([AT_LOC_LAST_LINE])
  59 m4_popdef([AT_LOC_LAST_COLUMN])])
  60
  61
  62
  63 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  64 # -----------------------------------------
  65 m4_define([AT_BISON_OPTION_PUSHDEFS],
  66 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  67
  68
  69 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  70 # --------------------------------------------------
  71 # This macro works around the impossibility to define macros
  72 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  73 # This sucks hard, GNU M4 should really provide M5-like $$1.
  74 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  75 [m4_if([$1$2], $[1]$[2], [],
  76        [m4_fatal([$0: Invalid arguments: $@])])dnl
  77 m4_pushdef([AT_DEFINES_IF],
  78 [m4_bmatch([$3], [%defines], [$1], [$2])])
  79 m4_pushdef([AT_SKEL_CC_IF],
  80 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  81 m4_pushdef([AT_GLR_IF],
  82 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  83 m4_pushdef([AT_LALR1_CC_IF],
  84 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  85 m4_pushdef([AT_GLR_CC_IF],
  86 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  87 # Using yacc.c?
  88 m4_pushdef([AT_YACC_IF],
  89 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  90 m4_pushdef([AT_LEXPARAM_IF],
  91 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  92 m4_pushdef([AT_LOCATION_IF],
  93 [m4_bmatch([$3], [%locations], [$1], [$2])])
  94 m4_pushdef([AT_LOCATION_TYPE_IF],
  95 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
  96 m4_pushdef([AT_PARAM_IF],
  97 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
  98 m4_pushdef([AT_PURE_IF],
  99 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 100            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 101            [$2])])
 102 m4_pushdef([AT_PURE_AND_LOC_IF],
 103 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 104 m4_pushdef([AT_GLR_OR_PARAM_IF],
 105 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 106 m4_pushdef([AT_NAME_PREFIX],
 107 [m4_bmatch([$3], [%name-prefix ".*"],
 108            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
 109            [yy])])
 110 m4_pushdef([AT_TOKEN_PREFIX],
 111 [m4_bmatch([$3], [%define api.tokens.prefix ".*"],
 112            [m4_bregexp([$3], [%define api.tokens.prefix "\(.*\)"], [\1])])])
 113 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 114 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 115 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 116                     [$2])])
 117 # yyerror always sees the locations (when activated), except if
 118 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 119 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 120 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 121                                         [$1])],
 122                             [$1])],
 123                 [$2])])
 124
 125 # The interface is pure: either because %define api.pure, or because we
 126 # are using the C++ parsers.
 127 m4_pushdef([AT_PURE_LEX_IF],
 128 [AT_PURE_IF([$1],
 129             [AT_SKEL_CC_IF([$1], [$2])])])
 130
 131 AT_PURE_LEX_IF(
 132 [m4_pushdef([AT_LOC], [(*llocp)])
 133  m4_pushdef([AT_VAL], [(*lvalp)])
 134  m4_pushdef([AT_LEX_FORMALS],
 135             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 136  m4_pushdef([AT_LEX_ARGS],
 137             [lvalp[]AT_LOCATION_IF([, llocp])])
 138  m4_pushdef([AT_USE_LEX_ARGS],
 139             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 140  m4_pushdef([AT_LEX_PRE_FORMALS],
 141             [AT_LEX_FORMALS, ])
 142  m4_pushdef([AT_LEX_PRE_ARGS],
 143             [AT_LEX_ARGS, ])
 144 ],
 145 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 146  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 147  m4_pushdef([AT_LEX_FORMALS],     [void])
 148  m4_pushdef([AT_LEX_ARGS],        [])
 149  m4_pushdef([AT_USE_LEX_ARGS],    [])
 150  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 151  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 152 ])
 153
 154 # Handle the different types of location components.
 155
 156 AT_SKEL_CC_IF(
 157   [AT_LOCATION_TYPE_IF(
 158     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 159     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 160   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 161
 162
 163 AT_GLR_IF([AT_KEYWORDS([glr])])
 164 ])# _AT_BISON_OPTION_PUSHDEFS
 165
 166
 167 # AT_BISON_OPTION_POPDEFS
 168 # -----------------------
 169 m4_define([AT_BISON_OPTION_POPDEFS],
 170 [m4_popdef([AT_LEX_PRE_ARGS])
 171 m4_popdef([AT_LEX_PRE_FORMALS])
 172 m4_popdef([AT_USE_LEX_ARGS])
 173 m4_popdef([AT_LEX_ARGS])
 174 m4_popdef([AT_LEX_FORMALS])
 175 m4_popdef([AT_VAL])
 176 m4_popdef([AT_LOC])
 177 m4_popdef([AT_PURE_LEX_IF])
 178 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 179 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 180 m4_popdef([AT_NAME_PREFIX])
 181 m4_popdef([AT_GLR_OR_PARAM_IF])
 182 m4_popdef([AT_PURE_AND_LOC_IF])
 183 m4_popdef([AT_LOCATION_TYPE_IF])
 184 m4_popdef([AT_LOCATION_IF])
 185 m4_popdef([AT_PARAM_IF])
 186 m4_popdef([AT_LEXPARAM_IF])
 187 m4_popdef([AT_YACC_IF])
 188 m4_popdef([AT_GLR_IF])
 189 m4_popdef([AT_SKEL_CC_IF])
 190 m4_popdef([AT_GLR_CC_IF])
 191 m4_popdef([AT_LALR1_CC_IF])
 192 m4_popdef([AT_DEFINES_IF])
 193 AT_LOC_POPDEF
 194 ])# AT_BISON_OPTION_POPDEFS
 195
 196
 197
 198 ## -------------------------- ##
 199 ## Generating Grammar Files.  ##
 200 ## -------------------------- ##
 201
 202 # AT_DATA_SOURCE_PROLOGUE
 203 # ------------------------
 204 # The prologue that should be included in any source code that is
 205 # meant to be compiled.
 206 m4_define([AT_DATA_SOURCE_PROLOGUE],
 207 [[#include <config.h>
 208 /* We don't need perfect functions for these tests. */
 209 #undef malloc
 210 #undef memcmp
 211 #undef realloc
 212 ]])
 213
 214 # AT_DATA_GRAMMAR_PROLOGUE
 215 # ------------------------
 216 # The prologue that should be included in any grammar which parser is
 217 # meant to be compiled.
 218 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 219 [[%code top {
 220 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 221 [}
 222 ]])
 223
 224 # AT_DATA_SOURCE(NAME, CONTENT)
 225 # -----------------------------
 226 # Generate the file NAME, which CONTENT is preceded by
 227 # AT_DATA_SOURCE_PROLOGUE.
 228 m4_define([AT_DATA_SOURCE],
 229 [AT_DATA([$1],
 230 [AT_DATA_SOURCE_PROLOGUE
 231 $2])
 232 ])
 233
 234 # AT_DATA_GRAMMAR(NAME, CONTENT)
 235 # ------------------------------
 236 # Generate the file NAME, which CONTENT is preceded by
 237 # AT_DATA_GRAMMAR_PROLOGUE.
 238 m4_define([AT_DATA_GRAMMAR],
 239 [AT_DATA([$1],
 240 [AT_DATA_GRAMMAR_PROLOGUE
 241 $2])
 242 ])
 243
 244 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 245 # -------------------------------------------------
 246 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 247 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 248 #
 249 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 250 # Bison in the test suite.  For now it ensures that:
 251 #
 252 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 253 #      a non-zero exit status since Bison doesn't always try to free all memory
 254 #      in that case.
 255 #
 256 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 257 #      --graph and --report=all output for every working grammar.
 258 m4_define([AT_BISON_CHECK],
 259 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 260        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 261 AT_BISON_CHECK_NO_XML($@)])
 262
 263 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 264 # --------------------------------------------------------
 265 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 266 # when a tortured grammar's XML is known to be too large for xsltproc to
 267 # handle.
 268 m4_define([AT_BISON_CHECK_NO_XML],
 269 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 270                 [AT_QUELL_VALGRIND ])[[bison ]]$@)])
 271
 272 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 273 # -----------------------------------------------------
 274 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 275 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 276 # have a non-zero exit status.
 277 m4_define([AT_BISON_CHECK_XML],
 278 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 279   mkdir xml-tests]
 280   m4_pushdef([AT_BISON_ARGS],
 281              [m4_bpatsubsts([[$1]],
 282                             [--report(-file)?=[^][ ]*], [],
 283                             [--graph=[^][ ]*], [],
 284                             [--xml=[^][ ]*], [])])dnl
 285   # Don't combine these Bison invocations since we want to be sure that
 286   # --report=all isn't required to get the full XML file.
 287   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 288              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 289            [[0]], [ignore], [ignore])
 290   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 291            [[0]], [ignore], [ignore])
 292   m4_popdef([AT_BISON_ARGS])dnl
 293   [cp xml-tests/test.output expout]
 294   AT_CHECK([[$XSLTPROC \
 295              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 296              xml-tests/test.xml]], [[0]], [expout])
 297   [cp xml-tests/test.dot expout]
 298   AT_CHECK([[$XSLTPROC \
 299              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 300              xml-tests/test.xml]], [[0]], [expout])
 301   [rm -rf xml-tests expout
 302 fi]])
 303
 304 # AT_QUELL_VALGRIND
 305 # -----------------
 306 # Put this before a Bison invocation to keep Valgrind from complaining about
 307 # reachable memory.
 308 #
 309 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 310 # The triple quoting below will cause test cases to fail if you do.  If you do
 311 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 312 # will then fail to shell-escape its contents when attempting to print them.
 313 # The testsuite verbose output, at least, will be incorrect, but nothing may
 314 # fail to make sure you notice.
 315 m4_define([AT_QUELL_VALGRIND],
 316 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 317
 318 ## ------------------------ ##
 319 ## Compiling C, C++ Files.  ##
 320 ## ------------------------ ##
 321
 322
 323 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 324 # ----------------------------------------
 325 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 326 # assume that we are linking too; this is a hack.
 327 m4_define([AT_COMPILE],
 328 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 329            0, [ignore], [ignore])])
 330
 331 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 332 # --------------------------------------------
 333 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 334 # assume that we are linking too; this is a hack.
 335 # If the C++ compiler does not work, ignore the test.
 336 m4_define([AT_COMPILE_CXX],
 337 [AT_KEYWORDS(c++)
 338 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 339 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 340          0, [ignore], [ignore])])
 341
 342
 343 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 344 # --------------------------------
 345 # Compile OUTPUT.y to OUTPUT.c or OUTPUT.cc, and compile it to OUTPUT.
 346 # If OTHER is specified, compile OUTPUT-OTHER.c or OUTPUT-OTHER.cc to OUTPUT
 347 # along with it.
 348 # Relies on AT_SKEL_CC_IF.
 349 m4_define([AT_FULL_COMPILE],
 350 [AT_SKEL_CC_IF(
 351   [AT_BISON_CHECK([-o $1.cc $1.y])
 352    AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1.cc $1-$2.cc]]))],
 353   [AT_BISON_CHECK([-o $1.c $1.y])
 354    AT_COMPILE([$1]m4_ifval($2, [, [$1.c $1-$2.c]]))])
 355 ])
 356
 357
 358 ## ---------------------------- ##
 359 ## Running a generated parser.  ##
 360 ## ---------------------------- ##
 361
 362 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 363 # ------------------------------------------------------------
 364 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 365 m4_define([AT_PARSER_CHECK],
 366 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 367
 368 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 369 #                          DECLS, GRAMMAR, INPUT,
 370 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 371 #                          [OTHER-CHECKS],
 372 #                          [PARSER-EXIT-VALUE],
 373 #                          [PARSER-STDOUT], [PARSER-STDERR])
 374 # -------------------------------------------------------------
 375 # Using TITLE as the test group title, check the generated parser tables
 376 # and parser for a specified grammar file under a condition labeled by
 377 # COND-VALUE.
 378 #
 379 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 380 # recognized attribute is described below where it is relevant.
 381 #
 382 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 383 # the grammar file.  Insert basic yyerror, yylex, and main function
 384 # definitions as well.  Hardcode yylex to return the (possibly empty)
 385 # comma-delimited series of tokens in INPUT followed by token 0.
 386 #
 387 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 388 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 389 # On the bison command-line, specify `--report=all --defines'.  Check
 390 # that Bison exits with value 0, has no stdout, and has stderr
 391 # BISON-STDERR.
 392 #
 393 # If TEST-SPEC contains the attribute `last-state', check that the value
 394 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 395 # the grammar; in other words, check the number of states (minus one).
 396 # Otherwise, check that everything in the `.output' file starting with
 397 # the definition of state 0 is the same as the entire value of
 398 # TABLES-OR-LAST-STATE.
 399 #
 400 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 401 # `.output' file, which is named `input.output', and/or grammar file,
 402 # which is named `input.y'.
 403 #
 404 # Finally, compile the generated parser and then run it using
 405 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 406 # PARSER-STDERR as the 2nd-4th arguments.
 407 #
 408 # As a precondition, you must properly double-quote all arguments that
 409 # are to be interpreted as strings.
 410 #
 411 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 412 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 413 # first argument.  This is useful, for example, when wrapping multiple
 414 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 415 # condition, in another macro.
 416 #
 417 # For example:
 418 #
 419 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 420 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 421 #   # ---------------------------------------------------------------------
 422 #   m4_define([AT_TEST_SYNTAX_ERROR],
 423 #   [
 424 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 425 #                              [[last-state]],
 426 #                              [[%error-verbose ]$2], [$3], [$4],
 427 #                              [[]], [$5], [], [$6], [$7], [$8])
 428 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 429 #                              [[last-state]],
 430 #                              [$2], [$3], [$4],
 431 #                              [[]], [$5], [], [$6], [$7], [$8])
 432 #   ])
 433 #
 434 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 435 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 436 #                        [[3]],
 437 #                        [[1]], [[]],
 438 #                        [AT_COND_CASE([[no verbose]],
 439 #                                      [[syntax error
 440 #   ]],
 441 #                                      [[syntax error, unexpected 'b', expecting $end
 442 #   ]])])
 443 m4_define([AT_TEST_TABLES_AND_PARSE],
 444 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 445
 446 AT_SETUP([$1])
 447
 448 AT_DATA_GRAMMAR([[input.y]],
 449 [[%code {
 450   #include <stdio.h>
 451   static void yyerror (char const *msg);
 452   static int yylex (void);
 453 }
 454
 455 ]$4[
 456
 457 %%
 458
 459 ]$5[
 460
 461 %%
 462
 463 static void
 464 yyerror (char const *msg)
 465 {
 466   fprintf (stderr, "%s\n", msg);
 467 }
 468
 469 static int
 470 yylex (void)
 471 {
 472   static int const input[] = {
 473     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 474   };
 475   static int const *inputp = input;
 476   return *inputp++;
 477 }
 478
 479 int
 480 main (void)
 481 {
 482   return yyparse ();
 483 }
 484 ]])
 485
 486 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 487 # expanding macros, so it corrupts some special characters in the
 488 # macros.  To avoid this, expand now and pass it the result with proper
 489 # string quotation.  Assume args 7 thru 12 expand to properly quoted
 490 # strings.
 491
 492 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 493       [AT_BISON_CHECK],
 494       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 495                                [0], [], m4_dquote($7))
 496
 497 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 498       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 499                 m4_dquote($8))],
 500       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 501                 m4_dquote($8)[[
 502 ]])])
 503
 504 $9
 505
 506 AT_COMPILE([[input]])
 507
 508 AT_PARSER_CHECK([[./input]],
 509                 m4_ifval([$10], [m4_dquote($10)]),
 510                 m4_ifval([$11], [m4_dquote($11)]),
 511                 m4_ifval([$12], [m4_dquote($12)]))
 512
 513 AT_CLEANUP
 514
 515 m4_popdef([AT_COND_CASE])])
 516
 517
 518
 519 ## ----------------------- ##
 520 ## Launch the test suite.  ##
 521 ## ----------------------- ##
 522
 523 AT_INIT
 524
 525 AT_TESTED([bison])