ppc/sys/_setjmp.s

   1 /*
   2  * Copyright (c) 1999 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. Please obtain a copy of the License at
  10  * http://www.opensource.apple.com/apsl/ and read it before using this
  11  * file.
  12  *
  13  * The Original Code and all software distributed under the License are
  14  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  15  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  16  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  18  * Please see the License for the specific language governing rights and
  19  * limitations under the License.
  20  *
  21  * @APPLE_LICENSE_HEADER_END@
  22  */
  23
  24 /*      int _setjmp(jmp_buf env); */
  25 /*
  26  * Copyright (c) 1998 Apple Computer, Inc. All rights reserved.
  27  *
  28  *      File: sys/ppc/_setjmp.s
  29  *
  30  *      Implements _setjmp()
  31  *
  32  *      History:
  33  *      8 September 1998        Matt Watson (mwatson@apple.com)
  34  *              Created. Derived from setjmp.s
  35  */
  36
  37
  38 #include <architecture/ppc/asm_help.h>
  39 #include "_setjmp.h"
  40
  41 #define VRSave  256
  42
  43 /* special flag bit definitions copied from /osfmk/ppc/thread_act.h */
  44
  45 #define floatUsedbit    1
  46 #define vectorUsedbit   2
  47
  48 #define FlagsFastTrap   0x7FF3
  49
  50
  51 LEAF(__setjmp)
  52         stw r31, JMP_r31(r3)
  53         /* r1, r2, r13-r30 */
  54         stw r1, JMP_r1(r3)
  55         stw r2, JMP_r2(r3)
  56         stw r13, JMP_r13(r3)
  57         stw r14, JMP_r14(r3)
  58         stw r15, JMP_r15(r3)
  59         stw r16, JMP_r16(r3)
  60         stw r17, JMP_r17(r3)
  61         stw r18, JMP_r18(r3)
  62         stw r19, JMP_r19(r3)
  63         stw r20, JMP_r20(r3)
  64         stw r21, JMP_r21(r3)
  65         stw r22, JMP_r22(r3)
  66         mfcr r0
  67         stw r23, JMP_r23(r3)
  68         stw r24, JMP_r24(r3)
  69         mflr r5
  70         stw r25, JMP_r25(r3)
  71         stw r26, JMP_r26(r3)
  72         mfctr r6                                ; XXX   ctr is volatile
  73         stw r27, JMP_r27(r3)
  74         stw r28, JMP_r28(r3)
  75         mfxer r7                                ; XXX   xer is volatile
  76         stw r29, JMP_r29(r3)
  77         stw r30, JMP_r30(r3)
  78         stw r0, JMP_cr(r3)
  79         stw r5, JMP_lr(r3)
  80         stw r6, JMP_ctr(r3)
  81         stw r7, JMP_xer(r3)
  82
  83         mr      r31,r3                          ; save jmp_buf ptr
  84         li      r0,FlagsFastTrap
  85         sc                                      ; get FPR-inuse and VR-inuse flags from kernel
  86         rlwinm  r4,r3,0,floatUsedbit,floatUsedbit
  87         rlwinm. r5,r3,0,vectorUsedbit,vectorUsedbit
  88         cmpwi   cr1,r4,0                        ; set CR1 bne iff FPRs in use
  89         stw     r3,JMP_flags(r31)
  90         stw     r31,JMP_addr_at_setjmp(r31)
  91         mr      r3,r31                          ; restore jmp_buf ptr
  92         lwz     r31,JMP_r31(r31)
  93         beq     LSaveFPRsIfNecessary            ; skip if vectorUsedbit was 0
  94
  95         ; must save VRs and VRSAVE
  96
  97         mfspr   r4,VRSave
  98         andi.   r0,r4,0xFFF                     ; we only care about v20-v31
  99         stw     r0,JMP_vrsave(r3)               ; set up effective VRSAVE
 100         beq     LSaveFPRsIfNecessary            ; no live non-volatile VRs
 101         addi    r6,r3,JMP_vr_base_addr
 102         stvx    v20,0,r6
 103         li      r4,16*1
 104         stvx    v21,r4,r6
 105         li      r4,16*2
 106         stvx    v22,r4,r6
 107         li      r4,16*3
 108         stvx    v23,r4,r6
 109         li      r4,16*4
 110         stvx    v24,r4,r6
 111         li      r4,16*5
 112         stvx    v25,r4,r6
 113         li      r4,16*6
 114         stvx    v26,r4,r6
 115         li      r4,16*7
 116         stvx    v27,r4,r6
 117         li      r4,16*8
 118         stvx    v28,r4,r6
 119         li      r4,16*9
 120         stvx    v29,r4,r6
 121         li      r4,16*10
 122         stvx    v30,r4,r6
 123         li      r4,16*11
 124         stvx    v31,r4,r6
 125
 126         ; must save FPRs if they are live in this thread
 127         ;       CR1 = bne iff FPRs are in use
 128
 129 LSaveFPRsIfNecessary:
 130         beq     cr1,LExit                       ; FPRs not in use
 131         addi    r6,r3,JMP_fp_base_addr
 132         rlwinm  r6,r6,0,0,27                    ; mask off low 4 bits to qw align
 133         stfd    f14,0*8(r6)
 134         stfd    f15,1*8(r6)
 135         stfd    f16,2*8(r6)
 136         stfd    f17,3*8(r6)
 137         stfd    f18,4*8(r6)
 138         stfd    f19,5*8(r6)
 139         stfd    f20,6*8(r6)
 140         stfd    f21,7*8(r6)
 141         stfd    f22,8*8(r6)
 142         stfd    f23,9*8(r6)
 143         stfd    f24,10*8(r6)
 144         stfd    f25,11*8(r6)
 145         stfd    f26,12*8(r6)
 146         stfd    f27,13*8(r6)
 147         stfd    f28,14*8(r6)
 148         stfd    f29,15*8(r6)
 149         stfd    f30,16*8(r6)
 150         stfd    f31,17*8(r6)
 151
 152 LExit:
 153         li      r3, 0
 154         blr
 155