src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301  USA
  21 */
  22
  23 #include <config.h>
  24 #include "system.h"
  25
  26 #include <strverscmp.h>
  27
  28 #include "complain.h"
  29 #include "conflicts.h"
  30 #include "files.h"
  31 #include "getargs.h"
  32 #include "gram.h"
  33 #include "muscle_tab.h"
  34 #include "quotearg.h"
  35 #include "reader.h"
  36 #include "symlist.h"
  37 #include "scan-gram.h"
  38 #include "scan-code.h"
  39
  40 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  41 static YYLTYPE lloc_default (YYLTYPE const *, int);
  42
  43 #define YY_LOCATION_PRINT(File, Loc) \
  44           location_print (File, Loc)
  45
  46 static void version_check (location const *loc, char const *version);
  47
  48 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  49    FIXME: depends on the undocumented availability of YYLLOC.  */
  50 #undef  yyerror
  51 #define yyerror(Msg) \
  52         gram_error (&yylloc, Msg)
  53 static void gram_error (location const *, char const *);
  54
  55 static char const *char_name (char);
  56
  57 /** Add a lex-param or a parse-param.
  58  *
  59  * \param type  \a lex_param or \a parse_param
  60  * \param decl  the formal argument
  61  * \param loc   the location in the source.
  62  */
  63 static void add_param (char const *type, char *decl, location loc);
  64
  65
  66 static symbol_class current_class = unknown_sym;
  67 static uniqstr current_type = NULL;
  68 static symbol *current_lhs;
  69 static location current_lhs_location;
  70 static int current_prec = 0;
  71
  72 #define YYTYPE_INT16 int_fast16_t
  73 #define YYTYPE_INT8 int_fast8_t
  74 #define YYTYPE_UINT16 uint_fast16_t
  75 #define YYTYPE_UINT8 uint_fast8_t
  76 %}
  77
  78 %debug
  79 %verbose
  80 %defines
  81 %locations
  82 %pure-parser
  83 %error-verbose
  84 %defines
  85 %name-prefix="gram_"
  86 %expect 0
  87
  88 %initial-action
  89 {
  90   /* Bison's grammar can initial empty locations, hence a default
  91      location is needed. */
  92   boundary_set (&@$.start, current_file, 1, 1);
  93   boundary_set (&@$.end, current_file, 1, 1);
  94 }
  95
  96 %union
  97 {
  98   symbol *symbol;
  99   symbol_list *list;
 100   int integer;
 101   char const *chars;
 102   char *code;
 103   assoc assoc;
 104   uniqstr uniqstr;
 105   unsigned char character;
 106 };
 107
 108 /* Define the tokens together with their human representation.  */
 109 %token GRAM_EOF 0 "end of file"
 110 %token STRING     "string"
 111 %token INT        "integer"
 112
 113 %token PERCENT_TOKEN       "%token"
 114 %token PERCENT_NTERM       "%nterm"
 115
 116 %token PERCENT_TYPE        "%type"
 117 %token PERCENT_DESTRUCTOR  "%destructor"
 118 %token PERCENT_PRINTER     "%printer"
 119
 120 %token PERCENT_LEFT        "%left"
 121 %token PERCENT_RIGHT       "%right"
 122 %token PERCENT_NONASSOC    "%nonassoc"
 123
 124 %token PERCENT_PREC          "%prec"
 125 %token PERCENT_DPREC         "%dprec"
 126 %token PERCENT_MERGE         "%merge"
 127
 128
 129 /*----------------------.
 130 | Global Declarations.  |
 131 `----------------------*/
 132
 133 %token
 134   PERCENT_CODE            "%code"
 135   PERCENT_CODE_TOP        "%code-top"
 136   PERCENT_DEBUG           "%debug"
 137   PERCENT_DEFAULT_PREC    "%default-prec"
 138   PERCENT_DEFINE          "%define"
 139   PERCENT_DEFINES         "%defines"
 140   PERCENT_ERROR_VERBOSE   "%error-verbose"
 141   PERCENT_EXPECT          "%expect"
 142   PERCENT_EXPECT_RR       "%expect-rr"
 143   PERCENT_FILE_PREFIX     "%file-prefix"
 144   PERCENT_GLR_PARSER      "%glr-parser"
 145   PERCENT_INITIAL_ACTION  "%initial-action"
 146   PERCENT_LEX_PARAM       "%lex-param"
 147   PERCENT_LOCATIONS       "%locations"
 148   PERCENT_NAME_PREFIX     "%name-prefix"
 149   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 150   PERCENT_NO_LINES        "%no-lines"
 151   PERCENT_NONDETERMINISTIC_PARSER
 152                           "%nondeterministic-parser"
 153   PERCENT_OUTPUT          "%output"
 154   PERCENT_PARSE_PARAM     "%parse-param"
 155   PERCENT_PROVIDES        "%provides"
 156   PERCENT_PURE_PARSER     "%pure-parser"
 157   PERCENT_PUSH_PARSER     "%push-parser"
 158   PERCENT_REQUIRE         "%require"
 159   PERCENT_REQUIRES        "%requires"
 160   PERCENT_SKELETON        "%skeleton"
 161   PERCENT_START           "%start"
 162   PERCENT_TOKEN_TABLE     "%token-table"
 163   PERCENT_VERBOSE         "%verbose"
 164   PERCENT_YACC            "%yacc"
 165 ;
 166
 167 %token BRACED_CODE     "{...}"
 168 %token CHAR            "char"
 169 %token EPILOGUE        "epilogue"
 170 %token EQUAL           "="
 171 %token ID              "identifier"
 172 %token ID_COLON        "identifier:"
 173 %token PERCENT_PERCENT "%%"
 174 %token PIPE            "|"
 175 %token PROLOGUE        "%{...%}"
 176 %token SEMICOLON       ";"
 177 %token TYPE            "type"
 178 %token TYPE_TAG_ANY    "<*>"
 179 %token TYPE_TAG_NONE   "<!>"
 180
 181 %type <character> CHAR
 182 %printer { fputs (char_name ($$), stderr); } CHAR
 183
 184 /* braceless is not to be used for rule or symbol actions, as it
 185    calls code_props_plain_init. */
 186 %type <chars> STRING "%{...%}" EPILOGUE braceless content content.opt
 187 %type <code> "{...}"
 188 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 189          STRING
 190 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 191          braceless content content.opt "{...}" "%{...%}" EPILOGUE
 192
 193 %type <uniqstr> TYPE ID ID_COLON
 194 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 195 %printer { fputs ($$, stderr); } ID
 196 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 197
 198 %type <integer> INT
 199 %printer { fprintf (stderr, "%d", $$); } INT
 200
 201 %type <symbol> id id_colon symbol string_as_id
 202 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 203 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 204
 205 %type <assoc> precedence_declarator
 206 %type <list>  symbols.1 generic_symlist generic_symlist_item
 207 %%
 208
 209 input:
 210   prologue_declarations "%%" grammar epilogue.opt
 211 ;
 212
 213
 214         /*------------------------------------.
 215         | Declarations: before the first %%.  |
 216         `------------------------------------*/
 217
 218 prologue_declarations:
 219   /* Nothing */
 220 | prologue_declarations prologue_declaration
 221 ;
 222
 223 prologue_declaration:
 224   grammar_declaration
 225 | "%{...%}" {
 226    code_props plain_code;
 227    code_props_plain_init (&plain_code, $1, @1);
 228    code_props_translate_code (&plain_code);
 229    gram_scanner_last_string_free ();
 230    prologue_augment (code_props_code_get (plain_code), @1, union_seen);
 231    code_scanner_last_string_free ();
 232 }
 233 | "%debug"                         { debug_flag = true; }
 234 | "%define" STRING content.opt     { muscle_insert ($2, $3); }
 235 | "%defines"                       { defines_flag = true; }
 236 | "%error-verbose"                 { error_verbose = true; }
 237 | "%expect" INT                    { expected_sr_conflicts = $2; }
 238 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 239 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; }
 240 | "%glr-parser"
 241     {
 242       nondeterministic_parser = true;
 243       glr_parser = true;
 244     }
 245 | "%initial-action" "{...}"
 246     {
 247       code_props action;
 248       code_props_symbol_action_init (&action, $2, @2);
 249       code_props_translate_code (&action);
 250       gram_scanner_last_string_free ();
 251       muscle_code_grow ("initial_action", code_props_code_get (action), @2);
 252       code_scanner_last_string_free ();
 253     }
 254 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 255 | "%locations"                  { locations_flag = true; }
 256 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; }
 257 | "%no-lines"                   { no_lines_flag = true; }
 258 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 259 | "%output" "=" STRING          { spec_outfile = $3; }
 260 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 261 | "%pure-parser"                { pure_parser = true; }
 262 | "%push-parser"                { push_parser = true; }
 263 | "%require" STRING             { version_check (&@2, $2); }
 264 | "%skeleton" STRING            { skeleton = $2; }
 265 | "%token-table"                { token_table_flag = true; }
 266 | "%verbose"                    { report_flag = report_states; }
 267 | "%yacc"                       { yacc_flag = true; }
 268 | /*FIXME: Err?  What is this horror doing here? */ ";"
 269 ;
 270
 271 grammar_declaration:
 272   precedence_declaration
 273 | symbol_declaration
 274 | "%start" symbol
 275     {
 276       grammar_start_symbol_set ($2, @2);
 277     }
 278 | "%destructor" "{...}" generic_symlist
 279     {
 280       symbol_list *list;
 281       for (list = $3; list; list = list->next)
 282         symbol_list_destructor_set (list, $2, @2);
 283       symbol_list_free ($3);
 284     }
 285 | "%printer" "{...}" generic_symlist
 286     {
 287       symbol_list *list;
 288       for (list = $3; list; list = list->next)
 289         symbol_list_printer_set (list, $2, @2);
 290       symbol_list_free ($3);
 291     }
 292 | "%default-prec"
 293     {
 294       default_prec = true;
 295     }
 296 | "%no-default-prec"
 297     {
 298       default_prec = false;
 299     }
 300 | "%code" braceless      { prologue_augment ($2, @2, true); }
 301 | "%code-top" braceless  { prologue_augment ($2, @2, false); }
 302 | "%provides" braceless  { muscle_code_grow ("provides", $2, @2); }
 303 | "%requires" braceless  { muscle_code_grow ("requires", $2, @2); }
 304 ;
 305
 306
 307 /*----------*
 308  | %union.  |
 309  *----------*/
 310
 311 %token PERCENT_UNION "%union";
 312
 313 union_name:
 314   /* Nothing. */ {}
 315 | ID             { muscle_code_grow ("union_name", $1, @1); }
 316 ;
 317
 318 grammar_declaration:
 319   "%union" union_name "{...}"
 320     {
 321       char const *body = $3;
 322
 323       /* Concatenate the %union bodies.  If this is the first %union, make sure
 324          the synchronization line appears after the opening '{' so as not to
 325          confuse Doxygen.  Otherwise, turn the previous %union's trailing '}'
 326          into '\n', and omit the new %union's leading '{'.  */
 327       if (!union_seen)
 328         {
 329           muscle_grow ("stype", "{", "");
 330         }
 331       else
 332         {
 333           char *code = muscle_find ("stype");
 334           code[strlen (code) - 1] = '\n';
 335         }
 336       body++;
 337
 338       union_seen = true;
 339       muscle_code_grow ("stype", body, @3);
 340       gram_scanner_last_string_free ();
 341     }
 342 ;
 343
 344
 345
 346
 347 symbol_declaration:
 348   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 349     {
 350       current_class = unknown_sym;
 351       current_type = NULL;
 352     }
 353 | "%token" { current_class = token_sym; } symbol_defs.1
 354     {
 355       current_class = unknown_sym;
 356       current_type = NULL;
 357     }
 358 | "%type" TYPE symbols.1
 359     {
 360       symbol_list *list;
 361       tag_seen = true;
 362       for (list = $3; list; list = list->next)
 363         symbol_type_set (list->content.sym, $2, @2);
 364       symbol_list_free ($3);
 365     }
 366 ;
 367
 368 precedence_declaration:
 369   precedence_declarator type.opt symbols.1
 370     {
 371       symbol_list *list;
 372       ++current_prec;
 373       for (list = $3; list; list = list->next)
 374         {
 375           symbol_type_set (list->content.sym, current_type, @2);
 376           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 377         }
 378       symbol_list_free ($3);
 379       current_type = NULL;
 380     }
 381 ;
 382
 383 precedence_declarator:
 384   "%left"     { $$ = left_assoc; }
 385 | "%right"    { $$ = right_assoc; }
 386 | "%nonassoc" { $$ = non_assoc; }
 387 ;
 388
 389 type.opt:
 390   /* Nothing. */ { current_type = NULL; }
 391 | TYPE           { current_type = $1; tag_seen = true; }
 392 ;
 393
 394 /* One or more symbols to be %typed. */
 395 symbols.1:
 396   symbol
 397     { $$ = symbol_list_sym_new ($1, @1); }
 398 | symbols.1 symbol
 399     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 400 ;
 401
 402 generic_symlist:
 403   generic_symlist_item { $$ = $1; }
 404 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 405 ;
 406
 407 generic_symlist_item:
 408   symbol            { $$ = symbol_list_sym_new ($1, @1); }
 409 | TYPE              { $$ = symbol_list_type_new ($1, @1); }
 410 | "<*>"             { $$ = symbol_list_default_tagged_new (@1); }
 411 | "<!>"             { $$ = symbol_list_default_tagless_new (@1); }
 412 ;
 413
 414 /* One token definition.  */
 415 symbol_def:
 416   TYPE
 417      {
 418        current_type = $1;
 419        tag_seen = true;
 420      }
 421 | id
 422      {
 423        symbol_class_set ($1, current_class, @1, true);
 424        symbol_type_set ($1, current_type, @1);
 425      }
 426 | id INT
 427     {
 428       symbol_class_set ($1, current_class, @1, true);
 429       symbol_type_set ($1, current_type, @1);
 430       symbol_user_token_number_set ($1, $2, @2);
 431     }
 432 | id string_as_id
 433     {
 434       symbol_class_set ($1, current_class, @1, true);
 435       symbol_type_set ($1, current_type, @1);
 436       symbol_make_alias ($1, $2, @$);
 437     }
 438 | id INT string_as_id
 439     {
 440       symbol_class_set ($1, current_class, @1, true);
 441       symbol_type_set ($1, current_type, @1);
 442       symbol_user_token_number_set ($1, $2, @2);
 443       symbol_make_alias ($1, $3, @$);
 444     }
 445 ;
 446
 447 /* One or more symbol definitions. */
 448 symbol_defs.1:
 449   symbol_def
 450 | symbol_defs.1 symbol_def
 451 ;
 452
 453
 454         /*------------------------------------------.
 455         | The grammar section: between the two %%.  |
 456         `------------------------------------------*/
 457
 458 grammar:
 459   rules_or_grammar_declaration
 460 | grammar rules_or_grammar_declaration
 461 ;
 462
 463 /* As a Bison extension, one can use the grammar declarations in the
 464    body of the grammar.  */
 465 rules_or_grammar_declaration:
 466   rules
 467 | grammar_declaration ";"
 468 | error ";"
 469     {
 470       yyerrok;
 471     }
 472 ;
 473
 474 rules:
 475   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 476 ;
 477
 478 rhses.1:
 479   rhs                { grammar_current_rule_end (@1); }
 480 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 481 | rhses.1 ";"
 482 ;
 483
 484 rhs:
 485   /* Nothing.  */
 486     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 487 | rhs symbol
 488     { grammar_current_rule_symbol_append ($2, @2); }
 489 | rhs "{...}"
 490     { grammar_current_rule_action_append ($2, @2); }
 491 | rhs "%prec" symbol
 492     { grammar_current_rule_prec_set ($3, @3); }
 493 | rhs "%dprec" INT
 494     { grammar_current_rule_dprec_set ($3, @3); }
 495 | rhs "%merge" TYPE
 496     { grammar_current_rule_merge_set ($3, @3); }
 497 ;
 498
 499
 500 /*-----------*
 501  | content.  |
 502  *-----------*/
 503
 504 content:
 505   STRING
 506 | braceless
 507 ;
 508
 509 /* Some content or "1" by default. */
 510 content.opt:
 511   /* Nothing. */
 512     {
 513       static char one[] = "1";
 514       $$ = one;
 515     }
 516 | content
 517 ;
 518
 519
 520 braceless:
 521   "{...}"
 522     {
 523       code_props plain_code;
 524       $1[strlen ($1) - 1] = '\n';
 525       code_props_plain_init (&plain_code, $1+1, @1);
 526       code_props_translate_code (&plain_code);
 527       gram_scanner_last_string_free ();
 528       $$ = code_props_code_get (plain_code);
 529     }
 530 ;
 531
 532
 533 /*---------------*
 534  | Identifiers.  |
 535  *---------------*/
 536
 537 /* Identifiers are returned as uniqstr values by the scanner.
 538    Depending on their use, we may need to make them genuine symbols.  */
 539
 540 id:
 541   ID
 542     { $$ = symbol_from_uniqstr ($1, @1); }
 543 | CHAR
 544     {
 545       $$ = symbol_get (char_name ($1), @1);
 546       symbol_class_set ($$, token_sym, @1, false);
 547       symbol_user_token_number_set ($$, $1, @1);
 548     }
 549 ;
 550
 551 id_colon:
 552   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 553 ;
 554
 555
 556 symbol:
 557   id
 558 | string_as_id
 559 ;
 560
 561 /* A string used as an ID: quote it.  */
 562 string_as_id:
 563   STRING
 564     {
 565       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 566       symbol_class_set ($$, token_sym, @1, false);
 567     }
 568 ;
 569
 570 epilogue.opt:
 571   /* Nothing.  */
 572 | "%%" EPILOGUE
 573     {
 574       code_props plain_code;
 575       code_props_plain_init (&plain_code, $2, @2);
 576       code_props_translate_code (&plain_code);
 577       gram_scanner_last_string_free ();
 578       muscle_code_grow ("epilogue", code_props_code_get (plain_code), @2);
 579       code_scanner_last_string_free ();
 580     }
 581 ;
 582
 583 %%
 584
 585
 586 /* Return the location of the left-hand side of a rule whose
 587    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 588    the right-hand side, and return an empty location equal to the end
 589    boundary of RHS[0] if the right-hand side is empty.  */
 590
 591 static YYLTYPE
 592 lloc_default (YYLTYPE const *rhs, int n)
 593 {
 594   int i;
 595   YYLTYPE loc;
 596
 597   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 598      The bug is fixed in 7.4.2m, but play it safe for now.  */
 599   loc.start = rhs[n].end;
 600   loc.end = rhs[n].end;
 601
 602   /* Ignore empty nonterminals the start of the the right-hand side.
 603      Do not bother to ignore them at the end of the right-hand side,
 604      since empty nonterminals have the same end as their predecessors.  */
 605   for (i = 1; i <= n; i++)
 606     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 607       {
 608         loc.start = rhs[i].start;
 609         break;
 610       }
 611
 612   return loc;
 613 }
 614
 615
 616 /* Add a lex-param or a parse-param (depending on TYPE) with
 617    declaration DECL and location LOC.  */
 618
 619 static void
 620 add_param (char const *type, char *decl, location loc)
 621 {
 622   static char const alphanum[26 + 26 + 1 + 10] =
 623     "abcdefghijklmnopqrstuvwxyz"
 624     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 625     "_"
 626     "0123456789";
 627   char const *name_start = NULL;
 628   char *p;
 629
 630   /* Stop on last actual character.  */
 631   for (p = decl; p[1]; p++)
 632     if ((p == decl
 633          || ! memchr (alphanum, p[-1], sizeof alphanum))
 634         && memchr (alphanum, p[0], sizeof alphanum - 10))
 635       name_start = p;
 636
 637   /* Strip the surrounding '{' and '}', and any blanks just inside
 638      the braces.  */
 639   while (*--p == ' ' || *p == '\t')
 640     continue;
 641   p[1] = '\0';
 642   while (*++decl == ' ' || *decl == '\t')
 643     continue;
 644
 645   if (! name_start)
 646     complain_at (loc, _("missing identifier in parameter declaration"));
 647   else
 648     {
 649       char *name;
 650       size_t name_len;
 651
 652       for (name_len = 1;
 653            memchr (alphanum, name_start[name_len], sizeof alphanum);
 654            name_len++)
 655         continue;
 656
 657       name = xmalloc (name_len + 1);
 658       memcpy (name, name_start, name_len);
 659       name[name_len] = '\0';
 660       muscle_pair_list_grow (type, decl, name);
 661       free (name);
 662     }
 663
 664   gram_scanner_last_string_free ();
 665 }
 666
 667
 668 static void
 669 version_check (location const *loc, char const *version)
 670 {
 671   if (strverscmp (version, PACKAGE_VERSION) > 0)
 672     {
 673       complain_at (*loc, "require bison %s, but have %s",
 674                    version, PACKAGE_VERSION);
 675       exit (63);
 676     }
 677 }
 678
 679 static void
 680 gram_error (location const *loc, char const *msg)
 681 {
 682   complain_at (*loc, "%s", msg);
 683 }
 684
 685 char const *
 686 token_name (int type)
 687 {
 688   return yytname[YYTRANSLATE (type)];
 689 }
 690
 691 static char const *
 692 char_name (char c)
 693 {
 694   if (c == '\'')
 695     return "'\\''";
 696   else
 697     {
 698       char buf[4];
 699       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 700       return quotearg_style (escape_quoting_style, buf);
 701     }
 702 }