src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007 Free Software Foundation,
   4    Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software; you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation; either version 2 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program; if not, write to the Free Software
  20    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21    02110-1301  USA
  22 */
  23
  24 #include <config.h>
  25 #include "system.h"
  26
  27 #include <strverscmp.h>
  28
  29 #include "complain.h"
  30 #include "conflicts.h"
  31 #include "files.h"
  32 #include "getargs.h"
  33 #include "gram.h"
  34 #include "muscle_tab.h"
  35 #include "quotearg.h"
  36 #include "reader.h"
  37 #include "symlist.h"
  38 #include "scan-gram.h"
  39 #include "scan-code.h"
  40
  41 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  42 static YYLTYPE lloc_default (YYLTYPE const *, int);
  43
  44 #define YY_LOCATION_PRINT(File, Loc) \
  45           location_print (File, Loc)
  46
  47 static void version_check (location const *loc, char const *version);
  48
  49 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  50    FIXME: depends on the undocumented availability of YYLLOC.  */
  51 #undef  yyerror
  52 #define yyerror(Msg) \
  53         gram_error (&yylloc, Msg)
  54 static void gram_error (location const *, char const *);
  55
  56 static char const *char_name (char);
  57
  58 /** Add a lex-param or a parse-param.
  59  *
  60  * \param type  \a lex_param or \a parse_param
  61  * \param decl  the formal argument
  62  * \param loc   the location in the source.
  63  */
  64 static void add_param (char const *type, char *decl, location loc);
  65
  66
  67 static symbol_class current_class = unknown_sym;
  68 static uniqstr current_type = NULL;
  69 static symbol *current_lhs;
  70 static location current_lhs_location;
  71 static int current_prec = 0;
  72
  73 #define YYTYPE_INT16 int_fast16_t
  74 #define YYTYPE_INT8 int_fast8_t
  75 #define YYTYPE_UINT16 uint_fast16_t
  76 #define YYTYPE_UINT8 uint_fast8_t
  77 %}
  78
  79 %debug
  80 %verbose
  81 %defines
  82 %locations
  83 %pure-parser
  84 %error-verbose
  85 %name-prefix="gram_"
  86 %expect 0
  87
  88 %initial-action
  89 {
  90   /* Bison's grammar can initial empty locations, hence a default
  91      location is needed. */
  92   boundary_set (&@$.start, current_file, 1, 1);
  93   boundary_set (&@$.end, current_file, 1, 1);
  94 }
  95
  96 %union
  97 {
  98   symbol *symbol;
  99   symbol_list *list;
 100   int integer;
 101   char const *chars;
 102   char *code;
 103   assoc assoc;
 104   uniqstr uniqstr;
 105   unsigned char character;
 106 };
 107
 108 /* Define the tokens together with their human representation.  */
 109 %token GRAM_EOF 0 "end of file"
 110 %token STRING     "string"
 111 %token INT        "integer"
 112
 113 %token PERCENT_TOKEN       "%token"
 114 %token PERCENT_NTERM       "%nterm"
 115
 116 %token PERCENT_TYPE        "%type"
 117 %token PERCENT_DESTRUCTOR  "%destructor"
 118 %token PERCENT_PRINTER     "%printer"
 119
 120 %token PERCENT_LEFT        "%left"
 121 %token PERCENT_RIGHT       "%right"
 122 %token PERCENT_NONASSOC    "%nonassoc"
 123
 124 %token PERCENT_PREC          "%prec"
 125 %token PERCENT_DPREC         "%dprec"
 126 %token PERCENT_MERGE         "%merge"
 127
 128
 129 /*----------------------.
 130 | Global Declarations.  |
 131 `----------------------*/
 132
 133 %token
 134   PERCENT_CODE            "%code"
 135   PERCENT_DEBUG           "%debug"
 136   PERCENT_DEFAULT_PREC    "%default-prec"
 137   PERCENT_DEFINE          "%define"
 138   PERCENT_DEFINES         "%defines"
 139   PERCENT_ERROR_VERBOSE   "%error-verbose"
 140   PERCENT_EXPECT          "%expect"
 141   PERCENT_EXPECT_RR       "%expect-rr"
 142   PERCENT_FILE_PREFIX     "%file-prefix"
 143   PERCENT_GLR_PARSER      "%glr-parser"
 144   PERCENT_INITIAL_ACTION  "%initial-action"
 145   PERCENT_LANGUAGE        "%language"
 146   PERCENT_LEX_PARAM       "%lex-param"
 147   PERCENT_LOCATIONS       "%locations"
 148   PERCENT_NAME_PREFIX     "%name-prefix"
 149   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 150   PERCENT_NO_LINES        "%no-lines"
 151   PERCENT_NONDETERMINISTIC_PARSER
 152                           "%nondeterministic-parser"
 153   PERCENT_OUTPUT          "%output"
 154   PERCENT_PARSE_PARAM     "%parse-param"
 155   PERCENT_PURE_PARSER     "%pure-parser"
 156   PERCENT_PUSH_PARSER     "%push-parser"
 157   PERCENT_PUSH_PULL_PARSER
 158                           "%push-pull-parser"
 159   PERCENT_REQUIRE         "%require"
 160   PERCENT_SKELETON        "%skeleton"
 161   PERCENT_START           "%start"
 162   PERCENT_TOKEN_TABLE     "%token-table"
 163   PERCENT_VERBOSE         "%verbose"
 164   PERCENT_YACC            "%yacc"
 165 ;
 166
 167 %token BRACED_CODE     "{...}"
 168 %token CHAR            "char"
 169 %token EPILOGUE        "epilogue"
 170 %token EQUAL           "="
 171 %token ID              "identifier"
 172 %token ID_COLON        "identifier:"
 173 %token PERCENT_PERCENT "%%"
 174 %token PIPE            "|"
 175 %token PROLOGUE        "%{...%}"
 176 %token SEMICOLON       ";"
 177 %token TYPE            "type"
 178 %token TYPE_TAG_ANY    "<*>"
 179 %token TYPE_TAG_NONE   "<>"
 180
 181 %type <character> CHAR
 182 %printer { fputs (char_name ($$), stderr); } CHAR
 183
 184 /* braceless is not to be used for rule or symbol actions, as it
 185    calls code_props_plain_init.  */
 186 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 187 %type <code> "{...}"
 188 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 189          STRING
 190 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 191          braceless content.opt "{...}" "%{...%}" EPILOGUE
 192
 193 %type <uniqstr> TYPE ID ID_COLON variable
 194 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 195 %printer { fputs ($$, stderr); } ID variable
 196 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 197
 198 %type <integer> INT
 199 %printer { fprintf (stderr, "%d", $$); } INT
 200
 201 %type <symbol> id id_colon symbol string_as_id
 202 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 203 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 204
 205 %type <assoc> precedence_declarator
 206 %type <list>  symbols.1 generic_symlist generic_symlist_item
 207 %%
 208
 209 input:
 210   prologue_declarations "%%" grammar epilogue.opt
 211 ;
 212
 213
 214         /*------------------------------------.
 215         | Declarations: before the first %%.  |
 216         `------------------------------------*/
 217
 218 prologue_declarations:
 219   /* Nothing */
 220 | prologue_declarations prologue_declaration
 221 ;
 222
 223 prologue_declaration:
 224   grammar_declaration
 225 | "%{...%}"
 226     {
 227       code_props plain_code;
 228       code_props_plain_init (&plain_code, $1, @1);
 229       code_props_translate_code (&plain_code);
 230       gram_scanner_last_string_free ();
 231       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 232                         plain_code.code, @1);
 233       code_scanner_last_string_free ();
 234     }
 235 | "%debug"                         { debug_flag = true; }
 236 | "%define" variable content.opt
 237     {
 238       char const name_prefix[] = "percent_define(";
 239       size_t length = strlen ($2);
 240       char *name = xmalloc (sizeof name_prefix + length + 1);
 241       strcpy (name, name_prefix);
 242       strcpy (name + sizeof name_prefix - 1, $2);
 243       strcpy (name + sizeof name_prefix - 1 + length, ")");
 244       if (muscle_find_const (name))
 245         warn_at (@2, _("%s `%s' redefined"), "%define variable", $2);
 246       MUSCLE_INSERT_STRING (uniqstr_new (name), $3);
 247       free (name);
 248       muscle_grow_user_name_list ("percent_define_user_variables", $2, @2);
 249     }
 250 | "%defines"                       { defines_flag = true; }
 251 | "%defines" STRING
 252     {
 253       defines_flag = true;
 254       spec_defines_file = xstrdup ($2);
 255     }
 256 | "%error-verbose"                 { error_verbose = true; }
 257 | "%expect" INT                    { expected_sr_conflicts = $2; }
 258 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 259 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 260 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 261 | "%glr-parser"
 262     {
 263       nondeterministic_parser = true;
 264       glr_parser = true;
 265     }
 266 | "%initial-action" "{...}"
 267     {
 268       code_props action;
 269       code_props_symbol_action_init (&action, $2, @2);
 270       code_props_translate_code (&action);
 271       gram_scanner_last_string_free ();
 272       muscle_code_grow ("initial_action", action.code, @2);
 273       code_scanner_last_string_free ();
 274     }
 275 | "%language" STRING            { language_argmatch ($2, 1, &@1); }
 276 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 277 | "%locations"                  { locations_flag = true; }
 278 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 279 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 280 | "%no-lines"                   { no_lines_flag = true; }
 281 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 282 | "%output" STRING              { spec_outfile = $2; }
 283 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 284 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 285 | "%pure-parser"                { pure_parser = true; }
 286 | "%push-parser"                { push_parser = true; pull_parser = false; }
 287 | "%push-pull-parser"           { push_parser = true; pull_parser = true; }
 288 | "%require" STRING             { version_check (&@2, $2); }
 289 | "%skeleton" STRING            { skeleton_arg ($2, 1, &@1); }
 290 | "%token-table"                { token_table_flag = true; }
 291 | "%verbose"                    { report_flag = report_states; }
 292 | "%yacc"                       { yacc_flag = true; }
 293 | /*FIXME: Err?  What is this horror doing here? */ ";"
 294 ;
 295
 296 grammar_declaration:
 297   precedence_declaration
 298 | symbol_declaration
 299 | "%start" symbol
 300     {
 301       grammar_start_symbol_set ($2, @2);
 302     }
 303 | "%destructor" "{...}" generic_symlist
 304     {
 305       symbol_list *list;
 306       for (list = $3; list; list = list->next)
 307         symbol_list_destructor_set (list, $2, @2);
 308       symbol_list_free ($3);
 309     }
 310 | "%printer" "{...}" generic_symlist
 311     {
 312       symbol_list *list;
 313       for (list = $3; list; list = list->next)
 314         symbol_list_printer_set (list, $2, @2);
 315       symbol_list_free ($3);
 316     }
 317 | "%default-prec"
 318     {
 319       default_prec = true;
 320     }
 321 | "%no-default-prec"
 322     {
 323       default_prec = false;
 324     }
 325 | "%code" braceless
 326     {
 327       muscle_code_grow ("percent_code_unqualified", $2, @2);
 328       code_scanner_last_string_free ();
 329     }
 330 | "%code" ID braceless
 331     {
 332       char const name_prefix[] = "percent_code(";
 333       size_t length = strlen ($2);
 334       char *name = xmalloc (sizeof name_prefix + length + 1);
 335       strcpy (name, name_prefix);
 336       strcpy (name + sizeof name_prefix - 1, $2);
 337       strcpy (name + sizeof name_prefix - 1 + length, ")");
 338       muscle_code_grow (uniqstr_new (name), $3, @3);
 339       free (name);
 340       code_scanner_last_string_free ();
 341       muscle_grow_user_name_list ("percent_code_user_qualifiers", $2, @2);
 342     }
 343 ;
 344
 345
 346 /*----------*
 347  | %union.  |
 348  *----------*/
 349
 350 %token PERCENT_UNION "%union";
 351
 352 union_name:
 353   /* Nothing. */ {}
 354 | ID             { muscle_code_grow ("union_name", $1, @1); }
 355 ;
 356
 357 grammar_declaration:
 358   "%union" union_name braceless
 359     {
 360       union_seen = true;
 361       muscle_code_grow ("stype", $3, @3);
 362       code_scanner_last_string_free ();
 363     }
 364 ;
 365
 366
 367
 368
 369 symbol_declaration:
 370   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 371     {
 372       current_class = unknown_sym;
 373       current_type = NULL;
 374     }
 375 | "%token" { current_class = token_sym; } symbol_defs.1
 376     {
 377       current_class = unknown_sym;
 378       current_type = NULL;
 379     }
 380 | "%type" TYPE symbols.1
 381     {
 382       symbol_list *list;
 383       tag_seen = true;
 384       for (list = $3; list; list = list->next)
 385         symbol_type_set (list->content.sym, $2, @2);
 386       symbol_list_free ($3);
 387     }
 388 ;
 389
 390 precedence_declaration:
 391   precedence_declarator type.opt symbols.1
 392     {
 393       symbol_list *list;
 394       ++current_prec;
 395       for (list = $3; list; list = list->next)
 396         {
 397           symbol_type_set (list->content.sym, current_type, @2);
 398           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 399         }
 400       symbol_list_free ($3);
 401       current_type = NULL;
 402     }
 403 ;
 404
 405 precedence_declarator:
 406   "%left"     { $$ = left_assoc; }
 407 | "%right"    { $$ = right_assoc; }
 408 | "%nonassoc" { $$ = non_assoc; }
 409 ;
 410
 411 type.opt:
 412   /* Nothing. */ { current_type = NULL; }
 413 | TYPE           { current_type = $1; tag_seen = true; }
 414 ;
 415
 416 /* One or more symbols to be %typed. */
 417 symbols.1:
 418   symbol
 419     { $$ = symbol_list_sym_new ($1, @1); }
 420 | symbols.1 symbol
 421     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 422 ;
 423
 424 generic_symlist:
 425   generic_symlist_item { $$ = $1; }
 426 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 427 ;
 428
 429 generic_symlist_item:
 430   symbol            { $$ = symbol_list_sym_new ($1, @1); }
 431 | TYPE              { $$ = symbol_list_type_new ($1, @1); }
 432 | "<*>"             { $$ = symbol_list_default_tagged_new (@1); }
 433 | "<>"             { $$ = symbol_list_default_tagless_new (@1); }
 434 ;
 435
 436 /* One token definition.  */
 437 symbol_def:
 438   TYPE
 439      {
 440        current_type = $1;
 441        tag_seen = true;
 442      }
 443 | id
 444      {
 445        symbol_class_set ($1, current_class, @1, true);
 446        symbol_type_set ($1, current_type, @1);
 447      }
 448 | id INT
 449     {
 450       symbol_class_set ($1, current_class, @1, true);
 451       symbol_type_set ($1, current_type, @1);
 452       symbol_user_token_number_set ($1, $2, @2);
 453     }
 454 | id string_as_id
 455     {
 456       symbol_class_set ($1, current_class, @1, true);
 457       symbol_type_set ($1, current_type, @1);
 458       symbol_make_alias ($1, $2, @$);
 459     }
 460 | id INT string_as_id
 461     {
 462       symbol_class_set ($1, current_class, @1, true);
 463       symbol_type_set ($1, current_type, @1);
 464       symbol_user_token_number_set ($1, $2, @2);
 465       symbol_make_alias ($1, $3, @$);
 466     }
 467 ;
 468
 469 /* One or more symbol definitions. */
 470 symbol_defs.1:
 471   symbol_def
 472 | symbol_defs.1 symbol_def
 473 ;
 474
 475
 476         /*------------------------------------------.
 477         | The grammar section: between the two %%.  |
 478         `------------------------------------------*/
 479
 480 grammar:
 481   rules_or_grammar_declaration
 482 | grammar rules_or_grammar_declaration
 483 ;
 484
 485 /* As a Bison extension, one can use the grammar declarations in the
 486    body of the grammar.  */
 487 rules_or_grammar_declaration:
 488   rules
 489 | grammar_declaration ";"
 490 | error ";"
 491     {
 492       yyerrok;
 493     }
 494 ;
 495
 496 rules:
 497   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 498 ;
 499
 500 rhses.1:
 501   rhs                { grammar_current_rule_end (@1); }
 502 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 503 | rhses.1 ";"
 504 ;
 505
 506 rhs:
 507   /* Nothing.  */
 508     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 509 | rhs symbol
 510     { grammar_current_rule_symbol_append ($2, @2); }
 511 | rhs "{...}"
 512     { grammar_current_rule_action_append ($2, @2); }
 513 | rhs "%prec" symbol
 514     { grammar_current_rule_prec_set ($3, @3); }
 515 | rhs "%dprec" INT
 516     { grammar_current_rule_dprec_set ($3, @3); }
 517 | rhs "%merge" TYPE
 518     { grammar_current_rule_merge_set ($3, @3); }
 519 ;
 520
 521
 522 /*----------------------------*
 523  | variable and content.opt.  |
 524  *---------------------------*/
 525
 526 variable:
 527   ID
 528   | STRING { $$ = uniqstr_new ($1); } /* deprecated and not M4-friendly */
 529   ;
 530
 531 /* Some content or "1" by default. */
 532 content.opt:
 533   /* Nothing. */
 534     {
 535       static char one[] = "1";
 536       $$ = one;
 537     }
 538 | STRING
 539 ;
 540
 541
 542 /*-------------*
 543  | braceless.  |
 544  *-------------*/
 545
 546 braceless:
 547   "{...}"
 548     {
 549       code_props plain_code;
 550       $1[strlen ($1) - 1] = '\n';
 551       code_props_plain_init (&plain_code, $1+1, @1);
 552       code_props_translate_code (&plain_code);
 553       gram_scanner_last_string_free ();
 554       $$ = plain_code.code;
 555     }
 556 ;
 557
 558
 559 /*---------------*
 560  | Identifiers.  |
 561  *---------------*/
 562
 563 /* Identifiers are returned as uniqstr values by the scanner.
 564    Depending on their use, we may need to make them genuine symbols.  */
 565
 566 id:
 567   ID
 568     { $$ = symbol_from_uniqstr ($1, @1); }
 569 | CHAR
 570     {
 571       $$ = symbol_get (char_name ($1), @1);
 572       symbol_class_set ($$, token_sym, @1, false);
 573       symbol_user_token_number_set ($$, $1, @1);
 574     }
 575 ;
 576
 577 id_colon:
 578   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 579 ;
 580
 581
 582 symbol:
 583   id
 584 | string_as_id
 585 ;
 586
 587 /* A string used as an ID: quote it.  */
 588 string_as_id:
 589   STRING
 590     {
 591       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 592       symbol_class_set ($$, token_sym, @1, false);
 593     }
 594 ;
 595
 596 epilogue.opt:
 597   /* Nothing.  */
 598 | "%%" EPILOGUE
 599     {
 600       code_props plain_code;
 601       code_props_plain_init (&plain_code, $2, @2);
 602       code_props_translate_code (&plain_code);
 603       gram_scanner_last_string_free ();
 604       muscle_code_grow ("epilogue", plain_code.code, @2);
 605       code_scanner_last_string_free ();
 606     }
 607 ;
 608
 609 %%
 610
 611
 612 /* Return the location of the left-hand side of a rule whose
 613    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 614    the right-hand side, and return an empty location equal to the end
 615    boundary of RHS[0] if the right-hand side is empty.  */
 616
 617 static YYLTYPE
 618 lloc_default (YYLTYPE const *rhs, int n)
 619 {
 620   int i;
 621   YYLTYPE loc;
 622
 623   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 624      The bug is fixed in 7.4.2m, but play it safe for now.  */
 625   loc.start = rhs[n].end;
 626   loc.end = rhs[n].end;
 627
 628   /* Ignore empty nonterminals the start of the the right-hand side.
 629      Do not bother to ignore them at the end of the right-hand side,
 630      since empty nonterminals have the same end as their predecessors.  */
 631   for (i = 1; i <= n; i++)
 632     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 633       {
 634         loc.start = rhs[i].start;
 635         break;
 636       }
 637
 638   return loc;
 639 }
 640
 641
 642 /* Add a lex-param or a parse-param (depending on TYPE) with
 643    declaration DECL and location LOC.  */
 644
 645 static void
 646 add_param (char const *type, char *decl, location loc)
 647 {
 648   static char const alphanum[26 + 26 + 1 + 10] =
 649     "abcdefghijklmnopqrstuvwxyz"
 650     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 651     "_"
 652     "0123456789";
 653   char const *name_start = NULL;
 654   char *p;
 655
 656   /* Stop on last actual character.  */
 657   for (p = decl; p[1]; p++)
 658     if ((p == decl
 659          || ! memchr (alphanum, p[-1], sizeof alphanum))
 660         && memchr (alphanum, p[0], sizeof alphanum - 10))
 661       name_start = p;
 662
 663   /* Strip the surrounding '{' and '}', and any blanks just inside
 664      the braces.  */
 665   while (*--p == ' ' || *p == '\t')
 666     continue;
 667   p[1] = '\0';
 668   while (*++decl == ' ' || *decl == '\t')
 669     continue;
 670
 671   if (! name_start)
 672     complain_at (loc, _("missing identifier in parameter declaration"));
 673   else
 674     {
 675       char *name;
 676       size_t name_len;
 677
 678       for (name_len = 1;
 679            memchr (alphanum, name_start[name_len], sizeof alphanum);
 680            name_len++)
 681         continue;
 682
 683       name = xmalloc (name_len + 1);
 684       memcpy (name, name_start, name_len);
 685       name[name_len] = '\0';
 686       muscle_pair_list_grow (type, decl, name);
 687       free (name);
 688     }
 689
 690   gram_scanner_last_string_free ();
 691 }
 692
 693
 694 static void
 695 version_check (location const *loc, char const *version)
 696 {
 697   if (strverscmp (version, PACKAGE_VERSION) > 0)
 698     {
 699       complain_at (*loc, "require bison %s, but have %s",
 700                    version, PACKAGE_VERSION);
 701       exit (63);
 702     }
 703 }
 704
 705 static void
 706 gram_error (location const *loc, char const *msg)
 707 {
 708   complain_at (*loc, "%s", msg);
 709 }
 710
 711 char const *
 712 token_name (int type)
 713 {
 714   return yytname[YYTRANSLATE (type)];
 715 }
 716
 717 static char const *
 718 char_name (char c)
 719 {
 720   if (c == '\'')
 721     return "'\\''";
 722   else
 723     {
 724       char buf[4];
 725       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 726       return quotearg_style (escape_quoting_style, buf);
 727     }
 728 }