i386/sys/setjmp.s

   1 /*
   2  * Copyright (c) 1999 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. Please obtain a copy of the License at
  10  * http://www.opensource.apple.com/apsl/ and read it before using this
  11  * file.
  12  *
  13  * The Original Code and all software distributed under the License are
  14  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  15  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  16  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  18  * Please see the License for the specific language governing rights and
  19  * limitations under the License.
  20  *
  21  * @APPLE_LICENSE_HEADER_END@
  22  */
  23 /*
  24  * Copyright (c) 1995 NeXT Computer, Inc. All Rights Reserved
  25  */
  26 /*
  27  * NeXT 386 setjmp/longjmp
  28  *
  29  * Written by Bruce Martin, NeXT Inc. 4/9/92
  30  */
  31
  32 /*
  33  * C library -- setjmp, longjmp
  34  *
  35  *      longjmp(a,v)
  36  * will generate a "return(v)" from
  37  * the last call to
  38  *      setjmp(a)
  39  * by restoring registers from the stack,
  40  * The previous value of the signal mask is
  41  * restored.
  42  *
  43  */
  44
  45 #include <architecture/i386/asm_help.h>
  46 #include "SYS.h"
  47
  48 #define JB_ONSTACK      0
  49 #define JB_MASK         4
  50 #define JB_EAX          8
  51 #define JB_EBX          12
  52 #define JB_ECX          16
  53 #define JB_EDX          20
  54 #define JB_EDI          24
  55 #define JB_ESI          28
  56 #define JB_EBP          32
  57 #define JB_ESP          36
  58 #define JB_SS           40
  59 #define JB_EFLAGS       44
  60 #define JB_EIP          48
  61 #define JB_CS           52
  62 #define JB_DS           56
  63 #define JB_ES           60
  64 #define JB_FS           64
  65 #define JB_GS           68
  66 #define JB_SAVEMASK     72      // sigsetjmp/siglongjmp only
  67
  68 LEAF(_sigsetjmp, 0)
  69         movl    4(%esp), %eax           // sigjmp_buf * jmpbuf;
  70         movl    8(%esp), %ecx           // int savemask;
  71         movl    %ecx, JB_SAVEMASK(%eax) // jmpbuf[_JBLEN] = savemask;
  72         cmpl    $0, %ecx                // if savemask != 0
  73         jne     _setjmp                 //     setjmp(jmpbuf);
  74         jmp L_do__setjmp                // else _setjmp(jmpbuf);
  75
  76 LEAF(_setjmp, 0)
  77         subl    $4, %esp                // make space for return from sigprocmask
  78         pushl   %esp                    // oset
  79         pushl   $0                              // set = NULL
  80         pushl   $1                              // how = SIG_BLOCK
  81         CALL_EXTERN(_sigprocmask)
  82         movl    12(%esp),%eax   // save the mask
  83         addl    $16, %esp               // restore original esp
  84         movl    4(%esp), %ecx           // jmp_buf (struct sigcontext *)
  85         movl    %eax, JB_MASK(%ecx)
  86 L_do__setjmp:
  87         BRANCH_EXTERN(__setjmp)
  88
  89 LEAF(_siglongjmp, 0)
  90         movl 4(%esp), %eax              // sigjmp_buf * jmpbuf;
  91         cmpl $0, JB_SAVEMASK(%eax)      // if jmpbuf[_JBLEN] != 0
  92         jne     _longjmp                //     longjmp(jmpbuf, var);
  93         jmp L_do__longjmp               // else _longjmp(jmpbuf, var);
  94
  95 LEAF(_longjmp, 0)
  96         movl    4(%esp), %ecx           // address of jmp_buf (saved context)
  97         movl    JB_MASK(%ecx),%eax      // get the mask
  98         pushl   %eax                            // store the mask
  99         movl    %esp, %edx                      // save the address where we stored the mask
 100         pushl   $0                                      // oset = NULL
 101         pushl   %edx                            // set
 102         pushl   $3                                      // how = SIG_SETMASK
 103         CALL_EXTERN_AGAIN(_sigprocmask)
 104         addl    $16, %esp                       // restore original esp
 105 L_do__longjmp:
 106         BRANCH_EXTERN(__longjmp)        // else
 107 END(_longjmp)