src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301  USA
  21 */
  22
  23 #include <config.h>
  24 #include "system.h"
  25
  26 #include <strverscmp.h>
  27
  28 #include "complain.h"
  29 #include "conflicts.h"
  30 #include "files.h"
  31 #include "getargs.h"
  32 #include "gram.h"
  33 #include "muscle_tab.h"
  34 #include "quotearg.h"
  35 #include "reader.h"
  36 #include "symlist.h"
  37 #include "scan-gram.h"
  38 #include "scan-code.h"
  39
  40 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  41 static YYLTYPE lloc_default (YYLTYPE const *, int);
  42
  43 #define YY_LOCATION_PRINT(File, Loc) \
  44           location_print (File, Loc)
  45
  46 static void version_check (location const *loc, char const *version);
  47
  48 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  49    FIXME: depends on the undocumented availability of YYLLOC.  */
  50 #undef  yyerror
  51 #define yyerror(Msg) \
  52         gram_error (&yylloc, Msg)
  53 static void gram_error (location const *, char const *);
  54
  55 static char const *char_name (char);
  56
  57 /** Add a lex-param or a parse-param.
  58  *
  59  * \param type  \a lex_param or \a parse_param
  60  * \param decl  the formal argument
  61  * \param loc   the location in the source.
  62  */
  63 static void add_param (char const *type, char *decl, location loc);
  64
  65
  66 static symbol_class current_class = unknown_sym;
  67 static uniqstr current_type = NULL;
  68 static symbol *current_lhs;
  69 static location current_lhs_location;
  70 static int current_prec = 0;
  71
  72 #define YYTYPE_INT16 int_fast16_t
  73 #define YYTYPE_INT8 int_fast8_t
  74 #define YYTYPE_UINT16 uint_fast16_t
  75 #define YYTYPE_UINT8 uint_fast8_t
  76 %}
  77
  78 %debug
  79 %verbose
  80 %defines
  81 %locations
  82 %pure-parser
  83 %error-verbose
  84 %defines
  85 %name-prefix="gram_"
  86 %expect 0
  87
  88 %initial-action
  89 {
  90   /* Bison's grammar can initial empty locations, hence a default
  91      location is needed. */
  92   boundary_set (&@$.start, current_file, 1, 1);
  93   boundary_set (&@$.end, current_file, 1, 1);
  94 }
  95
  96 %union
  97 {
  98   symbol *symbol;
  99   symbol_list *list;
 100   int integer;
 101   char const *chars;
 102   char *code;
 103   assoc assoc;
 104   uniqstr uniqstr;
 105   unsigned char character;
 106 };
 107
 108 /* Define the tokens together with their human representation.  */
 109 %token GRAM_EOF 0 "end of file"
 110 %token STRING     "string"
 111 %token INT        "integer"
 112
 113 %token PERCENT_TOKEN       "%token"
 114 %token PERCENT_NTERM       "%nterm"
 115
 116 %token PERCENT_TYPE        "%type"
 117 %token PERCENT_DESTRUCTOR  "%destructor"
 118 %token PERCENT_PRINTER     "%printer"
 119
 120 %token PERCENT_LEFT        "%left"
 121 %token PERCENT_RIGHT       "%right"
 122 %token PERCENT_NONASSOC    "%nonassoc"
 123
 124 %token PERCENT_PREC          "%prec"
 125 %token PERCENT_DPREC         "%dprec"
 126 %token PERCENT_MERGE         "%merge"
 127
 128
 129 /*----------------------.
 130 | Global Declarations.  |
 131 `----------------------*/
 132
 133 %token
 134   PERCENT_CODE            "%code"
 135   PERCENT_CODE_TOP        "%code-top"
 136   PERCENT_DEBUG           "%debug"
 137   PERCENT_DEFAULT_PREC    "%default-prec"
 138   PERCENT_DEFINE          "%define"
 139   PERCENT_DEFINES         "%defines"
 140   PERCENT_ERROR_VERBOSE   "%error-verbose"
 141   PERCENT_EXPECT          "%expect"
 142   PERCENT_EXPECT_RR       "%expect-rr"
 143   PERCENT_FILE_PREFIX     "%file-prefix"
 144   PERCENT_GLR_PARSER      "%glr-parser"
 145   PERCENT_INITIAL_ACTION  "%initial-action"
 146   PERCENT_LANGUAGE        "%language"
 147   PERCENT_LEX_PARAM       "%lex-param"
 148   PERCENT_LOCATIONS       "%locations"
 149   PERCENT_NAME_PREFIX     "%name-prefix"
 150   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 151   PERCENT_NO_LINES        "%no-lines"
 152   PERCENT_NONDETERMINISTIC_PARSER
 153                           "%nondeterministic-parser"
 154   PERCENT_OUTPUT          "%output"
 155   PERCENT_PARSE_PARAM     "%parse-param"
 156   PERCENT_PROVIDES        "%provides"
 157   PERCENT_PURE_PARSER     "%pure-parser"
 158   PERCENT_PUSH_PARSER     "%push-parser"
 159   PERCENT_PUSH_PULL_PARSER
 160                           "%push-pull-parser"
 161   PERCENT_REQUIRE         "%require"
 162   PERCENT_REQUIRES        "%requires"
 163   PERCENT_SKELETON        "%skeleton"
 164   PERCENT_START           "%start"
 165   PERCENT_TOKEN_TABLE     "%token-table"
 166   PERCENT_VERBOSE         "%verbose"
 167   PERCENT_YACC            "%yacc"
 168 ;
 169
 170 %token BRACED_CODE     "{...}"
 171 %token CHAR            "char"
 172 %token EPILOGUE        "epilogue"
 173 %token EQUAL           "="
 174 %token ID              "identifier"
 175 %token ID_COLON        "identifier:"
 176 %token PERCENT_PERCENT "%%"
 177 %token PIPE            "|"
 178 %token PROLOGUE        "%{...%}"
 179 %token SEMICOLON       ";"
 180 %token TYPE            "type"
 181 %token TYPE_TAG_ANY    "<*>"
 182 %token TYPE_TAG_NONE   "<>"
 183
 184 %type <character> CHAR
 185 %printer { fputs (char_name ($$), stderr); } CHAR
 186
 187 /* braceless is not to be used for rule or symbol actions, as it
 188    calls translate_code. */
 189 %type <chars> STRING "%{...%}" EPILOGUE braceless content content.opt
 190 %type <code> "{...}"
 191 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 192          STRING
 193 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 194          braceless content content.opt "{...}" "%{...%}" EPILOGUE
 195
 196 %type <uniqstr> TYPE ID ID_COLON
 197 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 198 %printer { fputs ($$, stderr); } ID
 199 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 200
 201 %type <integer> INT
 202 %printer { fprintf (stderr, "%d", $$); } INT
 203
 204 %type <symbol> id id_colon symbol string_as_id
 205 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 206 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 207
 208 %type <assoc> precedence_declarator
 209 %type <list>  symbols.1 generic_symlist generic_symlist_item
 210 %%
 211
 212 input:
 213   prologue_declarations "%%" grammar epilogue.opt
 214 ;
 215
 216
 217         /*------------------------------------.
 218         | Declarations: before the first %%.  |
 219         `------------------------------------*/
 220
 221 prologue_declarations:
 222   /* Nothing */
 223 | prologue_declarations prologue_declaration
 224 ;
 225
 226 prologue_declaration:
 227   grammar_declaration
 228 | "%{...%}"     { prologue_augment (translate_code ($1, @1), @1, union_seen); }
 229 | "%debug"                         { debug_flag = true; }
 230 | "%define" STRING content.opt     { muscle_insert ($2, $3); }
 231 | "%defines"                       { defines_flag = true; }
 232 | "%defines" STRING
 233     {
 234       defines_flag = true;
 235       spec_defines_file = xstrdup ($2);
 236     }
 237 | "%error-verbose"                 { error_verbose = true; }
 238 | "%expect" INT                    { expected_sr_conflicts = $2; }
 239 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 240 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 241 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 242 | "%glr-parser"
 243     {
 244       nondeterministic_parser = true;
 245       glr_parser = true;
 246     }
 247 | "%initial-action" "{...}"
 248     {
 249       muscle_code_grow ("initial_action", translate_symbol_action ($2, @2), @2);
 250     }
 251 | "%language" STRING            { language_argmatch ($2, 1, &@1); }
 252 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 253 | "%locations"                  { locations_flag = true; }
 254 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 255 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 256 | "%no-lines"                   { no_lines_flag = true; }
 257 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 258 | "%output" STRING              { spec_outfile = $2; }
 259 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 260 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 261 | "%pure-parser"                { pure_parser = true; }
 262 | "%push-parser"                { push_parser = true; pull_parser = false; }
 263 | "%push-pull-parser"           { push_parser = true; pull_parser = true; }
 264 | "%require" STRING             { version_check (&@2, $2); }
 265 | "%skeleton" STRING            { skeleton_arg ($2, 1, &@1); }
 266 | "%token-table"                { token_table_flag = true; }
 267 | "%verbose"                    { report_flag = report_states; }
 268 | "%yacc"                       { yacc_flag = true; }
 269 | /*FIXME: Err?  What is this horror doing here? */ ";"
 270 ;
 271
 272 grammar_declaration:
 273   precedence_declaration
 274 | symbol_declaration
 275 | "%start" symbol
 276     {
 277       grammar_start_symbol_set ($2, @2);
 278     }
 279 | "%destructor" "{...}" generic_symlist
 280     {
 281       symbol_list *list;
 282       const char *action = translate_symbol_action ($2, @2);
 283       for (list = $3; list; list = list->next)
 284         symbol_list_destructor_set (list, action, @2);
 285       symbol_list_free ($3);
 286     }
 287 | "%printer" "{...}" generic_symlist
 288     {
 289       symbol_list *list;
 290       const char *action = translate_symbol_action ($2, @2);
 291       for (list = $3; list; list = list->next)
 292         symbol_list_printer_set (list, action, @2);
 293       symbol_list_free ($3);
 294     }
 295 | "%default-prec"
 296     {
 297       default_prec = true;
 298     }
 299 | "%no-default-prec"
 300     {
 301       default_prec = false;
 302     }
 303 | "%code" braceless      { prologue_augment ($2, @2, true); }
 304 | "%code-top" braceless  { prologue_augment ($2, @2, false); }
 305 | "%provides" braceless  { muscle_code_grow ("provides", $2, @2); }
 306 | "%requires" braceless  { muscle_code_grow ("requires", $2, @2); }
 307 ;
 308
 309
 310 /*----------*
 311  | %union.  |
 312  *----------*/
 313
 314 %token PERCENT_UNION "%union";
 315
 316 union_name:
 317   /* Nothing. */ {}
 318 | ID             { muscle_code_grow ("union_name", $1, @1); }
 319 ;
 320
 321 grammar_declaration:
 322   "%union" union_name "{...}"
 323     {
 324       char const *body = $3;
 325
 326       /* Concatenate the %union bodies.  If this is the first %union, make sure
 327          the synchronization line appears after the opening '{' so as not to
 328          confuse Doxygen.  Otherwise, turn the previous %union's trailing '}'
 329          into '\n', and omit the new %union's leading '{'.  */
 330       if (!union_seen)
 331         {
 332           muscle_grow ("stype", "{", "");
 333         }
 334       else
 335         {
 336           char *code = muscle_find ("stype");
 337           code[strlen (code) - 1] = '\n';
 338         }
 339       body++;
 340
 341       union_seen = true;
 342       muscle_code_grow ("stype", body, @3);
 343     }
 344 ;
 345
 346
 347
 348
 349 symbol_declaration:
 350   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 351     {
 352       current_class = unknown_sym;
 353       current_type = NULL;
 354     }
 355 | "%token" { current_class = token_sym; } symbol_defs.1
 356     {
 357       current_class = unknown_sym;
 358       current_type = NULL;
 359     }
 360 | "%type" TYPE symbols.1
 361     {
 362       symbol_list *list;
 363       tag_seen = true;
 364       for (list = $3; list; list = list->next)
 365         symbol_type_set (list->content.sym, $2, @2);
 366       symbol_list_free ($3);
 367     }
 368 ;
 369
 370 precedence_declaration:
 371   precedence_declarator type.opt symbols.1
 372     {
 373       symbol_list *list;
 374       ++current_prec;
 375       for (list = $3; list; list = list->next)
 376         {
 377           symbol_type_set (list->content.sym, current_type, @2);
 378           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 379         }
 380       symbol_list_free ($3);
 381       current_type = NULL;
 382     }
 383 ;
 384
 385 precedence_declarator:
 386   "%left"     { $$ = left_assoc; }
 387 | "%right"    { $$ = right_assoc; }
 388 | "%nonassoc" { $$ = non_assoc; }
 389 ;
 390
 391 type.opt:
 392   /* Nothing. */ { current_type = NULL; }
 393 | TYPE           { current_type = $1; tag_seen = true; }
 394 ;
 395
 396 /* One or more symbols to be %typed. */
 397 symbols.1:
 398   symbol
 399     { $$ = symbol_list_sym_new ($1, @1); }
 400 | symbols.1 symbol
 401     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 402 ;
 403
 404 generic_symlist:
 405   generic_symlist_item { $$ = $1; }
 406 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 407 ;
 408
 409 generic_symlist_item:
 410   symbol            { $$ = symbol_list_sym_new ($1, @1); }
 411 | TYPE              { $$ = symbol_list_type_new ($1, @1); }
 412 | "<*>"             { $$ = symbol_list_default_tagged_new (@1); }
 413 | "<>"             { $$ = symbol_list_default_tagless_new (@1); }
 414 ;
 415
 416 /* One token definition.  */
 417 symbol_def:
 418   TYPE
 419      {
 420        current_type = $1;
 421        tag_seen = true;
 422      }
 423 | id
 424      {
 425        symbol_class_set ($1, current_class, @1, true);
 426        symbol_type_set ($1, current_type, @1);
 427      }
 428 | id INT
 429     {
 430       symbol_class_set ($1, current_class, @1, true);
 431       symbol_type_set ($1, current_type, @1);
 432       symbol_user_token_number_set ($1, $2, @2);
 433     }
 434 | id string_as_id
 435     {
 436       symbol_class_set ($1, current_class, @1, true);
 437       symbol_type_set ($1, current_type, @1);
 438       symbol_make_alias ($1, $2, @$);
 439     }
 440 | id INT string_as_id
 441     {
 442       symbol_class_set ($1, current_class, @1, true);
 443       symbol_type_set ($1, current_type, @1);
 444       symbol_user_token_number_set ($1, $2, @2);
 445       symbol_make_alias ($1, $3, @$);
 446     }
 447 ;
 448
 449 /* One or more symbol definitions. */
 450 symbol_defs.1:
 451   symbol_def
 452 | symbol_defs.1 symbol_def
 453 ;
 454
 455
 456         /*------------------------------------------.
 457         | The grammar section: between the two %%.  |
 458         `------------------------------------------*/
 459
 460 grammar:
 461   rules_or_grammar_declaration
 462 | grammar rules_or_grammar_declaration
 463 ;
 464
 465 /* As a Bison extension, one can use the grammar declarations in the
 466    body of the grammar.  */
 467 rules_or_grammar_declaration:
 468   rules
 469 | grammar_declaration ";"
 470 | error ";"
 471     {
 472       yyerrok;
 473     }
 474 ;
 475
 476 rules:
 477   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 478 ;
 479
 480 rhses.1:
 481   rhs                { grammar_current_rule_end (@1); }
 482 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 483 | rhses.1 ";"
 484 ;
 485
 486 rhs:
 487   /* Nothing.  */
 488     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 489 | rhs symbol
 490     { grammar_current_rule_symbol_append ($2, @2); }
 491 | rhs "{...}"
 492     { grammar_current_rule_action_append ($2, @2); }
 493 | rhs "%prec" symbol
 494     { grammar_current_rule_prec_set ($3, @3); }
 495 | rhs "%dprec" INT
 496     { grammar_current_rule_dprec_set ($3, @3); }
 497 | rhs "%merge" TYPE
 498     { grammar_current_rule_merge_set ($3, @3); }
 499 ;
 500
 501
 502 /*-----------*
 503  | content.  |
 504  *-----------*/
 505
 506 content:
 507   STRING
 508 | braceless
 509 ;
 510
 511 /* Some content or "1" by default. */
 512 content.opt:
 513   /* Nothing. */
 514     {
 515       static char one[] = "1";
 516       $$ = one;
 517     }
 518 | content
 519 ;
 520
 521
 522 braceless:
 523   "{...}"
 524     {
 525       $1[strlen ($1) - 1] = '\n';
 526       $$ = translate_code ($1 + 1, @1);
 527     }
 528 ;
 529
 530
 531 /*---------------*
 532  | Identifiers.  |
 533  *---------------*/
 534
 535 /* Identifiers are returned as uniqstr values by the scanner.
 536    Depending on their use, we may need to make them genuine symbols.  */
 537
 538 id:
 539   ID
 540     { $$ = symbol_from_uniqstr ($1, @1); }
 541 | CHAR
 542     {
 543       $$ = symbol_get (char_name ($1), @1);
 544       symbol_class_set ($$, token_sym, @1, false);
 545       symbol_user_token_number_set ($$, $1, @1);
 546     }
 547 ;
 548
 549 id_colon:
 550   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 551 ;
 552
 553
 554 symbol:
 555   id
 556 | string_as_id
 557 ;
 558
 559 /* A string used as an ID: quote it.  */
 560 string_as_id:
 561   STRING
 562     {
 563       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 564       symbol_class_set ($$, token_sym, @1, false);
 565     }
 566 ;
 567
 568 epilogue.opt:
 569   /* Nothing.  */
 570 | "%%" EPILOGUE
 571     {
 572       muscle_code_grow ("epilogue", translate_code ($2, @2), @2);
 573       gram_scanner_last_string_free ();
 574     }
 575 ;
 576
 577 %%
 578
 579
 580 /* Return the location of the left-hand side of a rule whose
 581    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 582    the right-hand side, and return an empty location equal to the end
 583    boundary of RHS[0] if the right-hand side is empty.  */
 584
 585 static YYLTYPE
 586 lloc_default (YYLTYPE const *rhs, int n)
 587 {
 588   int i;
 589   YYLTYPE loc;
 590
 591   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 592      The bug is fixed in 7.4.2m, but play it safe for now.  */
 593   loc.start = rhs[n].end;
 594   loc.end = rhs[n].end;
 595
 596   /* Ignore empty nonterminals the start of the the right-hand side.
 597      Do not bother to ignore them at the end of the right-hand side,
 598      since empty nonterminals have the same end as their predecessors.  */
 599   for (i = 1; i <= n; i++)
 600     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 601       {
 602         loc.start = rhs[i].start;
 603         break;
 604       }
 605
 606   return loc;
 607 }
 608
 609
 610 /* Add a lex-param or a parse-param (depending on TYPE) with
 611    declaration DECL and location LOC.  */
 612
 613 static void
 614 add_param (char const *type, char *decl, location loc)
 615 {
 616   static char const alphanum[26 + 26 + 1 + 10] =
 617     "abcdefghijklmnopqrstuvwxyz"
 618     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 619     "_"
 620     "0123456789";
 621   char const *name_start = NULL;
 622   char *p;
 623
 624   /* Stop on last actual character.  */
 625   for (p = decl; p[1]; p++)
 626     if ((p == decl
 627          || ! memchr (alphanum, p[-1], sizeof alphanum))
 628         && memchr (alphanum, p[0], sizeof alphanum - 10))
 629       name_start = p;
 630
 631   /* Strip the surrounding '{' and '}', and any blanks just inside
 632      the braces.  */
 633   while (*--p == ' ' || *p == '\t')
 634     continue;
 635   p[1] = '\0';
 636   while (*++decl == ' ' || *decl == '\t')
 637     continue;
 638
 639   if (! name_start)
 640     complain_at (loc, _("missing identifier in parameter declaration"));
 641   else
 642     {
 643       char *name;
 644       size_t name_len;
 645
 646       for (name_len = 1;
 647            memchr (alphanum, name_start[name_len], sizeof alphanum);
 648            name_len++)
 649         continue;
 650
 651       name = xmalloc (name_len + 1);
 652       memcpy (name, name_start, name_len);
 653       name[name_len] = '\0';
 654       muscle_pair_list_grow (type, decl, name);
 655       free (name);
 656     }
 657
 658   gram_scanner_last_string_free ();
 659 }
 660
 661
 662 static void
 663 version_check (location const *loc, char const *version)
 664 {
 665   if (strverscmp (version, PACKAGE_VERSION) > 0)
 666     {
 667       complain_at (*loc, "require bison %s, but have %s",
 668                    version, PACKAGE_VERSION);
 669       exit (63);
 670     }
 671 }
 672
 673 static void
 674 gram_error (location const *loc, char const *msg)
 675 {
 676   complain_at (*loc, "%s", msg);
 677 }
 678
 679 char const *
 680 token_name (int type)
 681 {
 682   return yytname[YYTRANSLATE (type)];
 683 }
 684
 685 static char const *
 686 char_name (char c)
 687 {
 688   if (c == '\'')
 689     return "'\\''";
 690   else
 691     {
 692       char buf[4];
 693       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 694       return quotearg_style (escape_quoting_style, buf);
 695     }
 696 }