tests/synclines.at

   1 # Executing Actions.                               -*- Autotest -*-
   2 # Copyright (C) 2002, 2004, 2005, 2007, 2009 Free Software Foundation,
   3 # Inc.
   4
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 AT_BANNER([[User Actions.]])
  19
  20
  21 # AT_SYNCLINES_COMPILE(FILE)
  22 # --------------------------
  23 # Compile FILE expecting an error, and save in the file stdout the
  24 # normalized output.  Ignore the exit status, since some compilers
  25 # (e.g. c89 on IRIX 6.5) triger warnings on `#error', instead of
  26 # errors.
  27 m4_define([AT_SYNCLINES_COMPILE],
  28 [AT_CHECK([$CC $CFLAGS $CPPFLAGS -c $1], [ignore], [], [stderr])
  29 # In case GCC displays column information, strip it down.
  30 #
  31 #   input.y:4:2: #error "4"    or
  32 #   input.y:4.2: #error "4"    or
  33 #   input.y:4:2: error: #error "4"
  34 # =>
  35 #   input.y:4: #error "4"
  36 #
  37 # It may also issue more context information:
  38 #
  39 #   input.y: In function 'yyparse':
  40 #   input.y:8: #error "8"
  41 # =>
  42 #   input.y:4: #error "8"
  43 #
  44 AT_CHECK([[sed -e 's/^\([^:]*:[^:.]*\)[.:][^:]*:\(.*\)$/\1:\2/'      \
  45                -e 's/^\([^:]*:[^:]*:\)[^@%:@]*\( @%:@error\)/\1\2/'  \
  46                -e "/^[^:]*: In function '[^\']*':$/d"                \
  47             stderr]],
  48          0, [stdout])
  49 ])
  50
  51 # AT_TEST_SYNCLINE(TITLE, INPUT, ERROR-MSG)
  52 # -----------------------------------------
  53 # Check that compiling the parser produced from INPUT cause GCC
  54 # to issue ERROR-MSG.
  55 m4_define([AT_TEST_SYNCLINE],
  56 [AT_SETUP([$1])
  57
  58 # It seems impossible to find a generic scheme to check the location
  59 # of an error.  Even requiring GCC is not sufficient, since for instance
  60 # the version modified by Apple:
  61 #
  62 # | Reading specs from /usr/libexec/gcc/darwin/ppc/2.95.2/specs
  63 # | Apple Computer, Inc. version gcc-934.3, based on gcc version 2.95.2
  64 # | 19991024 (release) configure:2124: $? = 0
  65 #
  66 # instead of:
  67 #
  68 # | input.y:2: #error "2"
  69 #
  70 # it reports:
  71 #
  72 # | input.y:2: "2"
  73 # | cpp-precomp: warning: errors during smart preprocessing, retrying in basic mode
  74
  75 AT_DATA([syncline.c],
  76 [[#error "1"
  77 ]])
  78
  79 AT_SYNCLINES_COMPILE([syncline.c])
  80 AT_CHECK([[test "`cat stdout`" = 'syncline.c:1: @%:@error "1"' || exit 77]])
  81
  82 AT_DATA([[input.y]], [$2])
  83 AT_BISON_CHECK([-o input.c input.y])
  84 AT_SYNCLINES_COMPILE([input.c])
  85 AT_CHECK([cat stdout], 0, [$3])
  86 AT_CLEANUP
  87 ])
  88
  89
  90 ## --------------------- ##
  91 ## Prologue synch line.  ##
  92 ## --------------------- ##
  93
  94
  95 AT_TEST_SYNCLINE([Prologue synch line],
  96 [[%{
  97 #error "2"
  98 void yyerror (const char *s);
  99 int yylex (void);
 100 %}
 101 %%
 102 exp: '0';
 103 ]],
 104 [input.y:2: #error "2"
 105 ])
 106
 107
 108 ## ------------------- ##
 109 ## %union synch line.  ##
 110 ## ------------------- ##
 111
 112 AT_TEST_SYNCLINE([%union synch line],
 113 [[%union {
 114 #error "2"
 115   char dummy;
 116 }
 117 %{
 118 void yyerror (const char *s);
 119 int yylex (void);
 120 %}
 121 %%
 122 exp: '0';
 123 ]],
 124 [input.y:2: #error "2"
 125 ])
 126
 127
 128 ## ------------------------- ##
 129 ## Postprologue synch line.  ##
 130 ## ------------------------- ##
 131
 132 AT_TEST_SYNCLINE([Postprologue synch line],
 133 [[%{
 134 void yyerror (const char *s);
 135 int yylex (void);
 136 %}
 137 %union
 138 {
 139   int ival;
 140 }
 141 %{
 142 #error "10"
 143 %}
 144 %%
 145 exp: '0';
 146 ]],
 147 [input.y:10: #error "10"
 148 ])
 149
 150
 151 ## ------------------- ##
 152 ## Action synch line.  ##
 153 ## ------------------- ##
 154
 155 AT_TEST_SYNCLINE([Action synch line],
 156 [[%{
 157 void yyerror (const char *s);
 158 int yylex (void);
 159 %}
 160 %%
 161 exp:
 162 {
 163 #error "8"
 164 };
 165 ]],
 166 [input.y:8: #error "8"
 167 ])
 168
 169
 170 ## --------------------- ##
 171 ## Epilogue synch line.  ##
 172 ## --------------------- ##
 173
 174 AT_TEST_SYNCLINE([Epilogue synch line],
 175 [[%{
 176 void yyerror (const char *s);
 177 int yylex (void);
 178 %}
 179 %%
 180 exp: '0';
 181 %%
 182 #error "8"
 183 ]],
 184 [input.y:8: #error "8"
 185 ])