tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2011 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # We want a recent Autotest.
  21 m4_version_prereq([2.58])
  22
  23
  24 ## ------------- ##
  25 ## Basic tests.  ##
  26 ## ------------- ##
  27
  28 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  29 # ------------------------------------------
  30 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  31 # taken in "slurp" mode, i.e., one can match end-of-lines.
  32 m4_define([AT_MATCHES_CHECK],
  33 [AT_CHECK([perl -0777 -ne '
  34 my $count = 0;
  35 s{$2}{ ++$count; "" }gem;
  36 printf "$count\n";' $1], [0], [$3
  37 ])])
  38
  39
  40 ## ------------------------------- ##
  41 ## Macros decoding Bison options.  ##
  42 ## ------------------------------- ##
  43
  44 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  45 # ----------------------------------------------------------------
  46 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  47 m4_define([AT_LOC_PUSHDEF],
  48 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  49 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  50 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  51 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  52
  53 # AT_LOC_POPDEF
  54 # -------------
  55 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  56 m4_define([AT_LOC_POPDEF],
  57 [m4_popdef([AT_LOC_FIRST_LINE])
  58 m4_popdef([AT_LOC_FIRST_COLUMN])
  59 m4_popdef([AT_LOC_LAST_LINE])
  60 m4_popdef([AT_LOC_LAST_COLUMN])])
  61
  62
  63
  64 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  65 # -----------------------------------------
  66 m4_define([AT_BISON_OPTION_PUSHDEFS],
  67 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  68
  69
  70 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  71 # --------------------------------------------------
  72 # This macro works around the impossibility to define macros
  73 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  74 # This sucks hard, GNU M4 should really provide M5-like $$1.
  75 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  76 [m4_if([$1$2], $[1]$[2], [],
  77        [m4_fatal([$0: Invalid arguments: $@])])dnl
  78 m4_pushdef([AT_DEFINES_IF],
  79 [m4_bmatch([$3], [%defines], [$1], [$2])])
  80 m4_pushdef([AT_SKEL_CC_IF],
  81 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  82 m4_pushdef([AT_SKEL_JAVA_IF],
  83 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
  84 m4_pushdef([AT_GLR_IF],
  85 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  86 m4_pushdef([AT_LALR1_CC_IF],
  87 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  88 m4_pushdef([AT_GLR_CC_IF],
  89 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  90 # Using yacc.c?
  91 m4_pushdef([AT_YACC_IF],
  92 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  93 m4_pushdef([AT_LEXPARAM_IF],
  94 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  95 m4_pushdef([AT_LOCATION_IF],
  96 [m4_bmatch([$3], [%locations], [$1], [$2])])
  97 m4_pushdef([AT_LOCATION_TYPE_IF],
  98 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
  99 m4_pushdef([AT_PARAM_IF],
 100 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 101 m4_pushdef([AT_PURE_IF],
 102 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 103            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 104            [$2])])
 105 m4_pushdef([AT_PURE_AND_LOC_IF],
 106 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 107 m4_pushdef([AT_GLR_OR_PARAM_IF],
 108 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 109 m4_pushdef([AT_NAME_PREFIX],
 110 [m4_bmatch([$3], [%name-prefix ".*"],
 111            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
 112            [yy])])
 113 m4_pushdef([AT_TOKEN_PREFIX],
 114 [m4_bmatch([$3], [%define api.tokens.prefix ".*"],
 115            [m4_bregexp([$3], [%define api.tokens.prefix "\(.*\)"], [\1])])])
 116 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 117 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 118 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 119                     [$2])])
 120 # yyerror always sees the locations (when activated), except if
 121 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 122 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 123 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 124                                         [$1])],
 125                             [$1])],
 126                 [$2])])
 127
 128 # The interface is pure: either because %define api.pure, or because we
 129 # are using the C++ parsers.
 130 m4_pushdef([AT_PURE_LEX_IF],
 131 [AT_PURE_IF([$1],
 132             [AT_SKEL_CC_IF([$1], [$2])])])
 133
 134 AT_PURE_LEX_IF(
 135 [m4_pushdef([AT_LOC], [(*llocp)])
 136  m4_pushdef([AT_VAL], [(*lvalp)])
 137  m4_pushdef([AT_LEX_FORMALS],
 138             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 139  m4_pushdef([AT_LEX_ARGS],
 140             [lvalp[]AT_LOCATION_IF([, llocp])])
 141  m4_pushdef([AT_USE_LEX_ARGS],
 142             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 143  m4_pushdef([AT_LEX_PRE_FORMALS],
 144             [AT_LEX_FORMALS, ])
 145  m4_pushdef([AT_LEX_PRE_ARGS],
 146             [AT_LEX_ARGS, ])
 147 ],
 148 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 149  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 150  m4_pushdef([AT_LEX_FORMALS],     [void])
 151  m4_pushdef([AT_LEX_ARGS],        [])
 152  m4_pushdef([AT_USE_LEX_ARGS],    [])
 153  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 154  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 155 ])
 156
 157 # Handle the different types of location components.
 158
 159 AT_SKEL_CC_IF(
 160   [AT_LOCATION_TYPE_IF(
 161     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 162     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 163   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 164
 165
 166 AT_GLR_IF([AT_KEYWORDS([glr])])
 167 ])# _AT_BISON_OPTION_PUSHDEFS
 168
 169
 170 # AT_BISON_OPTION_POPDEFS
 171 # -----------------------
 172 m4_define([AT_BISON_OPTION_POPDEFS],
 173 [m4_popdef([AT_LEX_PRE_ARGS])
 174 m4_popdef([AT_LEX_PRE_FORMALS])
 175 m4_popdef([AT_USE_LEX_ARGS])
 176 m4_popdef([AT_LEX_ARGS])
 177 m4_popdef([AT_LEX_FORMALS])
 178 m4_popdef([AT_VAL])
 179 m4_popdef([AT_LOC])
 180 m4_popdef([AT_PURE_LEX_IF])
 181 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 182 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 183 m4_popdef([AT_NAME_PREFIX])
 184 m4_popdef([AT_GLR_OR_PARAM_IF])
 185 m4_popdef([AT_PURE_AND_LOC_IF])
 186 m4_popdef([AT_LOCATION_TYPE_IF])
 187 m4_popdef([AT_LOCATION_IF])
 188 m4_popdef([AT_PARAM_IF])
 189 m4_popdef([AT_LEXPARAM_IF])
 190 m4_popdef([AT_YACC_IF])
 191 m4_popdef([AT_GLR_IF])
 192 m4_popdef([AT_SKEL_CC_IF])
 193 m4_popdef([AT_SKEL_JAVA_IF])
 194 m4_popdef([AT_GLR_CC_IF])
 195 m4_popdef([AT_LALR1_CC_IF])
 196 m4_popdef([AT_DEFINES_IF])
 197 AT_LOC_POPDEF
 198 ])# AT_BISON_OPTION_POPDEFS
 199
 200
 201
 202 ## -------------------------- ##
 203 ## Generating Grammar Files.  ##
 204 ## -------------------------- ##
 205
 206 # AT_DATA_SOURCE_PROLOGUE
 207 # ------------------------
 208 # The prologue that should be included in any source code that is
 209 # meant to be compiled.
 210 m4_define([AT_DATA_SOURCE_PROLOGUE],
 211 [[#include <config.h>
 212 /* We don't need perfect functions for these tests. */
 213 #undef malloc
 214 #undef memcmp
 215 #undef realloc
 216 ]])
 217
 218 # AT_DATA_GRAMMAR_PROLOGUE
 219 # ------------------------
 220 # The prologue that should be included in any grammar which parser is
 221 # meant to be compiled.
 222 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 223 [[%code top {
 224 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 225 [}
 226 ]])
 227
 228 # AT_DATA_SOURCE(NAME, CONTENT)
 229 # -----------------------------
 230 # Generate the file NAME, which CONTENT is preceded by
 231 # AT_DATA_SOURCE_PROLOGUE.
 232 m4_define([AT_DATA_SOURCE],
 233 [AT_DATA([$1],
 234 [AT_DATA_SOURCE_PROLOGUE
 235 $2])
 236 ])
 237
 238 # AT_DATA_GRAMMAR(NAME, CONTENT)
 239 # ------------------------------
 240 # Generate the file NAME, which CONTENT is preceded by
 241 # AT_DATA_GRAMMAR_PROLOGUE.
 242 m4_define([AT_DATA_GRAMMAR],
 243 [AT_DATA([$1],
 244 [AT_DATA_GRAMMAR_PROLOGUE
 245 $2])
 246 ])
 247
 248 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 249 # -------------------------------------------------
 250 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 251 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 252 #
 253 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 254 # Bison in the test suite.  For now it ensures that:
 255 #
 256 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 257 #      a non-zero exit status since Bison doesn't always try to free all memory
 258 #      in that case.
 259 #
 260 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 261 #      --graph and --report=all output for every working grammar.
 262 #
 263 #   3. If stderr contains a warning, -Werror and --warnings=error
 264 #      convert the warning to an error.
 265 m4_define([AT_BISON_CHECK],
 266 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 267        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 268 AT_BISON_CHECK_NO_XML($@)])
 269
 270 m4_define([AT_BISON_WERROR_MSG],
 271           [[bison: warnings being treated as errors]])
 272
 273 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 274 # --------------------------------------------------------
 275 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 276 # when a tortured grammar's XML is known to be too large for xsltproc to
 277 # handle.
 278 m4_define([AT_BISON_CHECK_NO_XML],
 279 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 280                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 281 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 282       [m4_if(m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0],
 283              [[# Don't interfere with caller's files.
 284               if test -f stderr; then
 285                 mv stderr at-bison-check-stderr.bak
 286               fi
 287               if test -f experr; then
 288                 mv experr at-bison-check-experr.bak
 289               fi
 290
 291               # Run with -Werror.
 292               ]AT_CHECK(AT_QUELL_VALGRIND[[ bison -Werror ]$1],
 293                         [[1]], [$3], [stderr])[
 294
 295               # Build expected stderr up to and including the "warnings
 296               # being treated as errors" message.
 297               ]AT_DATA([[at-bison-check-warnings]], [$4])[
 298               at_bison_check_first="` \
 299                 sed -n '/: warning: /=' at-bison-check-warnings \
 300                 | sed -n 1p \
 301               `"
 302               if test $at_bison_check_first -gt 1; then
 303                 sed -n "1,`expr $at_bison_check_first - 1`"p \
 304                   at-bison-check-warnings > experr
 305               fi
 306               echo ']AT_BISON_WERROR_MSG[' >> experr
 307
 308               # Finish building expected stderr and check.  Unlike
 309               # warnings, complaints cause bison to exit early.  Thus,
 310               # with -Werror, bison does not necessarily report all
 311               # warnings that it does without -Werror, but it at least
 312               # reports one.
 313               at_bison_check_last="`sed -n '$=' stderr`"
 314               if test x"$at_bison_check_last" = x; then
 315                 at_bison_check_last=1
 316               fi
 317               at_bison_check_last="`expr $at_bison_check_last - 1`"
 318               sed -n "$at_bison_check_first,$at_bison_check_last"p \
 319                 at-bison-check-warnings >> experr
 320               ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 321                           stderr 1>&2]], [[0]], [[]], [experr])[
 322
 323               # Now check --warnings=error.
 324               cp stderr experr
 325               ]AT_CHECK(AT_QUELL_VALGRIND[[ bison --warnings=error ]$1],
 326                         [[1]], [$3], [experr])[
 327
 328               # Restore caller's files.
 329               if test -f at-bison-check-experr.bak; then
 330                 mv at-bison-check-experr.bak experr
 331               fi
 332               if test -f at-bison-check-stderr.bak; then
 333                 mv at-bison-check-stderr.bak stderr
 334               fi
 335              ]])
 336       ])
 337 ])
 338
 339 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 340 # -----------------------------------------------------
 341 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 342 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 343 # have a non-zero exit status.
 344 m4_define([AT_BISON_CHECK_XML],
 345 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 346   mkdir xml-tests]
 347   m4_pushdef([AT_BISON_ARGS],
 348              [m4_bpatsubsts([[$1]],
 349                             [--report(-file)?=[^][ ]*], [],
 350                             [--graph=[^][ ]*], [],
 351                             [--xml=[^][ ]*], [])])dnl
 352   # Don't combine these Bison invocations since we want to be sure that
 353   # --report=all isn't required to get the full XML file.
 354   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 355              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 356            [[0]], [ignore], [ignore])
 357   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 358            [[0]], [ignore], [ignore])
 359   m4_popdef([AT_BISON_ARGS])dnl
 360   [cp xml-tests/test.output expout]
 361   AT_CHECK([[$XSLTPROC \
 362              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 363              xml-tests/test.xml]], [[0]], [expout])
 364   [cp xml-tests/test.dot expout]
 365   AT_CHECK([[$XSLTPROC \
 366              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 367              xml-tests/test.xml]], [[0]], [expout])
 368   [rm -rf xml-tests expout
 369 fi]])
 370
 371 # AT_QUELL_VALGRIND
 372 # -----------------
 373 # Put this before a Bison invocation to keep Valgrind from complaining about
 374 # reachable memory.
 375 #
 376 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 377 # The triple quoting below will cause test cases to fail if you do.  If you do
 378 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 379 # will then fail to shell-escape its contents when attempting to print them.
 380 # The testsuite verbose output, at least, will be incorrect, but nothing may
 381 # fail to make sure you notice.
 382 m4_define([AT_QUELL_VALGRIND],
 383 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 384
 385 ## ------------------------ ##
 386 ## Compiling C, C++ Files.  ##
 387 ## ------------------------ ##
 388
 389
 390 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 391 # ----------------------------------------
 392 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 393 # assume that we are linking too; this is a hack.
 394 m4_define([AT_COMPILE],
 395 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 396            0, [ignore], [ignore])])
 397
 398 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 399 # --------------------------------------------
 400 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 401 # assume that we are linking too; this is a hack.
 402 # If the C++ compiler does not work, ignore the test.
 403 m4_define([AT_COMPILE_CXX],
 404 [AT_KEYWORDS(c++)
 405 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 406 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 407          0, [ignore], [ignore])])
 408
 409 # AT_JAVA_COMPILE(SOURCES)
 410 # ------------------------
 411 # Compile SOURCES into Java class files.  Skip the test if java or javac
 412 # is not installed.
 413 m4_define([AT_JAVA_COMPILE],
 414 [AT_KEYWORDS(java)
 415 AT_CHECK([[test -n "$CONF_JAVA" || exit 77
 416            test -n "$CONF_JAVAC" || exit 77]])
 417 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 418          [[0]], [ignore], [ignore])])
 419
 420 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 421 # --------------------------------
 422 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 423 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 424 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 425 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 426 # AT_SKEL_JAVA_IF.
 427 m4_define([AT_FULL_COMPILE], [
 428   AT_SKEL_JAVA_IF([
 429     AT_BISON_CHECK([[-o ]$1[.java ]$1[.y]])
 430     AT_JAVA_COMPILE([$1[.java]]m4_ifval($2,
 431                                         [[$1[.java ]$1[-]$2[.java]]]))
 432   ], [
 433     AT_SKEL_CC_IF([
 434       AT_BISON_CHECK([[-o ]$1[.cc ]$1[.y]])
 435       AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1[.cc ]$1[-]$2[.cc]]]))
 436     ], [
 437       AT_BISON_CHECK([[-o ]$1[.c ]$1[.y]])
 438       AT_COMPILE([$1]m4_ifval($2, [, [$1[.c ]$1[-]$2[.c]]]))
 439     ])
 440   ])
 441 ])
 442
 443
 444 ## ---------------------------- ##
 445 ## Running a generated parser.  ##
 446 ## ---------------------------- ##
 447
 448 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 449 # ------------------------------------------------------------
 450 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 451 m4_define([AT_PARSER_CHECK],
 452 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 453
 454 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 455 # -----------------------------------------------------------------
 456 m4_define([AT_JAVA_PARSER_CHECK],
 457 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 458
 459 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 460 #                          DECLS, GRAMMAR, INPUT,
 461 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 462 #                          [OTHER-CHECKS],
 463 #                          [PARSER-EXIT-VALUE],
 464 #                          [PARSER-STDOUT], [PARSER-STDERR])
 465 # -------------------------------------------------------------
 466 # Using TITLE as the test group title, check the generated parser tables
 467 # and parser for a specified grammar file under a condition labeled by
 468 # COND-VALUE.
 469 #
 470 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 471 # recognized attribute is described below where it is relevant.
 472 #
 473 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 474 # the grammar file.  Insert basic yyerror, yylex, and main function
 475 # definitions as well.  Hardcode yylex to return the (possibly empty)
 476 # comma-delimited series of tokens in INPUT followed by token 0.
 477 #
 478 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 479 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 480 # On the bison command-line, specify `--report=all --defines'.  Check
 481 # that Bison exits with value 0, has no stdout, and has stderr
 482 # BISON-STDERR.
 483 #
 484 # If TEST-SPEC contains the attribute `last-state', check that the value
 485 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 486 # the grammar; in other words, check the number of states (minus one).
 487 # Otherwise, check that everything in the `.output' file starting with
 488 # the definition of state 0 is the same as the entire value of
 489 # TABLES-OR-LAST-STATE.
 490 #
 491 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 492 # `.output' file, which is named `input.output', and/or grammar file,
 493 # which is named `input.y'.
 494 #
 495 # Finally, compile the generated parser and then run it using
 496 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 497 # PARSER-STDERR as the 2nd-4th arguments.
 498 #
 499 # As a precondition, you must properly double-quote all arguments that
 500 # are to be interpreted as strings.
 501 #
 502 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 503 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 504 # first argument.  This is useful, for example, when wrapping multiple
 505 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 506 # condition, in another macro.
 507 #
 508 # For example:
 509 #
 510 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 511 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 512 #   # ---------------------------------------------------------------------
 513 #   m4_define([AT_TEST_SYNTAX_ERROR],
 514 #   [
 515 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 516 #                              [[last-state]],
 517 #                              [[%error-verbose ]$2], [$3], [$4],
 518 #                              [[]], [$5], [], [$6], [$7], [$8])
 519 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 520 #                              [[last-state]],
 521 #                              [$2], [$3], [$4],
 522 #                              [[]], [$5], [], [$6], [$7], [$8])
 523 #   ])
 524 #
 525 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 526 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 527 #                        [[3]],
 528 #                        [[1]], [[]],
 529 #                        [AT_COND_CASE([[no verbose]],
 530 #                                      [[syntax error
 531 #   ]],
 532 #                                      [[syntax error, unexpected 'b', expecting $end
 533 #   ]])])
 534 m4_define([AT_TEST_TABLES_AND_PARSE],
 535 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 536
 537 AT_SETUP([$1])
 538
 539 AT_DATA_GRAMMAR([[input.y]],
 540 [[%code {
 541   #include <stdio.h>
 542   static void yyerror (char const *msg);
 543   static int yylex (void);
 544 }
 545
 546 ]$4[
 547
 548 %%
 549
 550 ]$5[
 551
 552 %%
 553
 554 static void
 555 yyerror (char const *msg)
 556 {
 557   fprintf (stderr, "%s\n", msg);
 558 }
 559
 560 static int
 561 yylex (void)
 562 {
 563   static int const input[] = {
 564     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 565   };
 566   static int const *inputp = input;
 567   return *inputp++;
 568 }
 569
 570 int
 571 main (void)
 572 {
 573   return yyparse ();
 574 }
 575 ]])
 576
 577 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 578 # expanding macros, so it corrupts some special characters in the
 579 # macros.  To avoid this, expand now and pass it the result with proper
 580 # string quotation.  Assume args 7 thru 12 expand to properly quoted
 581 # strings.
 582
 583 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 584       [AT_BISON_CHECK],
 585       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 586                                [0], [], m4_dquote($7))
 587
 588 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 589       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 590                 m4_dquote($8))],
 591       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 592                 m4_dquote($8)[[
 593 ]])])
 594
 595 $9
 596
 597 AT_COMPILE([[input]])
 598
 599 AT_PARSER_CHECK([[./input]],
 600                 m4_ifval([$10], [m4_dquote($10)]),
 601                 m4_ifval([$11], [m4_dquote($11)]),
 602                 m4_ifval([$12], [m4_dquote($12)]))
 603
 604 AT_CLEANUP
 605
 606 m4_popdef([AT_COND_CASE])])
 607
 608
 609
 610 ## ----------------------- ##
 611 ## Launch the test suite.  ##
 612 ## ----------------------- ##
 613
 614 AT_INIT
 615
 616 AT_TESTED([bison])