tests/calc.at

   1 # Checking the output filenames.                         -*- Autotest -*-
   2 # Copyright 2000, 2001 Free Software Foundation, Inc.
   3
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2, or (at your option)
   7 # any later version.
   8
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  17 # 02111-1307, USA.
  18
  19 AT_BANNER([[Simple Calculator.]])
  20
  21 ## ---------------------------------------------------- ##
  22 ## Compile the grammar described in the documentation.  ##
  23 ## ---------------------------------------------------- ##
  24
  25
  26 # ------------------------- #
  27 # Helping Autotest macros.  #
  28 # ------------------------- #
  29
  30
  31 # _AT_DATA_CALC_Y($1, $2, $3, [CPP-DIRECTIVES])
  32 # ---------------------------------------------
  33 # Produce `calc.y'.  Don't call this macro directly, because it contains
  34 # some occurrences of `$1' etc. which will be interpreted by m4.  So
  35 # you should call it with $1, $2, and $3 as arguments, which is what
  36 # AT_DATA_CALC_Y does.
  37 m4_define([_AT_DATA_CALC_Y],
  38 [m4_if([$1$2$3], $[1]$[2]$[3], [],
  39        [m4_fatal([$0: Invalid arguments: $@])])dnl
  40 AT_DATA([calc.y],
  41 [[/* Infix notation calculator--calc */
  42
  43 %{
  44 #include <config.h>
  45 /* We don't need a perfect malloc for these tests. */
  46 #undef malloc
  47 #include <stdio.h>
  48
  49 #if STDC_HEADERS
  50 # include <stdlib.h>
  51 # include <string.h>
  52 #else
  53 char *strcat(char *dest, const char *src);
  54 #endif
  55 #include <ctype.h>
  56
  57 static int power (int base, int exponent);
  58 static void yyerror (const char *s);
  59 static int yylex (void);
  60 static int yygetc (void);
  61 static void yyungetc (int c);
  62
  63 extern void perror (const char *s);
  64 %}
  65
  66 /* Bison Declarations */
  67 %token CALC_EOF 0 "end of file"
  68 %token NUM "number"
  69
  70 %nonassoc '=' /* comparison            */
  71 %left '-' '+'
  72 %left '*' '/'
  73 %left NEG     /* negation--unary minus */
  74 %right '^'    /* exponentiation        */
  75
  76 ]$4[
  77
  78 /* Grammar follows */
  79 %%
  80 input:
  81   line
  82 | input line
  83 ;
  84
  85 line:
  86   '\n'
  87 | exp '\n'
  88 ;
  89
  90 exp:
  91   NUM                { $$ = $1;             }
  92 | exp '=' exp
  93   {
  94      if ($1 != $3)
  95        printf ("calc: error: %d != %d\n", $1, $3);
  96      $$ = $1 == $3;
  97   }
  98 | exp '+' exp        { $$ = $1 + $3;        }
  99 | exp '-' exp        { $$ = $1 - $3;        }
 100 | exp '*' exp        { $$ = $1 * $3;        }
 101 | exp '/' exp        { $$ = $1 / $3;        }
 102 | '-' exp  %prec NEG { $$ = -$2;            }
 103 | exp '^' exp        { $$ = power ($1, $3); }
 104 | '(' exp ')'        { $$ = $2;             }
 105 ;
 106 %%
 107 /* The input. */
 108 FILE *yyin;
 109
 110 static void
 111 yyerror (const char *s)
 112 {
 113 #if YYLSP_NEEDED
 114   fprintf (stderr, "%d.%d:%d.%d: ",
 115            yylloc.first_line, yylloc.first_column,
 116            yylloc.last_line, yylloc.last_column);
 117 #endif
 118   fprintf (stderr, "%s\n", s);
 119 }
 120
 121
 122 #if YYLSP_NEEDED
 123 static YYLTYPE last_yylloc;
 124 #endif
 125 static int
 126 yygetc (void)
 127 {
 128   int res = getc (yyin);
 129 #if YYLSP_NEEDED
 130   last_yylloc = yylloc;
 131   if (res == '\n')
 132     {
 133       yylloc.last_line++;
 134       yylloc.last_column = 0;
 135     }
 136   else
 137     yylloc.last_column++;
 138 #endif
 139   return res;
 140 }
 141
 142
 143 static void
 144 yyungetc (int c)
 145 {
 146 #if YYLSP_NEEDED
 147   /* Wrong when C == `\n'. */
 148   yylloc = last_yylloc;
 149 #endif
 150   ungetc (c, yyin);
 151 }
 152
 153 static int
 154 read_signed_integer (void)
 155 {
 156   int c = yygetc ();
 157   int sign = 1;
 158   int n = 0;
 159
 160   if (c == '-')
 161     {
 162       c = yygetc ();
 163       sign = -1;
 164     }
 165
 166   while (isdigit (c))
 167     {
 168       n = 10 * n + (c - '0');
 169       c = yygetc ();
 170     }
 171
 172   yyungetc (c);
 173
 174   return sign * n;
 175 }
 176
 177
 178
 179 /*---------------------------------------------------------------.
 180 | Lexical analyzer returns an integer on the stack and the token |
 181 | NUM, or the ASCII character read if not a number.  Skips all   |
 182 | blanks and tabs, returns 0 for EOF.                            |
 183 `---------------------------------------------------------------*/
 184
 185 static int
 186 yylex (void)
 187 {
 188   int c;
 189
 190 #if YYLSP_NEEDED
 191   yylloc.first_column = yylloc.last_column;
 192   yylloc.first_line = yylloc.last_line;
 193 #endif
 194
 195   /* Skip white space.  */
 196   while ((c = yygetc ()) == ' ' || c == '\t')
 197     {
 198 #if YYLSP_NEEDED
 199       yylloc.first_column = yylloc.last_column;
 200       yylloc.first_line = yylloc.last_line;
 201 #endif
 202     }
 203
 204   /* process numbers   */
 205   if (c == '.' || isdigit (c))
 206     {
 207       yyungetc (c);
 208       yylval = read_signed_integer ();
 209       return NUM;
 210     }
 211
 212   /* Return end-of-file.  */
 213   if (c == EOF)
 214     return CALC_EOF;
 215
 216   /* Return single chars. */
 217   return c;
 218 }
 219
 220 static int
 221 power (int base, int exponent)
 222 {
 223   int res = 1;
 224   if (exponent < 0)
 225     exit (1);
 226   for (/* Niente */; exponent; --exponent)
 227     res *= base;
 228   return res;
 229 }
 230
 231 int
 232 main (int argc, const char **argv)
 233 {
 234   yyin = NULL;
 235
 236   if (argc == 2)
 237     yyin = fopen (argv[1], "r");
 238   else
 239     yyin = stdin;
 240
 241   if (!yyin)
 242     {
 243       perror (argv[1]);
 244       exit (1);
 245     }
 246
 247 #if YYDEBUG
 248   yydebug = 1;
 249 #endif
 250 #if YYLSP_NEEDED
 251   yylloc.last_column = 0;
 252   yylloc.last_line = 1;
 253 #endif
 254   yyparse ();
 255   return 0;
 256 }
 257 ]])
 258 ])# _AT_DATA_CALC_Y
 259
 260
 261 # AT_DATA_CALC_Y([BISON-OPTIONS])
 262 # -------------------------------
 263 # Produce `calc.y'.
 264 m4_define([AT_DATA_CALC_Y],
 265 [_AT_DATA_CALC_Y($[1], $[2], $[3],
 266                  [m4_bmatch([$1], [--yyerror-verbose],
 267                             [[%error-verbose]])])])
 268
 269
 270
 271 # _AT_CHECK_CALC(BISON-OPTIONS, INPUT, [NUM-STDERR-LINES = 0])
 272 # ------------------------------------------------------------
 273 # Run `calc' on INPUT and expect no STDOUT nor STDERR.
 274 #
 275 # If BISON-OPTIONS contains `--debug', then NUM-STDERR-LINES is the number
 276 # of expected lines on stderr.
 277 m4_define([_AT_CHECK_CALC],
 278 [AT_DATA([[input]],
 279 [[$2
 280 ]])
 281 AT_CHECK([calc input], 0, [], [stderr])dnl
 282 AT_CHECK([wc -l <stderr | sed 's/[[^0-9]]//g'], 0,
 283          [m4_bmatch([$1], [--debug],
 284                     [$3], [0])
 285 ])
 286 ])
 287
 288
 289 # _AT_CHECK_CALC_ERROR(BISON-OPTIONS, INPUT, [NUM-DEBUG-LINES],
 290 #                      [ERROR-LOCATION], [IF-YYERROR-VERBOSE])
 291 # ------------------------------------------------------------
 292 # Run `calc' on INPUT, and expect a `parse error' message.
 293 #
 294 # If INPUT starts with a slash, it is used as absolute input file name,
 295 # otherwise as contents.
 296 #
 297 # If BISON-OPTIONS contains `--location', then make sure the ERROR-LOCATION
 298 # is correctly output on stderr.
 299 #
 300 # If BISON-OPTIONS contains `--yyerror-verbose', then make sure the
 301 # IF-YYERROR-VERBOSE message is properly output after `parse error, '
 302 # on STDERR.
 303 #
 304 # If BISON-OPTIONS contains `--debug', then NUM-STDERR-LINES is the number
 305 # of expected lines on stderr.
 306 m4_define([_AT_CHECK_CALC_ERROR],
 307 [m4_bmatch([$2], [^/],
 308            [AT_CHECK([calc $2], 0, [], [stderr])],
 309            [AT_DATA([[input]],
 310 [[$2
 311 ]])
 312 AT_CHECK([calc input], 0, [], [stderr])])
 313
 314
 315 AT_CHECK([wc -l <stderr | sed 's/[[^0-9]]//g'], 0,
 316          [m4_bmatch([$1], [--debug],
 317                     [$3], [1])
 318 ])
 319
 320 egrep -v '^((Start|Enter|Read|Reduc|Shift)ing|state|Error:) ' stderr >at-stderr
 321 mv at-stderr stderr
 322
 323 AT_CHECK([cat stderr], 0,
 324 [m4_bmatch([$1], [--location], [$4: ])[]dnl
 325 parse error[]dnl
 326 m4_bmatch([$1], [--yyerror-verbose], [, $5])[]dnl
 327
 328 ])
 329
 330 ])
 331
 332
 333 # AT_CHECK_CALC([BISON-OPTIONS], [PARSER-EXPECTED-STDERR])
 334 # --------------------------------------------------------
 335 # Start a testing chunk which compiles `calc' grammar with
 336 # BISON-OPTIONS, and performs several tests over the parser.
 337 m4_define([AT_CHECK_CALC],
 338 [# We use integers to avoid dependencies upon the precision of doubles.
 339 AT_SETUP([Calculator $1])
 340
 341 AT_DATA_CALC_Y([$1])
 342
 343 # Specify the output files to avoid problems on different file systems.
 344 AT_CHECK([bison calc.y -o calc.c m4_bpatsubst([$1], [--yyerror-verbose])],
 345          [0], [], [])
 346
 347 # Some compilers issue warnings we don't want to hear about.
 348 # Maybe some day we will have proper Autoconf macros to disable these
 349 # warnings, but this place is not the right one for that.
 350 # So let's keep only GCC warnings, which we know are sane.
 351 # Well, that's only part of the story: some assemblers issue warnings
 352 # which can be totally useless, and actually polluting.  It seems that
 353 # the best bet be to completely ignore stderr, but to pass -Werror
 354 # to GCC.
 355 if test "$GCC" = yes; then
 356   CFLAGS="$CFLAGS -Werror"
 357 fi
 358 AT_CHECK([$CC $CFLAGS $CPPFLAGS calc.c -o calc], 0, [], [ignore])
 359
 360 # Test the priorities.
 361 _AT_CHECK_CALC([$1],
 362 [1 + 2 * 3 = 7
 363 1 + 2 * -3 = -5
 364
 365 -1^2 = -1
 366 (-1)^2 = 1
 367
 368 ---1 = -1
 369
 370 1 - 2 - 3 = -4
 371 1 - (2 - 3) = 2
 372
 373 2^2^3 = 256
 374 (2^2)^3 = 64], [488])
 375
 376 # Some parse errors.
 377 _AT_CHECK_CALC_ERROR([$1], [0 0], [10],
 378                      [1.2:1.3],
 379                      [unexpected "number"])
 380 _AT_CHECK_CALC_ERROR([$1], [1//2], [13],
 381                      [1.2:1.3],
 382                      [unexpected '/', expecting "number" or '-' or '('])
 383 _AT_CHECK_CALC_ERROR([$1], [error], [4],
 384                      [1.0:1.1],
 385                      [unexpected $undefined., expecting "number" or '-' or '\n' or '('])
 386 _AT_CHECK_CALC_ERROR([$1], [1 = 2 = 3], [19],
 387                      [1.6:1.7],
 388                      [unexpected '='])
 389 _AT_CHECK_CALC_ERROR([$1],
 390                      [
 391 +1],
 392                      [13],
 393                      [2.0:2.1],
 394                      [unexpected '+'])
 395 # Exercise error messages with EOF: work on an empty file.
 396 _AT_CHECK_CALC_ERROR([$1],
 397                      [/dev/null],
 398                      [4],
 399                      [1.0:1.1],
 400                      [unexpected "end of file", expecting "number" or '-' or '\n' or '('])
 401
 402 AT_CLEANUP
 403 ])# AT_CHECK_CALC
 404
 405
 406
 407
 408 # ------------------ #
 409 # Test the parsers.  #
 410 # ------------------ #
 411
 412 AT_CHECK_CALC()
 413
 414 AT_CHECK_CALC([--defines])
 415 AT_CHECK_CALC([--locations])
 416 AT_CHECK_CALC([--name-prefix=calc])
 417 AT_CHECK_CALC([--verbose])
 418 AT_CHECK_CALC([--yacc])
 419 AT_CHECK_CALC([--yyerror-verbose])
 420
 421 AT_CHECK_CALC([--locations --yyerror-verbose])
 422
 423 AT_CHECK_CALC([--defines --locations --name-prefix=calc --verbose --yacc --yyerror-verbose])
 424
 425 AT_CHECK_CALC([--debug])
 426 AT_CHECK_CALC([--debug --defines --locations --name-prefix=calc --verbose --yacc --yyerror-verbose])