src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007 Free Software Foundation,
   4    Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software; you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation; either version 2 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program; if not, write to the Free Software
  20    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21    02110-1301  USA
  22 */
  23
  24 #include <config.h>
  25 #include "system.h"
  26
  27 #include <strverscmp.h>
  28
  29 #include "complain.h"
  30 #include "conflicts.h"
  31 #include "files.h"
  32 #include "getargs.h"
  33 #include "gram.h"
  34 #include "muscle_tab.h"
  35 #include "quotearg.h"
  36 #include "reader.h"
  37 #include "symlist.h"
  38 #include "scan-gram.h"
  39 #include "scan-code.h"
  40
  41 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  42 static YYLTYPE lloc_default (YYLTYPE const *, int);
  43
  44 #define YY_LOCATION_PRINT(File, Loc) \
  45           location_print (File, Loc)
  46
  47 static void version_check (location const *loc, char const *version);
  48
  49 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  50    FIXME: depends on the undocumented availability of YYLLOC.  */
  51 #undef  yyerror
  52 #define yyerror(Msg) \
  53         gram_error (&yylloc, Msg)
  54 static void gram_error (location const *, char const *);
  55
  56 static char const *char_name (char);
  57
  58 /** Add a lex-param or a parse-param.
  59  *
  60  * \param type  \a lex_param or \a parse_param
  61  * \param decl  the formal argument
  62  * \param loc   the location in the source.
  63  */
  64 static void add_param (char const *type, char *decl, location loc);
  65
  66
  67 static symbol_class current_class = unknown_sym;
  68 static uniqstr current_type = NULL;
  69 static symbol *current_lhs;
  70 static location current_lhs_location;
  71 static int current_prec = 0;
  72
  73 #define YYTYPE_INT16 int_fast16_t
  74 #define YYTYPE_INT8 int_fast8_t
  75 #define YYTYPE_UINT16 uint_fast16_t
  76 #define YYTYPE_UINT8 uint_fast8_t
  77 %}
  78
  79 %debug
  80 %verbose
  81 %defines
  82 %locations
  83 %pure-parser
  84 %error-verbose
  85 %name-prefix="gram_"
  86 %expect 0
  87
  88 %initial-action
  89 {
  90   /* Bison's grammar can initial empty locations, hence a default
  91      location is needed. */
  92   boundary_set (&@$.start, current_file, 1, 1);
  93   boundary_set (&@$.end, current_file, 1, 1);
  94 }
  95
  96 %union
  97 {
  98   symbol *symbol;
  99   symbol_list *list;
 100   int integer;
 101   char const *chars;
 102   char *code;
 103   assoc assoc;
 104   uniqstr uniqstr;
 105   unsigned char character;
 106 };
 107
 108 /* Define the tokens together with their human representation.  */
 109 %token GRAM_EOF 0 "end of file"
 110 %token STRING     "string"
 111 %token INT        "integer"
 112
 113 %token PERCENT_TOKEN       "%token"
 114 %token PERCENT_NTERM       "%nterm"
 115
 116 %token PERCENT_TYPE        "%type"
 117 %token PERCENT_DESTRUCTOR  "%destructor"
 118 %token PERCENT_PRINTER     "%printer"
 119
 120 %token PERCENT_LEFT        "%left"
 121 %token PERCENT_RIGHT       "%right"
 122 %token PERCENT_NONASSOC    "%nonassoc"
 123
 124 %token PERCENT_PREC          "%prec"
 125 %token PERCENT_DPREC         "%dprec"
 126 %token PERCENT_MERGE         "%merge"
 127
 128
 129 /*----------------------.
 130 | Global Declarations.  |
 131 `----------------------*/
 132
 133 %token
 134   PERCENT_CODE            "%code"
 135   PERCENT_DEBUG           "%debug"
 136   PERCENT_DEFAULT_PREC    "%default-prec"
 137   PERCENT_DEFINE          "%define"
 138   PERCENT_DEFINES         "%defines"
 139   PERCENT_ERROR_VERBOSE   "%error-verbose"
 140   PERCENT_EXPECT          "%expect"
 141   PERCENT_EXPECT_RR       "%expect-rr"
 142   PERCENT_FILE_PREFIX     "%file-prefix"
 143   PERCENT_GLR_PARSER      "%glr-parser"
 144   PERCENT_INITIAL_ACTION  "%initial-action"
 145   PERCENT_LANGUAGE        "%language"
 146   PERCENT_LEX_PARAM       "%lex-param"
 147   PERCENT_LOCATIONS       "%locations"
 148   PERCENT_NAME_PREFIX     "%name-prefix"
 149   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 150   PERCENT_NO_LINES        "%no-lines"
 151   PERCENT_NONDETERMINISTIC_PARSER
 152                           "%nondeterministic-parser"
 153   PERCENT_OUTPUT          "%output"
 154   PERCENT_PARSE_PARAM     "%parse-param"
 155   PERCENT_PURE_PARSER     "%pure-parser"
 156   PERCENT_PUSH_PARSER     "%push-parser"
 157   PERCENT_PUSH_PULL_PARSER
 158                           "%push-pull-parser"
 159   PERCENT_REQUIRE         "%require"
 160   PERCENT_SKELETON        "%skeleton"
 161   PERCENT_START           "%start"
 162   PERCENT_TOKEN_TABLE     "%token-table"
 163   PERCENT_VERBOSE         "%verbose"
 164   PERCENT_YACC            "%yacc"
 165 ;
 166
 167 %token BRACED_CODE     "{...}"
 168 %token CHAR            "char"
 169 %token EPILOGUE        "epilogue"
 170 %token EQUAL           "="
 171 %token ID              "identifier"
 172 %token ID_COLON        "identifier:"
 173 %token PERCENT_PERCENT "%%"
 174 %token PIPE            "|"
 175 %token PROLOGUE        "%{...%}"
 176 %token SEMICOLON       ";"
 177 %token TYPE            "type"
 178 %token TYPE_TAG_ANY    "<*>"
 179 %token TYPE_TAG_NONE   "<>"
 180
 181 %type <character> CHAR
 182 %printer { fputs (char_name ($$), stderr); } CHAR
 183
 184 /* braceless is not to be used for rule or symbol actions, as it
 185    calls code_props_plain_init.  */
 186 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 187 %type <code> "{...}"
 188 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 189          STRING
 190 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 191          braceless content.opt "{...}" "%{...%}" EPILOGUE
 192
 193 %type <uniqstr> TYPE ID ID_COLON
 194 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 195 %printer { fputs ($$, stderr); } ID
 196 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 197
 198 %type <integer> INT
 199 %printer { fprintf (stderr, "%d", $$); } INT
 200
 201 %type <symbol> id id_colon symbol string_as_id
 202 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 203 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 204
 205 %type <assoc> precedence_declarator
 206 %type <list>  symbols.1 generic_symlist generic_symlist_item
 207 %%
 208
 209 input:
 210   prologue_declarations "%%" grammar epilogue.opt
 211 ;
 212
 213
 214         /*------------------------------------.
 215         | Declarations: before the first %%.  |
 216         `------------------------------------*/
 217
 218 prologue_declarations:
 219   /* Nothing */
 220 | prologue_declarations prologue_declaration
 221 ;
 222
 223 prologue_declaration:
 224   grammar_declaration
 225 | "%{...%}"
 226     {
 227       code_props plain_code;
 228       code_props_plain_init (&plain_code, $1, @1);
 229       code_props_translate_code (&plain_code);
 230       gram_scanner_last_string_free ();
 231       prologue_augment (plain_code.code, @1, union_seen);
 232       code_scanner_last_string_free ();
 233     }
 234 | "%debug"                         { debug_flag = true; }
 235 | "%define" STRING content.opt
 236     {
 237       /* FIXME: Special characters in $2 may break %define.
 238          For example: `['.  */
 239       char const name_prefix[] = "percent_define_";
 240       char *name = xmalloc (sizeof name_prefix + strlen ($2));
 241       strcpy (name, name_prefix);
 242       strcpy (name + sizeof name_prefix - 1, $2);
 243       if (muscle_find_const (name))
 244         warn_at (@2, _("%s `%s' redefined"), "%define variable", $2);
 245       MUSCLE_INSERT_STRING (uniqstr_new (name), $3);
 246       free (name);
 247       muscle_grow_user_name_list ("user_percent_define_variables", $2, @2);
 248     }
 249 | "%defines"                       { defines_flag = true; }
 250 | "%defines" STRING
 251     {
 252       defines_flag = true;
 253       spec_defines_file = xstrdup ($2);
 254     }
 255 | "%error-verbose"                 { error_verbose = true; }
 256 | "%expect" INT                    { expected_sr_conflicts = $2; }
 257 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 258 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 259 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 260 | "%glr-parser"
 261     {
 262       nondeterministic_parser = true;
 263       glr_parser = true;
 264     }
 265 | "%initial-action" "{...}"
 266     {
 267       code_props action;
 268       code_props_symbol_action_init (&action, $2, @2);
 269       code_props_translate_code (&action);
 270       gram_scanner_last_string_free ();
 271       muscle_code_grow ("initial_action", action.code, @2);
 272       code_scanner_last_string_free ();
 273     }
 274 | "%language" STRING            { language_argmatch ($2, 1, &@1); }
 275 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 276 | "%locations"                  { locations_flag = true; }
 277 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 278 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 279 | "%no-lines"                   { no_lines_flag = true; }
 280 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 281 | "%output" STRING              { spec_outfile = $2; }
 282 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 283 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 284 | "%pure-parser"                { pure_parser = true; }
 285 | "%push-parser"                { push_parser = true; pull_parser = false; }
 286 | "%push-pull-parser"           { push_parser = true; pull_parser = true; }
 287 | "%require" STRING             { version_check (&@2, $2); }
 288 | "%skeleton" STRING            { skeleton_arg ($2, 1, &@1); }
 289 | "%token-table"                { token_table_flag = true; }
 290 | "%verbose"                    { report_flag = report_states; }
 291 | "%yacc"                       { yacc_flag = true; }
 292 | /*FIXME: Err?  What is this horror doing here? */ ";"
 293 ;
 294
 295 grammar_declaration:
 296   precedence_declaration
 297 | symbol_declaration
 298 | "%start" symbol
 299     {
 300       grammar_start_symbol_set ($2, @2);
 301     }
 302 | "%destructor" "{...}" generic_symlist
 303     {
 304       symbol_list *list;
 305       for (list = $3; list; list = list->next)
 306         symbol_list_destructor_set (list, $2, @2);
 307       symbol_list_free ($3);
 308     }
 309 | "%printer" "{...}" generic_symlist
 310     {
 311       symbol_list *list;
 312       for (list = $3; list; list = list->next)
 313         symbol_list_printer_set (list, $2, @2);
 314       symbol_list_free ($3);
 315     }
 316 | "%default-prec"
 317     {
 318       default_prec = true;
 319     }
 320 | "%no-default-prec"
 321     {
 322       default_prec = false;
 323     }
 324 | "%code" braceless
 325     {
 326       muscle_code_grow ("percent_code", $2, @2);
 327       code_scanner_last_string_free ();
 328     }
 329 | "%code" STRING braceless
 330     {
 331       /* FIXME: Special characters in $2 may break %code.
 332          For example: `['.  */
 333       char const name_prefix[] = "percent_code_";
 334       char *name = xmalloc (sizeof name_prefix + strlen ($2));
 335       strcpy (name, name_prefix);
 336       strcpy (name + sizeof name_prefix - 1, $2);
 337       muscle_code_grow (uniqstr_new (name), $3, @3);
 338       free (name);
 339       code_scanner_last_string_free ();
 340       muscle_grow_user_name_list ("user_percent_code_qualifiers", $2, @2);
 341     }
 342 ;
 343
 344
 345 /*----------*
 346  | %union.  |
 347  *----------*/
 348
 349 %token PERCENT_UNION "%union";
 350
 351 union_name:
 352   /* Nothing. */ {}
 353 | ID             { muscle_code_grow ("union_name", $1, @1); }
 354 ;
 355
 356 grammar_declaration:
 357   "%union" union_name "{...}"
 358     {
 359       char const *body = $3;
 360
 361       /* Concatenate the %union bodies.  If this is the first %union, make sure
 362          the synchronization line appears after the opening '{' so as not to
 363          confuse Doxygen.  Otherwise, turn the previous %union's trailing '}'
 364          into '\n', and omit the new %union's leading '{'.  */
 365       if (!union_seen)
 366         {
 367           muscle_grow ("stype", "{", "");
 368         }
 369       else
 370         {
 371           char *code = muscle_find ("stype");
 372           code[strlen (code) - 1] = '\n';
 373         }
 374       body++;
 375
 376       union_seen = true;
 377       muscle_code_grow ("stype", body, @3);
 378       gram_scanner_last_string_free ();
 379     }
 380 ;
 381
 382
 383
 384
 385 symbol_declaration:
 386   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 387     {
 388       current_class = unknown_sym;
 389       current_type = NULL;
 390     }
 391 | "%token" { current_class = token_sym; } symbol_defs.1
 392     {
 393       current_class = unknown_sym;
 394       current_type = NULL;
 395     }
 396 | "%type" TYPE symbols.1
 397     {
 398       symbol_list *list;
 399       tag_seen = true;
 400       for (list = $3; list; list = list->next)
 401         symbol_type_set (list->content.sym, $2, @2);
 402       symbol_list_free ($3);
 403     }
 404 ;
 405
 406 precedence_declaration:
 407   precedence_declarator type.opt symbols.1
 408     {
 409       symbol_list *list;
 410       ++current_prec;
 411       for (list = $3; list; list = list->next)
 412         {
 413           symbol_type_set (list->content.sym, current_type, @2);
 414           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 415         }
 416       symbol_list_free ($3);
 417       current_type = NULL;
 418     }
 419 ;
 420
 421 precedence_declarator:
 422   "%left"     { $$ = left_assoc; }
 423 | "%right"    { $$ = right_assoc; }
 424 | "%nonassoc" { $$ = non_assoc; }
 425 ;
 426
 427 type.opt:
 428   /* Nothing. */ { current_type = NULL; }
 429 | TYPE           { current_type = $1; tag_seen = true; }
 430 ;
 431
 432 /* One or more symbols to be %typed. */
 433 symbols.1:
 434   symbol
 435     { $$ = symbol_list_sym_new ($1, @1); }
 436 | symbols.1 symbol
 437     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 438 ;
 439
 440 generic_symlist:
 441   generic_symlist_item { $$ = $1; }
 442 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 443 ;
 444
 445 generic_symlist_item:
 446   symbol            { $$ = symbol_list_sym_new ($1, @1); }
 447 | TYPE              { $$ = symbol_list_type_new ($1, @1); }
 448 | "<*>"             { $$ = symbol_list_default_tagged_new (@1); }
 449 | "<>"             { $$ = symbol_list_default_tagless_new (@1); }
 450 ;
 451
 452 /* One token definition.  */
 453 symbol_def:
 454   TYPE
 455      {
 456        current_type = $1;
 457        tag_seen = true;
 458      }
 459 | id
 460      {
 461        symbol_class_set ($1, current_class, @1, true);
 462        symbol_type_set ($1, current_type, @1);
 463      }
 464 | id INT
 465     {
 466       symbol_class_set ($1, current_class, @1, true);
 467       symbol_type_set ($1, current_type, @1);
 468       symbol_user_token_number_set ($1, $2, @2);
 469     }
 470 | id string_as_id
 471     {
 472       symbol_class_set ($1, current_class, @1, true);
 473       symbol_type_set ($1, current_type, @1);
 474       symbol_make_alias ($1, $2, @$);
 475     }
 476 | id INT string_as_id
 477     {
 478       symbol_class_set ($1, current_class, @1, true);
 479       symbol_type_set ($1, current_type, @1);
 480       symbol_user_token_number_set ($1, $2, @2);
 481       symbol_make_alias ($1, $3, @$);
 482     }
 483 ;
 484
 485 /* One or more symbol definitions. */
 486 symbol_defs.1:
 487   symbol_def
 488 | symbol_defs.1 symbol_def
 489 ;
 490
 491
 492         /*------------------------------------------.
 493         | The grammar section: between the two %%.  |
 494         `------------------------------------------*/
 495
 496 grammar:
 497   rules_or_grammar_declaration
 498 | grammar rules_or_grammar_declaration
 499 ;
 500
 501 /* As a Bison extension, one can use the grammar declarations in the
 502    body of the grammar.  */
 503 rules_or_grammar_declaration:
 504   rules
 505 | grammar_declaration ";"
 506 | error ";"
 507     {
 508       yyerrok;
 509     }
 510 ;
 511
 512 rules:
 513   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 514 ;
 515
 516 rhses.1:
 517   rhs                { grammar_current_rule_end (@1); }
 518 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 519 | rhses.1 ";"
 520 ;
 521
 522 rhs:
 523   /* Nothing.  */
 524     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 525 | rhs symbol
 526     { grammar_current_rule_symbol_append ($2, @2); }
 527 | rhs "{...}"
 528     { grammar_current_rule_action_append ($2, @2); }
 529 | rhs "%prec" symbol
 530     { grammar_current_rule_prec_set ($3, @3); }
 531 | rhs "%dprec" INT
 532     { grammar_current_rule_dprec_set ($3, @3); }
 533 | rhs "%merge" TYPE
 534     { grammar_current_rule_merge_set ($3, @3); }
 535 ;
 536
 537
 538 /*---------------*
 539  | content.opt.  |
 540  *--------------*/
 541
 542 /* Some content or "1" by default. */
 543 content.opt:
 544   /* Nothing. */
 545     {
 546       static char one[] = "1";
 547       $$ = one;
 548     }
 549 | STRING
 550 ;
 551
 552
 553 /*-------------*
 554  | braceless.  |
 555  *-------------*/
 556
 557 braceless:
 558   "{...}"
 559     {
 560       code_props plain_code;
 561       $1[strlen ($1) - 1] = '\n';
 562       code_props_plain_init (&plain_code, $1+1, @1);
 563       code_props_translate_code (&plain_code);
 564       gram_scanner_last_string_free ();
 565       $$ = plain_code.code;
 566     }
 567 ;
 568
 569
 570 /*---------------*
 571  | Identifiers.  |
 572  *---------------*/
 573
 574 /* Identifiers are returned as uniqstr values by the scanner.
 575    Depending on their use, we may need to make them genuine symbols.  */
 576
 577 id:
 578   ID
 579     { $$ = symbol_from_uniqstr ($1, @1); }
 580 | CHAR
 581     {
 582       $$ = symbol_get (char_name ($1), @1);
 583       symbol_class_set ($$, token_sym, @1, false);
 584       symbol_user_token_number_set ($$, $1, @1);
 585     }
 586 ;
 587
 588 id_colon:
 589   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 590 ;
 591
 592
 593 symbol:
 594   id
 595 | string_as_id
 596 ;
 597
 598 /* A string used as an ID: quote it.  */
 599 string_as_id:
 600   STRING
 601     {
 602       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 603       symbol_class_set ($$, token_sym, @1, false);
 604     }
 605 ;
 606
 607 epilogue.opt:
 608   /* Nothing.  */
 609 | "%%" EPILOGUE
 610     {
 611       code_props plain_code;
 612       code_props_plain_init (&plain_code, $2, @2);
 613       code_props_translate_code (&plain_code);
 614       gram_scanner_last_string_free ();
 615       muscle_code_grow ("epilogue", plain_code.code, @2);
 616       code_scanner_last_string_free ();
 617     }
 618 ;
 619
 620 %%
 621
 622
 623 /* Return the location of the left-hand side of a rule whose
 624    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 625    the right-hand side, and return an empty location equal to the end
 626    boundary of RHS[0] if the right-hand side is empty.  */
 627
 628 static YYLTYPE
 629 lloc_default (YYLTYPE const *rhs, int n)
 630 {
 631   int i;
 632   YYLTYPE loc;
 633
 634   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 635      The bug is fixed in 7.4.2m, but play it safe for now.  */
 636   loc.start = rhs[n].end;
 637   loc.end = rhs[n].end;
 638
 639   /* Ignore empty nonterminals the start of the the right-hand side.
 640      Do not bother to ignore them at the end of the right-hand side,
 641      since empty nonterminals have the same end as their predecessors.  */
 642   for (i = 1; i <= n; i++)
 643     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 644       {
 645         loc.start = rhs[i].start;
 646         break;
 647       }
 648
 649   return loc;
 650 }
 651
 652
 653 /* Add a lex-param or a parse-param (depending on TYPE) with
 654    declaration DECL and location LOC.  */
 655
 656 static void
 657 add_param (char const *type, char *decl, location loc)
 658 {
 659   static char const alphanum[26 + 26 + 1 + 10] =
 660     "abcdefghijklmnopqrstuvwxyz"
 661     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 662     "_"
 663     "0123456789";
 664   char const *name_start = NULL;
 665   char *p;
 666
 667   /* Stop on last actual character.  */
 668   for (p = decl; p[1]; p++)
 669     if ((p == decl
 670          || ! memchr (alphanum, p[-1], sizeof alphanum))
 671         && memchr (alphanum, p[0], sizeof alphanum - 10))
 672       name_start = p;
 673
 674   /* Strip the surrounding '{' and '}', and any blanks just inside
 675      the braces.  */
 676   while (*--p == ' ' || *p == '\t')
 677     continue;
 678   p[1] = '\0';
 679   while (*++decl == ' ' || *decl == '\t')
 680     continue;
 681
 682   if (! name_start)
 683     complain_at (loc, _("missing identifier in parameter declaration"));
 684   else
 685     {
 686       char *name;
 687       size_t name_len;
 688
 689       for (name_len = 1;
 690            memchr (alphanum, name_start[name_len], sizeof alphanum);
 691            name_len++)
 692         continue;
 693
 694       name = xmalloc (name_len + 1);
 695       memcpy (name, name_start, name_len);
 696       name[name_len] = '\0';
 697       muscle_pair_list_grow (type, decl, name);
 698       free (name);
 699     }
 700
 701   gram_scanner_last_string_free ();
 702 }
 703
 704
 705 static void
 706 version_check (location const *loc, char const *version)
 707 {
 708   if (strverscmp (version, PACKAGE_VERSION) > 0)
 709     {
 710       complain_at (*loc, "require bison %s, but have %s",
 711                    version, PACKAGE_VERSION);
 712       exit (63);
 713     }
 714 }
 715
 716 static void
 717 gram_error (location const *loc, char const *msg)
 718 {
 719   complain_at (*loc, "%s", msg);
 720 }
 721
 722 char const *
 723 token_name (int type)
 724 {
 725   return yytname[YYTRANSLATE (type)];
 726 }
 727
 728 static char const *
 729 char_name (char c)
 730 {
 731   if (c == '\'')
 732     return "'\\''";
 733   else
 734     {
 735       char buf[4];
 736       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 737       return quotearg_style (escape_quoting_style, buf);
 738     }
 739 }