[apple/xnu.git] / osfmk / x86_64 / cswitch.s

/*
 * Copyright (c) 2000-2006 Apple Computer, Inc. All rights reserved.
 *
 * @APPLE_OSREFERENCE_LICENSE_HEADER_START@
 * 
 * This file contains Original Code and/or Modifications of Original Code
 * as defined in and that are subject to the Apple Public Source License
 * Version 2.0 (the 'License'). You may not use this file except in
 * compliance with the License. The rights granted to you under the License
 * may not be used to create, or enable the creation or redistribution of,
 * unlawful or unlicensed copies of an Apple operating system, or to
 * circumvent, violate, or enable the circumvention or violation of, any
 * terms of an Apple operating system software license agreement.
 * 
 * Please obtain a copy of the License at
 * http://www.opensource.apple.com/apsl/ and read it before using this file.
 * 
 * The Original Code and all software distributed under the License are
 * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
 * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
 * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
 * Please see the License for the specific language governing rights and
 * limitations under the License.
 * 
 * @APPLE_OSREFERENCE_LICENSE_HEADER_END@
 */
/*
 * @OSF_COPYRIGHT@
 */
/* 
 * Mach Operating System
 * Copyright (c) 1991,1990 Carnegie Mellon University
 * All Rights Reserved.
 * 
 * Permission to use, copy, modify and distribute this software and its
 * documentation is hereby granted, provided that both the copyright
 * notice and this permission notice appear in all copies of the
 * software, derivative works or modified versions, and any portions
 * thereof, and that both notices appear in supporting documentation.
 * 
 * CARNEGIE MELLON ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS"
 * CONDITION.  CARNEGIE MELLON DISCLAIMS ANY LIABILITY OF ANY KIND FOR
 * ANY DAMAGES WHATSOEVER RESULTING FROM THE USE OF THIS SOFTWARE.
 * 
 * Carnegie Mellon requests users of this software to return to
 * 
 *  Software Distribution Coordinator  or  Software.Distribution@CS.CMU.EDU
 *  School of Computer Science
 *  Carnegie Mellon University
 *  Pittsburgh PA 15213-3890
 * 
 * any improvements or extensions that they make and grant Carnegie Mellon
 * the rights to redistribute these changes.
 */
/*
 */


#include <i386/asm.h>
#include <i386/proc_reg.h>
#include <assym.s>

Entry(Load_context)
	movq	TH_KERNEL_STACK(%rdi),%rcx	/* get kernel stack */
	leaq	-IKS_SIZE(%rcx),%rdx
	addq	EXT(kernel_stack_size)(%rip),%rdx /* point to stack top */
	movq	%rcx,%gs:CPU_ACTIVE_STACK	/* store stack address */
	movq	%rdx,%gs:CPU_KERNEL_STACK	/* store stack top */

	movq	%rdx,%rsp
	xorl	%ebp, %ebp

	xorl	%edi,%edi			/* return zero (no old thread) */
	call	EXT(thread_continue)


/*
 * thread_t Switch_context(
 *		thread_t old,				// %rsi
 *		thread_continue_t continuation,		// %rdi
 *		thread_t new)				// %rdx
 */
Entry(Switch_context)
	popq	%rax				/* pop return PC */

	/* Test for a continuation and skip all state saving if so... */
	cmpq	$0, %rsi
	jne 	5f
	movq	%gs:CPU_KERNEL_STACK,%rcx	/* get old kernel stack top */
	movq	%rbx,KSS_RBX(%rcx)		/* save registers */
	movq	%rbp,KSS_RBP(%rcx)
	movq	%r12,KSS_R12(%rcx)
	movq	%r13,KSS_R13(%rcx)
	movq	%r14,KSS_R14(%rcx)
	movq	%r15,KSS_R15(%rcx)
	movq	%rax,KSS_RIP(%rcx)		/* save return PC */
	movq	%rsp,KSS_RSP(%rcx)		/* save SP */
5:
	movq	%rdi,%rax			/* return old thread */
	/* new thread in %rdx */
	movq    %rdx,%gs:CPU_ACTIVE_THREAD      /* new thread is active */
	movq	TH_KERNEL_STACK(%rdx),%rdx	/* get its kernel stack */
	lea	-IKS_SIZE(%rdx),%rcx
	add	EXT(kernel_stack_size)(%rip),%rcx /* point to stack top */

	movq	%rdx,%gs:CPU_ACTIVE_STACK	/* set current stack */
	movq	%rcx,%gs:CPU_KERNEL_STACK	/* set stack top */

	movq	KSS_RSP(%rcx),%rsp		/* switch stacks */
	movq	KSS_RBX(%rcx),%rbx		/* restore registers */
	movq	KSS_RBP(%rcx),%rbp
	movq	KSS_R12(%rcx),%r12
	movq	KSS_R13(%rcx),%r13
	movq	KSS_R14(%rcx),%r14
	movq	KSS_R15(%rcx),%r15
	jmp	*KSS_RIP(%rcx)			/* return old thread */


