tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 ## ------------- ##
  24 ## Basic tests.  ##
  25 ## ------------- ##
  26
  27 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  28 # ------------------------------------------
  29 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  30 # taken in "slurp" mode, i.e., one can match end-of-lines.
  31 m4_define([AT_MATCHES_CHECK],
  32 [AT_CHECK([perl -0777 -ne '
  33 my $count = 0;
  34 s{$2}{ ++$count; "" }gem;
  35 printf "$count\n";' $1], [0], [$3
  36 ])])
  37
  38
  39 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  40 # ------------------------------------------------
  41 # Don't interfere with caller's files.
  42 m4_divert_text([PREPARE_TESTS],
  43 [at_save_special_files ()
  44 {
  45   for at_save_file in stderr experr expout
  46   do
  47     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  48   done
  49 }
  50
  51 at_restore_special_files ()
  52 {
  53   for at_save_file in stderr experr expout
  54   do
  55     test ! -f at-bison-check-$at_save_file.bak ||
  56       mv at-bison-check-$at_save_file.bak $at_save_file
  57   done
  58 }
  59 ])
  60
  61 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  62 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  63
  64
  65
  66 ## ------------------------------- ##
  67 ## Macros decoding Bison options.  ##
  68 ## ------------------------------- ##
  69
  70 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  71 # ----------------------------------------------------------------
  72 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  73 m4_define([AT_LOC_PUSHDEF],
  74 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  75 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  76 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  77 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  78
  79 # AT_LOC_POPDEF
  80 # -------------
  81 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  82 m4_define([AT_LOC_POPDEF],
  83 [m4_popdef([AT_LOC_FIRST_LINE])
  84 m4_popdef([AT_LOC_FIRST_COLUMN])
  85 m4_popdef([AT_LOC_LAST_LINE])
  86 m4_popdef([AT_LOC_LAST_COLUMN])])
  87
  88
  89
  90 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  91 # -----------------------------------------
  92 m4_define([AT_BISON_OPTION_PUSHDEFS],
  93 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  94
  95
  96 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  97 # --------------------------------------------------
  98 # This macro works around the impossibility to define macros
  99 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 100 # This sucks hard, GNU M4 should really provide M5 like $$1.
 101 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 102 [m4_if([$1$2], $[1]$[2], [],
 103        [m4_fatal([$0: Invalid arguments: $@])])dnl
 104 m4_pushdef([AT_DEFINES_IF],
 105 [m4_bmatch([$3], [%defines], [$1], [$2])])
 106 m4_pushdef([AT_SKEL_CC_IF],
 107 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 108 m4_pushdef([AT_SKEL_JAVA_IF],
 109 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 110 m4_pushdef([AT_LANG],
 111 [AT_SKEL_JAVA_IF([java],
 112                  [AT_SKEL_CC_IF([c++],
 113                                 [c])])])
 114 m4_pushdef([AT_GLR_IF],
 115 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 116 m4_pushdef([AT_LALR1_CC_IF],
 117 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 118 m4_pushdef([AT_GLR_CC_IF],
 119 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 120 # Using yacc.c?
 121 m4_pushdef([AT_YACC_IF],
 122 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 123 m4_pushdef([AT_LEXPARAM_IF],
 124 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 125 m4_pushdef([AT_LOCATION_IF],
 126 [m4_bmatch([$3], [%locations], [$1], [$2])])
 127 m4_pushdef([AT_LOCATION_TYPE_IF],
 128 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
 129 m4_pushdef([AT_PARAM_IF],
 130 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 131 m4_pushdef([AT_PURE_IF],
 132 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 133            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 134            [$2])])
 135 m4_pushdef([AT_PURE_AND_LOC_IF],
 136 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 137 m4_pushdef([AT_GLR_OR_PARAM_IF],
 138 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 139 m4_pushdef([AT_NAME_PREFIX],
 140 [m4_bmatch([$3], [\(%define api\.prefix\|%name-prefix\) ".*"],
 141            [m4_bregexp([$3], [\(%define api\.prefix\|%name-prefix\) "\([^""]*\)"], [\2])],
 142            [yy])])
 143 m4_pushdef([AT_API_prefix],
 144 [m4_bmatch([$3], [%define api\.prefix ".*"],
 145            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 146            [yy])])
 147 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 148 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 149 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 150                     [$2])])
 151 # yyerror always sees the locations (when activated), except if
 152 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 153 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 154 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 155                                         [$1])],
 156                             [$1])],
 157                 [$2])])
 158
 159 # The interface is pure: either because %define api.pure, or because we
 160 # are using the C++ parsers.
 161 m4_pushdef([AT_PURE_LEX_IF],
 162 [AT_PURE_IF([$1],
 163             [AT_SKEL_CC_IF([$1], [$2])])])
 164
 165 m4_pushdef([AT_YYSTYPE],
 166 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
 167                [[YYSTYPE]])])
 168 m4_pushdef([AT_YYLTYPE],
 169 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
 170                [[YYLTYPE]])])
 171
 172
 173 AT_PURE_LEX_IF(
 174 [m4_pushdef([AT_LOC], [(*llocp)])
 175  m4_pushdef([AT_VAL], [(*lvalp)])
 176  m4_pushdef([AT_YYLEX_FORMALS],
 177             [AT_YYSTYPE *lvalp[]AT_LOCATION_IF([, AT_YYLTYPE *llocp])])
 178  m4_pushdef([AT_YYLEX_ARGS],
 179             [lvalp[]AT_LOCATION_IF([, llocp])])
 180  m4_pushdef([AT_USE_LEX_ARGS],
 181             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 182  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 183             [AT_YYLEX_FORMALS, ])
 184  m4_pushdef([AT_YYLEX_PRE_ARGS],
 185             [AT_YYLEX_ARGS, ])
 186 ],
 187 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 188  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 189  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 190  m4_pushdef([AT_YYLEX_ARGS],        [])
 191  m4_pushdef([AT_USE_LEX_ARGS],    [])
 192  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 193  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 194 ])
 195
 196 # Handle the different types of location components.
 197
 198 AT_SKEL_CC_IF(
 199   [AT_LOCATION_TYPE_IF(
 200     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 201     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 202   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 203
 204 ])# _AT_BISON_OPTION_PUSHDEFS
 205
 206
 207 # AT_BISON_OPTION_POPDEFS
 208 # -----------------------
 209 m4_define([AT_BISON_OPTION_POPDEFS],
 210 [m4_popdef([AT_YYLEX_PRE_ARGS])
 211 m4_popdef([AT_YYLEX_PRE_FORMALS])
 212 m4_popdef([AT_USE_LEX_ARGS])
 213 m4_popdef([AT_YYLEX_ARGS])
 214 m4_popdef([AT_YYLEX_FORMALS])
 215 m4_popdef([AT_YYLTYPE])
 216 m4_popdef([AT_YYSTYPE])
 217 m4_popdef([AT_VAL])
 218 m4_popdef([AT_LOC])
 219 m4_popdef([AT_PURE_LEX_IF])
 220 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 221 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 222 m4_popdef([AT_API_prefix])
 223 m4_popdef([AT_NAME_PREFIX])
 224 m4_popdef([AT_GLR_OR_PARAM_IF])
 225 m4_popdef([AT_PURE_AND_LOC_IF])
 226 m4_popdef([AT_LOCATION_TYPE_IF])
 227 m4_popdef([AT_LOCATION_IF])
 228 m4_popdef([AT_PARAM_IF])
 229 m4_popdef([AT_LEXPARAM_IF])
 230 m4_popdef([AT_YACC_IF])
 231 m4_popdef([AT_GLR_IF])
 232 m4_popdef([AT_SKEL_CC_IF])
 233 m4_popdef([AT_LANG])
 234 m4_popdef([AT_SKEL_JAVA_IF])
 235 m4_popdef([AT_GLR_CC_IF])
 236 m4_popdef([AT_LALR1_CC_IF])
 237 m4_popdef([AT_DEFINES_IF])
 238 AT_LOC_POPDEF
 239 ])# AT_BISON_OPTION_POPDEFS
 240
 241
 242
 243 ## -------------------------- ##
 244 ## Generating Grammar Files.  ##
 245 ## -------------------------- ##
 246
 247 # AT_DATA_SOURCE_PROLOGUE
 248 # ------------------------
 249 # The prologue that should be included in any source code that is
 250 # meant to be compiled.
 251 m4_define([AT_DATA_SOURCE_PROLOGUE],
 252 [[#include <config.h>
 253 /* We don't need perfect functions for these tests. */
 254 #undef malloc
 255 #undef memcmp
 256 #undef realloc
 257 ]])
 258
 259 # AT_DATA_GRAMMAR_PROLOGUE
 260 # ------------------------
 261 # The prologue that should be included in any grammar which parser is
 262 # meant to be compiled.
 263 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 264 [[%code top {
 265 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 266 [}
 267 ]])
 268
 269 # AT_DATA_SOURCE(NAME, CONTENT)
 270 # -----------------------------
 271 # Generate the file NAME, which CONTENT is preceded by
 272 # AT_DATA_SOURCE_PROLOGUE.
 273 m4_define([AT_DATA_SOURCE],
 274 [AT_DATA([$1],
 275 [AT_DATA_SOURCE_PROLOGUE
 276 $2])
 277 ])
 278
 279 # AT_DATA_GRAMMAR(NAME, CONTENT)
 280 # ------------------------------
 281 # Generate the file NAME, which CONTENT is preceded by
 282 # AT_DATA_GRAMMAR_PROLOGUE.
 283 m4_define([AT_DATA_GRAMMAR],
 284 [AT_DATA([$1],
 285 [AT_DATA_GRAMMAR_PROLOGUE
 286 $2])
 287 ])
 288
 289 # AT_YYLEX_PROTOTYPE
 290 # AT_YYLEX_DECLARE_EXTERN
 291 # AT_YYLEX_DECLARE
 292 # AT_YYLEX_DEFINE(INPUT-STRING, [ACTION])
 293 # ---------------------------------------
 294 m4_define([AT_YYLEX_PROTOTYPE],
 295 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 296 ])
 297
 298 m4_define([AT_YYLEX_DECLARE_EXTERN],
 299 [AT_YYLEX_PROTOTYPE;dnl
 300 ])
 301
 302 m4_define([AT_YYLEX_DECLARE],
 303 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 304 ])
 305
 306 m4_define([AT_YYLEX_DEFINE],
 307 [[#include <assert.h>
 308 static
 309 ]AT_YYLEX_PROTOTYPE[
 310 {
 311   static char const input[] = "$1";
 312   static size_t toknum = 0;
 313   int res;
 314   ]AT_USE_LEX_ARGS[;
 315   assert (toknum < sizeof input);
 316   res = input[toknum++];
 317   ]$2[;]AT_LOCATION_IF([[
 318   ]AT_LOC_FIRST_LINE[ = ]AT_LOC_LAST_LINE[ = 1;
 319   ]AT_LOC_FIRST_COLUMN[ = ]AT_LOC_LAST_COLUMN[ = toknum;]])[
 320   return res;
 321 }]dnl
 322 ])
 323
 324 # AT_YYERROR_PROTOTYPE
 325 # AT_YYERROR_DECLARE_EXTERN
 326 # AT_YYERROR_DECLARE
 327 # AT_YYERROR_DEFINE
 328 # -------------------------
 329 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 330 m4_define([AT_YYERROR_FORMALS],
 331 [m4_case(AT_LANG,
 332 [c], [AT_YYERROR_ARG_LOC_IF([YYLTYPE *llocp, ])[const char *msg]])[]dnl
 333 ])
 334
 335 m4_define([AT_YYERROR_PROTOTYPE],
 336 [m4_case(AT_LANG,
 337 [c], [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])[]dnl
 338 ])
 339
 340 m4_define([AT_YYERROR_DECLARE_EXTERN],
 341 [m4_case(AT_LANG,
 342 [c], [AT_YYERROR_PROTOTYPE;])[]dnl
 343 ])
 344
 345 m4_define([AT_YYERROR_DECLARE],
 346 [m4_case(AT_LANG,
 347 [c], [static AT_YYERROR_DECLARE_EXTERN])[]dnl
 348 ])
 349
 350 m4_define([AT_YYERROR_DEFINE],
 351 [m4_case(AT_LANG,
 352 [c], [[#include <stdio.h>
 353 /* A C error reporting function.  */
 354 static
 355 ]AT_YYERROR_PROTOTYPE[
 356 {
 357 ]AT_YYERROR_SEES_LOC_IF([[
 358   fprintf (stderr, "%d.%d",
 359            ]AT_LOC_FIRST_LINE[, ]AT_LOC_FIRST_COLUMN[);
 360   if (]AT_LOC_FIRST_LINE[ != ]AT_LOC_LAST_LINE[)
 361     fprintf (stderr, "-%d.%d",
 362              ]AT_LOC_LAST_LINE[,  ]AT_LOC_LAST_COLUMN[ - 1);
 363   else if (]AT_LOC_FIRST_COLUMN[ != ]AT_LOC_LAST_COLUMN[ - 1)
 364     fprintf (stderr, "-%d",
 365              ]AT_LOC_LAST_COLUMN[ - 1);
 366   fprintf (stderr, ": ");]])[
 367   fprintf (stderr, "%s\n", msg);
 368 }]],
 369 [c++], [[/* A C++ error reporting function.  */
 370 void
 371 ]AT_NAME_PREFIX[::parser::error (const location_type& l, const std::string& m)
 372 {
 373   (void) l;
 374   std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 375 }]],
 376 [java], [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 377   {
 378     if (l == null)
 379       System.err.println (s);
 380     else
 381       System.err.println (l + ": " + s);
 382   }
 383 ]], [[
 384   public void yyerror (String s)
 385   {
 386     System.err.println (s);
 387   }]])])dnl
 388 ])
 389
 390
 391 ## --------------- ##
 392 ## Running Bison.  ##
 393 ## --------------- ##
 394
 395 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 396 # -------------------------------------------------
 397 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 398 # shell constructs (such as redirection or pipes) that would prevent
 399 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 400 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 401 #
 402 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 403 # Bison in the test suite.  For now it ensures that:
 404 #
 405 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 406 #      a non-zero exit status since Bison doesn't always try to free all memory
 407 #      in that case.
 408 #
 409 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 410 #      --graph and --report=all output for every working grammar.
 411 #
 412 #   3. If stderr contains a warning, -Werror and --warnings=error
 413 #      convert the warning to an error.
 414 #
 415 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 416 m4_define([AT_BISON_CHECK],
 417 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 418        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 419 AT_BISON_CHECK_NO_XML($@)])
 420
 421 m4_define([AT_BISON_WERROR_MSG],
 422           [[bison: warnings being treated as errors]])
 423
 424 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 425 # --------------------------------------------------------
 426 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 427 # when a tortured grammar's XML is known to be too large for xsltproc to
 428 # handle.
 429 m4_define([AT_BISON_CHECK_NO_XML],
 430 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 431                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 432 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 433       m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0], [[
 434         # Defining POSIXLY_CORRECT causes bison to complain if options
 435         # are added after the grammar file name, so skip these checks
 436         # in that case.
 437         if test -z "${POSIXLY_CORRECT+set}"; then
 438           ]AT_SAVE_SPECIAL_FILES[
 439
 440           # To avoid expanding it repeatedly, store specified stdout.
 441           ]AT_DATA([expout], [$3])[
 442
 443           # Run with -Werror.
 444           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Werror]],
 445                     [[1]], [expout], [stderr])[
 446
 447           # Build expected stderr up to and including the "warnings being
 448           # treated as errors" message.
 449           ]AT_DATA([[at-bison-check-warnings]], [$4])[
 450           at_bison_check_first=`sed -n \
 451             '/: warning: /{=;q;}' at-bison-check-warnings`
 452           : ${at_bison_check_first:=1}
 453           at_bison_check_first_tmp=`sed -n \
 454             '/conflicts: [0-9].*reduce$/{=;q;}' at-bison-check-warnings`
 455           : ${at_bison_check_first_tmp:=1}
 456           if test $at_bison_check_first_tmp -lt $at_bison_check_first; then
 457             at_bison_check_first=$at_bison_check_first_tmp
 458           fi
 459           if test $at_bison_check_first -gt 1; then
 460             sed -n "1,`expr $at_bison_check_first - 1`"p \
 461               at-bison-check-warnings > experr
 462           fi
 463           echo ']AT_BISON_WERROR_MSG[' >> experr
 464
 465           # Finish building expected stderr and check.  Unlike warnings,
 466           # complaints cause bison to exit early.  Thus, with -Werror, bison
 467           # does not necessarily report all warnings that it does without
 468           # -Werror, but it at least reports one.
 469           at_bison_check_last=`sed -n '$=' stderr`
 470           : ${at_bison_check_last:=1}
 471           at_bison_check_last=`expr $at_bison_check_last - 1`
 472           sed -n "$at_bison_check_first,$at_bison_check_last"p \
 473             at-bison-check-warnings >> experr
 474           ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 475                       stderr 1>&2]], [[0]], [[]], [experr])[
 476
 477           # Now check --warnings=error.
 478           cp stderr experr
 479           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=error]],
 480                     [[1]], [expout], [experr])[
 481
 482           # Now check -Wnone and --warnings=none by making sure that
 483           # -Werror doesn't change the exit status when -Wnone or
 484           # --warnings=none is specified.
 485           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Wnone -Werror]],
 486                     [[0]], [expout])[
 487           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=none \
 488                     -Werror]], [[0]], [expout])[
 489
 490           ]AT_RESTORE_SPECIAL_FILES[
 491         fi
 492       ]])
 493 ])
 494
 495 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 496 # -----------------------------------------------------
 497 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 498 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 499 # have a non-zero exit status.
 500 m4_define([AT_BISON_CHECK_XML],
 501 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 502   AT_SAVE_SPECIAL_FILES
 503   [mkdir xml-tests]
 504   m4_pushdef([AT_BISON_ARGS],
 505              [m4_bpatsubsts([[$1]],
 506                             [--report(-file)?=[^][ ]*], [],
 507                             [--graph=[^][ ]*], [],
 508                             [--xml=[^][ ]*], [])])dnl
 509   # Don't combine these Bison invocations since we want to be sure that
 510   # --report=all isn't required to get the full XML file.
 511   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 512              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 513            [[0]], [ignore], [ignore])
 514   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 515            [[0]], [ignore], [ignore])
 516   m4_popdef([AT_BISON_ARGS])dnl
 517   [cp xml-tests/test.output expout]
 518   AT_CHECK([[$XSLTPROC \
 519              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 520              xml-tests/test.xml]], [[0]], [expout])
 521   [cp xml-tests/test.dot expout]
 522   AT_CHECK([[$XSLTPROC \
 523              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 524              xml-tests/test.xml]], [[0]], [expout])
 525   [rm -rf xml-tests expout]
 526   AT_RESTORE_SPECIAL_FILES
 527 [fi]])
 528
 529 # AT_QUELL_VALGRIND
 530 # -----------------
 531 # Put this before a Bison invocation to keep Valgrind from complaining about
 532 # reachable memory.
 533 #
 534 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 535 # The triple quoting below will cause test cases to fail if you do.  If you do
 536 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 537 # will then fail to shell-escape its contents when attempting to print them.
 538 # The testsuite verbose output, at least, will be incorrect, but nothing may
 539 # fail to make sure you notice.
 540 m4_define([AT_QUELL_VALGRIND],
 541 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 542
 543 ## ------------------------ ##
 544 ## Compiling C, C++ Files.  ##
 545 ## ------------------------ ##
 546
 547
 548 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 549 # ----------------------------------------
 550 # Compile SOURCES into OUTPUT.
 551 #
 552 # If OUTPUT does not contain '.', assume that we are linking too,
 553 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 554 # with trailing .o removed, and ".c" appended.
 555 m4_define([AT_COMPILE],
 556 [AT_CHECK(m4_join([ ],
 557                   [$CC $CFLAGS $CPPFLAGS],
 558                   [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 559                   [-o $1],
 560                   [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 561                   [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 562            0, [ignore], [ignore])])
 563
 564 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 565 # ---------------------------------------------
 566 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 567 # ignore the test.
 568 #
 569 # If OUTPUT does not contain '.', assume that we are linking too,
 570 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 571 # with trailing .o removed, and ".cc" appended.
 572 m4_define([AT_COMPILE_CXX],
 573 [AT_KEYWORDS(c++)
 574 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 575 AT_CHECK(m4_join([ ],
 576                  [$CXX $CXXFLAGS $CPPFLAGS],
 577                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 578                  [-o $1],
 579                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 580                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 581          0, [ignore], [ignore])])
 582
 583 # AT_JAVA_COMPILE(SOURCES)
 584 # ------------------------
 585 # Compile SOURCES into Java class files.  Skip the test if java or javac
 586 # is not installed.
 587 m4_define([AT_JAVA_COMPILE],
 588 [AT_KEYWORDS(java)
 589 AT_SKIP_IF([[test -z "$CONF_JAVA$CONF_JAVAC"]])
 590 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 591          [[0]], [ignore], [ignore])])
 592
 593 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 594 # --------------------------------------------
 595 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 596 #
 597 # If OUTPUT does not contain '.', assume that we are linking too,
 598 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 599 # with trailing .o removed, and ".c"/".cc" appended.
 600 m4_define([AT_LANG_COMPILE],
 601 [m4_case(AT_LANG,
 602 [c],    [AT_COMPILE([$1], [$2])],
 603 [c++],  [AT_COMPILE_CXX([$1], [$2])],
 604 [java], [AT_JAVA_COMPILE([$1.java], [$2])],
 605         [m4_fatal([unknown language: ]m4_defn([AT_LANG]))])[]dnl
 606 ])
 607
 608 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 609 # -------------------------------------------
 610 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 611 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 612 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 613 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 614 # AT_SKEL_JAVA_IF.
 615 m4_define([AT_FULL_COMPILE],
 616 [m4_case(AT_LANG,
 617 [java],
 618   [AT_BISON_CHECK([-o $1.java $1.y])
 619    AT_LANG_COMPILE([$1],
 620                    m4_join([ ],
 621                            [$1.java],
 622                            m4_ifval($2, [[$1-$2.java]]),
 623                            m4_ifval($3, [[$1-$3.java]])))],
 624 [c++],
 625   [AT_BISON_CHECK([-o $1.cc $1.y])
 626    AT_LANG_COMPILE([$1],
 627                    m4_join([ ],
 628                            [$1.cc],
 629                            m4_ifval($2, [[$1-$2.cc]]),
 630                            m4_ifval($3, [[$1-$3.cc]])))],
 631 [c],
 632   [AT_BISON_CHECK([-o $1.c $1.y])
 633    AT_LANG_COMPILE([$1],
 634                    m4_join([ ],
 635                            [$1.c],
 636                            m4_ifval($2, [[$1-$2.c]]),
 637                            m4_ifval($3, [[$1-$3.c]])))])
 638 ])
 639
 640
 641 ## ---------------------------- ##
 642 ## Running a generated parser.  ##
 643 ## ---------------------------- ##
 644
 645
 646 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 647 # ------------------------------------------------------------
 648 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 649 #
 650 # Get rid of spurious messages when compiled with --coverage:
 651 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 652 m4_define([AT_PARSER_CHECK],
 653 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 654 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 655          [0], [], [$4])
 656 ])
 657
 658
 659 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 660 # -----------------------------------------------------------------
 661 m4_define([AT_JAVA_PARSER_CHECK],
 662 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 663
 664
 665 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 666 #                          DECLS, GRAMMAR, INPUT,
 667 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 668 #                          [OTHER-CHECKS],
 669 #                          [PARSER-EXIT-VALUE],
 670 #                          [PARSER-STDOUT], [PARSER-STDERR])
 671 # -------------------------------------------------------------
 672 # Using TITLE as the test group title, check the generated parser tables
 673 # and parser for a specified grammar file under a condition labeled by
 674 # COND-VALUE.
 675 #
 676 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 677 # recognized attribute is described below where it is relevant.
 678 #
 679 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 680 # the grammar file.  Insert basic yyerror, yylex, and main function
 681 # definitions as well.  Hardcode yylex to return the (possibly empty)
 682 # comma-delimited series of tokens in INPUT followed by token 0.
 683 #
 684 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 685 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 686 # On the bison command-line, specify `--report=all --defines'.  Check
 687 # that Bison exits with value 0, has no stdout, and has stderr
 688 # BISON-STDERR.
 689 #
 690 # If TEST-SPEC contains the attribute `last-state', check that the value
 691 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 692 # the grammar; in other words, check the number of states (minus one).
 693 # Otherwise, check that everything in the `.output' file starting with
 694 # the definition of state 0 is the same as the entire value of
 695 # TABLES-OR-LAST-STATE.
 696 #
 697 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 698 # `.output' file, which is named `input.output', and/or grammar file,
 699 # which is named `input.y'.
 700 #
 701 # Finally, compile the generated parser and then run it using
 702 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 703 # PARSER-STDERR as the 2nd-4th arguments.
 704 #
 705 # As a precondition, you must properly double-quote all arguments that
 706 # are to be interpreted as strings.
 707 #
 708 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 709 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 710 # first argument.  This is useful, for example, when wrapping multiple
 711 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 712 # condition, in another macro.
 713 #
 714 # For example:
 715 #
 716 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 717 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 718 #   # ---------------------------------------------------------------------
 719 #   m4_define([AT_TEST_SYNTAX_ERROR],
 720 #   [
 721 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 722 #                              [[last-state]],
 723 #                              [[%error-verbose ]$2], [$3], [$4],
 724 #                              [[]], [$5], [], [$6], [$7], [$8])
 725 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 726 #                              [[last-state]],
 727 #                              [$2], [$3], [$4],
 728 #                              [[]], [$5], [], [$6], [$7], [$8])
 729 #   ])
 730 #
 731 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 732 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 733 #                        [[3]],
 734 #                        [[1]], [[]],
 735 #                        [AT_COND_CASE([[no verbose]],
 736 #                                      [[syntax error
 737 #   ]],
 738 #                                      [[syntax error, unexpected 'b', expecting $end
 739 #   ]])])
 740 m4_define([AT_TEST_TABLES_AND_PARSE],
 741 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 742
 743 AT_SETUP([$1])
 744 AT_BISON_OPTION_PUSHDEFS([$4])
 745 AT_DATA_GRAMMAR([[input.y]],
 746 [[%code {
 747   #include <stdio.h>
 748   ]AT_YYERROR_DECLARE[
 749   ]AT_YYLEX_DECLARE[
 750 }
 751
 752 ]$4[
 753
 754 %%
 755
 756 ]$5[
 757
 758 %%
 759 ]AT_YYERROR_DEFINE[
 760 static int
 761 yylex (void)
 762 {
 763   static int const input[] = {
 764     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 765   };
 766   static int const *inputp = input;
 767   return *inputp++;
 768 }
 769
 770 int
 771 main (void)
 772 {
 773   return yyparse ();
 774 }
 775 ]])
 776
 777 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 778 # expanding macros, so it corrupts some special characters in the
 779 # macros.  To avoid this, expand now and pass it the result with proper
 780 # string quotation.  Assume args 7 through 12 expand to properly quoted
 781 # strings.
 782
 783 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 784       [AT_BISON_CHECK],
 785       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 786                                [0], [], m4_dquote($7))
 787
 788 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 789       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 790                 m4_dquote($8))],
 791       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 792                 m4_dquote($8)[[
 793 ]])])
 794
 795 $9
 796
 797 # Canonical LR generates very large tables, resulting in very long
 798 # files with #line directives that may overflow what the standards
 799 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 800 # will issue an error.
 801 #
 802 # There is no "" around `wc` since some indent the result.
 803 m4_bmatch([$4], [%define lr.type canonical-lr],
 804 [if test 32767 -lt `wc -l < input.c`; then
 805   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 806   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 807 fi])
 808 AT_COMPILE([[input]])
 809
 810 AT_PARSER_CHECK([[./input]],
 811                 m4_ifval([$10], [m4_dquote($10)]),
 812                 m4_ifval([$11], [m4_dquote($11)]),
 813                 m4_ifval([$12], [m4_dquote($12)]))
 814
 815 AT_BISON_OPTION_POPDEFS
 816 AT_CLEANUP
 817
 818 m4_popdef([AT_COND_CASE])])
 819
 820
 821
 822 ## ----------------------- ##
 823 ## Launch the test suite.  ##
 824 ## ----------------------- ##
 825
 826 AT_INIT
 827
 828 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 829 # options are processed, so we don't know the value of CXX and
 830 # CXXFLAGS yet.
 831 #
 832 # Note that it also means that command line values for CXX and
 833 # CXXFLAGS will not be propagated to CC and CFLAGS.
 834 AT_ARG_OPTION([compile-c-with-cxx],
 835               [compile C parsers with the C++ compiler])
 836
 837 AT_COLOR_TESTS
 838
 839 AT_TESTED([bison])