git.saurik.com Git - apple/xnu.git/blame_incremental

... / ...

Commit	Line	Data
	1	/*
	2	* Copyright (c) 1999-2007 Apple Inc. All rights reserved.
	3	*
	4	* @APPLE_OSREFERENCE_LICENSE_HEADER_START@
	5	*
	6	* This file contains Original Code and/or Modifications of Original Code
	7	* as defined in and that are subject to the Apple Public Source License
	8	* Version 2.0 (the 'License'). You may not use this file except in
	9	* compliance with the License. The rights granted to you under the License
	10	* may not be used to create, or enable the creation or redistribution of,
	11	* unlawful or unlicensed copies of an Apple operating system, or to
	12	* circumvent, violate, or enable the circumvention or violation of, any
	13	* terms of an Apple operating system software license agreement.
	14	*
	15	* Please obtain a copy of the License at
	16	* http://www.opensource.apple.com/apsl/ and read it before using this file.
	17	*
	18	* The Original Code and all software distributed under the License are
	19	* distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
	20	* EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
	21	* INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
	22	* FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
	23	* Please see the License for the specific language governing rights and
	24	* limitations under the License.
	25	*
	26	* @APPLE_OSREFERENCE_LICENSE_HEADER_END@
	27	*/
	28
	29	#include "SYS.h"
	30
	31	#if defined(__ppc__) \|\| defined(__ppc64__)
	32
	33	.data
	34	.globl __current_pid
	35	.align 2
	36	__current_pid:
	37	.long 0
	38
	39	MI_ENTRY_POINT(___getpid)
	40	#if defined(__DYNAMIC__)
	41	mflr r0 // note we cannot use MI_GET_ADDRESS...
	42	bcl 20,31,1f // ...because we define __current_pid
	43	1:
	44	mflr r5
	45	mtlr r0
	46	addis r5, r5, ha16(__current_pid - 1b)
	47	addi r5, r5, lo16(__current_pid - 1b)
	48	#else
	49	lis r5,hi16(__current_pid)
	50	ori r5,r5,lo16(__current_pid)
	51	#endif
	52	lwz r3,0(r5) // get the cached pid
	53	cmpwi r3,0 // if positive,
	54	bgtlr++ // return it
	55
	56	SYSCALL_NONAME(getpid, 0)
	57
	58	lwarx r4,0,r5 // see if we can cache it
	59	cmpwi r4,0 // we can't if there are any...
	60	blt-- 1f // ...vforks in progress
	61
	62	stwcx. r3,0,r5 // ignore cache conflicts
	63	blr
	64	1:
	65	li r6,-4 // on 970, cancel the reservation using red zone...
	66	stwcx. r3,r6,r1 // ...to avoid an errata
	67	blr
	68
	69	#elif defined(__i386__)
	70
	71	.data
	72	.private_extern __current_pid
	73	__current_pid:
	74	.long 0
	75	L__current_pid_addr = __current_pid
	76
	77	#if defined(__DYNAMIC__)
	78	#define GET_CURRENT_PID \
	79	call 0f ; \
	80	0: ; \
	81	popl %ecx ; \
	82	leal L__current_pid_addr-0b(%ecx), %ecx
	83
	84	#define __current_pid (%ecx)
	85
	86	#else
	87	#define GET_CURRENT_PID
	88	#endif
	89
	90	/*
	91	* If __current_pid is > 0, return it, else make syscall.
	92	* If __current_pid is 0, cache result of syscall.
	93	*/
	94	TEXT
	95	LEAF(___getpid, 0)
	96	GET_CURRENT_PID
	97	movl __current_pid, %eax
	98	testl %eax, %eax
	99	jle 1f
	100	ret
	101	1:
	102	UNIX_SYSCALL_NONAME(getpid, 0)
	103	movl %eax, %edx
	104	xorl %eax, %eax
	105	GET_CURRENT_PID
	106	lock
	107	cmpxchgl %edx, __current_pid
	108	movl %edx, %eax
	109	ret
	110
	111	#elif defined(__x86_64__)
	112
	113	.data
	114	.private_extern __current_pid
	115	__current_pid:
	116	.long 0
	117
	118	/*
	119	* If __current_pid is > 0, return it, else make syscall.
	120	* If __current_pid is 0, cache result of syscall.
	121	*/
	122	TEXT
	123	LEAF(___getpid, 0)
	124	movl __current_pid(%rip), %eax
	125	testl %eax, %eax
	126	jle 1f
	127	ret
	128	1:
	129	UNIX_SYSCALL_NONAME(getpid, 0)
	130	movl %eax, %edx
	131	xorl %eax, %eax
	132	leaq __current_pid(%rip), %rcx
	133	lock
	134	cmpxchgl %edx, (%rcx)
	135	movl %edx, %eax
	136	ret
	137
	138	#elif defined(__arm__)
	139
	140	#include <arm/arch.h>
	141
	142	.data
	143	.globl __current_pid
	144	.align 2
	145	__current_pid:
	146	/* Cached pid. Possible values:
	147	* 0: no value cached
	148	* > 0: cached PID of current process
	149	* < 0: negative number of vforks in progress
	150	* INT_MIN: for pre-ARMv6, "looking" value (0x80000000)
	151	*/
	152	.long 0
	153
	154	MI_ENTRY_POINT(_getpid)
	155	ldr r3, L__current_pid
	156	L1: add r3, pc, r3 // r3 = &__current_pid
	157	ldr r0, [r3] // get the cached pid
	158	cmp r0, #0
	159	bxgt lr // if positive, return it
	160
	161	SYSCALL_NONAME(getpid, 0)
	162
	163	#ifdef _ARM_ARCH_6
	164	ldrex r2, [r3] // see if we can cache it
	165	cmp r2, #0 // we can't if there are any...
	166	bxlt lr // ...vforks in progress
	167	strex r2, r0, [r3] // ignore conflicts
	168	#else
	169	mov r1, #0x80000000 // load "looking" value
	170	swp r2, r1, [r3] // look at the value, lock others out
	171	cmp r2, r1 // anyone else trying to look?
	172	bxeq lr // yes, so return immediately/
	173	cmp r2, #0 // see if we can cache it
	174	streq r0, [r3] // if zero, we can
	175	strne r2, [r3] // otherwise restore previous value
	176	#endif
	177
	178	bx lr
	179
	180	L__current_pid:
	181	.long __current_pid - (L1+8)
	182
	183	#else
	184	#error Unsupported architecture
	185	#endif