Entry(Thread_continue)
	movq	%rax, %rdi			/* load thread argument */
	xorq	%rbp,%rbp			/* zero frame pointer */
	call	*%rbx				/* call real continuation */


/*
 * thread_t Shutdown_context(
 *		thread_t thread,		// %rdi
 *		void (*routine)(processor_t),	// %rsi
 *		processor_t processor)		// %rdx
 *
 * saves the kernel context of the thread,
 * switches to the interrupt stack,
 * continues the thread (with thread_continue),
 * then runs routine on the interrupt stack.
 *
 */
Entry(Shutdown_context)
	movq	%gs:CPU_KERNEL_STACK,%rcx	/* get old kernel stack top */
	movq	%rbx,KSS_RBX(%rcx)		/* save registers */
	movq	%rbp,KSS_RBP(%rcx)
	movq	%r12,KSS_R12(%rcx)
	movq	%r13,KSS_R13(%rcx)
	movq	%r14,KSS_R14(%rcx)
	movq	%r15,KSS_R15(%rcx)
	popq	KSS_RIP(%rcx)			/* save return PC */
	movq	%rsp,KSS_RSP(%rcx)		/* save SP */

	movq	%gs:CPU_ACTIVE_STACK,%rcx	/* get old kernel stack */
	movq	%rdi,%rax			/* get old thread */
	movq	%rcx,TH_KERNEL_STACK(%rax)	/* save old stack */

	movq	%gs:CPU_INT_STACK_TOP,%rsp 	/* switch to interrupt stack */

	movq	%rsp, %gs:CPU_ACTIVE_STACK
	movq	EXT(kernel_stack_size)(%rip),%rcx /* point to stack top */
	subq	%rcx, %gs:CPU_ACTIVE_STACK
	movq	%rdx,%rdi			/* processor arg to routine */
	call	*%rsi				/* call routine to run */
	hlt					/* (should never return) */
Commit	Line	Data
b0d623f7 A	1	/*
	2	* Copyright (c) 2000-2006 Apple Computer, Inc. All rights reserved.
	3	*
	4	* @APPLE_OSREFERENCE_LICENSE_HEADER_START@
	5	*
	6	* This file contains Original Code and/or Modifications of Original Code
	7	* as defined in and that are subject to the Apple Public Source License
	8	* Version 2.0 (the 'License'). You may not use this file except in
	9	* compliance with the License. The rights granted to you under the License
	10	* may not be used to create, or enable the creation or redistribution of,
	11	* unlawful or unlicensed copies of an Apple operating system, or to
	12	* circumvent, violate, or enable the circumvention or violation of, any
	13	* terms of an Apple operating system software license agreement.
	14	*
	15	* Please obtain a copy of the License at
	16	* http://www.opensource.apple.com/apsl/ and read it before using this file.
	17	*
	18	* The Original Code and all software distributed under the License are
	19	* distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
	20	* EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
	21	* INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
	22	* FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
	23	* Please see the License for the specific language governing rights and
	24	* limitations under the License.
	25	*
	26	* @APPLE_OSREFERENCE_LICENSE_HEADER_END@
	27	*/
	28	/*
	29	* @OSF_COPYRIGHT@
	30	*/
	31	/*
	32	* Mach Operating System
	33	* Copyright (c) 1991,1990 Carnegie Mellon University
	34	* All Rights Reserved.
	35	*
	36	* Permission to use, copy, modify and distribute this software and its
	37	* documentation is hereby granted, provided that both the copyright
	38	* notice and this permission notice appear in all copies of the
	39	* software, derivative works or modified versions, and any portions
	40	* thereof, and that both notices appear in supporting documentation.
	41	*
	42	* CARNEGIE MELLON ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS"
	43	* CONDITION. CARNEGIE MELLON DISCLAIMS ANY LIABILITY OF ANY KIND FOR
	44	* ANY DAMAGES WHATSOEVER RESULTING FROM THE USE OF THIS SOFTWARE.
	45	*
	46	* Carnegie Mellon requests users of this software to return to
	47	*
	48	* Software Distribution Coordinator or Software.Distribution@CS.CMU.EDU
	49	* School of Computer Science
	50	* Carnegie Mellon University
	51	* Pittsburgh PA 15213-3890
	52	*
	53	* any improvements or extensions that they make and grant Carnegie Mellon
	54	* the rights to redistribute these changes.
	55	*/
	56	/*
	57	*/
	58
b0d623f7 A	59
	60	#include <i386/asm.h>
	61	#include <i386/proc_reg.h>
6d2010ae	62	#include <assym.s>
b0d623f7 A	63
	64	Entry(Load_context)
	65	movq TH_KERNEL_STACK(%rdi),%rcx /* get kernel stack */
