src/scan-skel.l

   1 /* Scan Bison Skeletons.                                       -*- C -*-
   2
   3    Copyright (C) 2001, 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    Bison is free software; you can redistribute it and/or modify it
   8    under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2, or (at your option)
  10    any later version.
  11
  12    Bison is distributed in the hope that it will be useful, but
  13    WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with Bison; see the file COPYING.  If not, write to the Free
  19    Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301, USA.  */
  21
  22 %option nodefault noyywrap nounput never-interactive debug
  23 %option prefix="skel_" outfile="lex.yy.c"
  24
  25 %{
  26 /* Work around a bug in flex 2.5.31.  See Debian bug 333231
  27    <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=333231>.  */
  28 #undef skel_wrap
  29 #define skel_wrap() 1
  30
  31 #include "system.h"
  32
  33 #include <error.h>
  34 #include <quotearg.h>
  35
  36 #include "complain.h"
  37 #include "getargs.h"
  38 #include "files.h"
  39 #include "scan-skel.h"
  40
  41 #define QPUTS(String) \
  42    fputs (quotearg_style (c_quoting_style, (String)), yyout)
  43
  44 %}
  45 %%
  46
  47 %{
  48   int lineno IF_LINT (= 0);
  49   char *outname = NULL;
  50 %}
  51
  52 "@output ".*\n {
  53   char const *file_name = yytext + sizeof "@output " - 1;
  54   yytext[yyleng - 1] = '\0';
  55
  56   if (*file_name == '@')
  57     {
  58       if (strcmp (file_name, "@output_header_name@") == 0)
  59         file_name = spec_defines_file;
  60       else if (strcmp (file_name, "@output_parser_name@") == 0)
  61         file_name = parser_file_name;
  62       else
  63         fatal ("invalid token in skeleton: %s", yytext);
  64     }
  65
  66   if (outname)
  67     {
  68       free (outname);
  69       xfclose (yyout);
  70     }
  71   outname = xstrdup (file_name);
  72   yyout = xfopen (outname, "w");
  73   lineno = 1;
  74 }
  75
  76 "@@"       fputc ('@', yyout);
  77 "@{"       fputc ('[', yyout);
  78 "@}"       fputc (']', yyout);
  79
  80 "@oline@"  fprintf (yyout, "%d", lineno + 1);
  81 "@ofile@"  QPUTS (outname);
  82 "@dir_prefix@" QPUTS (dir_prefix);
  83 "@output_parser_name@"  QPUTS (parser_file_name);
  84 "@output_header_name@"  QPUTS (spec_defines_file);
  85
  86   /* This pattern must not match more than the previous @ patterns. */
  87 @[^{}@\n]* fatal ("invalid @ in skeleton: %s", yytext);
  88 \n         lineno++; ECHO;
  89 [^@\n]+    ECHO;
  90
  91 <<EOF>> {
  92   if (outname)
  93     {
  94       free (outname);
  95       xfclose (yyout);
  96     }
  97   return EOF;
  98 }
  99 %%
 100
 101 /*------------------------.
 102 | Scan a Bison skeleton.  |
 103 `------------------------*/
 104
 105 void
 106 scan_skel (FILE *in)
 107 {
 108   skel_in = in;
 109   skel__flex_debug = trace_flag & trace_skeleton;
 110   skel_lex ();
 111   /* Reclaim Flex's buffers.  */
 112   yy_delete_buffer (YY_CURRENT_BUFFER);
 113 }