]> git.saurik.com Git - apple/xnu.git/blob - libsyscall/custom/SYS.h
projects / apple / xnu.git / blob
? search:


3f95dbbaf4f7f8b321bec240f2b1a9ec16511659
[apple/xnu.git] / libsyscall / custom / SYS.h
1 /*
2 * Copyright (c) 1999-2007 Apple Inc. All rights reserved.
3 *
4 * @APPLE_OSREFERENCE_LICENSE_HEADER_START@
5 *
6 * This file contains Original Code and/or Modifications of Original Code
7 * as defined in and that are subject to the Apple Public Source License
8 * Version 2.0 (the 'License'). You may not use this file except in
9 * compliance with the License. The rights granted to you under the License
10 * may not be used to create, or enable the creation or redistribution of,
11 * unlawful or unlicensed copies of an Apple operating system, or to
12 * circumvent, violate, or enable the circumvention or violation of, any
13 * terms of an Apple operating system software license agreement.
14 *
15 * Please obtain a copy of the License at
16 * http://www.opensource.apple.com/apsl/ and read it before using this file.
17 *
18 * The Original Code and all software distributed under the License are
19 * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
20 * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
21 * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
22 * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
23 * Please see the License for the specific language governing rights and
24 * limitations under the License.
25 *
26 * @APPLE_OSREFERENCE_LICENSE_HEADER_END@
27 */
28 /* Copyright (c) 1992 NeXT Computer, Inc. All rights reserved.
29 *
30 * File: SYS.h
31 *
32 * Definition of the user side of the UNIX system call interface
33 * for M98K.
34 *
35 * Errors are flagged by the location of the trap return (ie., which
36 * instruction is executed upon rfi):
37 *
38 * SC PC + 4: Error (typically branch to cerror())
39 * SC PC + 8: Success
40 *
41 * HISTORY
42 * 18-Nov-92 Ben Fathi (benf@next.com)
43 * Ported to m98k.
44 *
45 * 9-Jan-92 Peter King (king@next.com)
46 * Created.
47 */
48
49 #include <sys/syscall.h>
50
51 #ifndef SYS_setquota
52 #define SYS_setquota 148
53 #endif
54 #ifndef SYS_quota
55 #define SYS_quota 149
56 #endif
57
58 #if defined(__ppc__) || defined(__ppc64__)
59
60 #include <architecture/ppc/mode_independent_asm.h>
61
62 /* From rhapsody kernel mach/ppc/syscall_sw.h */
63 #define kernel_trap_args_0
64 #define kernel_trap_args_1
65 #define kernel_trap_args_2
66 #define kernel_trap_args_3
67 #define kernel_trap_args_4
68 #define kernel_trap_args_5
69 #define kernel_trap_args_6
70 #define kernel_trap_args_7
71 #define kernel_trap_args_8
72 /* End of rhapsody kernel mach/ppc/syscall_sw.h */
73
74 /*
75 * Macros.
76 */
77
78 #define SYSCALL(name, nargs) \
79 .globl cerror @\
80 MI_ENTRY_POINT(_##name) @\
81 kernel_trap_args_##nargs @\
82 li r0,SYS_##name @\
83 sc @\
84 b 1f @\
85 blr @\
86 1: MI_BRANCH_EXTERNAL(cerror)
87
88
89 #define SYSCALL_NONAME(name, nargs) \
90 .globl cerror @\
91 kernel_trap_args_##nargs @\
92 li r0,SYS_##name @\
93 sc @\
94 b 1f @\
95 b 2f @\
96 1: MI_BRANCH_EXTERNAL(cerror) @\
97 2:
98
99
100 #define PSEUDO(pseudo, name, nargs) \
101 .private_extern _##pseudo @\
102 .text @\
103 .align 2 @\
104 _##pseudo: @\
105 SYSCALL_NONAME(name, nargs)
106
107 #define __SYSCALL(pseudo, name, nargs) \
108 PSEUDO(pseudo, name, nargs) @\
109 blr
110
111 #elif defined(__i386__)
112
113 #include <architecture/i386/asm_help.h>
114 #include <mach/i386/syscall_sw.h>
115
116 /*
117 * We have two entry points. int's is used for syscalls which need to preserve
118 * %ecx across the call, or return a 64-bit value in %eax:%edx. sysenter is used
119 * for the majority of syscalls which just return a value in %eax.
120 */
121
122 #define UNIX_SYSCALL_SYSENTER call __sysenter_trap
123 #define UNIX_SYSCALL(name, nargs) \
124 .globl cerror ;\
125 LEAF(_##name, 0) ;\
126 movl $ SYS_##name, %eax ;\
127 UNIX_SYSCALL_SYSENTER ;\
128 jnb 2f ;\
129 BRANCH_EXTERN(cerror) ;\
130 2:
131
132 #define UNIX_SYSCALL_INT(name, nargs) \
133 .globl cerror ;\
134 LEAF(_##name, 0) ;\
135 movl $ SYS_##name, %eax ;\
136 UNIX_SYSCALL_TRAP ;\
137 jnb 2f ;\
138 BRANCH_EXTERN(cerror) ;\
139 2:
140
141 #if defined(__SYSCALL_I386_ARG_BYTES) && ((__SYSCALL_I386_ARG_BYTES >= 4) && (__SYSCALL_I386_ARG_BYTES <= 20))
142 #define UNIX_SYSCALL_NONAME(name, nargs) \
143 movl $(SYS_##name | (__SYSCALL_I386_ARG_BYTES << I386_SYSCALL_ARG_BYTES_SHIFT)), %eax ;\
144 UNIX_SYSCALL_SYSENTER ;\
145 jnb 2f ;\
146 BRANCH_EXTERN(cerror) ;\
147 2:
148 #else /* __SYSCALL_I386_ARG_BYTES < 4 || > 20 */
149 #define UNIX_SYSCALL_NONAME(name, nargs) \
150 .globl cerror ;\
151 movl $ SYS_##name, %eax ;\
152 UNIX_SYSCALL_SYSENTER ;\
153 jnb 2f ;\
154 BRANCH_EXTERN(cerror) ;\
155 2:
156 #endif
157
158 #define UNIX_SYSCALL_INT_NONAME(name, nargs) \
159 .globl cerror ;\
160 movl $ SYS_##name, %eax ;\
161 UNIX_SYSCALL_TRAP ;\
162 jnb 2f ;\
163 BRANCH_EXTERN(cerror) ;\
164 2:
165
166 #define PSEUDO(pseudo, name, nargs) \
167 LEAF(_##pseudo, 0) ;\
168 UNIX_SYSCALL_NONAME(name, nargs)
169
170 #define PSEUDO_INT(pseudo, name, nargs) \
171 LEAF(_##pseudo, 0) ;\
172 UNIX_SYSCALL_INT_NONAME(name, nargs)
173
174 #define __SYSCALL(pseudo, name, nargs) \
175 PSEUDO(pseudo, name, nargs) ;\
176 ret
177
178 #define __SYSCALL_INT(pseudo, name, nargs) \
179 PSEUDO_INT(pseudo, name, nargs) ;\
180 ret
181
182 #elif defined(__x86_64__)
183
184 #include <architecture/i386/asm_help.h>
185 #include <mach/i386/syscall_sw.h>
186
187 #define UNIX_SYSCALL_SYSCALL \
188 movq %rcx, %r10 ;\
189 syscall
190
191 #define UNIX_SYSCALL(name, nargs) \
192 .globl cerror ;\
193 LEAF(_##name, 0) ;\
194 movl $ SYSCALL_CONSTRUCT_UNIX(SYS_##name), %eax ;\
195 UNIX_SYSCALL_SYSCALL ;\
196 jnb 2f ;\
197 BRANCH_EXTERN(cerror) ;\
198 2:
199
200 #define UNIX_SYSCALL_NONAME(name, nargs) \
201 .globl cerror ;\
202 movl $ SYSCALL_CONSTRUCT_UNIX(SYS_##name), %eax ;\
203 UNIX_SYSCALL_SYSCALL ;\
204 jnb 2f ;\
205 BRANCH_EXTERN(cerror) ;\
206 2:
207
208 #define PSEUDO(pseudo, name, nargs) \
209 LEAF(_##pseudo, 0) ;\
210 UNIX_SYSCALL_NONAME(name, nargs)
211
212 #define __SYSCALL(pseudo, name, nargs) \
213 PSEUDO(pseudo, name, nargs) ;\
214 ret
215
216 #elif defined(__arm__)
217
218 #define SWI_SYSCALL 0x80 // from <mach/vm_param.h>
219
220 /*
221 * ARM system call interface:
222 *
223 * swi 0x80
224 * args: r0-r6
225 * return code: r0
226 * on error, carry bit is set in the psr, otherwise carry bit is cleared.
227 */
228
229 /*
230 * Macros.
231 */
232
233 /*
234 * until we update the architecture project, these live here
235 */
236
237 #if defined(__DYNAMIC__)
238 #define MI_GET_ADDRESS(reg,var) \
239 ldr reg, 4f ;\
240 3: ldr reg, [pc, reg] ;\
241 b 5f ;\
242 4: .long 6f - (3b + 8) ;\
243 5: ;\
244 .non_lazy_symbol_pointer ;\
245 6: ;\
246 .indirect_symbol var ;\
247 .long 0 ;\
248 .text ;\
249 .align 2
250 #else
251 #define MI_GET_ADDRESS(reg,var) \
252 ldr reg, 3f ;\
253 b 4f ;\
254 3: .long var ;\
255 4:
256 #endif
257
258 #if defined(__DYNAMIC__)
259 #define MI_BRANCH_EXTERNAL(var) \
260 .globl var ;\
261 MI_GET_ADDRESS(ip, var) ;\
262 bx ip
263 #else
264 #define MI_BRANCH_EXTERNAL(var) ;\
265 .globl var ;\
266 b var
267 #endif
268
269 #if defined(__DYNAMIC__)
270 #define MI_CALL_EXTERNAL(var) \
271 .globl var ;\
272 MI_GET_ADDRESS(ip,var) ;\
273 mov lr, pc ;\
274 bx ip
275 #else
276 #define MI_CALL_EXTERNAL(var) \
277 .globl var ;\
278 bl var
279 #endif
280
281 #define MI_ENTRY_POINT(name) \
282 .align 2 ;\
283 .globl name ;\
284 .text ;\
285 name:
286
287 /* load the syscall number into r12 and trap */
288 #define DO_SYSCALL(num) \
289 .if (((num) & 0xff) == (num)) ;\
290 mov r12, #(num) ;\
291 .elseif (((num) & 0x3fc) == (num)) ;\
292 mov r12, #(num) ;\
293 .else ;\
294 mov r12, #((num) & 0xffffff00) /* top half of the syscall number */ ;\
295 orr r12, r12, #((num) & 0xff) /* bottom half */ ;\
296 .endif ;\
297 swi #SWI_SYSCALL
298
299 /* simple syscalls (0 to 4 args) */
300 #define SYSCALL_0to4(name) \
301 MI_ENTRY_POINT(_##name) ;\
302 DO_SYSCALL(SYS_##name) ;\
303 bxcc lr /* return if carry is clear (no error) */ ; \
304 1: MI_BRANCH_EXTERNAL(cerror)
305
306 /* syscalls with 5 args is different, because of the single arg register load */
307 #define SYSCALL_5(name) \
308 MI_ENTRY_POINT(_##name) ;\
309 mov ip, sp /* save a pointer to the args */ ; \
310 stmfd sp!, { r4-r5 } /* save r4-r5 */ ;\
311 ldr r4, [ip] /* load 5th arg */ ; \
312 DO_SYSCALL(SYS_##name) ;\
313 ldmfd sp!, { r4-r5 } /* restore r4-r5 */ ; \
314 bxcc lr /* return if carry is clear (no error) */ ; \
315 1: MI_BRANCH_EXTERNAL(cerror)
316
317 /* syscalls with 6 to 8 args */
318 #define SYSCALL_6to8(name, save_regs, arg_regs) \
319 MI_ENTRY_POINT(_##name) ;\
320 mov ip, sp /* save a pointer to the args */ ; \
321 stmfd sp!, { save_regs } /* callee saved regs */ ;\
322 ldmia ip, { arg_regs } /* load arg regs */ ; \
323 DO_SYSCALL(SYS_##name) ;\
324 ldmfd sp!, { save_regs } /* restore callee saved regs */ ; \
325 bxcc lr /* return if carry is clear (no error) */ ; \
326 1: MI_BRANCH_EXTERNAL(cerror)
327
328 #define COMMA ,
329
330 #define SYSCALL_0(name) SYSCALL_0to4(name)
331 #define SYSCALL_1(name) SYSCALL_0to4(name)
332 #define SYSCALL_2(name) SYSCALL_0to4(name)
333 #define SYSCALL_3(name) SYSCALL_0to4(name)
334 #define SYSCALL_4(name) SYSCALL_0to4(name)
335 /* SYSCALL_5 declared above */
336 #define SYSCALL_6(name) SYSCALL_6to8(name, r4-r5, r4-r5)
337 #define SYSCALL_7(name) SYSCALL_6to8(name, r4-r6 COMMA r8, r4-r6)
338 #define SYSCALL_8(name) SYSCALL_6to8(name, r4-r6 COMMA r8, r4-r6 COMMA r8)
339
340 /* select the appropriate syscall code, based on the number of arguments */
341 #define SYSCALL(name, nargs) SYSCALL_##nargs(name)
342
343 #define SYSCALL_NONAME_0to4(name) \
344 DO_SYSCALL(SYS_##name) ;\
345 bcc 1f /* branch if carry bit is clear (no error) */ ; \
346 MI_BRANCH_EXTERNAL(cerror) /* call cerror */ ; \
347 1:
348
349 #define SYSCALL_NONAME_5(name) \
350 mov ip, sp /* save a pointer to the args */ ; \
351 stmfd sp!, { r4-r5 } /* save r4-r5 */ ;\
352 ldr r4, [ip] /* load 5th arg */ ; \
353 DO_SYSCALL(SYS_##name) ;\
354 ldmfd sp!, { r4-r5 } /* restore r4-r7 */ ; \
355 bcc 1f /* branch if carry bit is clear (no error) */ ; \
356 MI_BRANCH_EXTERNAL(cerror) /* call cerror */ ; \
357 1:
358
359 #define SYSCALL_NONAME_6to8(name, save_regs, arg_regs) \
360 mov ip, sp /* save a pointer to the args */ ; \
361 stmfd sp!, { save_regs } /* callee save regs */ ;\
362 ldmia ip, { arg_regs } /* load arguments */ ; \
363 DO_SYSCALL(SYS_##name) ;\
364 ldmfd sp!, { save_regs } /* restore callee saved regs */ ; \
365 bcc 1f /* branch if carry bit is clear (no error) */ ; \
366 MI_BRANCH_EXTERNAL(cerror) /* call cerror */ ; \
367 1:
368
369 #define SYSCALL_NONAME_0(name) SYSCALL_NONAME_0to4(name)
370 #define SYSCALL_NONAME_1(name) SYSCALL_NONAME_0to4(name)
371 #define SYSCALL_NONAME_2(name) SYSCALL_NONAME_0to4(name)
372 #define SYSCALL_NONAME_3(name) SYSCALL_NONAME_0to4(name)
373 #define SYSCALL_NONAME_4(name) SYSCALL_NONAME_0to4(name)
374 /* SYSCALL_NONAME_5 declared above */
375 #define SYSCALL_NONAME_6(name) SYSCALL_NONAME_6to8(name, r4-r5, r4-r5)
376 #define SYSCALL_NONAME_7(name) SYSCALL_NONAME_6to8(name, r4-r6 COMMA r8, r4-r6)
377 #define SYSCALL_NONAME_8(name) SYSCALL_NONAME_6to8(name, r4-r6 COMMA r8, r4-r6 COMMA r8)
378
379 /* select the appropriate syscall code, based on the number of arguments */
380 #define SYSCALL_NONAME(name, nargs) SYSCALL_NONAME_##nargs(name)
381
382 #define PSEUDO(pseudo, name, nargs) \
383 .globl _##pseudo ;\
384 .text ;\
385 .align 2 ;\
386 _##pseudo: ;\
387 SYSCALL_NONAME(name, nargs)
388
389 #define __SYSCALL(pseudo, name, nargs) \
390 PSEUDO(pseudo, name, nargs) ;\
391 bx lr
392
393 #else
394 #error Unsupported architecture
395 #endif
mirror of XNU