6d2010ae	66	leaq -IKS_SIZE(%rcx),%rdx
b0d623f7 A	67	addq EXT(kernel_stack_size)(%rip),%rdx /* point to stack top */
	68	movq %rcx,%gs:CPU_ACTIVE_STACK /* store stack address */
	69	movq %rdx,%gs:CPU_KERNEL_STACK /* store stack top */
	70
	71	movq %rdx,%rsp
39037602	72	xorl %ebp, %ebp
b0d623f7	73
39037602	74	xorl %edi,%edi /* return zero (no old thread) */
b0d623f7 A	75	call EXT(thread_continue)
	76
	77
	78	/*
	79	* thread_t Switch_context(
	80	* thread_t old, // %rsi
	81	* thread_continue_t continuation, // %rdi
	82	* thread_t new) // %rdx
	83	*/
	84	Entry(Switch_context)
	85	popq %rax /* pop return PC */
	86
	87	/* Test for a continuation and skip all state saving if so... */
	88	cmpq $0, %rsi
	89	jne 5f
	90	movq %gs:CPU_KERNEL_STACK,%rcx /* get old kernel stack top */
	91	movq %rbx,KSS_RBX(%rcx) /* save registers */
	92	movq %rbp,KSS_RBP(%rcx)
	93	movq %r12,KSS_R12(%rcx)
	94	movq %r13,KSS_R13(%rcx)
	95	movq %r14,KSS_R14(%rcx)
	96	movq %r15,KSS_R15(%rcx)
	97	movq %rax,KSS_RIP(%rcx) /* save return PC */
	98	movq %rsp,KSS_RSP(%rcx) /* save SP */
	99	5:
	100	movq %rdi,%rax /* return old thread */
	101	/* new thread in %rdx */
	102	movq %rdx,%gs:CPU_ACTIVE_THREAD /* new thread is active */
	103	movq TH_KERNEL_STACK(%rdx),%rdx /* get its kernel stack */
6d2010ae	104	lea -IKS_SIZE(%rdx),%rcx
b0d623f7 A	105	add EXT(kernel_stack_size)(%rip),%rcx /* point to stack top */
	106
	107	movq %rdx,%gs:CPU_ACTIVE_STACK /* set current stack */
	108	movq %rcx,%gs:CPU_KERNEL_STACK /* set stack top */
	109
	110	movq KSS_RSP(%rcx),%rsp /* switch stacks */
	111	movq KSS_RBX(%rcx),%rbx /* restore registers */
	112	movq KSS_RBP(%rcx),%rbp
	113	movq KSS_R12(%rcx),%r12
	114	movq KSS_R13(%rcx),%r13
	115	movq KSS_R14(%rcx),%r14
	116	movq KSS_R15(%rcx),%r15
	117	jmp KSS_RIP(%rcx) / return old thread */
	118
	119
	120	Entry(Thread_continue)
	121	movq %rax, %rdi /* load thread argument */
	122	xorq %rbp,%rbp /* zero frame pointer */
	123	call %rbx / call real continuation */
	124
	125
	126	/*
	127	* thread_t Shutdown_context(
	128	* thread_t thread, // %rdi
	129	* void (*routine)(processor_t), // %rsi
	130	* processor_t processor) // %rdx
	131	*
	132	* saves the kernel context of the thread,
	133	* switches to the interrupt stack,
	134	* continues the thread (with thread_continue),
	135	* then runs routine on the interrupt stack.
	136	*
	137	*/
	138	Entry(Shutdown_context)
	139	movq %gs:CPU_KERNEL_STACK,%rcx /* get old kernel stack top */
	140	movq %rbx,KSS_RBX(%rcx) /* save registers */
	141	movq %rbp,KSS_RBP(%rcx)
	142	movq %r12,KSS_R12(%rcx)
	143	movq %r13,KSS_R13(%rcx)
	144	movq %r14,KSS_R14(%rcx)
	145	movq %r15,KSS_R15(%rcx)
	146	popq KSS_RIP(%rcx) /* save return PC */
	147	movq %rsp,KSS_RSP(%rcx) /* save SP */
	148
	149	movq %gs:CPU_ACTIVE_STACK,%rcx /* get old kernel stack */
	150	movq %rdi,%rax /* get old thread */
	151	movq %rcx,TH_KERNEL_STACK(%rax) /* save old stack */
	152
	153	movq %gs:CPU_INT_STACK_TOP,%rsp /* switch to interrupt stack */
	154
39037602 A	155	movq %rsp, %gs:CPU_ACTIVE_STACK
	156	movq EXT(kernel_stack_size)(%rip),%rcx /* point to stack top */
	157	subq %rcx, %gs:CPU_ACTIVE_STACK
b0d623f7 A	158	movq %rdx,%rdi /* processor arg to routine */
	159	call %rsi / call routine to run */
	160	hlt /* (should never return) */
	161