[apple/xnu.git] / libsyscall / custom / __getpid.s

/*
 * Copyright (c) 1999-2007 Apple Inc. All rights reserved.
 *
 * @APPLE_OSREFERENCE_LICENSE_HEADER_START@
 * 
 * This file contains Original Code and/or Modifications of Original Code
 * as defined in and that are subject to the Apple Public Source License
 * Version 2.0 (the 'License'). You may not use this file except in
 * compliance with the License. The rights granted to you under the License
 * may not be used to create, or enable the creation or redistribution of,
 * unlawful or unlicensed copies of an Apple operating system, or to
 * circumvent, violate, or enable the circumvention or violation of, any
 * terms of an Apple operating system software license agreement.
 * 
 * Please obtain a copy of the License at
 * http://www.opensource.apple.com/apsl/ and read it before using this file.
 * 
 * The Original Code and all software distributed under the License are
 * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
 * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
 * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
 * Please see the License for the specific language governing rights and
 * limitations under the License.
 * 
 * @APPLE_OSREFERENCE_LICENSE_HEADER_END@
 */

#include "SYS.h"

#if defined(__i386__)

	.data
	.private_extern __current_pid
L__current_pid_addr:
 __current_pid:
	.long 0

#if defined(__DYNAMIC__)
#define GET_CURRENT_PID				\
	call	0f				; \
0:						; \
	popl	%ecx				; \
	leal	L__current_pid_addr-0b(%ecx), %ecx

#define __current_pid (%ecx)

#else
#define GET_CURRENT_PID
#endif

/*
 * If __current_pid is > 0, return it, else make syscall.
 * If __current_pid is 0, cache result of syscall.
 */
TEXT
LEAF(___getpid, 0)
	GET_CURRENT_PID
	movl		__current_pid, %eax
	testl		%eax, %eax
	jle		1f
	ret
1:
	UNIX_SYSCALL_NONAME(getpid, 0, cerror_nocancel)
	movl		%eax, %edx
	xorl		%eax, %eax
	GET_CURRENT_PID
	lock
	cmpxchgl	%edx, __current_pid
	movl		%edx, %eax
	ret

#elif defined(__x86_64__)

	.data
	.private_extern __current_pid
__current_pid:
	.long 0

/*
 * If __current_pid is > 0, return it, else make syscall.
 * If __current_pid is 0, cache result of syscall.
 */
TEXT
LEAF(___getpid, 0)
	movl	__current_pid(%rip), %eax
	testl	%eax, %eax
	jle		1f
	ret
1:
	UNIX_SYSCALL_NONAME(getpid, 0, cerror_nocancel)
	movl		%eax, %edx
	xorl		%eax, %eax
	leaq		__current_pid(%rip), %rcx
	lock
	cmpxchgl	%edx, (%rcx)
	movl		%edx, %eax
	ret

#elif defined(__arm__)

#include <arm/arch.h>
	
	.data
	.globl	__current_pid
	.align 2
__current_pid:
	/* Cached pid.  Possible values:
	 *	0:		no value cached
	 *	> 0:		cached PID of current process
	 *	< 0:		negative number of vforks in progress
	 *	INT_MIN:	for pre-ARMv6, "looking" value (0x80000000)
	 */
	.long 0

MI_ENTRY_POINT(___getpid)
	ldr	r3, L__current_pid
L1:	add	r3, pc, r3		// r3 = &__current_pid
	ldr	r0, [r3]		// get the cached pid
	cmp	r0, #0
	bxgt	lr			// if positive, return it

	SYSCALL_NONAME(getpid, 0, cerror_nocancel)

#ifdef _ARM_ARCH_6
	ldrex	r2, [r3]		// see if we can cache it
	cmp	r2, #0			// we can't if there are any...
	bxlt	lr			// ...vforks in progress
	strex	r2, r0, [r3]		// ignore conflicts
