tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free
   6 # Software Foundation, Inc.
   7
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # We want a recent Autotest.
  22 m4_version_prereq([2.58])
  23
  24
  25 ## ------------- ##
  26 ## Basic tests.  ##
  27 ## ------------- ##
  28
  29 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  30 # ------------------------------------------
  31 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  32 # taken in "slurp" mode, i.e., one can match end-of-lines.
  33 m4_define([AT_MATCHES_CHECK],
  34 [AT_CHECK([perl -0777 -ne '
  35 my $count = 0;
  36 s{$2}{ ++$count; "" }gem;
  37 printf "$count\n";' $1], [0], [$3
  38 ])])
  39
  40
  41 ## ------------------------------- ##
  42 ## Macros decoding Bison options.  ##
  43 ## ------------------------------- ##
  44
  45 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  46 # ----------------------------------------------------------------
  47 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  48 m4_define([AT_LOC_PUSHDEF],
  49 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  50 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  51 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  52 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  53
  54 # AT_LOC_POPDEF
  55 # -------------
  56 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  57 m4_define([AT_LOC_POPDEF],
  58 [m4_popdef([AT_LOC_FIRST_LINE])
  59 m4_popdef([AT_LOC_FIRST_COLUMN])
  60 m4_popdef([AT_LOC_LAST_LINE])
  61 m4_popdef([AT_LOC_LAST_COLUMN])])
  62
  63
  64
  65 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  66 # -----------------------------------------
  67 m4_define([AT_BISON_OPTION_PUSHDEFS],
  68 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  69
  70
  71 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  72 # --------------------------------------------------
  73 # This macro works around the impossibility to define macros
  74 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  75 # This sucks hard, GNU M4 should really provide M5 like $$1.
  76 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  77 [m4_if([$1$2], $[1]$[2], [],
  78        [m4_fatal([$0: Invalid arguments: $@])])dnl
  79 m4_pushdef([AT_DEFINES_IF],
  80 [m4_bmatch([$3], [%defines], [$1], [$2])])
  81 m4_pushdef([AT_SKEL_CC_IF],
  82 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  83 m4_pushdef([AT_GLR_IF],
  84 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  85 m4_pushdef([AT_LALR1_CC_IF],
  86 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  87 m4_pushdef([AT_GLR_CC_IF],
  88 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  89 # Using yacc.c?
  90 m4_pushdef([AT_YACC_IF],
  91 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  92 m4_pushdef([AT_LEXPARAM_IF],
  93 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  94 m4_pushdef([AT_LOCATION_IF],
  95 [m4_bmatch([$3], [%locations], [$1], [$2])])
  96 m4_pushdef([AT_LOCATION_TYPE_IF],
  97 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
  98 m4_pushdef([AT_PARAM_IF],
  99 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 100 m4_pushdef([AT_PURE_IF],
 101 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 102            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 103            [$2])])
 104 m4_pushdef([AT_PURE_AND_LOC_IF],
 105 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 106 m4_pushdef([AT_GLR_OR_PARAM_IF],
 107 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 108 m4_pushdef([AT_NAME_PREFIX],
 109 [m4_bmatch([$3], [%name-prefix ".*"],
 110            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
 111            [yy])])
 112 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 113 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 114 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 115                     [$2])])
 116 # yyerror always sees the locations (when activated), except if
 117 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 118 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 119 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 120                                         [$1])],
 121                             [$1])],
 122                 [$2])])
 123
 124 # The interface is pure: either because %define api.pure, or because we
 125 # are using the C++ parsers.
 126 m4_pushdef([AT_PURE_LEX_IF],
 127 [AT_PURE_IF([$1],
 128             [AT_SKEL_CC_IF([$1], [$2])])])
 129
 130 AT_PURE_LEX_IF(
 131 [m4_pushdef([AT_LOC], [(*llocp)])
 132  m4_pushdef([AT_VAL], [(*lvalp)])
 133  m4_pushdef([AT_LEX_FORMALS],
 134             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 135  m4_pushdef([AT_LEX_ARGS],
 136             [lvalp[]AT_LOCATION_IF([, llocp])])
 137  m4_pushdef([AT_USE_LEX_ARGS],
 138             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 139  m4_pushdef([AT_LEX_PRE_FORMALS],
 140             [AT_LEX_FORMALS, ])
 141  m4_pushdef([AT_LEX_PRE_ARGS],
 142             [AT_LEX_ARGS, ])
 143 ],
 144 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 145  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 146  m4_pushdef([AT_LEX_FORMALS],     [void])
 147  m4_pushdef([AT_LEX_ARGS],        [])
 148  m4_pushdef([AT_USE_LEX_ARGS],    [])
 149  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 150  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 151 ])
 152
 153 # Handle the different types of location components.
 154
 155 AT_SKEL_CC_IF(
 156   [AT_LOCATION_TYPE_IF(
 157     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 158     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 159   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 160
 161 ])# _AT_BISON_OPTION_PUSHDEFS
 162
 163
 164 # AT_BISON_OPTION_POPDEFS
 165 # -----------------------
 166 m4_define([AT_BISON_OPTION_POPDEFS],
 167 [m4_popdef([AT_LEX_PRE_ARGS])
 168 m4_popdef([AT_LEX_PRE_FORMALS])
 169 m4_popdef([AT_USE_LEX_ARGS])
 170 m4_popdef([AT_LEX_ARGS])
 171 m4_popdef([AT_LEX_FORMALS])
 172 m4_popdef([AT_VAL])
 173 m4_popdef([AT_LOC])
 174 m4_popdef([AT_PURE_LEX_IF])
 175 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 176 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 177 m4_popdef([AT_NAME_PREFIX])
 178 m4_popdef([AT_GLR_OR_PARAM_IF])
 179 m4_popdef([AT_PURE_AND_LOC_IF])
 180 m4_popdef([AT_LOCATION_TYPE_IF])
 181 m4_popdef([AT_LOCATION_IF])
 182 m4_popdef([AT_PARAM_IF])
 183 m4_popdef([AT_LEXPARAM_IF])
 184 m4_popdef([AT_YACC_IF])
 185 m4_popdef([AT_GLR_IF])
 186 m4_popdef([AT_SKEL_CC_IF])
 187 m4_popdef([AT_GLR_CC_IF])
 188 m4_popdef([AT_LALR1_CC_IF])
 189 m4_popdef([AT_DEFINES_IF])
 190 AT_LOC_POPDEF
 191 ])# AT_BISON_OPTION_POPDEFS
 192
 193
 194
 195 ## -------------------------- ##
 196 ## Generating Grammar Files.  ##
 197 ## -------------------------- ##
 198
 199 # AT_DATA_SOURCE_PROLOGUE
 200 # ------------------------
 201 # The prologue that should be included in any source code that is
 202 # meant to be compiled.
 203 m4_define([AT_DATA_SOURCE_PROLOGUE],
 204 [[#include <config.h>
 205 /* We don't need perfect functions for these tests. */
 206 #undef malloc
 207 #undef memcmp
 208 #undef realloc
 209 ]])
 210
 211 # AT_DATA_GRAMMAR_PROLOGUE
 212 # ------------------------
 213 # The prologue that should be included in any grammar which parser is
 214 # meant to be compiled.
 215 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 216 [[%code top {
 217 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 218 [}
 219 ]])
 220
 221 # AT_DATA_SOURCE(NAME, CONTENT)
 222 # -----------------------------
 223 # Generate the file NAME, which CONTENT is preceded by
 224 # AT_DATA_SOURCE_PROLOGUE.
 225 m4_define([AT_DATA_SOURCE],
 226 [AT_DATA([$1],
 227 [AT_DATA_SOURCE_PROLOGUE
 228 $2])
 229 ])
 230
 231 # AT_DATA_GRAMMAR(NAME, CONTENT)
 232 # ------------------------------
 233 # Generate the file NAME, which CONTENT is preceded by
 234 # AT_DATA_GRAMMAR_PROLOGUE.
 235 m4_define([AT_DATA_GRAMMAR],
 236 [AT_DATA([$1],
 237 [AT_DATA_GRAMMAR_PROLOGUE
 238 $2])
 239 ])
 240
 241 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 242 # -------------------------------------------------
 243 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 244 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 245 #
 246 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 247 # Bison in the test suite.  For now it ensures that:
 248 #
 249 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 250 #      a non-zero exit status since Bison doesn't always try to free all memory
 251 #      in that case.
 252 #
 253 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 254 #      --graph and --report=all output for every working grammar.
 255 #
 256 #   3. If stderr contains a warning, -Werror and --warnings=error
 257 #      convert the warning to an error.
 258 m4_define([AT_BISON_CHECK],
 259 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 260        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 261 AT_BISON_CHECK_NO_XML($@)])
 262
 263 m4_define([AT_BISON_WERROR_MSG],
 264           [[bison: warnings being treated as errors]])
 265
 266 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 267 # --------------------------------------------------------
 268 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 269 # when a tortured grammar's XML is known to be too large for xsltproc to
 270 # handle.
 271 m4_define([AT_BISON_CHECK_NO_XML],
 272 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 273                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 274 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 275       [m4_if(m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0],
 276              [[# Don't interfere with caller's files.
 277               if test -f stderr; then
 278                 mv stderr at-bison-check-stderr.bak
 279               fi
 280               if test -f experr; then
 281                 mv experr at-bison-check-experr.bak
 282               fi
 283
 284               # Run with -Werror.
 285               ]AT_CHECK(AT_QUELL_VALGRIND[[ bison -Werror ]$1],
 286                         [[1]], [$3], [stderr])[
 287
 288               # Build expected stderr up to and including the "warnings
 289               # being treated as errors" message.
 290               ]AT_DATA([[at-bison-check-warnings]], [$4])[
 291               at_bison_check_first="` \
 292                 sed -n '/: warning: /=' at-bison-check-warnings \
 293                 | sed -n 1p \
 294               `"
 295               if test $at_bison_check_first -gt 1; then
 296                 sed -n "1,`expr $at_bison_check_first - 1`"p \
 297                   at-bison-check-warnings > experr
 298               fi
 299               echo ']AT_BISON_WERROR_MSG[' >> experr
 300
 301               # Finish building expected stderr and check.  Unlike
 302               # warnings, complaints cause bison to exit early.  Thus,
 303               # with -Werror, bison does not necessarily report all
 304               # warnings that it does without -Werror, but it at least
 305               # reports one.
 306               at_bison_check_last="`sed -n '$=' stderr`"
 307               if test x"$at_bison_check_last" = x; then
 308                 at_bison_check_last=1
 309               fi
 310               at_bison_check_last="`expr $at_bison_check_last - 1`"
 311               sed -n "$at_bison_check_first,$at_bison_check_last"p \
 312                 at-bison-check-warnings >> experr
 313               ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 314                           stderr 1>&2]], [[0]], [[]], [experr])[
 315
 316               # Now check --warnings=error.
 317               cp stderr experr
 318               ]AT_CHECK(AT_QUELL_VALGRIND[[ bison --warnings=error ]$1],
 319                         [[1]], [$3], [experr])[
 320
 321               # Restore caller's files.
 322               if test -f at-bison-check-experr.bak; then
 323                 mv at-bison-check-experr.bak experr
 324               fi
 325               if test -f at-bison-check-stderr.bak; then
 326                 mv at-bison-check-stderr.bak stderr
 327               fi
 328              ]])
 329       ])
 330 ])
 331
 332 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 333 # -----------------------------------------------------
 334 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 335 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 336 # have a non-zero exit status.
 337 m4_define([AT_BISON_CHECK_XML],
 338 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 339   mkdir xml-tests]
 340   m4_pushdef([AT_BISON_ARGS],
 341              [m4_bpatsubsts([[$1]],
 342                             [--report(-file)?=[^][ ]*], [],
 343                             [--graph=[^][ ]*], [],
 344                             [--xml=[^][ ]*], [])])dnl
 345   # Don't combine these Bison invocations since we want to be sure that
 346   # --report=all isn't required to get the full XML file.
 347   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 348              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 349            [[0]], [ignore], [ignore])
 350   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 351            [[0]], [ignore], [ignore])
 352   m4_popdef([AT_BISON_ARGS])dnl
 353   [cp xml-tests/test.output expout]
 354   AT_CHECK([[$XSLTPROC \
 355              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 356              xml-tests/test.xml]], [[0]], [expout])
 357   [cp xml-tests/test.dot expout]
 358   AT_CHECK([[$XSLTPROC \
 359              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 360              xml-tests/test.xml]], [[0]], [expout])
 361   [rm -rf xml-tests expout
 362 fi]])
 363
 364 # AT_QUELL_VALGRIND
 365 # -----------------
 366 # Put this before a Bison invocation to keep Valgrind from complaining about
 367 # reachable memory.
 368 #
 369 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 370 # The triple quoting below will cause test cases to fail if you do.  If you do
 371 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 372 # will then fail to shell-escape its contents when attempting to print them.
 373 # The testsuite verbose output, at least, will be incorrect, but nothing may
 374 # fail to make sure you notice.
 375 m4_define([AT_QUELL_VALGRIND],
 376 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 377
 378 ## ------------------------ ##
 379 ## Compiling C, C++ Files.  ##
 380 ## ------------------------ ##
 381
 382
 383 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 384 # ----------------------------------------
 385 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 386 # assume that we are linking too; this is a hack.
 387 m4_define([AT_COMPILE],
 388 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 389            0, [ignore], [ignore])])
 390
 391 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 392 # --------------------------------------------
 393 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 394 # assume that we are linking too; this is a hack.
 395 # If the C++ compiler does not work, ignore the test.
 396 m4_define([AT_COMPILE_CXX],
 397 [AT_KEYWORDS(c++)
 398 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 399 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 400          0, [ignore], [ignore])])
 401
 402
 403 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 404 # --------------------------------
 405 # Compile OUTPUT.y to OUTPUT.c or OUTPUT.cc, and compile it to OUTPUT.
 406 # If OTHER is specified, compile OUTPUT-OTHER.c or OUTPUT-OTHER.cc to OUTPUT
 407 # along with it.
 408 # Relies on AT_SKEL_CC_IF.
 409 m4_define([AT_FULL_COMPILE],
 410 [AT_SKEL_CC_IF(
 411   [AT_BISON_CHECK([-o $1.cc $1.y])
 412    AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1.cc $1-$2.cc]]))],
 413   [AT_BISON_CHECK([-o $1.c $1.y])
 414    AT_COMPILE([$1]m4_ifval($2, [, [$1.c $1-$2.c]]))])
 415 ])
 416
 417
 418 ## ---------------------------- ##
 419 ## Running a generated parser.  ##
 420 ## ---------------------------- ##
 421
 422 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 423 # ------------------------------------------------------------
 424 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 425 m4_define([AT_PARSER_CHECK],
 426 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 427
 428 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 429 #                          DECLS, GRAMMAR, INPUT,
 430 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 431 #                          [OTHER-CHECKS],
 432 #                          [PARSER-EXIT-VALUE],
 433 #                          [PARSER-STDOUT], [PARSER-STDERR])
 434 # -------------------------------------------------------------
 435 # Using TITLE as the test group title, check the generated parser tables
 436 # and parser for a specified grammar file under a condition labeled by
 437 # COND-VALUE.
 438 #
 439 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 440 # recognized attribute is described below where it is relevant.
 441 #
 442 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 443 # the grammar file.  Insert basic yyerror, yylex, and main function
 444 # definitions as well.  Hardcode yylex to return the (possibly empty)
 445 # comma-delimited series of tokens in INPUT followed by token 0.
 446 #
 447 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 448 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 449 # On the bison command-line, specify `--report=all --defines'.  Check
 450 # that Bison exits with value 0, has no stdout, and has stderr
 451 # BISON-STDERR.
 452 #
 453 # If TEST-SPEC contains the attribute `last-state', check that the value
 454 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 455 # the grammar; in other words, check the number of states (minus one).
 456 # Otherwise, check that everything in the `.output' file starting with
 457 # the definition of state 0 is the same as the entire value of
 458 # TABLES-OR-LAST-STATE.
 459 #
 460 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 461 # `.output' file, which is named `input.output', and/or grammar file,
 462 # which is named `input.y'.
 463 #
 464 # Finally, compile the generated parser and then run it using
 465 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 466 # PARSER-STDERR as the 2nd-4th arguments.
 467 #
 468 # As a precondition, you must properly double-quote all arguments that
 469 # are to be interpreted as strings.
 470 #
 471 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 472 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 473 # first argument.  This is useful, for example, when wrapping multiple
 474 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 475 # condition, in another macro.
 476 #
 477 # For example:
 478 #
 479 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 480 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 481 #   # ---------------------------------------------------------------------
 482 #   m4_define([AT_TEST_SYNTAX_ERROR],
 483 #   [
 484 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 485 #                              [[last-state]],
 486 #                              [[%error-verbose ]$2], [$3], [$4],
 487 #                              [[]], [$5], [], [$6], [$7], [$8])
 488 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 489 #                              [[last-state]],
 490 #                              [$2], [$3], [$4],
 491 #                              [[]], [$5], [], [$6], [$7], [$8])
 492 #   ])
 493 #
 494 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 495 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 496 #                        [[3]],
 497 #                        [[1]], [[]],
 498 #                        [AT_COND_CASE([[no verbose]],
 499 #                                      [[syntax error
 500 #   ]],
 501 #                                      [[syntax error, unexpected 'b', expecting $end
 502 #   ]])])
 503 m4_define([AT_TEST_TABLES_AND_PARSE],
 504 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 505
 506 AT_SETUP([$1])
 507
 508 AT_DATA_GRAMMAR([[input.y]],
 509 [[%code {
 510   #include <stdio.h>
 511   static void yyerror (char const *msg);
 512   static int yylex (void);
 513 }
 514
 515 ]$4[
 516
 517 %%
 518
 519 ]$5[
 520
 521 %%
 522
 523 static void
 524 yyerror (char const *msg)
 525 {
 526   fprintf (stderr, "%s\n", msg);
 527 }
 528
 529 static int
 530 yylex (void)
 531 {
 532   static int const input[] = {
 533     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 534   };
 535   static int const *inputp = input;
 536   return *inputp++;
 537 }
 538
 539 int
 540 main (void)
 541 {
 542   return yyparse ();
 543 }
 544 ]])
 545
 546 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 547 # expanding macros, so it corrupts some special characters in the
 548 # macros.  To avoid this, expand now and pass it the result with proper
 549 # string quotation.  Assume args 7 thru 12 expand to properly quoted
 550 # strings.
 551
 552 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 553       [AT_BISON_CHECK],
 554       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 555                                [0], [], m4_dquote($7))
 556
 557 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 558       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 559                 m4_dquote($8))],
 560       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 561                 m4_dquote($8)[[
 562 ]])])
 563
 564 $9
 565
 566 AT_COMPILE([[input]])
 567
 568 AT_PARSER_CHECK([[./input]],
 569                 m4_ifval([$10], [m4_dquote($10)]),
 570                 m4_ifval([$11], [m4_dquote($11)]),
 571                 m4_ifval([$12], [m4_dquote($12)]))
 572
 573 AT_CLEANUP
 574
 575 m4_popdef([AT_COND_CASE])])
 576
 577
 578
 579 ## ----------------------- ##
 580 ## Launch the test suite.  ##
 581 ## ----------------------- ##
 582
 583 AT_INIT
 584
 585 AT_TESTED([bison])