tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # We want a recent Autotest.
  21 m4_version_prereq([2.58])
  22
  23
  24 ## ------------- ##
  25 ## Basic tests.  ##
  26 ## ------------- ##
  27
  28 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  29 # ------------------------------------------
  30 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  31 # taken in "slurp" mode, i.e., one can match end-of-lines.
  32 m4_define([AT_MATCHES_CHECK],
  33 [AT_CHECK([perl -0777 -ne '
  34 my $count = 0;
  35 s{$2}{ ++$count; "" }gem;
  36 printf "$count\n";' $1], [0], [$3
  37 ])])
  38
  39
  40 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  41 # ------------------------------------------------
  42 # Don't interfere with caller's files.
  43 m4_divert_text([PREPARE_TESTS],
  44 [at_save_special_files ()
  45 {
  46   for at_save_file in stderr experr expout
  47   do
  48     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  49   done
  50 }
  51
  52 at_restore_special_files ()
  53 {
  54   for at_save_file in stderr experr expout
  55   do
  56     test ! -f at-bison-check-$at_save_file.bak ||
  57       mv at-bison-check-$at_save_file.bak $at_save_file
  58   done
  59 }
  60 ])
  61
  62 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  63 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  64
  65
  66
  67 ## ------------------------------- ##
  68 ## Macros decoding Bison options.  ##
  69 ## ------------------------------- ##
  70
  71 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  72 # ----------------------------------------------------------------
  73 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  74 m4_define([AT_LOC_PUSHDEF],
  75 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  76 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  77 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  78 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  79
  80 # AT_LOC_POPDEF
  81 # -------------
  82 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  83 m4_define([AT_LOC_POPDEF],
  84 [m4_popdef([AT_LOC_FIRST_LINE])
  85 m4_popdef([AT_LOC_FIRST_COLUMN])
  86 m4_popdef([AT_LOC_LAST_LINE])
  87 m4_popdef([AT_LOC_LAST_COLUMN])])
  88
  89
  90
  91 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  92 # -----------------------------------------
  93 m4_define([AT_BISON_OPTION_PUSHDEFS],
  94 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  95
  96
  97 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  98 # --------------------------------------------------
  99 # This macro works around the impossibility to define macros
 100 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 101 # This sucks hard, GNU M4 should really provide M5 like $$1.
 102 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 103 [m4_if([$1$2], $[1]$[2], [],
 104        [m4_fatal([$0: Invalid arguments: $@])])dnl
 105 m4_pushdef([AT_DEFINES_IF],
 106 [m4_bmatch([$3], [%defines], [$1], [$2])])
 107 m4_pushdef([AT_SKEL_CC_IF],
 108 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 109 m4_pushdef([AT_SKEL_JAVA_IF],
 110 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 111 m4_pushdef([AT_LANG],
 112 [AT_SKEL_JAVA_IF([java],
 113                  [AT_SKEL_CC_IF([cxx],
 114                                 [c])])])
 115 m4_pushdef([AT_GLR_IF],
 116 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 117 m4_pushdef([AT_LALR1_CC_IF],
 118 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 119 m4_pushdef([AT_GLR_CC_IF],
 120 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 121 # Using yacc.c?
 122 m4_pushdef([AT_YACC_IF],
 123 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 124 m4_pushdef([AT_LEXPARAM_IF],
 125 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 126 m4_pushdef([AT_LOCATION_IF],
 127 [m4_bmatch([$3], [%locations], [$1], [$2])])
 128 m4_pushdef([AT_LOCATION_TYPE_IF],
 129 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
 130 m4_pushdef([AT_PARAM_IF],
 131 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 132 m4_pushdef([AT_PURE_IF],
 133 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 134            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 135            [$2])])
 136 m4_pushdef([AT_PURE_AND_LOC_IF],
 137 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 138 m4_pushdef([AT_GLR_OR_PARAM_IF],
 139 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 140 m4_pushdef([AT_NAME_PREFIX],
 141 [m4_bmatch([$3], [%name-prefix ".*"],
 142            [m4_bregexp([$3], [name-prefix "\([^""]*\)"], [\1])],
 143            [yy])])
 144 m4_pushdef([AT_API_PREFIX],
 145 [m4_bmatch([$3], [%define api\.prefix ".*"],
 146            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 147            [yy])])
 148 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 149 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 150 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 151                     [$2])])
 152 # yyerror always sees the locations (when activated), except if
 153 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 154 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 155 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 156                                         [$1])],
 157                             [$1])],
 158                 [$2])])
 159
 160 # The interface is pure: either because %define api.pure, or because we
 161 # are using the C++ parsers.
 162 m4_pushdef([AT_PURE_LEX_IF],
 163 [AT_PURE_IF([$1],
 164             [AT_SKEL_CC_IF([$1], [$2])])])
 165
 166 AT_PURE_LEX_IF(
 167 [m4_pushdef([AT_LOC], [(*llocp)])
 168  m4_pushdef([AT_VAL], [(*lvalp)])
 169  m4_pushdef([AT_LEX_FORMALS],
 170             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 171  m4_pushdef([AT_LEX_ARGS],
 172             [lvalp[]AT_LOCATION_IF([, llocp])])
 173  m4_pushdef([AT_USE_LEX_ARGS],
 174             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 175  m4_pushdef([AT_LEX_PRE_FORMALS],
 176             [AT_LEX_FORMALS, ])
 177  m4_pushdef([AT_LEX_PRE_ARGS],
 178             [AT_LEX_ARGS, ])
 179 ],
 180 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 181  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 182  m4_pushdef([AT_LEX_FORMALS],     [void])
 183  m4_pushdef([AT_LEX_ARGS],        [])
 184  m4_pushdef([AT_USE_LEX_ARGS],    [])
 185  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 186  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 187 ])
 188
 189 # Handle the different types of location components.
 190
 191 AT_SKEL_CC_IF(
 192   [AT_LOCATION_TYPE_IF(
 193     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 194     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 195   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 196
 197 ])# _AT_BISON_OPTION_PUSHDEFS
 198
 199
 200 # AT_BISON_OPTION_POPDEFS
 201 # -----------------------
 202 m4_define([AT_BISON_OPTION_POPDEFS],
 203 [m4_popdef([AT_LEX_PRE_ARGS])
 204 m4_popdef([AT_LEX_PRE_FORMALS])
 205 m4_popdef([AT_USE_LEX_ARGS])
 206 m4_popdef([AT_LEX_ARGS])
 207 m4_popdef([AT_LEX_FORMALS])
 208 m4_popdef([AT_VAL])
 209 m4_popdef([AT_LOC])
 210 m4_popdef([AT_PURE_LEX_IF])
 211 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 212 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 213 m4_popdef([AT_API_PREFIX])
 214 m4_popdef([AT_NAME_PREFIX])
 215 m4_popdef([AT_GLR_OR_PARAM_IF])
 216 m4_popdef([AT_PURE_AND_LOC_IF])
 217 m4_popdef([AT_LOCATION_TYPE_IF])
 218 m4_popdef([AT_LOCATION_IF])
 219 m4_popdef([AT_PARAM_IF])
 220 m4_popdef([AT_LEXPARAM_IF])
 221 m4_popdef([AT_YACC_IF])
 222 m4_popdef([AT_GLR_IF])
 223 m4_popdef([AT_SKEL_CC_IF])
 224 m4_popdef([AT_LANG])
 225 m4_popdef([AT_SKEL_JAVA_IF])
 226 m4_popdef([AT_GLR_CC_IF])
 227 m4_popdef([AT_LALR1_CC_IF])
 228 m4_popdef([AT_DEFINES_IF])
 229 AT_LOC_POPDEF
 230 ])# AT_BISON_OPTION_POPDEFS
 231
 232
 233
 234 ## -------------------------- ##
 235 ## Generating Grammar Files.  ##
 236 ## -------------------------- ##
 237
 238 # AT_DATA_SOURCE_PROLOGUE
 239 # ------------------------
 240 # The prologue that should be included in any source code that is
 241 # meant to be compiled.
 242 m4_define([AT_DATA_SOURCE_PROLOGUE],
 243 [[#include <config.h>
 244 /* We don't need perfect functions for these tests. */
 245 #undef malloc
 246 #undef memcmp
 247 #undef realloc
 248 ]])
 249
 250 # AT_DATA_GRAMMAR_PROLOGUE
 251 # ------------------------
 252 # The prologue that should be included in any grammar which parser is
 253 # meant to be compiled.
 254 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 255 [[%code top {
 256 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 257 [}
 258 ]])
 259
 260 # AT_DATA_SOURCE(NAME, CONTENT)
 261 # -----------------------------
 262 # Generate the file NAME, which CONTENT is preceded by
 263 # AT_DATA_SOURCE_PROLOGUE.
 264 m4_define([AT_DATA_SOURCE],
 265 [AT_DATA([$1],
 266 [AT_DATA_SOURCE_PROLOGUE
 267 $2])
 268 ])
 269
 270 # AT_DATA_GRAMMAR(NAME, CONTENT)
 271 # ------------------------------
 272 # Generate the file NAME, which CONTENT is preceded by
 273 # AT_DATA_GRAMMAR_PROLOGUE.
 274 m4_define([AT_DATA_GRAMMAR],
 275 [AT_DATA([$1],
 276 [AT_DATA_GRAMMAR_PROLOGUE
 277 $2])
 278 ])
 279
 280 # AT_YYLEX_DECLARE_EXTERN
 281 # AT_YYLEX_DECLARE
 282 # AT_YYLEX_DEFINE(INPUT-STRING, [ACTION])
 283 # ---------------------------------------
 284 m4_define([AT_YYLEX_DECLARE_EXTERN],
 285 [int AT_API_PREFIX[]lex (void);dnl
 286 ])
 287
 288 m4_define([AT_YYLEX_DECLARE],
 289 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 290 ])
 291
 292 m4_define([AT_YYLEX_DEFINE],
 293 [[#include <stdlib.h> /* abort */
 294 static int
 295 ]AT_API_PREFIX[lex (void)
 296 {
 297   static char const input[] = "$1";
 298   static size_t toknum = 0;
 299   int res;
 300   if (! (toknum < sizeof input))
 301     abort ();
 302   res = input[toknum++];
 303   ]$2;[]AT_LOCATION_IF([[
 304   ]AT_API_PREFIX[lloc.first_line = ]AT_API_PREFIX[lloc.last_line = 1;
 305   ]AT_API_PREFIX[lloc.first_column = ]AT_API_PREFIX[lloc.last_column = toknum;]])[
 306   return res;
 307 }]dnl
 308 ])
 309
 310 # AT_YYERROR_DECLARE_EXTERN
 311 # AT_YYERROR_DECLARE
 312 # AT_YYERROR_DEFINE
 313 # -------------------------
 314 # Beware that must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS
 315 # pair.
 316 m4_define([AT_YYERROR_DECLARE_EXTERN],
 317 [void AT_API_PREFIX[]error (const char *msg);dnl
 318 ])
 319
 320 m4_define([AT_YYERROR_DECLARE],
 321 [static AT_YYERROR_DECLARE_EXTERN[]dnl
 322 ])
 323
 324 m4_define([AT_YYERROR_DEFINE],
 325 [AT_SKEL_JAVA_IF([[public void yyerror (String msg)
 326 {
 327   System.err.println (msg);
 328 }]], [AT_SKEL_CC_IF([[void
 329 yy::parser::error (const yy::location &, std::string const &msg)
 330 {
 331   std::cerr << msg << std::endl;
 332 }]], [[#include <stdio.h>
 333 static void
 334 ]AT_API_PREFIX[error (char const *msg)
 335 {
 336   fprintf (stderr, "%s\n", msg);
 337 }]])])dnl
 338 ])
 339
 340 ## --------------- ##
 341 ## Running Bison.  ##
 342 ## --------------- ##
 343
 344 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 345 # -------------------------------------------------
 346 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 347 # shell constructs (such as redirection or pipes) that would prevent
 348 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 349 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 350 #
 351 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 352 # Bison in the test suite.  For now it ensures that:
 353 #
 354 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 355 #      a non-zero exit status since Bison doesn't always try to free all memory
 356 #      in that case.
 357 #
 358 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 359 #      --graph and --report=all output for every working grammar.
 360 #
 361 #   3. If stderr contains a warning, -Werror and --warnings=error
 362 #      convert the warning to an error.
 363 #
 364 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 365 m4_define([AT_BISON_CHECK],
 366 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 367        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 368 AT_BISON_CHECK_NO_XML($@)])
 369
 370 m4_define([AT_BISON_WERROR_MSG],
 371           [[bison: warnings being treated as errors]])
 372
 373 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 374 # --------------------------------------------------------
 375 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 376 # when a tortured grammar's XML is known to be too large for xsltproc to
 377 # handle.
 378 m4_define([AT_BISON_CHECK_NO_XML],
 379 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 380                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 381 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 382       m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0], [[
 383         # Defining POSIXLY_CORRECT causes bison to complain if options
 384         # are added after the grammar file name, so skip these checks
 385         # in that case.
 386         if test -z "${POSIXLY_CORRECT+set}"; then
 387           ]AT_SAVE_SPECIAL_FILES[
 388
 389           # To avoid expanding it repeatedly, store specified stdout.
 390           ]AT_DATA([expout], [$3])[
 391
 392           # Run with -Werror.
 393           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Werror]],
 394                     [[1]], [expout], [stderr])[
 395
 396           # Build expected stderr up to and including the "warnings being
 397           # treated as errors" message.
 398           ]AT_DATA([[at-bison-check-warnings]], [$4])[
 399           at_bison_check_first=`sed -n \
 400             '/: warning: /{=;q;}' at-bison-check-warnings`
 401           : ${at_bison_check_first:=1}
 402           at_bison_check_first_tmp=`sed -n \
 403             '/conflicts: [0-9].*reduce$/{=;q;}' at-bison-check-warnings`
 404           : ${at_bison_check_first_tmp:=1}
 405           if test $at_bison_check_first_tmp -lt $at_bison_check_first; then
 406             at_bison_check_first=$at_bison_check_first_tmp
 407           fi
 408           if test $at_bison_check_first -gt 1; then
 409             sed -n "1,`expr $at_bison_check_first - 1`"p \
 410               at-bison-check-warnings > experr
 411           fi
 412           echo ']AT_BISON_WERROR_MSG[' >> experr
 413
 414           # Finish building expected stderr and check.  Unlike warnings,
 415           # complaints cause bison to exit early.  Thus, with -Werror, bison
 416           # does not necessarily report all warnings that it does without
 417           # -Werror, but it at least reports one.
 418           at_bison_check_last=`sed -n '$=' stderr`
 419           : ${at_bison_check_last:=1}
 420           at_bison_check_last=`expr $at_bison_check_last - 1`
 421           sed -n "$at_bison_check_first,$at_bison_check_last"p \
 422             at-bison-check-warnings >> experr
 423           ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 424                       stderr 1>&2]], [[0]], [[]], [experr])[
 425
 426           # Now check --warnings=error.
 427           cp stderr experr
 428           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=error]],
 429                     [[1]], [expout], [experr])[
 430
 431           # Now check -Wnone and --warnings=none by making sure that
 432           # -Werror doesn't change the exit status when -Wnone or
 433           # --warnings=none is specified.
 434           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Wnone -Werror]],
 435                     [[0]], [expout])[
 436           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=none \
 437                     -Werror]], [[0]], [expout])[
 438
 439           ]AT_RESTORE_SPECIAL_FILES[
 440         fi
 441       ]])
 442 ])
 443
 444 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 445 # -----------------------------------------------------
 446 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 447 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 448 # have a non-zero exit status.
 449 m4_define([AT_BISON_CHECK_XML],
 450 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 451   AT_SAVE_SPECIAL_FILES
 452   [mkdir xml-tests]
 453   m4_pushdef([AT_BISON_ARGS],
 454              [m4_bpatsubsts([[$1]],
 455                             [--report(-file)?=[^][ ]*], [],
 456                             [--graph=[^][ ]*], [],
 457                             [--xml=[^][ ]*], [])])dnl
 458   # Don't combine these Bison invocations since we want to be sure that
 459   # --report=all isn't required to get the full XML file.
 460   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 461              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 462            [[0]], [ignore], [ignore])
 463   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 464            [[0]], [ignore], [ignore])
 465   m4_popdef([AT_BISON_ARGS])dnl
 466   [cp xml-tests/test.output expout]
 467   AT_CHECK([[$XSLTPROC \
 468              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 469              xml-tests/test.xml]], [[0]], [expout])
 470   [cp xml-tests/test.dot expout]
 471   AT_CHECK([[$XSLTPROC \
 472              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 473              xml-tests/test.xml]], [[0]], [expout])
 474   [rm -rf xml-tests expout]
 475   AT_RESTORE_SPECIAL_FILES
 476 [fi]])
 477
 478 # AT_QUELL_VALGRIND
 479 # -----------------
 480 # Put this before a Bison invocation to keep Valgrind from complaining about
 481 # reachable memory.
 482 #
 483 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 484 # The triple quoting below will cause test cases to fail if you do.  If you do
 485 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 486 # will then fail to shell-escape its contents when attempting to print them.
 487 # The testsuite verbose output, at least, will be incorrect, but nothing may
 488 # fail to make sure you notice.
 489 m4_define([AT_QUELL_VALGRIND],
 490 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 491
 492 ## ------------------------ ##
 493 ## Compiling C, C++ Files.  ##
 494 ## ------------------------ ##
 495
 496
 497 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 498 # ----------------------------------------
 499 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 500 # assume that we are linking too; this is a hack.
 501 m4_define([AT_COMPILE],
 502 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 503            0, [ignore], [ignore])])
 504
 505 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 506 # --------------------------------------------
 507 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 508 # assume that we are linking too; this is a hack.
 509 # If the C++ compiler does not work, ignore the test.
 510 m4_define([AT_COMPILE_CXX],
 511 [AT_KEYWORDS(c++)
 512 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 513 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 514          0, [ignore], [ignore])])
 515
 516 # AT_JAVA_COMPILE(SOURCES)
 517 # ------------------------
 518 # Compile SOURCES into Java class files.  Skip the test if java or javac
 519 # is not installed.
 520 m4_define([AT_JAVA_COMPILE],
 521 [AT_KEYWORDS(java)
 522 AT_CHECK([[test -n "$CONF_JAVA" || exit 77
 523            test -n "$CONF_JAVAC" || exit 77]])
 524 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 525          [[0]], [ignore], [ignore])])
 526
 527 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 528 # --------------------------------------------
 529 m4_define([AT_LANG_COMPILE],
 530 [m4_case(AT_LANG,
 531 [c],    [AT_COMPILE([$1], [$2])],
 532 [cxx],  [AT_COMPILE_CXX([$1], [$2])],
 533 [java], [AT_JAVA_COMPILE([$1.java], [$2])],
 534         [m4_fatal([unknown language: ]m4_defn([AT_LANG]))])[]dnl
 535 ])
 536
 537 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 538 # -------------------------------------------
 539 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 540 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 541 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 542 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 543 # AT_SKEL_JAVA_IF.
 544 m4_define([AT_FULL_COMPILE],
 545 [m4_case(AT_LANG,
 546 [java],
 547   [AT_BISON_CHECK([-o $1.java $1.y])
 548    AT_LANG_COMPILE([$1],
 549                    m4_join([ ],
 550                            [$1.java],
 551                            m4_ifval($2, [[$1-$2.java]]),
 552                            m4_ifval($3, [[$1-$3.java]])))],
 553 [cxx],
 554   [AT_BISON_CHECK([-o $1.cc $1.y])
 555    AT_LANG_COMPILE([$1],
 556                    m4_join([ ],
 557                            [$1.cc],
 558                            m4_ifval($2, [[$1-$2.cc]]),
 559                            m4_ifval($3, [[$1-$3.cc]])))],
 560 [c],
 561   [AT_BISON_CHECK([-o $1.c $1.y])
 562    AT_LANG_COMPILE([$1],
 563                    m4_join([ ],
 564                            [$1.c],
 565                            m4_ifval($2, [[$1-$2.c]]),
 566                            m4_ifval($3, [[$1-$3.c]])))])
 567 ])
 568
 569
 570 ## ---------------------------- ##
 571 ## Running a generated parser.  ##
 572 ## ---------------------------- ##
 573
 574
 575 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 576 # ------------------------------------------------------------
 577 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 578 #
 579 # Get rid of spurious messages when compiled with --coverage:
 580 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 581 m4_define([AT_PARSER_CHECK],
 582 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 583 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 584          [0], [], [$4])
 585 ])
 586
 587
 588 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 589 # -----------------------------------------------------------------
 590 m4_define([AT_JAVA_PARSER_CHECK],
 591 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 592
 593
 594 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 595 #                          DECLS, GRAMMAR, INPUT,
 596 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 597 #                          [OTHER-CHECKS],
 598 #                          [PARSER-EXIT-VALUE],
 599 #                          [PARSER-STDOUT], [PARSER-STDERR])
 600 # -------------------------------------------------------------
 601 # Using TITLE as the test group title, check the generated parser tables
 602 # and parser for a specified grammar file under a condition labeled by
 603 # COND-VALUE.
 604 #
 605 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 606 # recognized attribute is described below where it is relevant.
 607 #
 608 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 609 # the grammar file.  Insert basic yyerror, yylex, and main function
 610 # definitions as well.  Hardcode yylex to return the (possibly empty)
 611 # comma-delimited series of tokens in INPUT followed by token 0.
 612 #
 613 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 614 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 615 # On the bison command-line, specify `--report=all --defines'.  Check
 616 # that Bison exits with value 0, has no stdout, and has stderr
 617 # BISON-STDERR.
 618 #
 619 # If TEST-SPEC contains the attribute `last-state', check that the value
 620 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 621 # the grammar; in other words, check the number of states (minus one).
 622 # Otherwise, check that everything in the `.output' file starting with
 623 # the definition of state 0 is the same as the entire value of
 624 # TABLES-OR-LAST-STATE.
 625 #
 626 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 627 # `.output' file, which is named `input.output', and/or grammar file,
 628 # which is named `input.y'.
 629 #
 630 # Finally, compile the generated parser and then run it using
 631 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 632 # PARSER-STDERR as the 2nd-4th arguments.
 633 #
 634 # As a precondition, you must properly double-quote all arguments that
 635 # are to be interpreted as strings.
 636 #
 637 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 638 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 639 # first argument.  This is useful, for example, when wrapping multiple
 640 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 641 # condition, in another macro.
 642 #
 643 # For example:
 644 #
 645 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 646 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 647 #   # ---------------------------------------------------------------------
 648 #   m4_define([AT_TEST_SYNTAX_ERROR],
 649 #   [
 650 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 651 #                              [[last-state]],
 652 #                              [[%error-verbose ]$2], [$3], [$4],
 653 #                              [[]], [$5], [], [$6], [$7], [$8])
 654 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 655 #                              [[last-state]],
 656 #                              [$2], [$3], [$4],
 657 #                              [[]], [$5], [], [$6], [$7], [$8])
 658 #   ])
 659 #
 660 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 661 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 662 #                        [[3]],
 663 #                        [[1]], [[]],
 664 #                        [AT_COND_CASE([[no verbose]],
 665 #                                      [[syntax error
 666 #   ]],
 667 #                                      [[syntax error, unexpected 'b', expecting $end
 668 #   ]])])
 669 m4_define([AT_TEST_TABLES_AND_PARSE],
 670 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 671
 672 AT_SETUP([$1])
 673 AT_BISON_OPTION_PUSHDEFS([$4])
 674 AT_DATA_GRAMMAR([[input.y]],
 675 [[%code {
 676   #include <stdio.h>
 677   ]AT_YYERROR_DECLARE[
 678   ]AT_YYLEX_DECLARE[
 679 }
 680
 681 ]$4[
 682
 683 %%
 684
 685 ]$5[
 686
 687 %%
 688 ]AT_YYERROR_DEFINE[
 689 static int
 690 yylex (void)
 691 {
 692   static int const input[] = {
 693     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 694   };
 695   static int const *inputp = input;
 696   return *inputp++;
 697 }
 698
 699 int
 700 main (void)
 701 {
 702   return yyparse ();
 703 }
 704 ]])
 705
 706 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 707 # expanding macros, so it corrupts some special characters in the
 708 # macros.  To avoid this, expand now and pass it the result with proper
 709 # string quotation.  Assume args 7 through 12 expand to properly quoted
 710 # strings.
 711
 712 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 713       [AT_BISON_CHECK],
 714       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 715                                [0], [], m4_dquote($7))
 716
 717 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 718       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 719                 m4_dquote($8))],
 720       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 721                 m4_dquote($8)[[
 722 ]])])
 723
 724 $9
 725
 726 # Canonical LR generates very large tables, resulting in very long
 727 # files with #line directives that may overflow what the standards
 728 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 729 # will issue an error.
 730 #
 731 # There is no "" around `wc` since some indent the result.
 732 m4_bmatch([$4], [%define lr.type canonical-lr],
 733 [if test 32767 -lt `wc -l < input.c`; then
 734   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 735   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 736 fi])
 737 AT_COMPILE([[input]])
 738
 739 AT_PARSER_CHECK([[./input]],
 740                 m4_ifval([$10], [m4_dquote($10)]),
 741                 m4_ifval([$11], [m4_dquote($11)]),
 742                 m4_ifval([$12], [m4_dquote($12)]))
 743
 744 AT_BISON_OPTION_POPDEFS
 745 AT_CLEANUP
 746
 747 m4_popdef([AT_COND_CASE])])
 748
 749
 750
 751 ## ----------------------- ##
 752 ## Launch the test suite.  ##
 753 ## ----------------------- ##
 754
 755 AT_INIT
 756
 757 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 758 # options are processed, so we don't know the value of CXX and
 759 # CXXFLAGS yet.
 760 #
 761 # Note that it also means that command line values for CXX and
 762 # CXXFLAGS will not be propagated to CC and CFLAGS.
 763 AT_ARG_OPTION([compile-c-with-cxx],
 764               [compile C parsers with the C++ compiler])
 765
 766 AT_COLOR_TESTS
 767
 768 AT_TESTED([bison])