#else
	mov	r1, #0x80000000		// load "looking" value
	swp	r2, r1, [r3]		// look at the value, lock others out
	cmp	r2, r1			// anyone else trying to look?
	bxeq	lr			// yes, so return immediately/	
	cmp	r2, #0			// see if we can cache it
	streq	r0, [r3]		// if zero, we can
	strne	r2, [r3]		// otherwise restore previous value
#endif
		
	bx	lr
				
L__current_pid:	
	.long	__current_pid - (L1+8)		

#elif defined(__arm64__)
	.data
	.globl	__current_pid
	.align 2
__current_pid:
	/* cached pid.  possible values:
	 *	0:		no value cached
	 *	> 0:		cached pid of current process
	 *	< 0:		negative number of vforks in progress
	 *	int_min:	for pre-armv6, "looking" value (0x80000000)
	 */
	.long 0

MI_ENTRY_POINT(___getpid)
	MI_GET_ADDRESS(x9, __current_pid)	// Get address of cached value
	ldr		w0, [x9]					// Load it
	cmp		w0, #0						// See if there's a cached value
	b.le	L_notcached					// If not, make syscall
	ret									// Else, we're done
L_notcached:
	SYSCALL_NONAME(getpid, 0, cerror_nocancel)
	ldxr	w10, [x9]					// Exclusive load
	cbnz	w10, L_done					// Unless unset, don't even try
	stxr	wzr, w0, [x9]				// Try to store, but don't care if we fail (someone will win, or not)
L_done:
	ret									// Done
#else
#error Unsupported architecture
#endif
Commit	Line	Data
2d21ac55 A	1	/*
	2	* Copyright (c) 1999-2007 Apple Inc. All rights reserved.
	3	*
	4	* @APPLE_OSREFERENCE_LICENSE_HEADER_START@
	5	*
	6	* This file contains Original Code and/or Modifications of Original Code
	7	* as defined in and that are subject to the Apple Public Source License
	8	* Version 2.0 (the 'License'). You may not use this file except in
	9	* compliance with the License. The rights granted to you under the License
	10	* may not be used to create, or enable the creation or redistribution of,
	11	* unlawful or unlicensed copies of an Apple operating system, or to
	12	* circumvent, violate, or enable the circumvention or violation of, any
	13	* terms of an Apple operating system software license agreement.
	14	*
	15	* Please obtain a copy of the License at
	16	* http://www.opensource.apple.com/apsl/ and read it before using this file.
	17	*
	18	* The Original Code and all software distributed under the License are
	19	* distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
	20	* EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
	21	* INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
	22	* FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
	23	* Please see the License for the specific language governing rights and
	24	* limitations under the License.
	25	*
	26	* @APPLE_OSREFERENCE_LICENSE_HEADER_END@
	27	*/
	28
	29	#include "SYS.h"
	30
6d2010ae	31	#if defined(__i386__)
2d21ac55 A	32
	33	.data
	34	.private_extern __current_pid
316670eb A	35	L__current_pid_addr:
316670eb A	36	__current_pid:
2d21ac55	37	.long 0
2d21ac55 A	38
	39	#if defined(__DYNAMIC__)
	40	#define GET_CURRENT_PID \
	41	call 0f ; \
	42	0: ; \
	43	popl %ecx ; \
	44	leal L__current_pid_addr-0b(%ecx), %ecx
	45
	46	#define __current_pid (%ecx)
	47
	48	#else
	49	#define GET_CURRENT_PID
	50	#endif
	51
	52	/*
	53	* If __current_pid is > 0, return it, else make syscall.
	54	* If __current_pid is 0, cache result of syscall.
	55	*/
	56	TEXT
	57	LEAF(___getpid, 0)
	58	GET_CURRENT_PID
	59	movl __current_pid, %eax
	60	testl %eax, %eax
	61	jle 1f
	62	ret
	63	1:
