data/bison.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Language-independent M4 Macros for Bison.
   4 # Copyright (C) 2002, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  19 # 02110-1301  USA
  20
  21
  22 ## ---------------- ##
  23 ## Identification.  ##
  24 ## ---------------- ##
  25
  26 # b4_copyright(TITLE, YEARS)
  27 # --------------------------
  28 m4_define([b4_copyright],
  29 [b4_comment([A Bison parser, made by GNU Bison b4_version.])
  30
  31 b4_comment([$1
  32
  33 m4_text_wrap([Copyright (C) $2 Free Software Foundation, Inc.], [   ])
  34
  35 This program is free software; you can redistribute it and/or modify
  36 it under the terms of the GNU General Public License as published by
  37 the Free Software Foundation; either version 2, or (at your option)
  38 any later version.
  39
  40 This program is distributed in the hope that it will be useful,
  41 but WITHOUT ANY WARRANTY; without even the implied warranty of
  42 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  43 GNU General Public License for more details.
  44
  45 You should have received a copy of the GNU General Public License
  46 along with this program; if not, write to the Free Software
  47 Foundation, Inc., 51 Franklin Street, Fifth Floor,
  48 Boston, MA 02110-1301, USA.])
  49
  50 b4_comment([As a special exception, you may create a larger work that contains
  51 part or all of the Bison parser skeleton and distribute that work
  52 under terms of your choice, so long as that work isn't itself a
  53 parser generator using the skeleton or a modified version thereof
  54 as a parser skeleton.  Alternatively, if you modify or redistribute
  55 the parser skeleton itself, you may (at your option) remove this
  56 special exception, which will cause the skeleton and the resulting
  57 Bison output files to be licensed under the GNU General Public
  58 License without this special exception.
  59
  60 This special exception was added by the Free Software Foundation in
  61 version 2.2 of Bison.])])
  62
  63
  64 ## ---------------- ##
  65 ## Error handling.  ##
  66 ## ---------------- ##
  67
  68 # b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
  69 # -------------------------------------------
  70 # Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
  71 m4_define([b4_error],
  72 [m4_divert_push(0)[@]$1[(]$2[]m4_if([$#], [2], [],
  73 [m4_foreach([b4_arg],
  74             m4_dquote(m4_shift(m4_shift($@))),
  75             [[@,]b4_arg])])[@)]m4_divert_pop(0)])
  76
  77 # b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
  78 # ----------------------------------------------------------
  79 # Write @KIND(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
  80 m4_define([b4_error_at],
  81 [m4_divert_push(0)[@]$1[_at(]$2[@,]$3[@,]$4[]m4_if([$#], [4], [],
  82 [m4_foreach([b4_arg],
  83             m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
  84             [[@,]b4_arg])])[@)]m4_divert_pop(0)])
  85
  86 # b4_warn(FORMAT, [ARG1], [ARG2], ...)
  87 # ------------------------------------
  88 # Write @warn(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
  89 #
  90 # As a simple test suite, this:
  91 #
  92 #   m4_define([asdf], [ASDF])
  93 #   m4_define([fsa], [FSA])
  94 #   m4_define([fdsa], [FDSA])
  95 #   b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
  96 #   m4_divert(0)
  97 #   b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
  98 #   m4_divert(0)
  99 #   b4_warn([asdf), asdf], [fsa), fsa], [fdsa), fdsa])
 100 #   m4_divert(0)
 101 #   b4_warn()
 102 #   m4_divert(0)
 103 #   b4_warn(1)
 104 #   m4_divert(0)
 105 #   b4_warn(1, 2)
 106 #
 107 # Should produce this:
 108 #
 109 #   @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
 110 #   @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
 111 #   @warn(ASDF), ASDF@,FSA), FSA@,FDSA), FDSA@)
 112 #   @warn(@)
 113 #   @warn(1@)
 114 #   @warn(1@,2@)
 115 m4_define([b4_warn],
 116 [b4_error([[warn]], $@)])
 117
 118 # b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 119 # ---------------------------------------------------
 120 # Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
 121 m4_define([b4_warn_at],
 122 [b4_error_at([[warn]], $@)])
 123
 124 # b4_complain(FORMAT, [ARG1], [ARG2], ...)
 125 # ----------------------------------------
 126 # Write @complain(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
 127 #
 128 # See the test suite for b4_warn above.
 129 m4_define([b4_complain],
 130 [b4_error([[complain]], $@)])
 131
 132 # b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 133 # -------------------------------------------------------
 134 # Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
 135 m4_define([b4_complain_at],
 136 [b4_error_at([[complain]], $@)])
 137
 138 # b4_fatal(FORMAT, [ARG1], [ARG2], ...)
 139 # -------------------------------------
 140 # Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
 141 #
 142 # See the test suite for b4_warn above.
 143 m4_define([b4_fatal],
 144 [b4_error([[fatal]], $@)])
 145
 146 # b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 147 # ----------------------------------------------------
 148 # Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
 149 m4_define([b4_fatal_at],
 150 [b4_error_at([[fatal]], $@)])
 151
 152
 153 ## ---------------- ##
 154 ## Default values.  ##
 155 ## ---------------- ##
 156
 157 # m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
 158 m4_define_default([b4_pre_prologue], [])
 159 m4_define_default([b4_post_prologue], [])
 160 m4_define_default([b4_epilogue], [])
 161 m4_define_default([b4_parse_param], [])
 162
 163 # The initial column and line.
 164 m4_define_default([b4_location_initial_column], [1])
 165 m4_define_default([b4_location_initial_line],   [1])
 166
 167
 168 ## ------------ ##
 169 ## Data Types.  ##
 170 ## ------------ ##
 171
 172 # b4_ints_in(INT1, INT2, LOW, HIGH)
 173 # ---------------------------------
 174 # Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
 175 m4_define([b4_ints_in],
 176 [m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
 177
 178
 179
 180 ## ------------------ ##
 181 ## Decoding options.  ##
 182 ## ------------------ ##
 183
 184 # b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
 185 # -----------------------------------
 186 # Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
 187 m4_define([b4_flag_if],
 188 [m4_case(b4_$1_flag,
 189          [0], [$3],
 190          [1], [$2],
 191          [m4_fatal([invalid $1 value: ]$1)])])
 192
 193
 194 # b4_define_flag_if(FLAG)
 195 # -----------------------
 196 # Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
 197 # value of the Boolean FLAG.
 198 m4_define([b4_define_flag_if],
 199 [_b4_define_flag_if($[1], $[2], [$1])])
 200
 201 # _b4_define_flag_if($1, $2, FLAG)
 202 # --------------------------------
 203 # This macro works around the impossibility to define macros
 204 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 205 # This sucks hard, GNU M4 should really provide M5 like $$1.
 206 m4_define([_b4_define_flag_if],
 207 [m4_if([$1$2], $[1]$[2], [],
 208        [m4_fatal([$0: Invalid arguments: $@])])dnl
 209 m4_define([b4_$3_if],
 210           [b4_flag_if([$3], [$1], [$2])])])
 211
 212
 213 # b4_FLAG_if(IF-TRUE, IF-FALSE)
 214 # -----------------------------
 215 # Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
 216 b4_define_flag_if([defines])            # Whether headers are requested.
 217 b4_define_flag_if([error_verbose])      # Whether error are verbose.
 218 b4_define_flag_if([glr])                # Whether a GLR parser is requested.
 219 b4_define_flag_if([locations])          # Whether locations are tracked.
 220 b4_define_flag_if([nondeterministic])   # Whether conflicts should be handled.
 221 b4_define_flag_if([pull])               # Whether pull parsing is requested.
 222 b4_define_flag_if([pure])               # Whether the interface is pure.
 223 b4_define_flag_if([push])               # Whether push parsing is requested.
 224 b4_define_flag_if([use_push_for_pull])  # Whether push parsing should be used
 225                                         # in place of pull parsing (where
 226                                         # available) for the sake of the test
 227                                         # suite.
 228 b4_define_flag_if([yacc])               # Whether POSIX Yacc is emulated.
 229
 230
 231 ## ------------------------- ##
 232 ## Assigning token numbers.  ##
 233 ## ------------------------- ##
 234
 235
 236 ## ----------- ##
 237 ## Synclines.  ##
 238 ## ----------- ##
 239
 240 # b4_basename(NAME)
 241 # -----------------
 242 # Similar to POSIX basename; the differences don't matter here.
 243 # Beware that NAME is not evaluated.
 244 m4_define([b4_basename],
 245 [m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
 246
 247
 248 # b4_syncline(LINE, FILE)
 249 # -----------------------
 250 m4_define([b4_syncline],
 251 [b4_flag_if([synclines], [
 252 b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
 253 b4_sync_start([$1], [$2])])])
 254
 255 m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
 256 m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
 257
 258 # b4_user_code(USER-CODE)
 259 # -----------------------
 260 # Emit code from the user, ending it with synclines.
 261 m4_define([b4_user_code],
 262 [$1
 263 b4_syncline([@oline@], [@ofile@])])
 264
 265
 266 # b4_define_user_code(MACRO)
 267 # --------------------------
 268 # From b4_MACRO, build b4_user_MACRO that includes the synclines.
 269 m4_define([b4_define_user_code],
 270 [m4_define([b4_user_$1],
 271 [b4_user_code([b4_$1])])])
 272
 273
 274 # b4_user_actions
 275 # b4_user_initial_action
 276 # b4_user_post_prologue
 277 # b4_user_pre_prologue
 278 # b4_user_stype
 279 # ----------------------
 280 # Macros that issue user code, ending with synclines.
 281 b4_define_user_code([actions])
 282 b4_define_user_code([initial_action])
 283 b4_define_user_code([post_prologue])
 284 b4_define_user_code([pre_prologue])
 285 b4_define_user_code([stype])
 286
 287
 288 # b4_check_user_names(WHAT, USER-LIST, SKELETON-LIST)
 289 # ---------------------------------------------------
 290 # Warn if any name of type WHAT is used by the user (as recorded in USER-LIST)
 291 # but is not used by the skeleton (as recorded in SKELETON-LIST).
 292 #
 293 # USER-LIST must expand to a list specifying all grammar occurrences of all
 294 # names of type WHAT.   Each item in the list is a triplet specifying one
 295 # occurrence: name, start boundary, and end boundary.  Empty string names are
 296 # fine.  An empty list is fine.
 297 #
 298 # For example, to define b4_user_foo_names to be used for USER-LIST with three
 299 # name occurrences and with correct quoting:
 300 #
 301 #   m4_define([b4_user_foo_names],
 302 #             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
 303 #               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
 304 #               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
 305 #
 306 # SKELETON-LIST must expand to a list specifying all names of type WHAT that
 307 # are used by the skeleton.  Multiple occurrences of the same name are fine.
 308 # Empty string names are fine, but it would be ugly for a Bison skeleton to
 309 # actually use one.  An empty list is fine.
 310 #
 311 # For example, to define b4_skeleton_foo_names to be used for SKELETON-LIST
 312 # with two names and with correct quoting:
 313 #
 314 #   m4_define([b4_skeleton_foo_names],
 315 #             [[[[bar]], [[baz]]]])
 316 #
 317 # To invoke b4_check_user_names with TYPE foo, with USER-LIST
 318 # b4_user_foo_names, with SKELETON-LIST b4_skeleton_foo_names, and with correct
 319 # quoting:
 320 #
 321 #   b4_check_user_names([[foo]], [b4_user_foo_names], [b4_skeleton_foo_names])
 322 m4_define([b4_check_user_names],
 323 [m4_foreach([b4_occurrence], $2,
 324 [m4_pushdef([b4_occurrence], b4_occurrence)dnl
 325 m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
 326 m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
 327 m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
 328 m4_pushdef([b4_found], [[0]])dnl
 329 m4_foreach([b4_skeleton_name], $3,
 330            [m4_if(m4_quote(b4_user_name),
 331                   m4_quote(b4_skeleton_name),
 332                   [m4_define([b4_found], [[1]])])])dnl
 333 m4_if(b4_found, [0], [b4_warn_at([b4_start], [b4_end],
 334                                  [[%s `%s' is not used]],
 335                                  [$1], [b4_user_name])])[]dnl
 336 m4_popdef([b4_found])dnl
 337 m4_popdef([b4_occurrence])dnl
 338 m4_popdef([b4_user_name])dnl
 339 m4_popdef([b4_start])dnl
 340 m4_popdef([b4_end])dnl
 341 ])])
 342
 343 # b4_get_percent_define(VARIABLE)
 344 # --------------------------------
 345 # If the %define variable VARIABLE is defined, emit it.  Also, record VARIABLE
 346 # in b4_skeleton_percent_define_variables.
 347 m4_define([b4_get_percent_define],
 348 [m4_append([b4_skeleton_percent_define_variables], [[$1]], [[, ]])dnl
 349 m4_ifdef([b4_percent_define_]$1, [b4_percent_define_]$1)])
 350
 351 # b4_get_percent_code([QUALIFIER])
 352 # --------------------------------
 353 # If any %code blocks for QUALIFIER are defined, emit them beginning with a
 354 # comment and ending with synclines and a newline.  If QUALIFIER is not
 355 # specified (thus, b4_get_percent_code is invoked without parens), do this for
 356 # the unqualified %code blocks.  Also, record QUALIFIER (if specified) in
 357 # b4_skeleton_percent_code_qualifiers.
 358 m4_define([b4_get_percent_code],
 359 [m4_pushdef([b4_macro_name], [[b4_percent_code]]m4_if([$#], [1], [[[_]$1]]))dnl
 360 m4_if([$#], [1],
 361       [m4_append([b4_skeleton_percent_code_qualifiers], [[$1]], [[, ]])])dnl
 362 m4_ifdef(b4_macro_name,
 363 [b4_comment([m4_if([$#], [0], [[Unqualified %code]],
 364                    [[%code "]$1["]])[ blocks.]])
 365 b4_user_code(b4_macro_name)])dnl
 366 m4_popdef([b4_macro_name])])
 367
 368
 369 ## --------------------------------------------------------- ##
 370 ## After processing the skeletons, check that all the user's ##
 371 ## %define variables and %code qualifiers were used.         ##
 372 ## --------------------------------------------------------- ##
 373
 374 m4_wrap([
 375 m4_pushdef([b4_check_user_names_wrap],
 376 [m4_ifdef([b4_skeleton_percent_$1],
 377           [m4_define([b4_skeleton_percent_$1],
 378                      m4_dquote(m4_dquote(b4_skeleton_percent_$1)))],
 379           [m4_define([b4_skeleton_percent_$1], [[]])])
 380
 381 m4_ifdef([b4_user_percent_$1],
 382          [b4_check_user_names([$2],
 383                               [b4_user_percent_$1],
 384                               [b4_skeleton_percent_$1])])
 385 ])
 386
 387 b4_check_user_names_wrap([define_variables], [[%define variable]])
 388 b4_check_user_names_wrap([code_qualifiers], [[%code qualifier]])
 389
 390 m4_popdef([b4_check_user_names_wrap])
 391 ])