data/bison.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Language-independent M4 Macros for Bison.
   4 # Copyright (C) 2002, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19
  20 ## ---------------- ##
  21 ## Identification.  ##
  22 ## ---------------- ##
  23
  24 # b4_copyright(TITLE, YEARS)
  25 # --------------------------
  26 m4_define([b4_copyright],
  27 [b4_comment([A Bison parser, made by GNU Bison b4_version.])
  28
  29 b4_comment([$1
  30
  31 m4_text_wrap([Copyright (C) $2 Free Software Foundation, Inc.], [   ])
  32
  33 This program is free software: you can redistribute it and/or modify
  34 it under the terms of the GNU General Public License as published by
  35 the Free Software Foundation, either version 3 of the License, or
  36 (at your option) any later version.
  37
  38 This program is distributed in the hope that it will be useful,
  39 but WITHOUT ANY WARRANTY; without even the implied warranty of
  40 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  41 GNU General Public License for more details.
  42
  43 You should have received a copy of the GNU General Public License
  44 along with this program.  If not, see <http://www.gnu.org/licenses/>.])
  45
  46 b4_comment([As a special exception, you may create a larger work that contains
  47 part or all of the Bison parser skeleton and distribute that work
  48 under terms of your choice, so long as that work isn't itself a
  49 parser generator using the skeleton or a modified version thereof
  50 as a parser skeleton.  Alternatively, if you modify or redistribute
  51 the parser skeleton itself, you may (at your option) remove this
  52 special exception, which will cause the skeleton and the resulting
  53 Bison output files to be licensed under the GNU General Public
  54 License without this special exception.
  55
  56 This special exception was added by the Free Software Foundation in
  57 version 2.2 of Bison.])])
  58
  59
  60 ## ---------------- ##
  61 ## Error handling.  ##
  62 ## ---------------- ##
  63
  64 # The following error handling macros print error directives that should not
  65 # become arguments of other macro invocations since they would likely then be
  66 # mangled.  Thus, they print to stdout directly.
  67
  68 # b4_cat(TEXT)
  69 # ------------
  70 # Write TEXT to stdout.  Precede the final newline with an @ so that it's
  71 # escaped.  For example:
  72 #
  73 #   b4_cat([[@complain(invalid input@)]])
  74 m4_define([b4_cat],
  75 [m4_syscmd([cat <<'_m4eof'
  76 ]m4_bpatsubst(m4_dquote($1), [_m4eof], [_m4@`eof])[@
  77 _m4eof])dnl
  78 m4_if(m4_sysval, [0], [], [m4_fatal([$0: cannot write to stdout])])])
  79
  80 # b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
  81 # -------------------------------------------
  82 # Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to stdout.
  83 #
  84 # For example:
  85 #
  86 #   b4_error([[warn]], [[invalid value for `%s': %s]], [[foo]], [[3]])
  87 m4_define([b4_error],
  88 [b4_cat([[@]$1[(]$2[]]dnl
  89 [m4_if([$#], [2], [],
  90        [m4_foreach([b4_arg],
  91                    m4_dquote(m4_shift(m4_shift($@))),
  92                    [[@,]b4_arg])])[@)]])])
  93
  94 # b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
  95 # ----------------------------------------------------------
  96 # Write @KIND_at(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
  97 #
  98 # For example:
  99 #
 100 #   b4_error_at([[complain]], [[input.y:2.3]], [[input.y:5.4]],
 101 #               [[invalid %s]], [[foo]])
 102 m4_define([b4_error_at],
 103 [b4_cat([[@]$1[_at(]$2[@,]$3[@,]$4[]]dnl
 104 [m4_if([$#], [4], [],
 105        [m4_foreach([b4_arg],
 106                    m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
 107                    [[@,]b4_arg])])[@)]])])
 108
 109 # b4_warn(FORMAT, [ARG1], [ARG2], ...)
 110 # ------------------------------------
 111 # Write @warn(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 112 #
 113 # For example:
 114 #
 115 #   b4_warn([[invalid value for `%s': %s]], [[foo]], [[3]])
 116 #
 117 # As a simple test suite, this:
 118 #
 119 #   m4_divert(-1)
 120 #   m4_define([asdf], [ASDF])
 121 #   m4_define([fsa], [FSA])
 122 #   m4_define([fdsa], [FDSA])
 123 #   b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
 124 #   b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
 125 #   b4_warn()
 126 #   b4_warn(1)
 127 #   b4_warn(1, 2)
 128 #
 129 # Should produce this without newlines:
 130 #
 131 #   @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
 132 #   @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
 133 #   @warn(@)
 134 #   @warn(1@)
 135 #   @warn(1@,2@)
 136 m4_define([b4_warn],
 137 [b4_error([[warn]], $@)])
 138
 139 # b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 140 # ---------------------------------------------------
 141 # Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 142 #
 143 # For example:
 144 #
 145 #   b4_warn_at([[input.y:2.3]], [[input.y:5.4]], [[invalid %s]], [[foo]])
 146 m4_define([b4_warn_at],
 147 [b4_error_at([[warn]], $@)])
 148
 149 # b4_complain(FORMAT, [ARG1], [ARG2], ...)
 150 # ----------------------------------------
 151 # Write @complain(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 152 #
 153 # See b4_warn example.
 154 m4_define([b4_complain],
 155 [b4_error([[complain]], $@)])
 156
 157 # b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 158 # -------------------------------------------------------
 159 # Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 160 #
 161 # See b4_warn_at example.
 162 m4_define([b4_complain_at],
 163 [b4_error_at([[complain]], $@)])
 164
 165 # b4_fatal(FORMAT, [ARG1], [ARG2], ...)
 166 # -------------------------------------
 167 # Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 168 #
 169 # See b4_warn example.
 170 m4_define([b4_fatal],
 171 [b4_error([[fatal]], $@)dnl
 172 m4_exit(1)])
 173
 174 # b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 175 # ----------------------------------------------------
 176 # Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 177 #
 178 # See b4_warn_at example.
 179 m4_define([b4_fatal_at],
 180 [b4_error_at([[fatal]], $@)dnl
 181 m4_exit(1)])
 182
 183
 184 ## ---------------- ##
 185 ## Default values.  ##
 186 ## ---------------- ##
 187
 188 # m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
 189 m4_define_default([b4_pre_prologue], [])
 190 m4_define_default([b4_post_prologue], [])
 191 m4_define_default([b4_epilogue], [])
 192 m4_define_default([b4_parse_param], [])
 193
 194 # The initial column and line.
 195 m4_define_default([b4_location_initial_column], [1])
 196 m4_define_default([b4_location_initial_line],   [1])
 197
 198
 199 ## ------------ ##
 200 ## Data Types.  ##
 201 ## ------------ ##
 202
 203 # b4_ints_in(INT1, INT2, LOW, HIGH)
 204 # ---------------------------------
 205 # Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
 206 m4_define([b4_ints_in],
 207 [m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
 208
 209
 210
 211 ## ------------------ ##
 212 ## Decoding options.  ##
 213 ## ------------------ ##
 214
 215 # b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
 216 # -----------------------------------
 217 # Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
 218 m4_define([b4_flag_if],
 219 [m4_case(b4_$1_flag,
 220          [0], [$3],
 221          [1], [$2],
 222          [m4_fatal([invalid $1 value: ]$1)])])
 223
 224
 225 # b4_define_flag_if(FLAG)
 226 # -----------------------
 227 # Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
 228 # value of the Boolean FLAG.
 229 m4_define([b4_define_flag_if],
 230 [_b4_define_flag_if($[1], $[2], [$1])])
 231
 232 # _b4_define_flag_if($1, $2, FLAG)
 233 # --------------------------------
 234 # This macro works around the impossibility to define macros
 235 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 236 # This sucks hard, GNU M4 should really provide M5 like $$1.
 237 m4_define([_b4_define_flag_if],
 238 [m4_if([$1$2], $[1]$[2], [],
 239        [m4_fatal([$0: Invalid arguments: $@])])dnl
 240 m4_define([b4_$3_if],
 241           [b4_flag_if([$3], [$1], [$2])])])
 242
 243
 244 # b4_FLAG_if(IF-TRUE, IF-FALSE)
 245 # -----------------------------
 246 # Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
 247 b4_define_flag_if([defines])            # Whether headers are requested.
 248 b4_define_flag_if([error_verbose])      # Whether error are verbose.
 249 b4_define_flag_if([glr])                # Whether a GLR parser is requested.
 250 b4_define_flag_if([locations])          # Whether locations are tracked.
 251 b4_define_flag_if([nondeterministic])   # Whether conflicts should be handled.
 252 b4_define_flag_if([pure])               # Whether the interface is pure.
 253 b4_define_flag_if([yacc])               # Whether POSIX Yacc is emulated.
 254
 255
 256 ## ------------------------- ##
 257 ## Assigning token numbers.  ##
 258 ## ------------------------- ##
 259
 260
 261 ## ----------- ##
 262 ## Synclines.  ##
 263 ## ----------- ##
 264
 265 # b4_basename(NAME)
 266 # -----------------
 267 # Similar to POSIX basename; the differences don't matter here.
 268 # Beware that NAME is not evaluated.
 269 m4_define([b4_basename],
 270 [m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
 271
 272
 273 # b4_syncline(LINE, FILE)
 274 # -----------------------
 275 m4_define([b4_syncline],
 276 [b4_flag_if([synclines], [
 277 b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
 278 b4_sync_start([$1], [$2])])])
 279
 280 m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
 281 m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
 282
 283 # b4_user_code(USER-CODE)
 284 # -----------------------
 285 # Emit code from the user, ending it with synclines.
 286 m4_define([b4_user_code],
 287 [$1
 288 b4_syncline([@oline@], [@ofile@])])
 289
 290
 291 # b4_define_user_code(MACRO)
 292 # --------------------------
 293 # From b4_MACRO, build b4_user_MACRO that includes the synclines.
 294 m4_define([b4_define_user_code],
 295 [m4_define([b4_user_$1],
 296 [b4_user_code([b4_$1])])])
 297
 298
 299 # b4_user_actions
 300 # b4_user_initial_action
 301 # b4_user_post_prologue
 302 # b4_user_pre_prologue
 303 # b4_user_stype
 304 # ----------------------
 305 # Macros that issue user code, ending with synclines.
 306 b4_define_user_code([actions])
 307 b4_define_user_code([initial_action])
 308 b4_define_user_code([post_prologue])
 309 b4_define_user_code([pre_prologue])
 310 b4_define_user_code([stype])
 311
 312
 313 # b4_check_user_names(WHAT, USER-LIST, BISON-NAMESPACE)
 314 # --------------------------------------------------------
 315 # Warn if any name of type WHAT is used by the user (as recorded in USER-LIST)
 316 # but is not used by Bison (as recorded by macros in the namespace
 317 # BISON-NAMESPACE).
 318 #
 319 # USER-LIST must expand to a list specifying all grammar occurrences of all
 320 # names of type WHAT.   Each item in the list must be a triplet specifying one
 321 # occurrence: name, start boundary, and end boundary.  Empty string names are
 322 # fine.  An empty list is fine.
 323 #
 324 # For example, to define b4_foo_user_names to be used for USER-LIST with three
 325 # name occurrences and with correct quoting:
 326 #
 327 #   m4_define([b4_foo_user_names],
 328 #             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
 329 #               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
 330 #               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
 331 #
 332 # The macro BISON-NAMESPACE(bar) must be defined iff the name bar of type WHAT
 333 # is used by Bison (in the front-end or in the skeleton).  Empty string names
 334 # are fine, but it would be ugly for Bison to actually use one.
 335 #
 336 # For example, to use b4_foo_bison_names for BISON-NAMESPACE and define that
 337 # the names bar and baz are used by Bison:
 338 #
 339 #   m4_define([b4_foo_bison_names(bar)])
 340 #   m4_define([b4_foo_bison_names(baz)])
 341 #
 342 # To invoke b4_check_user_names with TYPE foo, with USER-LIST
 343 # b4_foo_user_names, with BISON-NAMESPACE b4_foo_bison_names, and with correct
 344 # quoting:
 345 #
 346 #   b4_check_user_names([[foo]], [b4_foo_user_names],
 347 #                       [[b4_foo_bison_names]])
 348 m4_define([b4_check_user_names],
 349 [m4_foreach([b4_occurrence], $2,
 350 [m4_pushdef([b4_occurrence], b4_occurrence)dnl
 351 m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
 352 m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
 353 m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
 354 m4_ifndef($3[(]m4_quote(b4_user_name)[)],
 355           [b4_warn_at([b4_start], [b4_end],
 356                       [[%s `%s' is not used]],
 357                       [$1], [b4_user_name])])[]dnl
 358 m4_popdef([b4_occurrence])dnl
 359 m4_popdef([b4_user_name])dnl
 360 m4_popdef([b4_start])dnl
 361 m4_popdef([b4_end])dnl
 362 ])])
 363
 364 # b4_percent_define_get(VARIABLE)
 365 # -------------------------------
 366 # Mimic muscle_percent_define_get in ../src/muscle_tab.h exactly.  That is, if
 367 # the %define variable VARIABLE is defined, emit its value.  Also, record
 368 # Bison's usage of VARIABLE by defining
 369 # b4_percent_define_bison_variables(VARIABLE).
 370 #
 371 # For example:
 372 #
 373 #   b4_percent_define_get([[foo]])
 374 m4_define([b4_percent_define_get],
 375 [m4_define([b4_percent_define_bison_variables(]$1[)])dnl
 376 m4_ifdef([b4_percent_define(]$1[)], [m4_indir([b4_percent_define(]$1[)])])])
 377
 378 # b4_percent_define_ifdef(VARIABLE, IF-TRUE, [IF-FALSE])
 379 # ------------------------------------------------------
 380 # Mimic muscle_percent_define_ifdef in ../src/muscle_tab.h exactly.  That is,
 381 # if the %define variable VARIABLE is defined, expand IF-TRUE, else expand
 382 # IF-FALSE.  Also, record Bison's usage of VARIABLE by defining
 383 # b4_percent_define_bison_variables(VARIABLE).
 384 #
 385 # For example:
 386 #
 387 #   b4_percent_define_ifdef([[foo]], [[it's defined]], [[it's undefined]])
 388 m4_define([b4_percent_define_ifdef],
 389 [m4_ifdef([b4_percent_define(]$1[)],
 390           [m4_define([b4_percent_define_bison_variables(]$1[)])$2],
 391           [$3])])
 392
 393 # b4_percent_define_flag_if(VARIABLE, IF-TRUE, [IF-FALSE])
 394 # --------------------------------------------------------
 395 # Mimic muscle_percent_define_flag_if in ../src/muscle_tab.h exactly.  That is,
 396 # if the %define variable VARIABLE is defined to "" or "true", expand IF-TRUE.
 397 # If it is defined to "false", expand IF-FALSE.  Complain if it is undefined
 398 # (a Bison or skeleton error since the default value should have been set
 399 # already) or defined to any other value (possibly a user error).  Also, record
 400 # Bison's usage of VARIABLE by defining
 401 # b4_percent_define_bison_variables(VARIABLE).
 402 #
 403 # For example:
 404 #
 405 #   b4_percent_define_flag_if([[foo]], [[it's true]], [[it's false]])
 406 m4_define([b4_percent_define_flag_if],
 407 [b4_percent_define_ifdef([$1],
 408   [m4_case(b4_percent_define_get([$1]),
 409            [], [$2], [true], [$2], [false], [$3],
 410            [m4_expand_once([dnl
 411              m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
 412              b4_complain_at(b4_loc,
 413                             [[invalid value for %%define Boolean variable `%s']],
 414                             [$1])dnl
 415              m4_popdef([b4_loc])],
 416              [[b4_percent_define_flag_if($1)]])])],
 417   [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_flag_if]], [$1])])])
 418
 419 # b4_percent_define_default(VARIABLE, DEFAULT)
 420 # --------------------------------------------
 421 # Mimic muscle_percent_define_default in ../src/muscle_tab.h exactly.  That is,
 422 # if the %define variable VARIABLE is undefined, set its value to DEFAULT.
 423 # Don't record this as a Bison usage of VARIABLE as there's no reason to
 424 # suspect that the value has yet influenced the output.
 425 #
 426 # For example:
 427 #
 428 #   b4_percent_define_default([[foo]], [[default value]])
 429 m4_define([b4_percent_define_default],
 430 [m4_ifndef([b4_percent_define(]$1[)],
 431            [m4_define([b4_percent_define(]$1[)], [$2])dnl
 432             m4_define([b4_percent_define_loc(]$1[)],
 433                       [[[[[Bison:b4_percent_define_default]:0.0]], [[[Bison:b4_percent_define_default]:0.0]]]])])])
 434
 435 # b4_percent_define_check_values(VALUES)
 436 # --------------------------------------
 437 # Mimic muscle_percent_define_check_values in ../src/muscle_tab.h exactly
 438 # except that the VALUES structure is more appropriate for M4.  That is, VALUES
 439 # is a list of sublists of strings.  For each sublist, the first string is the
 440 # name of a %define variable, and all remaining strings in that sublist are the
 441 # valid values for that variable.  Complain if such a variable is undefined (a
 442 # Bison error since the default value should have been set already) or defined
 443 # to any other value (possibly a user error).  Don't record this as a Bison
 444 # usage of the variable as there's no reason to suspect that the value has yet
 445 # influenced the output.
 446 #
 447 # For example:
 448 #
 449 #   b4_percent_define_check_values([[[[foo]], [[foo-value1]], [[foo-value2]]]],
 450 #                                  [[[[bar]], [[bar-value1]]]])
 451 m4_define([b4_percent_define_check_values],
 452 [m4_foreach([b4_sublist], m4_quote($@),
 453             [_b4_percent_define_check_values(b4_sublist)])])
 454
 455 m4_define([_b4_percent_define_check_values],
 456 [m4_ifdef([b4_percent_define(]$1[)],
 457   [m4_pushdef([b4_good_value], [0])dnl
 458    m4_if($#, 1, [],
 459          [m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 460                      [m4_if(m4_indir([b4_percent_define(]$1[)]), b4_value,
 461                             [m4_define([b4_good_value], [1])])])])dnl
 462    m4_if(b4_good_value, [0],
 463          [m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
 464           b4_complain_at(b4_loc,
 465                          [[invalid value for %%define variable `%s': `%s']],
 466                          [$1],
 467                          m4_dquote(m4_indir([b4_percent_define(]$1[)])))dnl
 468           m4_popdef([b4_loc])])dnl
 469    m4_popdef([b4_good_value])],
 470   [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_check_values]], [$1])])])
 471
 472 # b4_percent_code_get([QUALIFIER])
 473 # --------------------------------
 474 # If any %code blocks for QUALIFIER are defined, emit them beginning with a
 475 # comment and ending with synclines and a newline.  If QUALIFIER is not
 476 # specified or empty, do this for the unqualified %code blocks.  Also, record
 477 # Bison's usage of QUALIFIER (if specified) by defining
 478 # b4_percent_code_bison_qualifiers(QUALIFIER).
 479 #
 480 # For example, to emit any unqualified %code blocks followed by any %code
 481 # blocks for the qualifier foo:
 482 #
 483 #   b4_percent_code_get
 484 #   b4_percent_code_get([[foo]])
 485 m4_define([b4_percent_code_get],
 486 [m4_pushdef([b4_macro_name], [[b4_percent_code(]$1[)]])dnl
 487 m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])dnl
 488 m4_ifdef(b4_macro_name,
 489 [b4_comment([m4_if([$#], [0], [[Unqualified %code]],
 490                    [[%code "]$1["]])[ blocks.]])
 491 b4_user_code([m4_indir(b4_macro_name)])
 492 ])dnl
 493 m4_popdef([b4_macro_name])])
 494
 495 # b4_percent_code_ifdef(QUALIFIER, IF-TRUE, [IF-FALSE])
 496 # -----------------------------------------------------
 497 # If any %code blocks for QUALIFIER (or unqualified %code blocks if
 498 # QUALIFIER is empty) are defined, expand IF-TRUE, else expand IF-FALSE.
 499 # Also, record Bison's usage of QUALIFIER (if specified) by defining
 500 # b4_percent_code_bison_qualifiers(QUALIFIER).
 501 m4_define([b4_percent_code_ifdef],
 502 [m4_ifdef([b4_percent_code(]$1[)],
 503           [m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])$2],
 504           [$3])])
 505
 506
 507 ## ----------------------------------------------------------- ##
 508 ## After processing the skeletons, check that all the user's   ##
 509 ## %define variables and %code qualifiers were used by Bison.  ##
 510 ## ----------------------------------------------------------- ##
 511
 512 m4_define([b4_check_user_names_wrap],
 513 [m4_ifdef([b4_percent_]$1[_user_]$2[s],
 514           [b4_check_user_names([[%]$1 $2],
 515                                [b4_percent_]$1[_user_]$2[s],
 516                                [[b4_percent_]$1[_bison_]$2[s]])])])
 517
 518 m4_wrap([
 519 b4_check_user_names_wrap([[define]], [[variable]])
 520 b4_check_user_names_wrap([[code]], [[qualifier]])
 521 ])