src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301  USA
  21 */
  22
  23 #include <config.h>
  24 #include "system.h"
  25
  26 #include "complain.h"
  27 #include "conflicts.h"
  28 #include "files.h"
  29 #include "getargs.h"
  30 #include "gram.h"
  31 #include "muscle_tab.h"
  32 #include "quotearg.h"
  33 #include "reader.h"
  34 #include "symlist.h"
  35 #include "scan-gram.h"
  36 #include "scan-code.h"
  37 #include "strverscmp.h"
  38
  39 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  40 static YYLTYPE lloc_default (YYLTYPE const *, int);
  41
  42 #define YY_LOCATION_PRINT(File, Loc) \
  43           location_print (File, Loc)
  44
  45 static void version_check (location const *loc, char const *version);
  46
  47 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  48    FIXME: depends on the undocumented availability of YYLLOC.  */
  49 #undef  yyerror
  50 #define yyerror(Msg) \
  51         gram_error (&yylloc, Msg)
  52 static void gram_error (location const *, char const *);
  53
  54 static char const *char_name (char);
  55
  56 static void add_param (char const *, char *, location);
  57
  58 static symbol_class current_class = unknown_sym;
  59 static uniqstr current_type = 0;
  60 static symbol *current_lhs;
  61 static location current_lhs_location;
  62 static int current_prec = 0;
  63
  64 #ifdef UINT_FAST8_MAX
  65 # define YYTYPE_UINT8 uint_fast8_t
  66 #endif
  67 #ifdef INT_FAST8_MAX
  68 # define YYTYPE_INT8 int_fast8_t
  69 #endif
  70 #ifdef UINT_FAST16_MAX
  71 # define YYTYPE_UINT16 uint_fast16_t
  72 #endif
  73 #ifdef INT_FAST16_MAX
  74 # define YYTYPE_INT16 int_fast16_t
  75 #endif
  76 %}
  77
  78 %debug
  79 %verbose
  80 %defines
  81 %locations
  82 %pure-parser
  83 %error-verbose
  84 %defines
  85 %name-prefix="gram_"
  86
  87 %initial-action
  88 {
  89   /* Bison's grammar can initial empty locations, hence a default
  90      location is needed. */
  91   boundary_set (&@$.start, current_file, 1, 0);
  92   boundary_set (&@$.end, current_file, 1, 0);
  93 }
  94
  95 /* Only NUMBERS have a value.  */
  96 %union
  97 {
  98   symbol *symbol;
  99   symbol_list *list;
 100   int integer;
 101   char *chars;
 102   assoc assoc;
 103   uniqstr uniqstr;
 104   unsigned char character;
 105 };
 106
 107 /* Define the tokens together with their human representation.  */
 108 %token GRAM_EOF 0 "end of file"
 109 %token STRING     "string"
 110 %token INT        "integer"
 111
 112 %token PERCENT_TOKEN       "%token"
 113 %token PERCENT_NTERM       "%nterm"
 114
 115 %token PERCENT_TYPE        "%type"
 116 %token PERCENT_DESTRUCTOR  "%destructor"
 117 %token PERCENT_PRINTER     "%printer"
 118
 119 %token PERCENT_LEFT        "%left"
 120 %token PERCENT_RIGHT       "%right"
 121 %token PERCENT_NONASSOC    "%nonassoc"
 122
 123 %token PERCENT_PREC          "%prec"
 124 %token PERCENT_DPREC         "%dprec"
 125 %token PERCENT_MERGE         "%merge"
 126
 127
 128 /*----------------------.
 129 | Global Declarations.  |
 130 `----------------------*/
 131
 132 %token
 133   PERCENT_AFTER_DEFINITIONS
 134                           "%after-definitions"
 135   PERCENT_BEFORE_DEFINITIONS
 136                           "%before-definitions"
 137   PERCENT_DEBUG           "%debug"
 138   PERCENT_DEFAULT_PREC    "%default-prec"
 139   PERCENT_DEFINE          "%define"
 140   PERCENT_DEFINES         "%defines"
 141   PERCENT_ERROR_VERBOSE   "%error-verbose"
 142   PERCENT_EXPECT          "%expect"
 143   PERCENT_EXPECT_RR       "%expect-rr"
 144   PERCENT_FILE_PREFIX     "%file-prefix"
 145   PERCENT_GLR_PARSER      "%glr-parser"
 146   PERCENT_INITIAL_ACTION  "%initial-action"
 147   PERCENT_LEX_PARAM       "%lex-param"
 148   PERCENT_LOCATIONS       "%locations"
 149   PERCENT_NAME_PREFIX     "%name-prefix"
 150   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 151   PERCENT_NO_LINES        "%no-lines"
 152   PERCENT_NONDETERMINISTIC_PARSER
 153                           "%nondeterministic-parser"
 154   PERCENT_OUTPUT          "%output"
 155   PERCENT_PARSE_PARAM     "%parse-param"
 156   PERCENT_PURE_PARSER     "%pure-parser"
 157   PERCENT_REQUIRE         "%require"
 158   PERCENT_SKELETON        "%skeleton"
 159   PERCENT_START           "%start"
 160   PERCENT_TOKEN_TABLE     "%token-table"
 161   PERCENT_VERBOSE         "%verbose"
 162   PERCENT_YACC            "%yacc"
 163 ;
 164
 165 %token BRACED_CODE     "{...}"
 166 %token CHAR            "char"
 167 %token EPILOGUE        "epilogue"
 168 %token EQUAL           "="
 169 %token ID              "identifier"
 170 %token ID_COLON        "identifier:"
 171 %token PERCENT_PERCENT "%%"
 172 %token PIPE            "|"
 173 %token PROLOGUE        "%{...%}"
 174 %token SEMICOLON       ";"
 175 %token TYPE            "type"
 176
 177 %type <character> CHAR
 178 %printer { fputs (char_name ($$), stderr); } CHAR
 179
 180 %type <chars> STRING string_content "{...}" PROLOGUE EPILOGUE
 181 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 182          STRING string_content
 183 %printer { fprintf (stderr, "{\n%s\n}", $$); } "{...}" PROLOGUE EPILOGUE
 184
 185 %type <uniqstr> TYPE ID ID_COLON
 186 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 187 %printer { fputs ($$, stderr); } ID
 188 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 189
 190 %type <integer> INT
 191 %printer { fprintf (stderr, "%d", $$); } INT
 192
 193 %type <symbol> id id_colon symbol string_as_id
 194 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 195 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 196
 197 %type <assoc> precedence_declarator
 198 %type <list>  symbols.1
 199 %%
 200
 201 input:
 202   declarations "%%" grammar epilogue.opt
 203 ;
 204
 205
 206         /*------------------------------------.
 207         | Declarations: before the first %%.  |
 208         `------------------------------------*/
 209
 210 declarations:
 211   /* Nothing */
 212 | declarations declaration
 213 ;
 214
 215 declaration:
 216   grammar_declaration
 217 | PROLOGUE                         { prologue_augment (translate_code ($1, @1),
 218                                                        @1); }
 219 | "%after-definitions" "{...}"
 220     {
 221       after_definitions = true;
 222       /* Remove the '{', and replace the '}' with '\n'.  */
 223       $2[strlen ($2) - 1] = '\n';
 224       muscle_code_grow ("after_definitions", $2+1, @2);
 225     }
 226 | "%before-definitions" "{...}"
 227     {
 228       before_definitions = true;
 229       /* Remove the '{', and replace the '}' with '\n'.  */
 230       $2[strlen ($2) - 1] = '\n';
 231       muscle_code_grow ("before_definitions", $2+1, @2);
 232     }
 233 | "%debug"                                 { debug_flag = true; }
 234 | "%define" string_content
 235     {
 236       static char one[] = "1";
 237       muscle_insert ($2, one);
 238     }
 239 | "%define" string_content string_content  { muscle_insert ($2, $3); }
 240 | "%defines"                               { defines_flag = true; }
 241 | "%error-verbose"                         { error_verbose = true; }
 242 | "%expect" INT                            { expected_sr_conflicts = $2; }
 243 | "%expect-rr" INT                         { expected_rr_conflicts = $2; }
 244 | "%file-prefix" "=" string_content        { spec_file_prefix = $3; }
 245 | "%glr-parser"
 246     {
 247       nondeterministic_parser = true;
 248       glr_parser = true;
 249     }
 250 | "%initial-action" "{...}"
 251     {
 252       muscle_code_grow ("initial_action", translate_symbol_action ($2, @2), @2);
 253     }
 254 | "%lex-param" "{...}"                     { add_param ("lex_param", $2, @2); }
 255 | "%locations"                             { locations_flag = true; }
 256 | "%name-prefix" "=" string_content        { spec_name_prefix = $3; }
 257 | "%no-lines"                              { no_lines_flag = true; }
 258 | "%nondeterministic-parser"               { nondeterministic_parser = true; }
 259 | "%output" "=" string_content             { spec_outfile = $3; }
 260 | "%parse-param" "{...}"                   { add_param ("parse_param", $2, @2); }
 261 | "%pure-parser"                           { pure_parser = true; }
 262 | "%require" string_content                { version_check (&@2, $2); }
 263 | "%skeleton" string_content               { skeleton = $2; }
 264 | "%token-table"                           { token_table_flag = true; }
 265 | "%verbose"                               { report_flag = report_states; }
 266 | "%yacc"                                  { yacc_flag = true; }
 267 | /*FIXME: Err?  What is this horror doing here? */ ";"
 268 ;
 269
 270 grammar_declaration:
 271   precedence_declaration
 272 | symbol_declaration
 273 | "%start" symbol
 274     {
 275       grammar_start_symbol_set ($2, @2);
 276     }
 277 | "%destructor" "{...}" symbols.1
 278     {
 279       symbol_list *list;
 280       const char *action = translate_symbol_action ($2, @2);
 281       for (list = $3; list; list = list->next)
 282         symbol_destructor_set (list->sym, action, @2);
 283       symbol_list_free ($3);
 284     }
 285 | "%printer" "{...}" symbols.1
 286     {
 287       symbol_list *list;
 288       const char *action = translate_symbol_action ($2, @2);
 289       for (list = $3; list; list = list->next)
 290         symbol_printer_set (list->sym, action, @2);
 291       symbol_list_free ($3);
 292     }
 293 | "%default-prec"
 294     {
 295       default_prec = true;
 296     }
 297 | "%no-default-prec"
 298     {
 299       default_prec = false;
 300     }
 301 ;
 302
 303
 304 /*----------*
 305  | %union.  |
 306  *----------*/
 307
 308 %token PERCENT_UNION "%union";
 309
 310 union_name:
 311   /* Nothing. */ {}
 312 | ID             { muscle_code_grow ("union_name", $1, @1); }
 313 ;
 314
 315 grammar_declaration:
 316   "%union" union_name "{...}"
 317     {
 318       char const *body = $3;
 319
 320       if (typed)
 321         {
 322           /* Concatenate the union bodies, turning the first one's
 323              trailing '}' into '\n', and omitting the second one's '{'.  */
 324           char *code = muscle_find ("stype");
 325           code[strlen (code) - 1] = '\n';
 326           body++;
 327         }
 328
 329       typed = true;
 330       muscle_code_grow ("stype", body, @3);
 331     }
 332 ;
 333
 334
 335
 336
 337 symbol_declaration:
 338   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 339     {
 340       current_class = unknown_sym;
 341       current_type = NULL;
 342     }
 343 | "%token" { current_class = token_sym; } symbol_defs.1
 344     {
 345       current_class = unknown_sym;
 346       current_type = NULL;
 347     }
 348 | "%type" TYPE symbols.1
 349     {
 350       symbol_list *list;
 351       for (list = $3; list; list = list->next)
 352         symbol_type_set (list->sym, $2, @2);
 353       symbol_list_free ($3);
 354     }
 355 ;
 356
 357 precedence_declaration:
 358   precedence_declarator type.opt symbols.1
 359     {
 360       symbol_list *list;
 361       ++current_prec;
 362       for (list = $3; list; list = list->next)
 363         {
 364           symbol_type_set (list->sym, current_type, @2);
 365           symbol_precedence_set (list->sym, current_prec, $1, @1);
 366         }
 367       symbol_list_free ($3);
 368       current_type = NULL;
 369     }
 370 ;
 371
 372 precedence_declarator:
 373   "%left"     { $$ = left_assoc; }
 374 | "%right"    { $$ = right_assoc; }
 375 | "%nonassoc" { $$ = non_assoc; }
 376 ;
 377
 378 type.opt:
 379   /* Nothing. */ { current_type = NULL; }
 380 | TYPE           { current_type = $1; }
 381 ;
 382
 383 /* One or more nonterminals to be %typed. */
 384 symbols.1:
 385   symbol            { $$ = symbol_list_new ($1, @1); }
 386 | symbols.1 symbol  { $$ = symbol_list_prepend ($1, $2, @2); }
 387 ;
 388
 389 /* One token definition.  */
 390 symbol_def:
 391   TYPE
 392      {
 393        current_type = $1;
 394      }
 395 | id
 396      {
 397        symbol_class_set ($1, current_class, @1, true);
 398        symbol_type_set ($1, current_type, @1);
 399      }
 400 | id INT
 401     {
 402       symbol_class_set ($1, current_class, @1, true);
 403       symbol_type_set ($1, current_type, @1);
 404       symbol_user_token_number_set ($1, $2, @2);
 405     }
 406 | id string_as_id
 407     {
 408       symbol_class_set ($1, current_class, @1, true);
 409       symbol_type_set ($1, current_type, @1);
 410       symbol_make_alias ($1, $2, @$);
 411     }
 412 | id INT string_as_id
 413     {
 414       symbol_class_set ($1, current_class, @1, true);
 415       symbol_type_set ($1, current_type, @1);
 416       symbol_user_token_number_set ($1, $2, @2);
 417       symbol_make_alias ($1, $3, @$);
 418     }
 419 ;
 420
 421 /* One or more symbol definitions. */
 422 symbol_defs.1:
 423   symbol_def
 424 | symbol_defs.1 symbol_def
 425 ;
 426
 427
 428         /*------------------------------------------.
 429         | The grammar section: between the two %%.  |
 430         `------------------------------------------*/
 431
 432 grammar:
 433   rules_or_grammar_declaration
 434 | grammar rules_or_grammar_declaration
 435 ;
 436
 437 /* As a Bison extension, one can use the grammar declarations in the
 438    body of the grammar.  */
 439 rules_or_grammar_declaration:
 440   rules
 441 | grammar_declaration ";"
 442 | error ";"
 443     {
 444       yyerrok;
 445     }
 446 ;
 447
 448 rules:
 449   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 450 ;
 451
 452 rhses.1:
 453   rhs                { grammar_current_rule_end (@1); }
 454 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 455 | rhses.1 ";"
 456 ;
 457
 458 rhs:
 459   /* Nothing.  */
 460     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 461 | rhs symbol
 462     { grammar_current_rule_symbol_append ($2, @2); }
 463 | rhs "{...}"
 464     { grammar_current_rule_action_append (gram_last_string,
 465                                           gram_last_braced_code_loc); }
 466 | rhs "%prec" symbol
 467     { grammar_current_rule_prec_set ($3, @3); }
 468 | rhs "%dprec" INT
 469     { grammar_current_rule_dprec_set ($3, @3); }
 470 | rhs "%merge" TYPE
 471     { grammar_current_rule_merge_set ($3, @3); }
 472 ;
 473
 474
 475 /*---------------*
 476  | Identifiers.  |
 477  *---------------*/
 478
 479 /* Identifiers are returned as uniqstr values by the scanner.
 480    Depending on their use, we may need to make them genuine symbols.  */
 481
 482 id:
 483   ID
 484     { $$ = symbol_from_uniqstr ($1, @1); }
 485 | CHAR
 486     {
 487       $$ = symbol_get (char_name ($1), @1);
 488       symbol_class_set ($$, token_sym, @1, false);
 489       symbol_user_token_number_set ($$, $1, @1);
 490     }
 491 ;
 492
 493 id_colon:
 494   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 495 ;
 496
 497
 498 symbol:
 499   id
 500 | string_as_id
 501 ;
 502
 503 /* A string used as an ID: quote it.  */
 504 string_as_id:
 505   STRING
 506     {
 507       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 508       symbol_class_set ($$, token_sym, @1, false);
 509     }
 510 ;
 511
 512 /* A string used for its contents.  Don't quote it.  */
 513 string_content:
 514   STRING
 515     { $$ = $1; }
 516 ;
 517
 518
 519 epilogue.opt:
 520   /* Nothing.  */
 521 | "%%" EPILOGUE
 522     {
 523       muscle_code_grow ("epilogue", translate_code ($2, @2), @2);
 524       gram_scanner_last_string_free ();
 525     }
 526 ;
 527
 528 %%
 529
 530
 531 /* Return the location of the left-hand side of a rule whose
 532    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 533    the right-hand side, and return an empty location equal to the end
 534    boundary of RHS[0] if the right-hand side is empty.  */
 535
 536 static YYLTYPE
 537 lloc_default (YYLTYPE const *rhs, int n)
 538 {
 539   int i;
 540   YYLTYPE loc;
 541
 542   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 543      The bug is fixed in 7.4.2m, but play it safe for now.  */
 544   loc.start = rhs[n].end;
 545   loc.end = rhs[n].end;
 546
 547   /* Ignore empty nonterminals the start of the the right-hand side.
 548      Do not bother to ignore them at the end of the right-hand side,
 549      since empty nonterminals have the same end as their predecessors.  */
 550   for (i = 1; i <= n; i++)
 551     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 552       {
 553         loc.start = rhs[i].start;
 554         break;
 555       }
 556
 557   return loc;
 558 }
 559
 560
 561 /* Add a lex-param or a parse-param (depending on TYPE) with
 562    declaration DECL and location LOC.  */
 563
 564 static void
 565 add_param (char const *type, char *decl, location loc)
 566 {
 567   static char const alphanum[26 + 26 + 1 + 10] =
 568     "abcdefghijklmnopqrstuvwxyz"
 569     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 570     "_"
 571     "0123456789";
 572   char const *name_start = NULL;
 573   char *p;
 574
 575   /* Stop on last actual character.  */
 576   for (p = decl; p[1]; p++)
 577     if ((p == decl
 578          || ! memchr (alphanum, p[-1], sizeof alphanum))
 579         && memchr (alphanum, p[0], sizeof alphanum - 10))
 580       name_start = p;
 581
 582   /* Strip the surrounding '{' and '}', and any blanks just inside
 583      the braces.  */
 584   while (*--p == ' ' || *p == '\t')
 585     continue;
 586   p[1] = '\0';
 587   while (*++decl == ' ' || *decl == '\t')
 588     continue;
 589
 590   if (! name_start)
 591     complain_at (loc, _("missing identifier in parameter declaration"));
 592   else
 593     {
 594       char *name;
 595       size_t name_len;
 596
 597       for (name_len = 1;
 598            memchr (alphanum, name_start[name_len], sizeof alphanum);
 599            name_len++)
 600         continue;
 601
 602       name = xmalloc (name_len + 1);
 603       memcpy (name, name_start, name_len);
 604       name[name_len] = '\0';
 605       muscle_pair_list_grow (type, decl, name);
 606       free (name);
 607     }
 608
 609   gram_scanner_last_string_free ();
 610 }
 611
 612 static void
 613 version_check (location const *loc, char const *version)
 614 {
 615   if (strverscmp (version, PACKAGE_VERSION) > 0)
 616     {
 617       complain_at (*loc, "require bison %s, but have %s",
 618                    version, PACKAGE_VERSION);
 619       exit (63);
 620     }
 621 }
 622
 623 static void
 624 gram_error (location const *loc, char const *msg)
 625 {
 626   complain_at (*loc, "%s", msg);
 627 }
 628
 629 char const *
 630 token_name (int type)
 631 {
 632   return yytname[YYTRANSLATE (type)];
 633 }
 634
 635 static char const *
 636 char_name (char c)
 637 {
 638   if (c == '\'')
 639     return "'\\''";
 640   else
 641     {
 642       char buf[4];
 643       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 644       return quotearg_style (escape_quoting_style, buf);
 645     }
 646 }