iokit/IOKit/ppc/IOSharedLockImp.h

   1 /*
   2  * Copyright (c) 1998-2000 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_LICENSE_HEADER_START@
   5  *
   6  * The contents of this file constitute Original Code as defined in and
   7  * are subject to the Apple Public Source License Version 1.1 (the
   8  * "License").  You may not use this file except in compliance with the
   9  * License.  Please obtain a copy of the License at
  10  * http://www.apple.com/publicsource and read it before using this file.
  11  *
  12  * This Original Code and all software distributed under the License are
  13  * distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  14  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  15  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  16  * FITNESS FOR A PARTICULAR PURPOSE OR NON-INFRINGEMENT.  Please see the
  17  * License for the specific language governing rights and limitations
  18  * under the License.
  19  *
  20  * @APPLE_LICENSE_HEADER_END@
  21  */
  22 /*
  23  * Copyright (c) 1998 Apple Computer, Inc.  All rights reserved.
  24  *
  25  * HISTORY
  26  *
  27  */
  28
  29 /*      Copyright (c) 1992 NeXT Computer, Inc.  All rights reserved.
  30  *
  31  * EventShmemLock.h -   Shared memory area locks for use between the
  32  *                      WindowServer and the Event Driver.
  33  *
  34  * HISTORY
  35  * 30 Nov   1992    Ben Fathi (benf@next.com)
  36  *      Ported to m98k.
  37  *
  38  * 29 April 1992    Mike Paquette at NeXT
  39  *      Created.
  40  *
  41  * Multiprocessor locks used within the shared memory area between the
  42  * kernel and event system.  These must work in both user and kernel mode.
  43  * The locks are defined in an include file so they get exported to the local
  44  * include file area.
  45  */
  46
  47
  48 #ifndef _IOKIT_IOSHAREDLOCKIMP_H
  49 #define _IOKIT_IOSHAREDLOCKIMP_H
  50
  51 #include <architecture/ppc/asm_help.h>
  52
  53 // 'Till we're building in kernel
  54 .macro DISABLE_PREEMPTION
  55 #ifdef KERNEL
  56 #endif
  57 .endmacro
  58 .macro ENABLE_PREEMPTION
  59 #ifdef KERNEL
  60 #endif
  61 .endmacro
  62
  63 /*
  64  *      void
  65  *      ev_lock(p)
  66  *              register int *p;
  67  *
  68  *      Lock the lock pointed to by p.  Spin (possibly forever) until
  69  *              the lock is available.  Test and test and set logic used.
  70  */
  71         TEXT
  72
  73 #ifndef KERNEL
  74 LEAF(_ev_lock)
  75         li      a6,1                    // lock value
  76         lwarx   a7,0,a0                 // CEMV10
  77 9:
  78         sync
  79         lwarx   a7,0,a0                 // read the lock
  80         cmpwi   cr0,a7,0                // is it busy?
  81         bne-    9b                      // yes, spin
  82         sync
  83         stwcx.  a6,0,a0                 // try to get the lock
  84         bne-    9b                      // failed, try again
  85         isync
  86         blr                             // got it, return
  87 END(_ev_lock)
  88
  89 LEAF(_IOSpinLock)
  90         li      a6,1                    // lock value
  91         lwarx   a7,0,a0                 // CEMV10
  92 9:
  93         sync
  94         lwarx   a7,0,a0                 // read the lock
  95         cmpwi   cr0,a7,0                // is it busy?
  96         bne-    9b                      // yes, spin
  97         sync
  98         stwcx.  a6,0,a0                 // try to get the lock
  99         bne-    9b                      // failed, try again
 100         isync
 101         blr                             // got it, return
 102 END(_IOSpinLock)
 103 #endif
 104
 105 /*
 106  *      void
 107  *      spin_unlock(p)
 108  *              int *p;
 109  *
 110  *      Unlock the lock pointed to by p.
 111  */
 112
 113 LEAF(_ev_unlock)
 114         sync
 115         li      a7,0
 116         stw     a7,0(a0)
 117         ENABLE_PREEMPTION()
 118         blr
 119 END(_ev_unlock)
 120
 121 LEAF(_IOSpinUnlock)
 122         sync
 123         li      a7,0
 124         stw     a7,0(a0)
 125         ENABLE_PREEMPTION()
 126         blr
 127 END(_IOSpinUnlock)
 128
 129
 130 /*
 131  *      ev_try_lock(p)
 132  *              int *p;
 133  *
 134  *      Try to lock p.  Return TRUE if successful in obtaining lock.
 135  */
 136
 137 LEAF(_ev_try_lock)
 138         li      a6,1                    // lock value
 139         DISABLE_PREEMPTION()
 140         lwarx   a7,0,a0                 // CEMV10
 141 8:
 142         sync
 143         lwarx   a7,0,a0                 // read the lock
 144         cmpwi   cr0,a7,0                // is it busy?
 145         bne-    9f                      // yes, give up
 146         sync
 147         stwcx.  a6,0,a0                 // try to get the lock
 148         bne-    8b                      // failed, try again
 149         li      a0,1                    // return TRUE
 150         isync
 151         blr
 152 9:
 153         ENABLE_PREEMPTION()
 154         li      a0,0                    // return FALSE
 155         blr
 156 END(_ev_try_lock)
 157
 158 LEAF(_IOTrySpinLock)
 159         li      a6,1                    // lock value
 160         DISABLE_PREEMPTION()
 161         lwarx   a7,0,a0                 // CEMV10
 162 8:
 163         sync
 164         lwarx   a7,0,a0                 // read the lock
 165         cmpwi   cr0,a7,0                // is it busy?
 166         bne-    9f                      // yes, give up
 167         sync
 168         stwcx.  a6,0,a0                 // try to get the lock
 169         bne-    8b                      // failed, try again
 170         li      a0,1                    // return TRUE
 171         isync
 172         blr
 173 9:
 174         ENABLE_PREEMPTION()
 175         li      a0,0                    // return FALSE
 176         blr
 177 END(_IOTrySpinLock)
 178
 179 #endif /* ! _IOKIT_IOSHAREDLOCKIMP_H */