src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software
   4    Foundation, Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software: you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation, either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  20
  21 #include <config.h>
  22 #include "system.h"
  23
  24 #include "complain.h"
  25 #include "conflicts.h"
  26 #include "files.h"
  27 #include "getargs.h"
  28 #include "gram.h"
  29 #include "muscle_tab.h"
  30 #include "quotearg.h"
  31 #include "reader.h"
  32 #include "symlist.h"
  33 #include "scan-gram.h"
  34 #include "scan-code.h"
  35
  36 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  37 static YYLTYPE lloc_default (YYLTYPE const *, int);
  38
  39 #define YY_LOCATION_PRINT(File, Loc) \
  40           location_print (File, Loc)
  41
  42 static void version_check (location const *loc, char const *version);
  43
  44 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  45    FIXME: depends on the undocumented availability of YYLLOC.  */
  46 #undef  yyerror
  47 #define yyerror(Msg) \
  48         gram_error (&yylloc, Msg)
  49 static void gram_error (location const *, char const *);
  50
  51 static char const *char_name (char);
  52
  53 /** Add a lex-param or a parse-param.
  54  *
  55  * \param type  \a lex_param or \a parse_param
  56  * \param decl  the formal argument
  57  * \param loc   the location in the source.
  58  */
  59 static void add_param (char const *type, char *decl, location loc);
  60
  61
  62 static symbol_class current_class = unknown_sym;
  63 static uniqstr current_type = NULL;
  64 static symbol *current_lhs;
  65 static location current_lhs_location;
  66 static int current_prec = 0;
  67
  68 #define YYTYPE_INT16 int_fast16_t
  69 #define YYTYPE_INT8 int_fast8_t
  70 #define YYTYPE_UINT16 uint_fast16_t
  71 #define YYTYPE_UINT8 uint_fast8_t
  72 %}
  73
  74 %debug
  75 %verbose
  76 %defines
  77 %locations
  78 %pure-parser
  79 %error-verbose
  80 %name-prefix="gram_"
  81 %expect 0
  82
  83 %initial-action
  84 {
  85   /* Bison's grammar can initial empty locations, hence a default
  86      location is needed. */
  87   boundary_set (&@$.start, current_file, 1, 1);
  88   boundary_set (&@$.end, current_file, 1, 1);
  89 }
  90
  91 %union
  92 {
  93   symbol *symbol;
  94   symbol_list *list;
  95   int integer;
  96   char const *chars;
  97   char *code;
  98   assoc assoc;
  99   uniqstr uniqstr;
 100   unsigned char character;
 101 };
 102
 103 /* Define the tokens together with their human representation.  */
 104 %token GRAM_EOF 0 "end of file"
 105 %token STRING     "string"
 106 %token INT        "integer"
 107
 108 %token PERCENT_TOKEN       "%token"
 109 %token PERCENT_NTERM       "%nterm"
 110
 111 %token PERCENT_TYPE        "%type"
 112 %token PERCENT_DESTRUCTOR  "%destructor"
 113 %token PERCENT_PRINTER     "%printer"
 114
 115 %token PERCENT_LEFT        "%left"
 116 %token PERCENT_RIGHT       "%right"
 117 %token PERCENT_NONASSOC    "%nonassoc"
 118 %token PERCENT_PRECEDENCE  "%precedence"
 119
 120 %token PERCENT_PREC          "%prec"
 121 %token PERCENT_DPREC         "%dprec"
 122 %token PERCENT_MERGE         "%merge"
 123
 124
 125 /*----------------------.
 126 | Global Declarations.  |
 127 `----------------------*/
 128
 129 %token
 130   PERCENT_CODE            "%code"
 131   PERCENT_DEBUG           "%debug"
 132   PERCENT_DEFAULT_PREC    "%default-prec"
 133   PERCENT_DEFINE          "%define"
 134   PERCENT_DEFINES         "%defines"
 135   PERCENT_ERROR_VERBOSE   "%error-verbose"
 136   PERCENT_EXPECT          "%expect"
 137   PERCENT_EXPECT_RR       "%expect-rr"
 138   PERCENT_FILE_PREFIX     "%file-prefix"
 139   PERCENT_GLR_PARSER      "%glr-parser"
 140   PERCENT_INITIAL_ACTION  "%initial-action"
 141   PERCENT_LANGUAGE        "%language"
 142   PERCENT_LEX_PARAM       "%lex-param"
 143   PERCENT_LOCATIONS       "%locations"
 144   PERCENT_NAME_PREFIX     "%name-prefix"
 145   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 146   PERCENT_NO_LINES        "%no-lines"
 147   PERCENT_NONDETERMINISTIC_PARSER
 148                           "%nondeterministic-parser"
 149   PERCENT_OUTPUT          "%output"
 150   PERCENT_PARSE_PARAM     "%parse-param"
 151   PERCENT_PURE_PARSER     "%pure-parser"
 152   PERCENT_REQUIRE         "%require"
 153   PERCENT_SKELETON        "%skeleton"
 154   PERCENT_START           "%start"
 155   PERCENT_TOKEN_TABLE     "%token-table"
 156   PERCENT_VERBOSE         "%verbose"
 157   PERCENT_YACC            "%yacc"
 158 ;
 159
 160 %token BRACED_CODE     "{...}"
 161 %token CHAR            "char"
 162 %token EPILOGUE        "epilogue"
 163 %token EQUAL           "="
 164 %token ID              "identifier"
 165 %token ID_COLON        "identifier:"
 166 %token PERCENT_PERCENT "%%"
 167 %token PIPE            "|"
 168 %token PROLOGUE        "%{...%}"
 169 %token SEMICOLON       ";"
 170 %token TAG             "<tag>"
 171 %token TAG_ANY         "<*>"
 172 %token TAG_NONE        "<>"
 173
 174 %type <character> CHAR
 175 %printer { fputs (char_name ($$), stderr); } CHAR
 176
 177 /* braceless is not to be used for rule or symbol actions, as it
 178    calls code_props_plain_init.  */
 179 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 180 %type <code> "{...}"
 181 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 182          STRING
 183 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 184          braceless content.opt "{...}" "%{...%}" EPILOGUE
 185
 186 %type <uniqstr> TAG ID ID_COLON variable
 187 %printer { fprintf (stderr, "<%s>", $$); } TAG
 188 %printer { fputs ($$, stderr); } ID variable
 189 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 190
 191 %type <integer> INT
 192 %printer { fprintf (stderr, "%d", $$); } INT
 193
 194 %type <symbol> id id_colon symbol symbol.prec string_as_id
 195 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 196 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 197
 198 %type <assoc> precedence_declarator
 199 %type <list>  symbols.1 symbols.prec generic_symlist generic_symlist_item
 200 %%
 201
 202 input:
 203   prologue_declarations "%%" grammar epilogue.opt
 204 ;
 205
 206
 207         /*------------------------------------.
 208         | Declarations: before the first %%.  |
 209         `------------------------------------*/
 210
 211 prologue_declarations:
 212   /* Nothing */
 213 | prologue_declarations prologue_declaration
 214 ;
 215
 216 prologue_declaration:
 217   grammar_declaration
 218 | "%{...%}"
 219     {
 220       code_props plain_code;
 221       code_props_plain_init (&plain_code, $1, @1);
 222       code_props_translate_code (&plain_code);
 223       gram_scanner_last_string_free ();
 224       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 225                         plain_code.code, @1);
 226       code_scanner_last_string_free ();
 227     }
 228 | "%debug"
 229     {
 230       muscle_percent_define_insert ("debug", @$, "");
 231     }
 232 | "%define" variable content.opt
 233     {
 234       muscle_percent_define_insert ($2, @2, $3);
 235     }
 236 | "%defines"                       { defines_flag = true; }
 237 | "%defines" STRING
 238     {
 239       defines_flag = true;
 240       spec_defines_file = xstrdup ($2);
 241     }
 242 | "%error-verbose"
 243     {
 244       muscle_percent_define_insert ("error_verbose", @$, "");
 245     }
 246 | "%expect" INT                    { expected_sr_conflicts = $2; }
 247 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 248 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 249 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 250 | "%glr-parser"
 251     {
 252       nondeterministic_parser = true;
 253       glr_parser = true;
 254     }
 255 | "%initial-action" "{...}"
 256     {
 257       code_props action;
 258       code_props_symbol_action_init (&action, $2, @2);
 259       code_props_translate_code (&action);
 260       gram_scanner_last_string_free ();
 261       muscle_code_grow ("initial_action", action.code, @2);
 262       code_scanner_last_string_free ();
 263     }
 264 | "%language" STRING            { language_argmatch ($2, grammar_prio, @1); }
 265 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 266 | "%locations"                  { locations_flag = true; }
 267 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 268 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 269 | "%no-lines"                   { no_lines_flag = true; }
 270 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 271 | "%output" STRING              { spec_outfile = $2; }
 272 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 273 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 274 | "%pure-parser"
 275     {
 276       /* %pure-parser is deprecated in favor of `%define api.pure', so use
 277          `%define api.pure' in a backward-compatible manner here.  First, don't
 278          complain if %pure-parser is specified multiple times.  */
 279       if (!muscle_find_const ("percent_define(api.pure)"))
 280         muscle_percent_define_insert ("api.pure", @1, "");
 281       /* In all cases, use api.pure now so that the backend doesn't complain if
 282          the skeleton ignores api.pure, but do warn now if there's a previous
 283          conflicting definition from an actual %define.  */
 284       if (!muscle_percent_define_flag_if ("api.pure"))
 285         muscle_percent_define_insert ("api.pure", @1, "");
 286     }
 287 | "%require" STRING             { version_check (&@2, $2); }
 288 | "%skeleton" STRING
 289     {
 290       char const *skeleton_user = $2;
 291       if (strchr (skeleton_user, '/'))
 292         {
 293           size_t dir_length = strlen (current_file);
 294           char *skeleton_build;
 295           while (dir_length && current_file[dir_length - 1] != '/')
 296             --dir_length;
 297           while (dir_length && current_file[dir_length - 1] == '/')
 298             --dir_length;
 299           skeleton_build =
 300             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 301           if (dir_length > 0)
 302             {
 303               strncpy (skeleton_build, current_file, dir_length);
 304               skeleton_build[dir_length++] = '/';
 305             }
 306           strcpy (skeleton_build + dir_length, skeleton_user);
 307           skeleton_user = uniqstr_new (skeleton_build);
 308           free (skeleton_build);
 309         }
 310       skeleton_arg (skeleton_user, grammar_prio, @1);
 311     }
 312 | "%token-table"                { token_table_flag = true; }
 313 | "%verbose"                    { report_flag |= report_states; }
 314 | "%yacc"                       { yacc_flag = true; }
 315 | /*FIXME: Err?  What is this horror doing here? */ ";"
 316 ;
 317
 318 grammar_declaration:
 319   precedence_declaration
 320 | symbol_declaration
 321 | "%start" symbol
 322     {
 323       grammar_start_symbol_set ($2, @2);
 324     }
 325 | "%destructor" "{...}" generic_symlist
 326     {
 327       symbol_list *list;
 328       for (list = $3; list; list = list->next)
 329         symbol_list_destructor_set (list, $2, @2);
 330       symbol_list_free ($3);
 331     }
 332 | "%printer" "{...}" generic_symlist
 333     {
 334       symbol_list *list;
 335       for (list = $3; list; list = list->next)
 336         symbol_list_printer_set (list, $2, @2);
 337       symbol_list_free ($3);
 338     }
 339 | "%default-prec"
 340     {
 341       default_prec = true;
 342     }
 343 | "%no-default-prec"
 344     {
 345       default_prec = false;
 346     }
 347 | "%code" braceless
 348     {
 349       /* Do not invoke muscle_percent_code_grow here since it invokes
 350          muscle_user_name_list_grow.  */
 351       muscle_code_grow ("percent_code()", $2, @2);
 352       code_scanner_last_string_free ();
 353     }
 354 | "%code" ID braceless
 355     {
 356       muscle_percent_code_grow ($2, @2, $3, @3);
 357       code_scanner_last_string_free ();
 358     }
 359 ;
 360
 361
 362 /*---------.
 363 | %union.  |
 364 `---------*/
 365
 366 %token PERCENT_UNION "%union";
 367
 368 union_name:
 369   /* Nothing. */ {}
 370 | ID             { muscle_code_grow ("union_name", $1, @1); }
 371 ;
 372
 373 grammar_declaration:
 374   "%union" union_name braceless
 375     {
 376       union_seen = true;
 377       muscle_code_grow ("stype", $3, @3);
 378       code_scanner_last_string_free ();
 379     }
 380 ;
 381
 382
 383
 384
 385 symbol_declaration:
 386   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 387     {
 388       current_class = unknown_sym;
 389       current_type = NULL;
 390     }
 391 | "%token" { current_class = token_sym; } symbol_defs.1
 392     {
 393       current_class = unknown_sym;
 394       current_type = NULL;
 395     }
 396 | "%type" TAG symbols.1
 397     {
 398       symbol_list *list;
 399       tag_seen = true;
 400       for (list = $3; list; list = list->next)
 401         symbol_type_set (list->content.sym, $2, @2);
 402       symbol_list_free ($3);
 403     }
 404 ;
 405
 406 precedence_declaration:
 407   precedence_declarator tag.opt symbols.prec
 408     {
 409       symbol_list *list;
 410       ++current_prec;
 411       for (list = $3; list; list = list->next)
 412         {
 413           symbol_type_set (list->content.sym, current_type, @2);
 414           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 415         }
 416       symbol_list_free ($3);
 417       current_type = NULL;
 418     }
 419 ;
 420
 421 precedence_declarator:
 422   "%left"       { $$ = left_assoc; }
 423 | "%right"      { $$ = right_assoc; }
 424 | "%nonassoc"   { $$ = non_assoc; }
 425 | "%precedence" { $$ = precedence_assoc; }
 426 ;
 427
 428 tag.opt:
 429   /* Nothing. */ { current_type = NULL; }
 430 | TAG            { current_type = $1; tag_seen = true; }
 431 ;
 432
 433 /* Just like symbols.1 but accept INT for the sake of POSIX.  */
 434 symbols.prec:
 435   symbol.prec
 436     { $$ = symbol_list_sym_new ($1, @1); }
 437 | symbols.prec symbol.prec
 438     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 439 ;
 440
 441 symbol.prec:
 442     symbol { $$ = $1; }
 443   | symbol INT { $$ = $1; symbol_user_token_number_set ($1, $2, @2); }
 444   ;
 445
 446 /* One or more symbols to be %typed. */
 447 symbols.1:
 448   symbol
 449     { $$ = symbol_list_sym_new ($1, @1); }
 450 | symbols.1 symbol
 451     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 452 ;
 453
 454 generic_symlist:
 455   generic_symlist_item { $$ = $1; }
 456 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 457 ;
 458
 459 generic_symlist_item:
 460   symbol    { $$ = symbol_list_sym_new ($1, @1); }
 461 | TAG       { $$ = symbol_list_type_new ($1, @1); }
 462 | "<*>"     { $$ = symbol_list_default_tagged_new (@1); }
 463 | "<>"      { $$ = symbol_list_default_tagless_new (@1); }
 464 ;
 465
 466 /* One token definition.  */
 467 symbol_def:
 468   TAG
 469      {
 470        current_type = $1;
 471        tag_seen = true;
 472      }
 473 | id
 474      {
 475        symbol_class_set ($1, current_class, @1, true);
 476        symbol_type_set ($1, current_type, @1);
 477      }
 478 | id INT
 479     {
 480       symbol_class_set ($1, current_class, @1, true);
 481       symbol_type_set ($1, current_type, @1);
 482       symbol_user_token_number_set ($1, $2, @2);
 483     }
 484 | id string_as_id
 485     {
 486       symbol_class_set ($1, current_class, @1, true);
 487       symbol_type_set ($1, current_type, @1);
 488       symbol_make_alias ($1, $2, @$);
 489     }
 490 | id INT string_as_id
 491     {
 492       symbol_class_set ($1, current_class, @1, true);
 493       symbol_type_set ($1, current_type, @1);
 494       symbol_user_token_number_set ($1, $2, @2);
 495       symbol_make_alias ($1, $3, @$);
 496     }
 497 ;
 498
 499 /* One or more symbol definitions. */
 500 symbol_defs.1:
 501   symbol_def
 502 | symbol_defs.1 symbol_def
 503 ;
 504
 505
 506         /*------------------------------------------.
 507         | The grammar section: between the two %%.  |
 508         `------------------------------------------*/
 509
 510 grammar:
 511   rules_or_grammar_declaration
 512 | grammar rules_or_grammar_declaration
 513 ;
 514
 515 /* As a Bison extension, one can use the grammar declarations in the
 516    body of the grammar.  */
 517 rules_or_grammar_declaration:
 518   rules
 519 | grammar_declaration ";"
 520 | error ";"
 521     {
 522       yyerrok;
 523     }
 524 ;
 525
 526 rules:
 527   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 528 ;
 529
 530 rhses.1:
 531   rhs                { grammar_current_rule_end (@1); }
 532 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 533 | rhses.1 ";"
 534 ;
 535
 536 rhs:
 537   /* Nothing.  */
 538     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 539 | rhs symbol
 540     { grammar_current_rule_symbol_append ($2, @2); }
 541 | rhs "{...}"
 542     { grammar_current_rule_action_append ($2, @2); }
 543 | rhs "%prec" symbol
 544     { grammar_current_rule_prec_set ($3, @3); }
 545 | rhs "%dprec" INT
 546     { grammar_current_rule_dprec_set ($3, @3); }
 547 | rhs "%merge" TAG
 548     { grammar_current_rule_merge_set ($3, @3); }
 549 ;
 550
 551
 552 /*---------------------------.
 553 | variable and content.opt.  |
 554 `---------------------------*/
 555
 556 variable:
 557   ID
 558 | STRING { $$ = uniqstr_new ($1); } /* deprecated and not M4-friendly */
 559 ;
 560
 561 /* Some content or empty by default. */
 562 content.opt:
 563   /* Nothing. */
 564     {
 565       $$ = "";
 566     }
 567 | STRING
 568 ;
 569
 570
 571 /*------------.
 572 | braceless.  |
 573 `------------*/
 574
 575 braceless:
 576   "{...}"
 577     {
 578       code_props plain_code;
 579       $1[strlen ($1) - 1] = '\n';
 580       code_props_plain_init (&plain_code, $1+1, @1);
 581       code_props_translate_code (&plain_code);
 582       gram_scanner_last_string_free ();
 583       $$ = plain_code.code;
 584     }
 585 ;
 586
 587
 588 /*--------------.
 589 | Identifiers.  |
 590 `--------------*/
 591
 592 /* Identifiers are returned as uniqstr values by the scanner.
 593    Depending on their use, we may need to make them genuine symbols.  */
 594
 595 id:
 596   ID
 597     { $$ = symbol_from_uniqstr ($1, @1); }
 598 | CHAR
 599     {
 600       $$ = symbol_get (char_name ($1), @1);
 601       symbol_class_set ($$, token_sym, @1, false);
 602       symbol_user_token_number_set ($$, $1, @1);
 603     }
 604 ;
 605
 606 id_colon:
 607   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 608 ;
 609
 610
 611 symbol:
 612   id
 613 | string_as_id
 614 ;
 615
 616 /* A string used as an ID: quote it.  */
 617 string_as_id:
 618   STRING
 619     {
 620       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 621       symbol_class_set ($$, token_sym, @1, false);
 622     }
 623 ;
 624
 625 epilogue.opt:
 626   /* Nothing.  */
 627 | "%%" EPILOGUE
 628     {
 629       code_props plain_code;
 630       code_props_plain_init (&plain_code, $2, @2);
 631       code_props_translate_code (&plain_code);
 632       gram_scanner_last_string_free ();
 633       muscle_code_grow ("epilogue", plain_code.code, @2);
 634       code_scanner_last_string_free ();
 635     }
 636 ;
 637
 638 %%
 639
 640
 641 /* Return the location of the left-hand side of a rule whose
 642    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 643    the right-hand side, and return an empty location equal to the end
 644    boundary of RHS[0] if the right-hand side is empty.  */
 645
 646 static YYLTYPE
 647 lloc_default (YYLTYPE const *rhs, int n)
 648 {
 649   int i;
 650   YYLTYPE loc;
 651
 652   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 653      The bug is fixed in 7.4.2m, but play it safe for now.  */
 654   loc.start = rhs[n].end;
 655   loc.end = rhs[n].end;
 656
 657   /* Ignore empty nonterminals the start of the the right-hand side.
 658      Do not bother to ignore them at the end of the right-hand side,
 659      since empty nonterminals have the same end as their predecessors.  */
 660   for (i = 1; i <= n; i++)
 661     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 662       {
 663         loc.start = rhs[i].start;
 664         break;
 665       }
 666
 667   return loc;
 668 }
 669
 670
 671 /* Add a lex-param or a parse-param (depending on TYPE) with
 672    declaration DECL and location LOC.  */
 673
 674 static void
 675 add_param (char const *type, char *decl, location loc)
 676 {
 677   static char const alphanum[26 + 26 + 1 + 10] =
 678     "abcdefghijklmnopqrstuvwxyz"
 679     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 680     "_"
 681     "0123456789";
 682   char const *name_start = NULL;
 683   char *p;
 684
 685   /* Stop on last actual character.  */
 686   for (p = decl; p[1]; p++)
 687     if ((p == decl
 688          || ! memchr (alphanum, p[-1], sizeof alphanum))
 689         && memchr (alphanum, p[0], sizeof alphanum - 10))
 690       name_start = p;
 691
 692   /* Strip the surrounding '{' and '}', and any blanks just inside
 693      the braces.  */
 694   while (*--p == ' ' || *p == '\t')
 695     continue;
 696   p[1] = '\0';
 697   while (*++decl == ' ' || *decl == '\t')
 698     continue;
 699
 700   if (! name_start)
 701     complain_at (loc, _("missing identifier in parameter declaration"));
 702   else
 703     {
 704       char *name;
 705       size_t name_len;
 706
 707       for (name_len = 1;
 708            memchr (alphanum, name_start[name_len], sizeof alphanum);
 709            name_len++)
 710         continue;
 711
 712       name = xmalloc (name_len + 1);
 713       memcpy (name, name_start, name_len);
 714       name[name_len] = '\0';
 715       muscle_pair_list_grow (type, decl, name);
 716       free (name);
 717     }
 718
 719   gram_scanner_last_string_free ();
 720 }
 721
 722
 723 static void
 724 version_check (location const *loc, char const *version)
 725 {
 726   if (strverscmp (version, PACKAGE_VERSION) > 0)
 727     {
 728       complain_at (*loc, "require bison %s, but have %s",
 729                    version, PACKAGE_VERSION);
 730       exit (63);
 731     }
 732 }
 733
 734 static void
 735 gram_error (location const *loc, char const *msg)
 736 {
 737   complain_at (*loc, "%s", msg);
 738 }
 739
 740 char const *
 741 token_name (int type)
 742 {
 743   return yytname[YYTRANSLATE (type)];
 744 }
 745
 746 static char const *
 747 char_name (char c)
 748 {
 749   if (c == '\'')
 750     return "'\\''";
 751   else
 752     {
 753       char buf[4];
 754       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 755       return quotearg_style (escape_quoting_style, buf);
 756     }
 757 }