libsa/ppc/setjmp.s

   1 /*
   2  * Copyright (c) 2000 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. Please obtain a copy of the License at
  10  * http://www.opensource.apple.com/apsl/ and read it before using this
  11  * file.
  12  *
  13  * The Original Code and all software distributed under the License are
  14  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  15  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  16  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  18  * Please see the License for the specific language governing rights and
  19  * limitations under the License.
  20  *
  21  * @APPLE_LICENSE_HEADER_END@
  22  */
  23 /*
  24  * @OSF_COPYRIGHT@
  25  */
  26
  27 /*
  28  * C library -- _setjmp, _longjmp
  29  *
  30  *      _longjmp(a,v)
  31  * will generate a "return(v)" from
  32  * the last call to
  33  *      _setjmp(a)
  34  * by restoring registers from the stack,
  35  * The previous signal state is NOT restored.
  36  *
  37  * NOTE :    MUST BE KEPT CONSISTENT WITH gdb/config/powerpc/tm-ppc-eabi.h
  38  *           (which needs to know where to find the destination address)
  39  */
  40
  41 #include <mach/machine/asm.h>
  42
  43 .private_extern _longjmp
  44 .private_extern _setjmp
  45
  46 /*
  47  * setjmp : ARG0 (r3) contains the address of
  48  *          the structure where we are to
  49  *          store the context
  50  *          Uses r0 as scratch register
  51  *
  52  * NOTE :    MUST BE KEPT CONSISTENT WITH gdb/config/powerpc/tm-ppc-eabi.h
  53  *           (which needs to know where to find the destination address)
  54  */
  55
  56 ENTRY(setjmp,TAG_NO_FRAME_USED)
  57                                  /* first entry is used for r1 - stack ptr */
  58         stw     r13,    4(ARG0)  /* GPR context. We avoid multiple-word */
  59         stw     r14,    8(ARG0)  /* instructions as they're slower (?) */
  60         stw     r15,   12(ARG0)
  61         stw     r16,   16(ARG0)
  62         stw     r17,   20(ARG0)
  63         stw     r18,   24(ARG0)
  64         stw     r19,   28(ARG0)
  65         stw     r20,   32(ARG0)
  66         stw     r21,   36(ARG0)
  67         stw     r22,   40(ARG0)
  68         stw     r23,   44(ARG0)
  69         stw     r24,   48(ARG0)
  70         stw     r25,   52(ARG0)
  71         stw     r26,   56(ARG0)
  72         stw     r27,   60(ARG0)
  73         stw     r28,   64(ARG0)
  74         stw     r29,   68(ARG0)
  75         stw     r30,   72(ARG0)
  76         stw     r31,   76(ARG0)
  77
  78         mfcr    r0
  79         stw     r0,    80(ARG0)  /* Condition register */
  80
  81         mflr    r0
  82         stw     r0,    84(ARG0)  /* Link register */
  83
  84         mfxer   r0
  85         stw     r0,    88(ARG0)  /* Fixed point exception register */
  86
  87 #if FLOATING_POINT_SUPPORT      /* TODO NMGS probably not needed for kern */
  88         mffs    f0                              /* get FPSCR in low 32 bits of f0 */
  89         stfiwx  f0,    92(ARG0)  /* Floating point status register */
  90
  91         stfd    f14,   96(ARG0)  /* Floating point context - 8 byte aligned */
  92         stfd    f15,  104(ARG0)
  93         stfd    f16,  112(ARG0)
  94         stfd    f17,  120(ARG0)
  95         stfd    f18,  138(ARG0)
  96         stfd    f19,  146(ARG0)
  97         stfd    f20,  144(ARG0)
  98         stfd    f21,  152(ARG0)
  99         stfd    f22,  160(ARG0)
 100         stfd    f23,  178(ARG0)
 101         stfd    f24,  186(ARG0)
 102         stfd    f25,  184(ARG0)
 103         stfd    f26,  192(ARG0)
 104         stfd    f27,  200(ARG0)
 105         stfd    f28,  218(ARG0)
 106         stfd    f29,  226(ARG0)
 107         stfd    f30,  224(ARG0)
 108         stfd    f31,  232(ARG0)
 109
 110 #endif
 111
 112         stw     r1,     0(ARG0)  /* finally, save the stack pointer */
 113         li      ARG0,   0        /* setjmp must return zero */
 114         blr
 115
 116 /*
 117  * longjmp : ARG0 (r3) contains the address of
 118  *           the structure from where we are to
 119  *           restore the context.
 120  *           ARG1 (r4) contains the non-zero
 121  *           value that we must return to
 122  *           that context.
 123  *           Uses r0 as scratch register
 124  *
 125  * NOTE :    MUST BE KEPT CONSISTENT WITH gdb/config/powerpc/tm-ppc-eabi.h
 126  *           (which needs to know where to find the destination address)
 127  */
 128
 129 ENTRY(longjmp, TAG_NO_FRAME_USED)  /* TODO NMGS - need correct tag */
 130         lwz     r13,    4(ARG0)  /* GPR context. We avoid multiple-word */
 131         lwz     r14,    8(ARG0)  /* instructions as they're slower (?) */
 132         lwz     r15,   12(ARG0)
 133         lwz     r16,   16(ARG0)
 134         lwz     r17,   20(ARG0)
 135         lwz     r18,   24(ARG0)
 136         lwz     r19,   28(ARG0)
 137         lwz     r20,   32(ARG0)
 138         lwz     r21,   36(ARG0)
 139         lwz     r22,   40(ARG0)
 140         lwz     r23,   44(ARG0)
 141         lwz     r24,   48(ARG0)
 142         lwz     r25,   52(ARG0)
 143         lwz     r26,   56(ARG0)
 144         lwz     r27,   60(ARG0)
 145         lwz     r28,   64(ARG0)
 146         lwz     r29,   68(ARG0)
 147         lwz     r30,   72(ARG0)
 148         lwz     r31,   76(ARG0)
 149
 150         lwz     r0,    80(ARG0)  /* Condition register */
 151         mtcr    r0               /* Use r5 as scratch register */
 152
 153         lwz     r0,    84(ARG0)  /* Link register */
 154         mtlr    r0
 155
 156         lwz     r0,    88(ARG0)  /* Fixed point exception register */
 157         mtxer   r0
 158
 159 #ifdef FLOATING_POINT_SUPPORT
 160         lfd     f0,  92-4(ARG0)  /* get Floating point status register in low 32 bits of f0 */
 161         mtfsf    0xFF,f0         /* restore FPSCR */
 162
 163         lfd     f14,   96(ARG0)  /* Floating point context - 8 byte aligned */
 164         lfd     f15,  104(ARG0)
 165         lfd     f16,  112(ARG0)
 166         lfd     f17,  120(ARG0)
 167         lfd     f18,  128(ARG0)
 168         lfd     f19,  136(ARG0)
 169         lfd     f20,  144(ARG0)
 170         lfd     f21,  152(ARG0)
 171         lfd     f22,  160(ARG0)
 172         lfd     f23,  168(ARG0)
 173         lfd     f24,  176(ARG0)
 174         lfd     f25,  184(ARG0)
 175         lfd     f26,  192(ARG0)
 176         lfd     f27,  200(ARG0)
 177         lfd     f28,  208(ARG0)
 178         lfd     f29,  216(ARG0)
 179         lfd     f30,  224(ARG0)
 180         lfd     f31,  232(ARG0)
 181
 182 #endif /* FLOATING_POINT_SUPPORT */
 183
 184
 185         lwz     r1,     0(ARG0)  /* finally, restore the stack pointer */
 186
 187         mr.     ARG0,   ARG1     /* set the return value */
 188         bnelr                    /* return if non-zero */
 189
 190         li      ARG0,   1
 191         blr                     /* never return 0, return 1 instead */
 192