316670eb	64	UNIX_SYSCALL_NONAME(getpid, 0, cerror_nocancel)
2d21ac55 A	65	movl %eax, %edx
	66	xorl %eax, %eax
	67	GET_CURRENT_PID
	68	lock
	69	cmpxchgl %edx, __current_pid
	70	movl %edx, %eax
	71	ret
	72
	73	#elif defined(__x86_64__)
	74
	75	.data
	76	.private_extern __current_pid
	77	__current_pid:
	78	.long 0
	79
	80	/*
	81	* If __current_pid is > 0, return it, else make syscall.
	82	* If __current_pid is 0, cache result of syscall.
	83	*/
	84	TEXT
	85	LEAF(___getpid, 0)
	86	movl __current_pid(%rip), %eax
	87	testl %eax, %eax
	88	jle 1f
	89	ret
	90	1:
316670eb	91	UNIX_SYSCALL_NONAME(getpid, 0, cerror_nocancel)
2d21ac55 A	92	movl %eax, %edx
	93	xorl %eax, %eax
	94	leaq __current_pid(%rip), %rcx
	95	lock
	96	cmpxchgl %edx, (%rcx)
	97	movl %edx, %eax
	98	ret
	99
5ba3f43e A	100	#elif defined(__arm__)
	101
	102	#include <arm/arch.h>
	103
	104	.data
	105	.globl __current_pid
	106	.align 2
	107	__current_pid:
	108	/* Cached pid. Possible values:
	109	* 0: no value cached
	110	* > 0: cached PID of current process
	111	* < 0: negative number of vforks in progress
	112	* INT_MIN: for pre-ARMv6, "looking" value (0x80000000)
	113	*/
	114	.long 0
	115
	116	MI_ENTRY_POINT(___getpid)
	117	ldr r3, L__current_pid
	118	L1: add r3, pc, r3 // r3 = &__current_pid
	119	ldr r0, [r3] // get the cached pid
	120	cmp r0, #0
	121	bxgt lr // if positive, return it
	122
	123	SYSCALL_NONAME(getpid, 0, cerror_nocancel)
	124
	125	#ifdef _ARM_ARCH_6
	126	ldrex r2, [r3] // see if we can cache it
	127	cmp r2, #0 // we can't if there are any...
	128	bxlt lr // ...vforks in progress
	129	strex r2, r0, [r3] // ignore conflicts
	130	#else
	131	mov r1, #0x80000000 // load "looking" value
	132	swp r2, r1, [r3] // look at the value, lock others out
	133	cmp r2, r1 // anyone else trying to look?
	134	bxeq lr // yes, so return immediately/
	135	cmp r2, #0 // see if we can cache it
	136	streq r0, [r3] // if zero, we can
	137	strne r2, [r3] // otherwise restore previous value
	138	#endif
	139
	140	bx lr
	141
	142	L__current_pid:
	143	.long __current_pid - (L1+8)
	144
	145	#elif defined(__arm64__)
	146	.data
	147	.globl __current_pid
	148	.align 2
	149	__current_pid:
	150	/* cached pid. possible values:
	151	* 0: no value cached
	152	* > 0: cached pid of current process
	153	* < 0: negative number of vforks in progress
	154	* int_min: for pre-armv6, "looking" value (0x80000000)
	155	*/
	156	.long 0
	157
	158	MI_ENTRY_POINT(___getpid)
	159	MI_GET_ADDRESS(x9, __current_pid) // Get address of cached value
	160	ldr w0, [x9] // Load it
	161	cmp w0, #0 // See if there's a cached value
d9a64523	162	b.le L_notcached // If not, make syscall
5ba3f43e A	163	ret // Else, we're done
	164	L_notcached:
	165	SYSCALL_NONAME(getpid, 0, cerror_nocancel)
	166	ldxr w10, [x9] // Exclusive load
	167	cbnz w10, L_done // Unless unset, don't even try
	168	stxr wzr, w0, [x9] // Try to store, but don't care if we fail (someone will win, or not)
	169	L_done:
	170	ret // Done
2d21ac55 A	171	#else
	172	#error Unsupported architecture
	173	#endif