API/JSManagedValue.mm

   1 /*
   2  * Copyright (C) 2013 Apple Inc. All rights reserved.
   3  *
   4  * Redistribution and use in source and binary forms, with or without
   5  * modification, are permitted provided that the following conditions
   6  * are met:
   7  * 1. Redistributions of source code must retain the above copyright
   8  *    notice, this list of conditions and the following disclaimer.
   9  * 2. Redistributions in binary form must reproduce the above copyright
  10  *    notice, this list of conditions and the following disclaimer in the
  11  *    documentation and/or other materials provided with the distribution.
  12  *
  13  * THIS SOFTWARE IS PROVIDED BY APPLE INC. AND ITS CONTRIBUTORS ``AS IS''
  14  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
  15  * THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  16  * PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL APPLE INC. OR ITS CONTRIBUTORS
  17  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  18  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  19  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  20  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  21  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  22  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF
  23  * THE POSSIBILITY OF SUCH DAMAGE.
  24  */
  25
  26
  27 #import "config.h"
  28 #import "JSManagedValue.h"
  29
  30 #if JSC_OBJC_API_ENABLED
  31
  32 #import "APICast.h"
  33 #import "Heap.h"
  34 #import "JSCJSValueInlines.h"
  35 #import "JSContextInternal.h"
  36 #import "JSValueInternal.h"
  37 #import "Weak.h"
  38 #import "WeakHandleOwner.h"
  39 #import "ObjcRuntimeExtras.h"
  40
  41 class JSManagedValueHandleOwner : public JSC::WeakHandleOwner {
  42 public:
  43     virtual void finalize(JSC::Handle<JSC::Unknown>, void* context);
  44     virtual bool isReachableFromOpaqueRoots(JSC::Handle<JSC::Unknown>, void* context, JSC::SlotVisitor&);
  45 };
  46
  47 static JSManagedValueHandleOwner* managedValueHandleOwner()
  48 {
  49     DEFINE_STATIC_LOCAL(JSManagedValueHandleOwner, jsManagedValueHandleOwner, ());
  50     return &jsManagedValueHandleOwner;
  51 }
  52
  53 @implementation JSManagedValue {
  54     JSC::Weak<JSC::JSObject> m_value;
  55 }
  56
  57 + (JSManagedValue *)managedValueWithValue:(JSValue *)value
  58 {
  59     return [[[self alloc] initWithValue:value] autorelease];
  60 }
  61
  62 - (id)init
  63 {
  64     return [self initWithValue:nil];
  65 }
  66
  67 - (id)initWithValue:(JSValue *)value
  68 {
  69     self = [super init];
  70     if (!self)
  71         return nil;
  72
  73     if (!value || !JSValueIsObject([value.context JSGlobalContextRef], [value JSValueRef])) {
  74         JSC::Weak<JSC::JSObject> weak;
  75         m_value.swap(weak);
  76     } else {
  77         JSC::JSObject* object = toJS(const_cast<OpaqueJSValue*>([value JSValueRef]));
  78         JSC::Weak<JSC::JSObject> weak(object, managedValueHandleOwner(), self);
  79         m_value.swap(weak);
  80     }
  81
  82     return self;
  83 }
  84
  85 - (JSValue *)value
  86 {
  87     if (!m_value)
  88         return nil;
  89     JSC::JSObject* object = m_value.get();
  90     JSContext *context = [JSContext contextWithJSGlobalContextRef:toGlobalRef(object->structure()->globalObject()->globalExec())];
  91     return [JSValue valueWithJSValueRef:toRef(object) inContext:context];
  92 }
  93
  94 - (void)disconnectValue
  95 {
  96     m_value.clear();
  97 }
  98
  99 @end
 100
 101 @interface JSManagedValue (PrivateMethods)
 102 - (void)disconnectValue;
 103 @end
 104
 105 bool JSManagedValueHandleOwner::isReachableFromOpaqueRoots(JSC::Handle<JSC::Unknown>, void* context, JSC::SlotVisitor& visitor)
 106 {
 107     JSManagedValue *managedValue = static_cast<JSManagedValue *>(context);
 108     return visitor.containsOpaqueRoot(managedValue);
 109 }
 110
 111 void JSManagedValueHandleOwner::finalize(JSC::Handle<JSC::Unknown>, void* context)
 112 {
 113     JSManagedValue *managedValue = static_cast<JSManagedValue *>(context);
 114     [managedValue disconnectValue];
 115 }
 116
 117 #endif // JSC_OBJC_API_ENABLED