| | 1 | /* |
| | 2 | * Copyright (c) 2000 Apple Computer, Inc. All rights reserved. |
| | 3 | * |
| | 4 | * @APPLE_OSREFERENCE_LICENSE_HEADER_START@ |
| | 5 | * |
| | 6 | * This file contains Original Code and/or Modifications of Original Code |
| | 7 | * as defined in and that are subject to the Apple Public Source License |
| | 8 | * Version 2.0 (the 'License'). You may not use this file except in |
| | 9 | * compliance with the License. The rights granted to you under the License |
| | 10 | * may not be used to create, or enable the creation or redistribution of, |
| | 11 | * unlawful or unlicensed copies of an Apple operating system, or to |
| | 12 | * circumvent, violate, or enable the circumvention or violation of, any |
| | 13 | * terms of an Apple operating system software license agreement. |
| | 14 | * |
| | 15 | * Please obtain a copy of the License at |
| | 16 | * http://www.opensource.apple.com/apsl/ and read it before using this file. |
| | 17 | * |
| | 18 | * The Original Code and all software distributed under the License are |
| | 19 | * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER |
| | 20 | * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES, |
| | 21 | * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY, |
| | 22 | * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT. |
| | 23 | * Please see the License for the specific language governing rights and |
| | 24 | * limitations under the License. |
| | 25 | * |
| | 26 | * @APPLE_OSREFERENCE_LICENSE_HEADER_END@ |
| | 27 | */ |
| | 28 | /* |
| | 29 | * @OSF_COPYRIGHT@ |
| | 30 | */ |
| | 31 | /* |
| | 32 | * Mach Operating System |
| | 33 | * Copyright (c) 1991,1990 Carnegie Mellon University |
| | 34 | * All Rights Reserved. |
| | 35 | * |
| | 36 | * Permission to use, copy, modify and distribute this software and its |
| | 37 | * documentation is hereby granted, provided that both the copyright |
| | 38 | * notice and this permission notice appear in all copies of the |
| | 39 | * software, derivative works or modified versions, and any portions |
| | 40 | * thereof, and that both notices appear in supporting documentation. |
| | 41 | * |
| | 42 | * CARNEGIE MELLON ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS" |
| | 43 | * CONDITION. CARNEGIE MELLON DISCLAIMS ANY LIABILITY OF ANY KIND FOR |
| | 44 | * ANY DAMAGES WHATSOEVER RESULTING FROM THE USE OF THIS SOFTWARE. |
| | 45 | * |
| | 46 | * Carnegie Mellon requests users of this software to return to |
| | 47 | * |
| | 48 | * Software Distribution Coordinator or Software.Distribution@CS.CMU.EDU |
| | 49 | * School of Computer Science |
| | 50 | * Carnegie Mellon University |
| | 51 | * Pittsburgh PA 15213-3890 |
| | 52 | * |
| | 53 | * any improvements or extensions that they make and grant Carnegie Mellon |
| | 54 | * the rights to redistribute these changes. |
| | 55 | */ |
| | 56 | /* |
| | 57 | */ |
| | 58 | |
| | 59 | #include <i386/asm.h> |
| | 60 | |
| | 61 | /* void *memcpy((void *) to, (const void *) from, (size_t) bcount) */ |
| | 62 | |
| | 63 | ENTRY(memcpy) |
| | 64 | pushl %edi |
| | 65 | pushl %esi |
| | 66 | movl 8+ 4(%esp),%edi /* to */ |
| | 67 | movl %edi,%eax /* returns its first argument */ |
| | 68 | movl 8+ 8(%esp),%esi /* from */ |
| | 69 | memcpy_common: |
| | 70 | movl 8+ 12(%esp),%edx /* number of bytes */ |
| | 71 | cld |
| | 72 | /* move longs*/ |
| | 73 | movl %edx,%ecx |
| | 74 | shrl $2,%ecx |
| | 75 | rep |
| | 76 | movsl |
| | 77 | /* move bytes*/ |
| | 78 | movl %edx,%ecx |
| | 79 | andl $3,%ecx |
| | 80 | rep |
| | 81 | movsb |
| | 82 | popl %esi |
| | 83 | popl %edi |
| | 84 | ret |
| | 85 | |
| | 86 | /* void bcopy((const char *) from, (char *) to, (unsigned int) count) */ |
| | 87 | |
| | 88 | ENTRY(bcopy_no_overwrite) |
| | 89 | pushl %edi |
| | 90 | pushl %esi |
| | 91 | movl 8+ 8(%esp),%edi /* to */ |
| | 92 | movl 8+ 4(%esp),%esi /* from */ |
| | 93 | jmp memcpy_common |
| | 94 | |
| | 95 | /* bcopy16(from, to, bcount) using word moves */ |
| | 96 | |
| | 97 | ENTRY(bcopy16) |
| | 98 | pushl %edi |
| | 99 | pushl %esi |
| | 100 | movl 8+12(%esp),%edx /* 8 for the two pushes above */ |
| | 101 | movl 8+ 8(%esp),%edi |
| | 102 | movl 8+ 4(%esp),%esi |
| | 103 | /* move words */ |
| | 104 | 0: cld |
| | 105 | movl %edx,%ecx |
| | 106 | shrl $1,%ecx |
| | 107 | rep |
| | 108 | movsw |
| | 109 | /* move bytes */ |
| | 110 | movl %edx,%ecx |
| | 111 | andl $1,%ecx |
| | 112 | rep |
| | 113 | movsb |
| | 114 | popl %esi |
| | 115 | popl %edi |
| | 116 | ret |
| | 117 | |
| | 118 | |
| | 119 | /* |
| | 120 | * Based on NetBSD's bcopy.S from their libc. |
| | 121 | * bcopy(src, dst, cnt) |
| | 122 | * ws@tools.de (Wolfgang Solfrank, TooLs GmbH) +49-228-985800 |
| | 123 | */ |
| | 124 | ENTRY(bcopy) |
| | 125 | pushl %esi |
| | 126 | pushl %edi |
| | 127 | movl 12(%esp),%esi |
| | 128 | movl 16(%esp),%edi |
| | 129 | movl 20(%esp),%ecx |
| | 130 | |
| | 131 | movl %edi,%edx |
| | 132 | subl %esi,%edx |
| | 133 | cmpl %ecx,%edx /* overlapping && src < dst? */ |
| | 134 | movl %ecx,%edx |
| | 135 | jb 1f |
| | 136 | |
| | 137 | shrl $2,%ecx /* copy by 32-bit words */ |
| | 138 | cld /* nope, copy forwards */ |
| | 139 | rep |
| | 140 | movsl |
| | 141 | movl %edx,%ecx |
| | 142 | andl $3,%ecx /* any bytes left? */ |
| | 143 | rep |
| | 144 | movsb |
| | 145 | popl %edi |
| | 146 | popl %esi |
| | 147 | ret |
| | 148 | |
| | 149 | |
| | 150 | 1: |
| | 151 | addl %ecx,%edi /* copy backwards */ |
| | 152 | addl %ecx,%esi |
| | 153 | decl %edi |
| | 154 | decl %esi |
| | 155 | andl $3,%ecx /* any fractional bytes? */ |
| | 156 | std |
| | 157 | rep |
| | 158 | movsb |
| | 159 | movl %edx,%ecx /* copy remainder by 32-bit words */ |
| | 160 | shrl $2,%ecx |
| | 161 | subl $3,%esi |
| | 162 | subl $3,%edi |
| | 163 | rep |
| | 164 | movsl |
| | 165 | popl %edi |
| | 166 | popl %esi |
| | 167 | cld |
| | 168 | ret |
projects / apple / xnu.git / blame_incremental