osfmk/ppc/_setjmp.s

   1 /*
   2  * Copyright (c) 2000 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. Please obtain a copy of the License at
  10  * http://www.opensource.apple.com/apsl/ and read it before using this
  11  * file.
  12  *
  13  * The Original Code and all software distributed under the License are
  14  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  15  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  16  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  18  * Please see the License for the specific language governing rights and
  19  * limitations under the License.
  20  *
  21  * @APPLE_LICENSE_HEADER_END@
  22  */
  23 /*
  24  * @OSF_COPYRIGHT@
  25  */
  26
  27 /*
  28  * C library -- _setjmp, _longjmp
  29  *
  30  *      _longjmp(a,v)
  31  * will generate a "return(v)" from
  32  * the last call to
  33  *      _setjmp(a)
  34  * by restoring registers from the stack,
  35  * The previous signal state is NOT restored.
  36  *
  37  * NOTE :    MUST BE KEPT CONSISTENT WITH gdb/config/powerpc/tm-ppc-eabi.h
  38  *           (which needs to know where to find the destination address)
  39  */
  40
  41 #include <ppc/asm.h>
  42
  43 /*
  44  * setjmp : ARG0 (r3) contains the address of
  45  *          the structure where we are to
  46  *          store the context
  47  *          Uses r0 as scratch register
  48  *
  49  * NOTE :    MUST BE KEPT CONSISTENT WITH gdb/config/powerpc/tm-ppc-eabi.h
  50  *           (which needs to know where to find the destination address)
  51  */
  52
  53 ENTRY(_setjmp,TAG_NO_FRAME_USED)
  54                                  /* first entry is used for r1 - stack ptr */
  55         stw     r13,    4(ARG0)  /* GPR context. We avoid multiple-word */
  56         stw     r14,    8(ARG0)  /* instructions as they're slower (?) */
  57         stw     r15,   12(ARG0)
  58         stw     r16,   16(ARG0)
  59         stw     r17,   20(ARG0)
  60         stw     r18,   24(ARG0)
  61         stw     r19,   28(ARG0)
  62         stw     r20,   32(ARG0)
  63         stw     r21,   36(ARG0)
  64         stw     r22,   40(ARG0)
  65         stw     r23,   44(ARG0)
  66         stw     r24,   48(ARG0)
  67         stw     r25,   52(ARG0)
  68         stw     r26,   56(ARG0)
  69         stw     r27,   60(ARG0)
  70         stw     r28,   64(ARG0)
  71         stw     r29,   68(ARG0)
  72         stw     r30,   72(ARG0)
  73         stw     r31,   76(ARG0)
  74
  75         mfcr    r0
  76         stw     r0,    80(ARG0)  /* Condition register */
  77
  78         mflr    r0
  79         stw     r0,    84(ARG0)  /* Link register */
  80
  81         mfxer   r0
  82         stw     r0,    88(ARG0)  /* Fixed point exception register */
  83
  84 #if FLOATING_POINT_SUPPORT      /* TODO NMGS probably not needed for kern */
  85         mffs    f0                              /* get FPSCR in low 32 bits of f0 */
  86         stfiwx  f0,    92(ARG0)  /* Floating point status register */
  87
  88         stfd    f14,   96(ARG0)  /* Floating point context - 8 byte aligned */
  89         stfd    f15,  104(ARG0)
  90         stfd    f16,  112(ARG0)
  91         stfd    f17,  120(ARG0)
  92         stfd    f18,  138(ARG0)
  93         stfd    f19,  146(ARG0)
  94         stfd    f20,  144(ARG0)
  95         stfd    f21,  152(ARG0)
  96         stfd    f22,  160(ARG0)
  97         stfd    f23,  178(ARG0)
  98         stfd    f24,  186(ARG0)
  99         stfd    f25,  184(ARG0)
 100         stfd    f26,  192(ARG0)
 101         stfd    f27,  200(ARG0)
 102         stfd    f28,  218(ARG0)
 103         stfd    f29,  226(ARG0)
 104         stfd    f30,  224(ARG0)
 105         stfd    f31,  232(ARG0)
 106
 107 #endif
 108
 109         stw     r1,     0(ARG0)  /* finally, save the stack pointer */
 110         li      ARG0,   0        /* setjmp must return zero */
 111         blr
 112
 113 /*
 114  * longjmp : ARG0 (r3) contains the address of
 115  *           the structure from where we are to
 116  *           restore the context.
 117  *           ARG1 (r4) contains the non-zero
 118  *           value that we must return to
 119  *           that context.
 120  *           Uses r0 as scratch register
 121  *
 122  * NOTE :    MUST BE KEPT CONSISTENT WITH gdb/config/powerpc/tm-ppc-eabi.h
 123  *           (which needs to know where to find the destination address)
 124  */
 125
 126 ENTRY(_longjmp, TAG_NO_FRAME_USED)  /* TODO NMGS - need correct tag */
 127         lwz     r13,    4(ARG0)  /* GPR context. We avoid multiple-word */
 128         lwz     r14,    8(ARG0)  /* instructions as they're slower (?) */
 129         lwz     r15,   12(ARG0)
 130         lwz     r16,   16(ARG0)
 131         lwz     r17,   20(ARG0)
 132         lwz     r18,   24(ARG0)
 133         lwz     r19,   28(ARG0)
 134         lwz     r20,   32(ARG0)
 135         lwz     r21,   36(ARG0)
 136         lwz     r22,   40(ARG0)
 137         lwz     r23,   44(ARG0)
 138         lwz     r24,   48(ARG0)
 139         lwz     r25,   52(ARG0)
 140         lwz     r26,   56(ARG0)
 141         lwz     r27,   60(ARG0)
 142         lwz     r28,   64(ARG0)
 143         lwz     r29,   68(ARG0)
 144         lwz     r30,   72(ARG0)
 145         lwz     r31,   76(ARG0)
 146
 147         lwz     r0,    80(ARG0)  /* Condition register */
 148         mtcr    r0               /* Use r5 as scratch register */
 149
 150         lwz     r0,    84(ARG0)  /* Link register */
 151         mtlr    r0
 152
 153         lwz     r0,    88(ARG0)  /* Fixed point exception register */
 154         mtxer   r0
 155
 156 #ifdef FLOATING_POINT_SUPPORT
 157         lfd     f0,  92-4(ARG0)  /* get Floating point status register in low 32 bits of f0 */
 158         mtfsf    0xFF,f0         /* restore FPSCR */
 159
 160         lfd     f14,   96(ARG0)  /* Floating point context - 8 byte aligned */
 161         lfd     f15,  104(ARG0)
 162         lfd     f16,  112(ARG0)
 163         lfd     f17,  120(ARG0)
 164         lfd     f18,  128(ARG0)
 165         lfd     f19,  136(ARG0)
 166         lfd     f20,  144(ARG0)
 167         lfd     f21,  152(ARG0)
 168         lfd     f22,  160(ARG0)
 169         lfd     f23,  168(ARG0)
 170         lfd     f24,  176(ARG0)
 171         lfd     f25,  184(ARG0)
 172         lfd     f26,  192(ARG0)
 173         lfd     f27,  200(ARG0)
 174         lfd     f28,  208(ARG0)
 175         lfd     f29,  216(ARG0)
 176         lfd     f30,  224(ARG0)
 177         lfd     f31,  232(ARG0)
 178
 179 #endif /* FLOATING_POINT_SUPPORT */
 180
 181
 182         lwz     r1,     0(ARG0)  /* finally, restore the stack pointer */
 183
 184         mr.     ARG0,   ARG1     /* set the return value */
 185         bnelr                    /* return if non-zero */
 186
 187         li      ARG0,   1
 188         blr                     /* never return 0, return 1 instead */
 189