data/c.m4

   1                                                             -*- Autoconf -*-
   2
   3 # C M4 Macros for Bison.
   4
   5 # Copyright (C) 2002, 2004-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_include(b4_pkgdatadir/[c-like.m4])
  21
  22 # b4_tocpp(STRING)
  23 # ----------------
  24 # Convert STRING into a valid C macro name.
  25 m4_define([b4_tocpp],
  26 [m4_toupper(m4_bpatsubst(m4_quote($1), [[^a-zA-Z0-9]+], [_]))])
  27
  28
  29 # b4_cpp_guard(FILE)
  30 # ------------------
  31 # A valid C macro name to use as a CPP header guard for FILE.
  32 m4_define([b4_cpp_guard],
  33 [b4_tocpp(m4_defn([b4_prefix])/[$1])])
  34
  35
  36 # b4_cpp_guard_open(FILE)
  37 # b4_cpp_guard_close(FILE)
  38 # ------------------------
  39 # Open/close CPP inclusion guards for FILE.
  40 m4_define([b4_cpp_guard_open],
  41 [#ifndef b4_cpp_guard([$1])
  42 # define b4_cpp_guard([$1])])
  43
  44 m4_define([b4_cpp_guard_close],
  45 [#endif b4_comment([!b4_cpp_guard([$1])])])
  46
  47
  48 ## ---------------- ##
  49 ## Identification.  ##
  50 ## ---------------- ##
  51
  52 # b4_comment_(TEXT, OPEN, CONTINUE, END)
  53 # --------------------------------------
  54 # Put TEXT in comment.  Avoid trailing spaces: don't indent empty lines.
  55 # Avoid adding indentation to the first line, as the indentation comes
  56 # from OPEN.  That's why we don't patsubst([$1], [^\(.\)], [   \1]).
  57 #
  58 # Prefix all the output lines with PREFIX.
  59 m4_define([b4_comment_], [$2[]m4_bpatsubst([$1], [
  60 \(.\)], [
  61 $3\1])$4])
  62
  63
  64 # b4_comment(TEXT, [PREFIX])
  65 # --------------------------
  66 # Put TEXT in comment.  Avoid trailing spaces: don't indent empty lines.
  67 # Avoid adding indentation to the first line, as the indentation comes
  68 # from "/*".  That's why we don't patsubst([$1], [^\(.\)], [   \1]).
  69 #
  70 # Prefix all the output lines with PREFIX.
  71 m4_define([b4_comment],
  72 [b4_comment_([$1], [$2/* ], [$2   ], [$2  */])])
  73
  74
  75 # b4_identification
  76 # -----------------
  77 # Depends on individual skeletons to define b4_pure_flag, b4_push_flag, or
  78 # b4_pull_flag if they use the values of the %define variables api.pure or
  79 # api.push-pull.
  80 m4_define([b4_identification],
  81 [[/* Identify Bison output.  */
  82 #define YYBISON 1
  83
  84 /* Bison version.  */
  85 #define YYBISON_VERSION "]b4_version["
  86
  87 /* Skeleton name.  */
  88 #define YYSKELETON_NAME ]b4_skeleton[]m4_ifdef([b4_pure_flag], [[
  89
  90 /* Pure parsers.  */
  91 #define YYPURE ]b4_pure_flag])[]m4_ifdef([b4_push_flag], [[
  92
  93 /* Push parsers.  */
  94 #define YYPUSH ]b4_push_flag])[]m4_ifdef([b4_pull_flag], [[
  95
  96 /* Pull parsers.  */
  97 #define YYPULL ]b4_pull_flag])[
  98 ]])
  99
 100
 101 ## ---------------- ##
 102 ## Default values.  ##
 103 ## ---------------- ##
 104
 105 # b4_api_prefix, b4_api_PREFIX
 106 # ----------------------------
 107 # Corresponds to %define api.prefix
 108 b4_percent_define_default([[api.prefix]], [[yy]])
 109 m4_define([b4_api_prefix],
 110 [b4_percent_define_get([[api.prefix]])])
 111 m4_define([b4_api_PREFIX],
 112 [m4_toupper(b4_api_prefix)])
 113
 114
 115 # b4_prefix
 116 # ---------
 117 # If the %name-prefix is not given, it is api.prefix.
 118 m4_define_default([b4_prefix], [b4_api_prefix])
 119
 120 # If the %union is not named, its name is YYSTYPE.
 121 m4_define_default([b4_union_name], [b4_api_PREFIX[]STYPE])
 122
 123
 124 ## ------------------------ ##
 125 ## Pure/impure interfaces.  ##
 126 ## ------------------------ ##
 127
 128 # b4_user_args
 129 # ------------
 130 m4_define([b4_user_args],
 131 [m4_ifset([b4_parse_param], [, b4_args(b4_parse_param)])])
 132
 133
 134 # b4_parse_param
 135 # --------------
 136 # If defined, b4_parse_param arrives double quoted, but below we prefer
 137 # it to be single quoted.
 138 m4_define([b4_parse_param],
 139 b4_parse_param)
 140
 141
 142 # b4_parse_param_for(DECL, FORMAL, BODY)
 143 # ---------------------------------------
 144 # Iterate over the user parameters, binding the declaration to DECL,
 145 # the formal name to FORMAL, and evaluating the BODY.
 146 m4_define([b4_parse_param_for],
 147 [m4_foreach([$1_$2], m4_defn([b4_parse_param]),
 148 [m4_pushdef([$1], m4_unquote(m4_car($1_$2)))dnl
 149 m4_pushdef([$2], m4_shift($1_$2))dnl
 150 $3[]dnl
 151 m4_popdef([$2])dnl
 152 m4_popdef([$1])dnl
 153 ])])
 154
 155 # b4_parse_param_use([VAL], [LOC])
 156 # --------------------------------
 157 # `YYUSE' VAL, LOC if locations are enabled, and all the parse-params.
 158 m4_define([b4_parse_param_use],
 159 [m4_ifvaln([$1], [  YYUSE([$1]);])dnl
 160 b4_locations_if([m4_ifvaln([$2], [  YYUSE ([$2]);])])dnl
 161 b4_parse_param_for([Decl], [Formal], [  YYUSE (Formal);
 162 ])dnl
 163 ])
 164
 165
 166 ## ------------ ##
 167 ## Data Types.  ##
 168 ## ------------ ##
 169
 170 # b4_int_type(MIN, MAX)
 171 # ---------------------
 172 # Return the smallest int type able to handle numbers ranging from
 173 # MIN to MAX (included).
 174 m4_define([b4_int_type],
 175 [m4_if(b4_ints_in($@,      [0],   [255]), [1], [unsigned char],
 176        b4_ints_in($@,   [-128],   [127]), [1], [signed char],
 177
 178        b4_ints_in($@,      [0], [65535]), [1], [unsigned short int],
 179        b4_ints_in($@, [-32768], [32767]), [1], [short int],
 180
 181        m4_eval([0 <= $1]),                [1], [unsigned int],
 182
 183                                                [int])])
 184
 185
 186 # b4_int_type_for(NAME)
 187 # ---------------------
 188 # Return the smallest int type able to handle numbers ranging from
 189 # `NAME_min' to `NAME_max' (included).
 190 m4_define([b4_int_type_for],
 191 [b4_int_type($1_min, $1_max)])
 192
 193
 194 # b4_table_value_equals(TABLE, VALUE, LITERAL)
 195 # --------------------------------------------
 196 # Without inducing a comparison warning from the compiler, check if the
 197 # literal value LITERAL equals VALUE from table TABLE, which must have
 198 # TABLE_min and TABLE_max defined.  YYID must be defined as an identity
 199 # function that suppresses warnings about constant conditions.
 200 m4_define([b4_table_value_equals],
 201 [m4_if(m4_eval($3 < m4_indir([b4_]$1[_min])
 202                || m4_indir([b4_]$1[_max]) < $3), [1],
 203        [[YYID (0)]],
 204        [[((]$2[) == (]$3[))]])])
 205
 206
 207 ## ---------##
 208 ## Values.  ##
 209 ## ---------##
 210
 211
 212 # b4_null_define
 213 # --------------
 214 # Portability issues: define a YY_NULL appropriate for the current
 215 # language (C, C++98, or C++11).
 216 m4_define([b4_null_define],
 217 [# ifndef YY_NULL
 218 #  if defined __cplusplus && 201103L <= __cplusplus
 219 #   define YY_NULL nullptr
 220 #  else
 221 #   define YY_NULL 0
 222 #  endif
 223 # endif[]dnl
 224 ])
 225
 226
 227 # b4_null
 228 # -------
 229 # Return a null pointer constant.
 230 m4_define([b4_null], [YY_NULL])
 231
 232 # b4_integral_parser_table_define(TABLE-NAME, CONTENT, COMMENT)
 233 # -------------------------------------------------------------
 234 # Define "yy<TABLE-NAME>" which contents is CONTENT.
 235 m4_define([b4_integral_parser_table_define],
 236 [m4_ifvaln([$3], [b4_comment([$3], [  ])])dnl
 237 static const b4_int_type_for([$2]) yy$1[[]] =
 238 {
 239   $2
 240 };dnl
 241 ])
 242
 243
 244 ## ------------------------- ##
 245 ## Assigning token numbers.  ##
 246 ## ------------------------- ##
 247
 248 # b4_token_define(TOKEN-NUM)
 249 # --------------------------
 250 # Output the definition of this token as #define.
 251 m4_define([b4_token_define],
 252 [b4_token_format([#define %s %s], [$1])])
 253
 254 # b4_token_defines
 255 # ----------------
 256 # Output the definition of the tokens.
 257 m4_define([b4_token_defines],
 258 [b4_any_token_visible_if([/* Tokens.  */
 259 m4_join([
 260 ], b4_symbol_map([b4_token_define]))
 261 ])])
 262
 263
 264 # b4_token_enum(TOKEN-NUM)
 265 # ------------------------
 266 # Output the definition of this token as an enum.
 267 m4_define([b4_token_enum],
 268 [b4_token_format([%s = %s], [$1])])
 269
 270
 271 # b4_token_enums
 272 # --------------
 273 # Output the definition of the tokens (if there are) as enums.
 274 m4_define([b4_token_enums],
 275 [b4_any_token_visible_if([[/* Tokens.  */
 276 #ifndef ]b4_api_PREFIX[TOKENTYPE
 277 # define ]b4_api_PREFIX[TOKENTYPE
 278   /* Put the tokens into the symbol table, so that GDB and other debuggers
 279      know about them.  */
 280   enum ]b4_api_prefix[tokentype
 281   {
 282     ]m4_join([,
 283     ],
 284              b4_symbol_map([b4_token_enum]))[
 285   };
 286 #endif
 287 ]])])
 288
 289
 290 # b4_token_enums_defines
 291 # ----------------------
 292 # Output the definition of the tokens (if there are any) as enums and,
 293 # if POSIX Yacc is enabled, as #defines.
 294 m4_define([b4_token_enums_defines],
 295 [b4_token_enums[]b4_yacc_if([b4_token_defines])])
 296
 297
 298 ## ----------------- ##
 299 ## Semantic Values.  ##
 300 ## ----------------- ##
 301
 302
 303 # b4_symbol_value(VAL, [TYPE])
 304 # ----------------------------
 305 # Given a semantic value VAL ($$, $1 etc.), extract its value of type
 306 # TYPE if TYPE is given, otherwise just return VAL.  The result can be
 307 # used safetly, it is put in parens to avoid nasty precedence issues.
 308 # TYPE is *not* put in braces, provide some if needed.
 309 m4_define([b4_symbol_value],
 310 [($1[]m4_ifval([$2], [.$2]))])
 311
 312
 313
 314 ## ---------------------- ##
 315 ## Defining C functions.  ##
 316 ## ---------------------- ##
 317
 318
 319 # b4_function_define(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 320 # -----------------------------------------------------------
 321 # Declare the function NAME in C.
 322 m4_define([b4_function_define],
 323 [$2
 324 $1 (b4_formals(m4_shift2($@)))[]dnl
 325 ])
 326
 327
 328 # b4_formals([DECL1, NAME1], ...)
 329 # -------------------------------
 330 # The formal arguments of a C function definition.
 331 m4_define([b4_formals],
 332 [m4_if([$#], [0], [void],
 333        [$#$1], [1], [void],
 334                [m4_map_sep([b4_formal], [, ], [$@])])])
 335
 336 m4_define([b4_formal],
 337 [$1])
 338
 339
 340
 341 ## ----------------------- ##
 342 ## Declaring C functions.  ##
 343 ## ----------------------- ##
 344
 345
 346 # b4_function_declare(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 347 # ------------------------------------------------------------
 348 # Declare the function NAME.
 349 m4_define([b4_function_declare],
 350 [$2 $1 (b4_formals(m4_shift2($@)));[]dnl
 351 ])
 352
 353
 354
 355
 356 ## --------------------- ##
 357 ## Calling C functions.  ##
 358 ## --------------------- ##
 359
 360
 361 # b4_function_call(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 362 # -----------------------------------------------------------
 363 # Call the function NAME with arguments NAME1, NAME2 etc.
 364 m4_define([b4_function_call],
 365 [$1 (b4_args(m4_shift2($@)))[]dnl
 366 ])
 367
 368
 369 # b4_args([DECL1, NAME1], ...)
 370 # ----------------------------
 371 # Output the arguments NAME1, NAME2...
 372 m4_define([b4_args],
 373 [m4_map_sep([b4_arg], [, ], [$@])])
 374
 375 m4_define([b4_arg],
 376 [$2])
 377
 378
 379 ## ----------- ##
 380 ## Synclines.  ##
 381 ## ----------- ##
 382
 383 # b4_sync_start(LINE, FILE)
 384 # -------------------------
 385 m4_define([b4_sync_start], [[#]line $1 $2])
 386
 387
 388 ## -------------- ##
 389 ## User actions.  ##
 390 ## -------------- ##
 391
 392 # b4_case(LABEL, STATEMENTS)
 393 # --------------------------
 394 m4_define([b4_case],
 395 [  case $1:
 396 $2
 397 b4_syncline([@oline@], [@ofile@])
 398     break;])
 399
 400
 401 # b4_predicate_case(LABEL, CONDITIONS)
 402 # ------------------------------------
 403 m4_define([b4_predicate_case],
 404 [  case $1:
 405     if (! ($2)) YYERROR;
 406 b4_syncline([@oline@], [@ofile@])
 407     break;])
 408
 409
 410 # b4_yydestruct_define
 411 # --------------------
 412 # Define the "yydestruct" function.
 413 m4_define_default([b4_yydestruct_define],
 414 [[/*-----------------------------------------------.
 415 | Release the memory associated to this symbol.  |
 416 `-----------------------------------------------*/
 417
 418 /*ARGSUSED*/
 419 ]b4_function_define([yydestruct],
 420     [static void],
 421     [[const char *yymsg],    [yymsg]],
 422     [[int yytype],           [yytype]],
 423     [[YYSTYPE *yyvaluep],    [yyvaluep]][]dnl
 424 b4_locations_if(            [, [[YYLTYPE *yylocationp], [yylocationp]]])[]dnl
 425 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 426 {
 427 ]b4_parse_param_use([yyvaluep], [yylocationp])dnl
 428 [  if (!yymsg)
 429     yymsg = "Deleting";
 430   YY_SYMBOL_PRINT (yymsg, yytype, yyvaluep, yylocationp);
 431
 432   switch (yytype)
 433     {
 434 ]b4_symbol_foreach([b4_symbol_destructor])dnl
 435 [      default:
 436         break;
 437     }
 438 }]dnl
 439 ])
 440
 441
 442 # b4_yy_symbol_print_define
 443 # -------------------------
 444 # Define the "yy_symbol_print" function.
 445 m4_define_default([b4_yy_symbol_print_define],
 446 [[
 447 /*--------------------------------.
 448 | Print this symbol on YYOUTPUT.  |
 449 `--------------------------------*/
 450
 451 /*ARGSUSED*/
 452 ]b4_function_define([yy_symbol_value_print],
 453     [static void],
 454                [[FILE *yyoutput],                       [yyoutput]],
 455                [[int yytype],                           [yytype]],
 456                [[YYSTYPE const * const yyvaluep],       [yyvaluep]][]dnl
 457 b4_locations_if([, [[YYLTYPE const * const yylocationp], [yylocationp]]])[]dnl
 458 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 459 {
 460   FILE *yyo = yyoutput;
 461 ]b4_parse_param_use([yyo], [yylocationp])dnl
 462 [  if (!yyvaluep)
 463     return;]
 464 dnl glr.c does not feature yytoknum.
 465 m4_if(b4_skeleton, ["yacc.c"],
 466 [[# ifdef YYPRINT
 467   if (yytype < YYNTOKENS)
 468     YYPRINT (yyoutput, yytoknum[yytype], *yyvaluep);
 469 # endif
 470 ]])dnl
 471 [  switch (yytype)
 472     {
 473 ]b4_symbol_foreach([b4_symbol_printer])dnl
 474 [      default:
 475         break;
 476     }
 477 }
 478
 479
 480 /*--------------------------------.
 481 | Print this symbol on YYOUTPUT.  |
 482 `--------------------------------*/
 483
 484 ]b4_function_define([yy_symbol_print],
 485     [static void],
 486                [[FILE *yyoutput],                       [yyoutput]],
 487                [[int yytype],                           [yytype]],
 488                [[YYSTYPE const * const yyvaluep],       [yyvaluep]][]dnl
 489 b4_locations_if([, [[YYLTYPE const * const yylocationp], [yylocationp]]])[]dnl
 490 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 491 {
 492   if (yytype < YYNTOKENS)
 493     YYFPRINTF (yyoutput, "token %s (", yytname[yytype]);
 494   else
 495     YYFPRINTF (yyoutput, "nterm %s (", yytname[yytype]);
 496
 497 ]b4_locations_if([  YY_LOCATION_PRINT (yyoutput, *yylocationp);
 498   YYFPRINTF (yyoutput, ": ");
 499 ])dnl
 500 [  yy_symbol_value_print (yyoutput, yytype, yyvaluep]dnl
 501 b4_locations_if([, yylocationp])[]b4_user_args[);
 502   YYFPRINTF (yyoutput, ")");
 503 }]dnl
 504 ])
 505
 506 ## -------------- ##
 507 ## Declarations.  ##
 508 ## -------------- ##
 509
 510 # b4_declare_yylstype
 511 # -------------------
 512 # Declarations that might either go into the header (if --defines) or
 513 # in the parser body.  Declare YYSTYPE/YYLTYPE, and yylval/yylloc.
 514 m4_define([b4_declare_yylstype],
 515 [[#if ! defined ]b4_api_PREFIX[STYPE && ! defined ]b4_api_PREFIX[STYPE_IS_DECLARED
 516 ]m4_ifdef([b4_stype],
 517 [[typedef union ]b4_union_name[
 518 {
 519 ]b4_user_stype[
 520 } ]b4_api_PREFIX[STYPE;
 521 # define ]b4_api_PREFIX[STYPE_IS_TRIVIAL 1]],
 522 [m4_if(b4_tag_seen_flag, 0,
 523 [[typedef int ]b4_api_PREFIX[STYPE;
 524 # define ]b4_api_PREFIX[STYPE_IS_TRIVIAL 1]])])[
 525 # define ]b4_api_PREFIX[STYPE_IS_DECLARED 1
 526 #endif]b4_locations_if([[
 527
 528 #if ! defined ]b4_api_PREFIX[LTYPE && ! defined ]b4_api_PREFIX[LTYPE_IS_DECLARED
 529 typedef struct ]b4_api_PREFIX[LTYPE
 530 {
 531   int first_line;
 532   int first_column;
 533   int last_line;
 534   int last_column;
 535 } ]b4_api_PREFIX[LTYPE;
 536 # define ]b4_api_PREFIX[LTYPE_IS_DECLARED 1
 537 # define ]b4_api_PREFIX[LTYPE_IS_TRIVIAL 1
 538 #endif]])
 539
 540 b4_pure_if([], [[extern ]b4_api_PREFIX[STYPE ]b4_prefix[lval;
 541 ]b4_locations_if([[extern ]b4_api_PREFIX[LTYPE ]b4_prefix[lloc;]])])[]dnl
 542 ])
 543
 544 # b4_YYDEBUG_define
 545 # ------------------
 546 m4_define([b4_YYDEBUG_define],
 547 [[/* Enabling traces.  */
 548 ]m4_if(b4_api_prefix, [yy],
 549 [[#ifndef YYDEBUG
 550 # define YYDEBUG ]b4_parse_trace_if([1], [0])[
 551 #endif]],
 552 [[#ifndef ]b4_api_PREFIX[DEBUG
 553 # if defined YYDEBUG
 554 #if YYDEBUG
 555 #   define ]b4_api_PREFIX[DEBUG 1
 556 #  else
 557 #   define ]b4_api_PREFIX[DEBUG 0
 558 #  endif
 559 # else /* ! defined YYDEBUG */
 560 #  define ]b4_api_PREFIX[DEBUG ]b4_parse_trace_if([1], [0])[
 561 # endif /* ! defined ]b4_api_PREFIX[DEBUG */
 562 #endif  /* ! defined ]b4_api_PREFIX[DEBUG */]])[]dnl
 563 ])
 564
 565 # b4_declare_yydebug
 566 # ------------------
 567 m4_define([b4_declare_yydebug],
 568 [b4_YYDEBUG_define[
 569 #if ]b4_api_PREFIX[DEBUG
 570 extern int ]b4_prefix[debug;
 571 #endif][]dnl
 572 ])
 573
 574 # b4_yylloc_default_define
 575 # ------------------------
 576 # Define YYLLOC_DEFAULT.
 577 m4_define([b4_yylloc_default_define],
 578 [[/* YYLLOC_DEFAULT -- Set CURRENT to span from RHS[1] to RHS[N].
 579    If N is 0, then set CURRENT to the empty location which ends
 580    the previous symbol: RHS[0] (always defined).  */
 581
 582 #ifndef YYLLOC_DEFAULT
 583 # define YYLLOC_DEFAULT(Current, Rhs, N)                                \
 584     do                                                                  \
 585       if (YYID (N))                                                     \
 586         {                                                               \
 587           (Current).first_line   = YYRHSLOC (Rhs, 1).first_line;        \
 588           (Current).first_column = YYRHSLOC (Rhs, 1).first_column;      \
 589           (Current).last_line    = YYRHSLOC (Rhs, N).last_line;         \
 590           (Current).last_column  = YYRHSLOC (Rhs, N).last_column;       \
 591         }                                                               \
 592       else                                                              \
 593         {                                                               \
 594           (Current).first_line   = (Current).last_line   =              \
 595             YYRHSLOC (Rhs, 0).last_line;                                \
 596           (Current).first_column = (Current).last_column =              \
 597             YYRHSLOC (Rhs, 0).last_column;                              \
 598         }                                                               \
 599     while (YYID (0))
 600 #endif
 601 ]])