ipsec-tools/racoon/cftoken.l

   1 /*      $NetBSD: cftoken.l,v 1.11.4.1 2007/08/01 11:52:20 vanhu Exp $   */
   2
   3 /* Id: cftoken.l,v 1.53 2006/08/22 18:17:17 manubsd Exp */
   4 %option noyywrap
   5 %{
   6 /*
   7  * Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002 and 2003 WIDE Project.
   8  * All rights reserved.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the project nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE PROJECT AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE PROJECT OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include "config.h"
  36
  37 #include <sys/types.h>
  38 #include <sys/param.h>
  39 #include <sys/socket.h>
  40
  41 #include <netinet/in.h>
  42 #ifdef HAVE_NETINET6_IPSEC
  43 #  include <netinet6/ipsec.h>
  44 #else
  45 #  include <netinet/ipsec.h>
  46 #endif
  47
  48 #include <stdlib.h>
  49 #include <stdio.h>
  50 #include <string.h>
  51 #include <errno.h>
  52 #include <limits.h>
  53 #include <ctype.h>
  54 #include <glob.h>
  55 #ifdef HAVE_STDARG_H
  56 #include <stdarg.h>
  57 #else
  58 #include <varargs.h>
  59 #endif
  60
  61 //%%% BUG FIX - 2 missing include files when not using
  62 // the bison files
  63 #ifdef HAVE_OPENSSL
  64 #include <openssl/bn.h>
  65 #include <openssl/rsa.h>
  66 #endif
  67
  68 #include "var.h"
  69 #include "misc.h"
  70 #include "vmbuf.h"
  71 #include "plog.h"
  72 #include "debug.h"
  73
  74 #include "algorithm.h"
  75 #include "cfparse_proto.h"
  76 #include "cftoken_proto.h"
  77 #include "localconf.h"
  78 #include "oakley.h"
  79 #include "isakmp_var.h"
  80 #include "isakmp.h"
  81 #include "ipsec_doi.h"
  82 #include "policy.h"
  83 #include "proposal.h"
  84 #include "remoteconf.h"
  85 #include "nattraversal.h"
  86 #ifdef GC
  87 #include "gcmalloc.h"
  88 #endif
  89
  90 #include "y.tab.h"
  91
  92 int yyerrorcount = 0;
  93
  94 #if defined(YIPS_DEBUG)
  95 #  define YYDB plog(LLV_DEBUG2, LOCATION, NULL,                                \
  96                 "begin <%d>%s\n", yy_start, yytext);
  97 #  define YYD {                                                                \
  98         plog(LLV_DEBUG2, LOCATION, NULL, "<%d>%s",                             \
  99             yy_start, loglevel >= LLV_DEBUG2 ? "\n" : "");                     \
 100 }
 101 #else
 102 #  define YYDB
 103 #  define YYD
 104 #endif /* defined(YIPS_DEBUG) */
 105
 106 #define MAX_INCLUDE_DEPTH 10
 107
 108 static struct include_stack {
 109         char *path;
 110         FILE *fp;
 111         YY_BUFFER_STATE prevstate;
 112         int lineno;
 113         glob_t matches;
 114         int matchon;
 115 } incstack[MAX_INCLUDE_DEPTH];
 116 static int incstackp = 0;
 117
 118 static int yy_first_time = 1;
 119 %}
 120
 121 /* common section */
 122 nl              \n
 123 ws              [ \t]+
 124 digit           [0-9]
 125 letter          [A-Za-z]
 126 hexdigit        [0-9A-Fa-f]
 127 /*octet         (([01]?{digit}?{digit})|((2([0-4]{digit}))|(25[0-5]))) */
 128 special         [()+\|\?\*]
 129 comma           \,
 130 dot             \.
 131 slash           \/
 132 bcl             \{
 133 ecl             \}
 134 blcl            \[
 135 elcl            \]
 136 hyphen          \-
 137 percent         \%
 138 semi            \;
 139 comment         \#.*
 140 ccomment        "/*"
 141 bracketstring   \<[^>]*\>
 142 quotedstring    \"[^"]*\"
 143 addrstring      [a-fA-F0-9:]([a-fA-F0-9:\.]*|[a-fA-F0-9:\.]*%[a-zA-Z0-9]*)
 144 decstring       {digit}+
 145 hexstring       0x{hexdigit}+
 146
 147 %s S_INI S_PRIV S_PTH S_INF S_LOG S_PAD S_LST S_RTRY S_CFG
 148 %s S_ALGST S_ALGCL
 149 %s S_SAINF S_SAINFS
 150 %s S_RMT S_RMTS S_RMTP
 151 %s S_SA
 152 %s S_GSSENC
 153
 154 %%
 155 %{
 156         if (yy_first_time) {
 157                 BEGIN S_INI;
 158                 yy_first_time = 0;
 159         }
 160 %}
 161
 162         /* privsep */
 163 <S_INI>privsep          { BEGIN S_PRIV; YYDB; return(PRIVSEP); }
 164 <S_PRIV>{bcl}           { return(BOC); }
 165 <S_PRIV>user            { YYD; return(USER); }
 166 <S_PRIV>group           { YYD; return(GROUP); }
 167 <S_PRIV>chroot          { YYD; return(CHROOT); }
 168 <S_PRIV>{ecl}           { BEGIN S_INI; return(EOC); }
 169
 170         /* path */
 171 <S_INI>path             { BEGIN S_PTH; YYDB; return(PATH); }
 172 <S_PTH>include          { YYD; yylval.num = LC_PATHTYPE_INCLUDE;
 173                                 return(PATHTYPE); }
 174 <S_PTH>pre_shared_key   { YYD; yylval.num = LC_PATHTYPE_PSK;
 175                                 return(PATHTYPE); }
 176 <S_PTH>certificate      { YYD; yylval.num = LC_PATHTYPE_CERT;
 177                                 return(PATHTYPE); }
 178 <S_PTH>script           { YYD; yylval.num = LC_PATHTYPE_SCRIPT;
 179                                 return(PATHTYPE); }
 180 <S_PTH>backupsa         { YYD; yylval.num = LC_PATHTYPE_BACKUPSA;
 181                                 return(PATHTYPE); }
 182 <S_PTH>pidfile          { YYD; yylval.num = LC_PATHTYPE_PIDFILE;
 183                                 return(PATHTYPE); }
 184 <S_PTH>logfile          { YYD; yylval.num = LC_PATHTYPE_LOGFILE;
 185                                 return(PATHTYPE); }
 186 <S_PTH>{semi}           { BEGIN S_INI; YYDB; return(EOS); }
 187
 188         /* include */
 189 <S_INI>include          { YYDB; return(INCLUDE); }
 190
 191         /* self information */
 192 <S_INI>identifier       { BEGIN S_INF; YYDB; yywarn("it is obsoleted.  use \"my_identifier\" in each remote directives."); return(IDENTIFIER); }
 193 <S_INF>{semi}           { BEGIN S_INI; return(EOS); }
 194
 195         /* special */
 196 <S_INI>complex_bundle   { YYDB; return(COMPLEX_BUNDLE); }
 197
 198         /* logging */
 199 <S_INI>log              { BEGIN S_LOG; YYDB; return(LOGGING); }
 200 <S_LOG>error            { YYD; yylval.num = LLV_ERROR; return(LOGLEV); }
 201 <S_LOG>warning          { YYD; yylval.num = LLV_WARNING; return(LOGLEV); }
 202 <S_LOG>notify           { YYD; yylval.num = LLV_NOTIFY; return(LOGLEV); }
 203 <S_LOG>info             { YYD; yylval.num = LLV_INFO; return(LOGLEV); }
 204 <S_LOG>debug            { YYD; yylval.num = LLV_DEBUG; return(LOGLEV); }
 205 <S_LOG>debug2           { YYD; yylval.num = LLV_DEBUG2; return(LOGLEV); }
 206 <S_LOG>debug3           { YYD; yywarn("it is obsoleted.  use \"debug2\""); yylval.num = LLV_DEBUG2; return(LOGLEV); }
 207 <S_LOG>debug4           { YYD; yywarn("it is obsoleted.  use \"debug2\""); yylval.num = LLV_DEBUG2; return(LOGLEV); }
 208 <S_LOG>{semi}           { BEGIN S_INI; return(EOS); }
 209
 210         /* padding */
 211 <S_INI>padding          { BEGIN S_PAD; YYDB; return(PADDING); }
 212 <S_PAD>{bcl}            { return(BOC); }
 213 <S_PAD>randomize        { YYD; return(PAD_RANDOMIZE); }
 214 <S_PAD>randomize_length { YYD; return(PAD_RANDOMIZELEN); }
 215 <S_PAD>maximum_length   { YYD; return(PAD_MAXLEN); }
 216 <S_PAD>strict_check     { YYD; return(PAD_STRICT); }
 217 <S_PAD>exclusive_tail   { YYD; return(PAD_EXCLTAIL); }
 218 <S_PAD>{ecl}            { BEGIN S_INI; return(EOC); }
 219
 220         /* listen */
 221 <S_INI>listen           { BEGIN S_LST; YYDB; return(LISTEN); }
 222 <S_LST>{bcl}            { return(BOC); }
 223 <S_LST>isakmp           { YYD; return(X_ISAKMP); }
 224 <S_LST>isakmp_natt      { YYD; return(X_ISAKMP_NATT); }
 225 <S_LST>admin            { YYD; return(X_ADMIN); }
 226 <S_LST>adminsock        { YYD; return(ADMINSOCK); }
 227 <S_LST>disabled         { YYD; return(DISABLED); }
 228 <S_LST>strict_address   { YYD; return(STRICT_ADDRESS); }
 229 <S_LST>{ecl}            { BEGIN S_INI; return(EOC); }
 230
 231         /* mode_cfg */
 232 <S_INI>mode_cfg         { BEGIN S_CFG; YYDB; return(MODECFG); }
 233 <S_CFG>{bcl}            { return(BOC); }
 234 <S_CFG>network4         { YYD; return(CFG_NET4); }
 235 <S_CFG>netmask4         { YYD; return(CFG_MASK4); }
 236 <S_CFG>dns4             { YYD; return(CFG_DNS4); }
 237 <S_CFG>wins4            { YYD; return(CFG_NBNS4); }
 238 <S_CFG>default_domain   { YYD; return(CFG_DEFAULT_DOMAIN); }
 239 <S_CFG>auth_source      { YYD; return(CFG_AUTH_SOURCE); }
 240 <S_CFG>auth_groups      { YYD; return(CFG_AUTH_GROUPS); }
 241 <S_CFG>group_source     { YYD; return(CFG_GROUP_SOURCE); }
 242 <S_CFG>conf_source      { YYD; return(CFG_CONF_SOURCE); }
 243 <S_CFG>accounting       { YYD; return(CFG_ACCOUNTING); }
 244 <S_CFG>system           { YYD; return(CFG_SYSTEM); }
 245 <S_CFG>local            { YYD; return(CFG_LOCAL); }
 246 <S_CFG>none             { YYD; return(CFG_NONE); }
 247 <S_CFG>radius           { YYD; return(CFG_RADIUS); }
 248 <S_CFG>pam              { YYD; return(CFG_PAM); }
 249 <S_CFG>pool_size        { YYD; return(CFG_POOL_SIZE); }
 250 <S_CFG>banner           { YYD; return(CFG_MOTD); }
 251 <S_CFG>auth_throttle    { YYD; return(CFG_AUTH_THROTTLE); }
 252 <S_CFG>split_network    { YYD; return(CFG_SPLIT_NETWORK); }
 253 <S_CFG>local_lan        { YYD; return(CFG_SPLIT_LOCAL); }
 254 <S_CFG>include          { YYD; return(CFG_SPLIT_INCLUDE); }
 255 <S_CFG>split_dns        { YYD; return(CFG_SPLIT_DNS); }
 256 <S_CFG>pfs_group        { YYD; return(CFG_PFS_GROUP); }
 257 <S_CFG>save_passwd      { YYD; return(CFG_SAVE_PASSWD); }
 258 <S_CFG>{comma}          { YYD; return(COMMA); }
 259 <S_CFG>{ecl}            { BEGIN S_INI; return(EOC); }
 260
 261         /* timer */
 262 <S_INI>timer            { BEGIN S_RTRY; YYDB; return(RETRY); }
 263 <S_RTRY>{bcl}           { return(BOC); }
 264 <S_RTRY>counter         { YYD; return(RETRY_COUNTER); }
 265 <S_RTRY>interval        { YYD; return(RETRY_INTERVAL); }
 266 <S_RTRY>persend         { YYD; return(RETRY_PERSEND); }
 267 <S_RTRY>phase1          { YYD; return(RETRY_PHASE1); }
 268 <S_RTRY>phase2          { YYD; return(RETRY_PHASE2); }
 269 <S_RTRY>natt_keepalive  { YYD; return(NATT_KA); }
 270 <S_RTRY>auto_exit_delay { YYD; return(AUTO_EXIT_DELAY); }
 271 <S_RTRY>{ecl}           { BEGIN S_INI; return(EOC); }
 272
 273         /* sainfo */
 274 <S_INI>sainfo           { BEGIN S_SAINF; YYDB; return(SAINFO); }
 275 <S_SAINF>anonymous      { YYD; return(ANONYMOUS); }
 276 <S_SAINF>{blcl}any{elcl}        { YYD; return(PORTANY); }
 277 <S_SAINF>any            { YYD; return(ANY); }
 278 <S_SAINF>from           { YYD; return(FROM); }
 279 <S_SAINF>group          { YYD; return(GROUP); }
 280         /* sainfo spec */
 281 <S_SAINF>{bcl}          { BEGIN S_SAINFS; return(BOC); }
 282 <S_SAINF>{semi}         { BEGIN S_INI; return(EOS); }
 283 <S_SAINFS>{ecl}         { BEGIN S_INI; return(EOC); }
 284 <S_SAINFS>pfs_group     { YYD; return(PFS_GROUP); }
 285 <S_SAINFS>remoteid      { YYD; return(REMOTEID); }
 286 <S_SAINFS>identifier    { YYD; yywarn("it is obsoleted.  use \"my_identifier\"."); return(IDENTIFIER); }
 287 <S_SAINFS>my_identifier { YYD; return(MY_IDENTIFIER); }
 288 <S_SAINFS>lifetime      { YYD; return(LIFETIME); }
 289 <S_SAINFS>time          { YYD; return(LIFETYPE_TIME); }
 290 <S_SAINFS>byte          { YYD; return(LIFETYPE_BYTE); }
 291 <S_SAINFS>encryption_algorithm { YYD; yylval.num = algclass_ipsec_enc; return(ALGORITHM_CLASS); }
 292 <S_SAINFS>authentication_algorithm { YYD; yylval.num = algclass_ipsec_auth; return(ALGORITHM_CLASS); }
 293 <S_SAINFS>compression_algorithm { YYD; yylval.num = algclass_ipsec_comp; return(ALGORITHM_CLASS); }
 294 <S_SAINFS>{comma}       { YYD; return(COMMA); }
 295
 296         /* remote */
 297 <S_INI>remote           { BEGIN S_RMT; YYDB; return(REMOTE); }
 298 <S_RMT>anonymous        { YYD; return(ANONYMOUS); }
 299 <S_RMT>inherit          { YYD; return(INHERIT); }
 300         /* remote spec */
 301 <S_RMT>{bcl}            { BEGIN S_RMTS; return(BOC); }
 302 <S_RMTS>{ecl}           { BEGIN S_INI; return(EOC); }
 303 <S_RMTS>exchange_mode   { YYD; return(EXCHANGE_MODE); }
 304 <S_RMTS>{comma}         { YYD; /* XXX ignored, but to be handled. */ ; }
 305 <S_RMTS>base            { YYD; yylval.num = ISAKMP_ETYPE_BASE; return(EXCHANGETYPE); }
 306 <S_RMTS>main            { YYD; yylval.num = ISAKMP_ETYPE_IDENT; return(EXCHANGETYPE); }
 307 <S_RMTS>aggressive      { YYD; yylval.num = ISAKMP_ETYPE_AGG; return(EXCHANGETYPE); }
 308 <S_RMTS>doi             { YYD; return(DOI); }
 309 <S_RMTS>ipsec_doi       { YYD; yylval.num = IPSEC_DOI; return(DOITYPE); }
 310 <S_RMTS>situation       { YYD; return(SITUATION); }
 311 <S_RMTS>identity_only   { YYD; yylval.num = IPSECDOI_SIT_IDENTITY_ONLY; return(SITUATIONTYPE); }
 312 <S_RMTS>secrecy         { YYD; yylval.num = IPSECDOI_SIT_SECRECY; return(SITUATIONTYPE); }
 313 <S_RMTS>integrity       { YYD; yylval.num = IPSECDOI_SIT_INTEGRITY; return(SITUATIONTYPE); }
 314 <S_RMTS>identifier      { YYD; yywarn("it is obsoleted.  use \"my_identifier\"."); return(IDENTIFIER); }
 315 <S_RMTS>my_identifier   { YYD; return(MY_IDENTIFIER); }
 316 <S_RMTS>xauth_login     { YYD; return(XAUTH_LOGIN); /* formerly identifier type login */ }
 317 <S_RMTS>peers_identifier        { YYD; return(PEERS_IDENTIFIER); }
 318 <S_RMTS>verify_identifier       { YYD; return(VERIFY_IDENTIFIER); }
 319 <S_RMTS>certificate_type        { YYD; return(CERTIFICATE_TYPE); }
 320 <S_RMTS>ca_type         { YYD; return(CA_TYPE); }
 321 <S_RMTS>x509            { YYD; yylval.num = ISAKMP_CERT_X509SIGN; return(CERT_X509); }
 322 <S_RMTS>plain_rsa       {
 323 #ifdef HAVE_OPENSSL
 324         YYD; yylval.num = ISAKMP_CERT_PLAINRSA; return(CERT_PLAINRSA);
 325 #else
 326         yyerror("plainrsa not supported.");
 327 #endif
 328 }
 329 <S_RMTS>open_dir_auth_group     {
 330 #if HAVE_OPENDIR
 331         YYD;
 332         return(OPEN_DIR_AUTH_GROUP);
 333 #else
 334         yyerror("Apple specific features not compiled in.");
 335 #endif
 336 }
 337 <S_RMTS>shared_secret {
 338         YYD;
 339         return(SHARED_SECRET);
 340 }
 341 <S_RMTS>in_keychain {
 342         YYD;
 343         return(IN_KEYCHAIN);
 344 }
 345 <S_RMTS>certificate_verification {
 346         YYD;
 347         return(CERTIFICATE_VERIFICATION);
 348 }
 349 <S_RMTS>peers_certfile  { YYD; return(PEERS_CERTFILE); }
 350 <S_RMTS>dnssec          { YYD; return(DNSSEC); }
 351 <S_RMTS>verify_cert     { YYD; return(VERIFY_CERT); }
 352 <S_RMTS>send_cert       { YYD; return(SEND_CERT); }
 353 <S_RMTS>send_cr         { YYD; return(SEND_CR); }
 354 <S_RMTS>dh_group        { YYD; return(DH_GROUP); }
 355 <S_RMTS>nonce_size      { YYD; return(NONCE_SIZE); }
 356 <S_RMTS>generate_policy { YYD; return(GENERATE_POLICY); }
 357 <S_RMTS>support_mip6    { YYD; yywarn("it is obsoleted.  use \"support_proxy\"."); return(SUPPORT_PROXY); }
 358 <S_RMTS>support_proxy   { YYD; return(SUPPORT_PROXY); }
 359 <S_RMTS>initial_contact { YYD; return(INITIAL_CONTACT); }
 360 <S_RMTS>nat_traversal   { YYD; return(NAT_TRAVERSAL); }
 361 <S_RMTS>force           { YYD; yylval.num = NATT_FORCE; return(NAT_TRAVERSAL_LEVEL); }
 362 <S_RMTS>nat_traversal_multi_user {
 363         YYD;
 364         return(NAT_TRAVERSAL_MULTI_USER);
 365 }
 366 <S_RMTS>nat_traversal_keepalive {
 367         YYD;
 368         return(NAT_TRAVERSAL_KEEPALIVE);
 369 }
 370 <S_RMTS>proposal_check  { YYD; return(PROPOSAL_CHECK); }
 371 <S_RMTS>obey            { YYD; yylval.num = PROP_CHECK_OBEY; return(PROPOSAL_CHECK_LEVEL); }
 372 <S_RMTS>strict          { YYD; yylval.num = PROP_CHECK_STRICT; return(PROPOSAL_CHECK_LEVEL); }
 373 <S_RMTS>exact           { YYD; yylval.num = PROP_CHECK_EXACT; return(PROPOSAL_CHECK_LEVEL); }
 374 <S_RMTS>claim           { YYD; yylval.num = PROP_CHECK_CLAIM; return(PROPOSAL_CHECK_LEVEL); }
 375 <S_RMTS>keepalive       { YYD; return(KEEPALIVE); }
 376 <S_RMTS>passive         { YYD; return(PASSIVE); }
 377 <S_RMTS>lifetime        { YYD; return(LIFETIME); }
 378 <S_RMTS>time            { YYD; return(LIFETYPE_TIME); }
 379 <S_RMTS>byte            { YYD; return(LIFETYPE_BYTE); }
 380 <S_RMTS>dpd                     { YYD; return(DPD); }
 381 <S_RMTS>dpd_delay       { YYD; return(DPD_DELAY); }
 382 <S_RMTS>dpd_retry       { YYD; return(DPD_RETRY); }
 383 <S_RMTS>dpd_maxfail     { YYD; return(DPD_MAXFAIL); }
 384 <S_RMTS>dpd_algorithm   { YYD; return(DPD_ALGORITHM); }
 385 <S_RMTS>disconnect_on_idle { YYD; return(DISCONNECT_ON_IDLE); }
 386 <S_RMTS>idle_timeout { YYD; return(IDLE_TIMEOUT); }
 387 <S_RMTS>idle_direction { YYD; return(IDLE_DIRECTION); }
 388 <S_RMTS>ike_frag        { YYD; return(IKE_FRAG); }
 389 <S_RMTS>esp_frag        { YYD; return(ESP_FRAG); }
 390 <S_RMTS>script          { YYD; return(SCRIPT); }
 391 <S_RMTS>phase1_up       { YYD; return(PHASE1_UP); }
 392 <S_RMTS>phase1_down     { YYD; return(PHASE1_DOWN); }
 393 <S_RMTS>mode_cfg        { YYD; return(MODE_CFG); }
 394 <S_RMTS>weak_phase1_check { YYD; return(WEAK_PHASE1_CHECK); }
 395         /* remote proposal */
 396 <S_RMTS>proposal        { BEGIN S_RMTP; YYDB; return(PROPOSAL); }
 397 <S_RMTP>{bcl}           { return(BOC); }
 398 <S_RMTP>{ecl}           { BEGIN S_RMTS; return(EOC); }
 399 <S_RMTP>lifetime        { YYD; return(LIFETIME); }
 400 <S_RMTP>time            { YYD; return(LIFETYPE_TIME); }
 401 <S_RMTP>byte            { YYD; return(LIFETYPE_BYTE); }
 402 <S_RMTP>encryption_algorithm { YYD; yylval.num = algclass_isakmp_enc; return(ALGORITHM_CLASS); }
 403 <S_RMTP>authentication_method { YYD; yylval.num = algclass_isakmp_ameth; return(ALGORITHM_CLASS); }
 404 <S_RMTP>hash_algorithm  { YYD; yylval.num = algclass_isakmp_hash; return(ALGORITHM_CLASS); }
 405 <S_RMTP>dh_group        { YYD; return(DH_GROUP); }
 406 <S_RMTP>gss_id          { YYD; return(GSS_ID); }
 407 <S_RMTP>gssapi_id       { YYD; return(GSS_ID); } /* for back compatibility */
 408
 409         /* GSS ID encoding type (global) */
 410 <S_INI>gss_id_enc       { BEGIN S_GSSENC; YYDB; return(GSS_ID_ENC); }
 411 <S_GSSENC>latin1        { YYD; yylval.num = LC_GSSENC_LATIN1;
 412                                 return(GSS_ID_ENCTYPE); }
 413 <S_GSSENC>utf-16le      { YYD; yylval.num = LC_GSSENC_UTF16LE;
 414                                 return(GSS_ID_ENCTYPE); }
 415 <S_GSSENC>{semi}        { BEGIN S_INI; YYDB; return(EOS); }
 416
 417         /* parameter */
 418 on              { YYD; yylval.num = TRUE; return(SWITCH); }
 419 off             { YYD; yylval.num = FALSE; return(SWITCH); }
 420
 421         /* prefix */
 422 {slash}({digit}{1,3}) {
 423                         YYD;
 424                         yytext++;
 425                         yylval.num = atoi(yytext);
 426                         return(PREFIX);
 427                 }
 428
 429         /* port number */
 430 {blcl}{decstring}{elcl} {
 431                         char *p = yytext;
 432                         YYD;
 433                         while (*++p != ']') ;
 434                         *p = 0;
 435                         yytext++;
 436                         yylval.num = atoi(yytext);
 437                         return(PORT);
 438                 }
 439
 440         /* address range */
 441 {hyphen}{addrstring} {
 442                         YYD;
 443                         yytext++;
 444                         yylval.val = vmalloc(yyleng + 1);
 445                         if (yylval.val == NULL) {
 446                                 yyerror("vmalloc failed");
 447                                 return -1;
 448                         }
 449                         memcpy(yylval.val->v, yytext, yylval.val->l);
 450                         return(ADDRRANGE);
 451                 }
 452
 453         /* upper protocol */
 454 esp             { YYD; yylval.num = IPPROTO_ESP; return(UL_PROTO); }
 455 ah              { YYD; yylval.num = IPPROTO_AH; return(UL_PROTO); }
 456 ipcomp          { YYD; yylval.num = IPPROTO_IPCOMP; return(UL_PROTO); }
 457 icmp            { YYD; yylval.num = IPPROTO_ICMP; return(UL_PROTO); }
 458 icmp6           { YYD; yylval.num = IPPROTO_ICMPV6; return(UL_PROTO); }
 459 tcp             { YYD; yylval.num = IPPROTO_TCP; return(UL_PROTO); }
 460 udp             { YYD; yylval.num = IPPROTO_UDP; return(UL_PROTO); }
 461
 462         /* algorithm type */
 463 des_iv64        { YYD; yylval.num = algtype_des_iv64;   return(ALGORITHMTYPE); }
 464 des             { YYD; yylval.num = algtype_des;        return(ALGORITHMTYPE); }
 465 3des            { YYD; yylval.num = algtype_3des;       return(ALGORITHMTYPE); }
 466 rc5             { YYD; yylval.num = algtype_rc5;        return(ALGORITHMTYPE); }
 467 idea            { YYD; yylval.num = algtype_idea;       return(ALGORITHMTYPE); }
 468 cast128         { YYD; yylval.num = algtype_cast128;    return(ALGORITHMTYPE); }
 469 blowfish        { YYD; yylval.num = algtype_blowfish;   return(ALGORITHMTYPE); }
 470 3idea           { YYD; yylval.num = algtype_3idea;      return(ALGORITHMTYPE); }
 471 des_iv32        { YYD; yylval.num = algtype_des_iv32;   return(ALGORITHMTYPE); }
 472 rc4             { YYD; yylval.num = algtype_rc4;        return(ALGORITHMTYPE); }
 473 null_enc        { YYD; yylval.num = algtype_null_enc;   return(ALGORITHMTYPE); }
 474 null            { YYD; yylval.num = algtype_null_enc;   return(ALGORITHMTYPE); }
 475 aes             { YYD; yylval.num = algtype_aes;        return(ALGORITHMTYPE); }
 476 rijndael        { YYD; yylval.num = algtype_aes;        return(ALGORITHMTYPE); }
 477 twofish         { YYD; yylval.num = algtype_twofish;    return(ALGORITHMTYPE); }
 478 non_auth        { YYD; yylval.num = algtype_non_auth;   return(ALGORITHMTYPE); }
 479 hmac_md5        { YYD; yylval.num = algtype_hmac_md5;   return(ALGORITHMTYPE); }
 480 hmac_sha1       { YYD; yylval.num = algtype_hmac_sha1;  return(ALGORITHMTYPE); }
 481 hmac_sha2_256   { YYD; yylval.num = algtype_hmac_sha2_256;      return(ALGORITHMTYPE); }
 482 hmac_sha256     { YYD; yylval.num = algtype_hmac_sha2_256;      return(ALGORITHMTYPE); }
 483 hmac_sha2_384   { YYD; yylval.num = algtype_hmac_sha2_384;      return(ALGORITHMTYPE); }
 484 hmac_sha384     { YYD; yylval.num = algtype_hmac_sha2_384;      return(ALGORITHMTYPE); }
 485 hmac_sha2_512   { YYD; yylval.num = algtype_hmac_sha2_512;      return(ALGORITHMTYPE); }
 486 hmac_sha512     { YYD; yylval.num = algtype_hmac_sha2_512;      return(ALGORITHMTYPE); }
 487 des_mac         { YYD; yylval.num = algtype_des_mac;    return(ALGORITHMTYPE); }
 488 kpdk            { YYD; yylval.num = algtype_kpdk;       return(ALGORITHMTYPE); }
 489 md5             { YYD; yylval.num = algtype_md5;        return(ALGORITHMTYPE); }
 490 sha1            { YYD; yylval.num = algtype_sha1;       return(ALGORITHMTYPE); }
 491 tiger           { YYD; yylval.num = algtype_tiger;      return(ALGORITHMTYPE); }
 492 sha2_256        { YYD; yylval.num = algtype_sha2_256;   return(ALGORITHMTYPE); }
 493 sha256          { YYD; yylval.num = algtype_sha2_256;   return(ALGORITHMTYPE); }
 494 sha2_384        { YYD; yylval.num = algtype_sha2_384;   return(ALGORITHMTYPE); }
 495 sha384          { YYD; yylval.num = algtype_sha2_384;   return(ALGORITHMTYPE); }
 496 sha2_512        { YYD; yylval.num = algtype_sha2_512;   return(ALGORITHMTYPE); }
 497 sha512          { YYD; yylval.num = algtype_sha2_512;   return(ALGORITHMTYPE); }
 498 oui             { YYD; yylval.num = algtype_oui;        return(ALGORITHMTYPE); }
 499 deflate         { YYD; yylval.num = algtype_deflate;    return(ALGORITHMTYPE); }
 500 lzs             { YYD; yylval.num = algtype_lzs;        return(ALGORITHMTYPE); }
 501 modp768         { YYD; yylval.num = algtype_modp768;    return(ALGORITHMTYPE); }
 502 modp1024        { YYD; yylval.num = algtype_modp1024;   return(ALGORITHMTYPE); }
 503 modp1536        { YYD; yylval.num = algtype_modp1536;   return(ALGORITHMTYPE); }
 504 ec2n155         { YYD; yylval.num = algtype_ec2n155;    return(ALGORITHMTYPE); }
 505 ec2n185         { YYD; yylval.num = algtype_ec2n185;    return(ALGORITHMTYPE); }
 506 modp2048        { YYD; yylval.num = algtype_modp2048;   return(ALGORITHMTYPE); }
 507 modp3072        { YYD; yylval.num = algtype_modp3072;   return(ALGORITHMTYPE); }
 508 modp4096        { YYD; yylval.num = algtype_modp4096;   return(ALGORITHMTYPE); }
 509 modp6144        { YYD; yylval.num = algtype_modp6144;   return(ALGORITHMTYPE); }
 510 modp8192        { YYD; yylval.num = algtype_modp8192;   return(ALGORITHMTYPE); }
 511 pre_shared_key  { YYD; yylval.num = algtype_psk;        return(ALGORITHMTYPE); }
 512 rsasig          { YYD; yylval.num = algtype_rsasig;     return(ALGORITHMTYPE); }
 513 dsssig          { YYD; yylval.num = algtype_dsssig;     return(ALGORITHMTYPE); }
 514 rsaenc          { YYD; yylval.num = algtype_rsaenc;     return(ALGORITHMTYPE); }
 515 rsarev          { YYD; yylval.num = algtype_rsarev;     return(ALGORITHMTYPE); }
 516 gssapi_krb      { YYD; yylval.num = algtype_gssapikrb;  return(ALGORITHMTYPE); }
 517 hybrid_rsa_server {
 518 #ifdef ENABLE_HYBRID
 519         YYD; yylval.num = algtype_hybrid_rsa_s; return(ALGORITHMTYPE);
 520 #else
 521         yyerror("racoon not configured with --enable-hybrid");
 522 #endif
 523 }
 524 hybrid_dss_server {
 525 #ifdef ENABLE_HYBRID
 526         YYD; yylval.num = algtype_hybrid_dss_s; return(ALGORITHMTYPE);
 527 #else
 528         yyerror("racoon not configured with --enable-hybrid");
 529 #endif
 530 }
 531 hybrid_rsa_client {
 532 #ifdef ENABLE_HYBRID
 533         YYD; yylval.num = algtype_hybrid_rsa_c; return(ALGORITHMTYPE);
 534 #else
 535         yyerror("racoon not configured with --enable-hybrid");
 536 #endif
 537 }
 538 hybrid_dss_client {
 539 #ifdef ENABLE_HYBRID
 540         YYD; yylval.num = algtype_hybrid_dss_c; return(ALGORITHMTYPE);
 541 #else
 542         yyerror("racoon not configured with --enable-hybrid");
 543 #endif
 544 }
 545
 546 xauth_psk_server {
 547 #ifdef ENABLE_HYBRID
 548         YYD; yylval.num = algtype_xauth_psk_s; return(ALGORITHMTYPE);
 549 #else
 550         yyerror("racoon not configured with --enable-hybrid");
 551 #endif
 552 }
 553 xauth_psk_client {
 554 #ifdef ENABLE_HYBRID
 555         YYD; yylval.num = algtype_xauth_psk_c; return(ALGORITHMTYPE);
 556 #else
 557         yyerror("racoon not configured with --enable-hybrid");
 558 #endif
 559 }
 560 xauth_rsa_server {
 561 #ifdef ENABLE_HYBRID
 562         YYD; yylval.num = algtype_xauth_rsa_s; return(ALGORITHMTYPE);
 563 #else
 564         yyerror("racoon not configured with --enable-hybrid");
 565 #endif
 566 }
 567 xauth_rsa_client {
 568 #ifdef ENABLE_HYBRID
 569         YYD; yylval.num = algtype_xauth_rsa_c; return(ALGORITHMTYPE);
 570 #else
 571         yyerror("racoon not configured with --enable-hybrid");
 572 #endif
 573 }
 574
 575
 576
 577         /* identifier type */
 578 vendor_id       { YYD; yywarn("it is obsoleted."); return(VENDORID); }
 579 user_fqdn       { YYD; yylval.num = IDTYPE_USERFQDN; return(IDENTIFIERTYPE); }
 580 fqdn            { YYD; yylval.num = IDTYPE_FQDN; return(IDENTIFIERTYPE); }
 581 keyid           { YYD; yylval.num = IDTYPE_KEYID; return(IDENTIFIERTYPE); }
 582 keyid_use       {
 583         YYD;
 584         yylval.num = IDTYPE_KEYIDUSE;
 585         return(IDENTIFIERTYPE);
 586 }
 587 address         { YYD; yylval.num = IDTYPE_ADDRESS; return(IDENTIFIERTYPE); }
 588 subnet          { YYD; yylval.num = IDTYPE_SUBNET; return(IDENTIFIERTYPE); }
 589 asn1dn          { YYD; yylval.num = IDTYPE_ASN1DN; return(IDENTIFIERTYPE); }
 590 certname        { YYD; yywarn("certname will be obsoleted in near future."); yylval.num = IDTYPE_ASN1DN; return(IDENTIFIERTYPE); }
 591
 592         /* shared secret type */
 593 use             {
 594         YYD;
 595         yylval.num = SECRETTYPE_USE;
 596         return(SECRETTYPE);
 597 }
 598 key             {
 599         YYD;
 600         yylval.num = SECRETTYPE_KEY;
 601         return(SECRETTYPE);
 602 }
 603 keychain        {
 604 #if HAVE_KEYCHAIN
 605         YYD;
 606         yylval.num = SECRETTYPE_KEYCHAIN;
 607         return(SECRETTYPE);
 608 #else
 609         yyerror("Apple specific features not compiled in.");
 610 #endif
 611 }
 612 keychain_by_id  {
 613         YYD;
 614         yylval.num = SECRETTYPE_KEYCHAIN_BY_ID;
 615         return(SECRETTYPE);
 616 }
 617
 618         /* certificate verification */
 619 openssl                 {
 620         YYD;
 621         yylval.num = VERIFICATION_MODULE_OPENSSL;
 622         return(VERIFICATION_MODULE);
 623 }
 624 sec_framework   {
 625         YYD;
 626         yylval.num = VERIFICATION_MODULE_SEC_FRAMEWORK;
 627         return(VERIFICATION_MODULE);
 628 }
 629 use_open_dir    {
 630         YYD;
 631         yylval.num = VERIFICATION_OPTION_OPEN_DIR;
 632         return(VERIFICATION_OPTION);
 633 }
 634 use_peers_identifier    {
 635         YYD;
 636         yylval.num = VERIFICATION_OPTION_PEERS_IDENTIFIER;
 637         return(VERIFICATION_OPTION);
 638 }
 639
 640         /* identifier qualifier */
 641 tag             { YYD; yylval.num = IDQUAL_TAG;  return(IDENTIFIERQUAL); }
 642 file            { YYD; yylval.num = IDQUAL_FILE; return(IDENTIFIERQUAL); }
 643
 644         /* units */
 645 B|byte|bytes            { YYD; return(UNITTYPE_BYTE); }
 646 KB                      { YYD; return(UNITTYPE_KBYTES); }
 647 MB                      { YYD; return(UNITTYPE_MBYTES); }
 648 TB                      { YYD; return(UNITTYPE_TBYTES); }
 649 sec|secs|second|seconds { YYD; return(UNITTYPE_SEC); }
 650 min|mins|minute|minutes { YYD; return(UNITTYPE_MIN); }
 651 hour|hours              { YYD; return(UNITTYPE_HOUR); }
 652
 653 dpd_default             { YYD; return(DPD_ALGO_TYPE_DEFAULT); }
 654 dpd_inbound_detect      { YYD; return(DPD_ALGO_TYPE_INBOUND); }
 655 dpd_blackhole_detect    { YYD; return(DPD_ALGO_TYPE_BLACKHOLE); }
 656
 657 idle_any                { YYD; return(IDLE_DIRECTION_ANY); }
 658 idle_inbound            { YYD; return(IDLE_DIRECTION_IN); }
 659 idle_outbound           { YYD; return(IDLE_DIRECTION_OUT); }
 660
 661         /* boolean */
 662 yes             { YYD; yylval.num = TRUE; return(BOOLEAN); }
 663 no              { YYD; yylval.num = FALSE; return(BOOLEAN); }
 664
 665 {decstring}     {
 666                         char *bp;
 667
 668                         YYD;
 669                         yylval.num = strtol(yytext, &bp, 10);
 670                         return(NUMBER);
 671                 }
 672
 673 {hexstring}     {
 674                         char *p;
 675
 676                         YYD;
 677                         yylval.val = vmalloc(yyleng + (yyleng & 1) + 1);
 678                         if (yylval.val == NULL) {
 679                                 yyerror("vmalloc failed");
 680                                 return -1;
 681                         }
 682
 683                         p = yylval.val->v;
 684                         *p++ = '0';
 685                         *p++ = 'x';
 686
 687                         /* fixed string if length is odd. */
 688                         if (yyleng & 1)
 689                                 *p++ = '0';
 690                         memcpy(p, &yytext[2], yyleng - 1);
 691
 692                         return(HEXSTRING);
 693                 }
 694
 695 {quotedstring}  {
 696                         char *p = yytext;
 697
 698                         YYD;
 699                         while (*++p != '"') ;
 700                         *p = '\0';
 701
 702                         yylval.val = vmalloc(yyleng - 1);
 703                         if (yylval.val == NULL) {
 704                                 yyerror("vmalloc failed");
 705                                 return -1;
 706                         }
 707                         memcpy(yylval.val->v, &yytext[1], yylval.val->l);
 708
 709                         return(QUOTEDSTRING);
 710                 }
 711
 712 {addrstring}    {
 713                         YYD;
 714
 715                         yylval.val = vmalloc(yyleng + 1);
 716                         if (yylval.val == NULL) {
 717                                 yyerror("vmalloc failed");
 718                                 return -1;
 719                         }
 720                         memcpy(yylval.val->v, yytext, yylval.val->l);
 721
 722                         return(ADDRSTRING);
 723                 }
 724
 725 <<EOF>>         {
 726                         yy_delete_buffer(YY_CURRENT_BUFFER);
 727                         incstackp--;
 728     nextfile:
 729                         if (incstack[incstackp].matches.gl_pathc != 0 &&
 730                                 incstack[incstackp].matches.gl_pathv &&
 731                                 incstack[incstackp].matchon <
 732                             incstack[incstackp].matches.gl_pathc) {
 733                                 char* filepath = incstack[incstackp].matches.gl_pathv[incstack[incstackp].matchon];
 734                                 incstack[incstackp].matchon++;
 735                                 incstackp++;
 736                                 if (yycf_set_buffer(filepath) != 0) {
 737                                         incstackp--;
 738                                         goto nextfile;
 739                                 }
 740                                 yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
 741                                 BEGIN(S_INI);
 742                         } else {
 743                                 globfree(&incstack[incstackp].matches);
 744                                 if (incstackp == 0)
 745                                         yyterminate();
 746                                 else
 747                                         yy_switch_to_buffer(incstack[incstackp].prevstate);
 748                         }
 749                 }
 750
 751         /* ... */
 752 {ws}            { ; }
 753 {nl}            { incstack[incstackp].lineno++; }
 754 {comment}       { YYD; }
 755 {semi}          { return(EOS); }
 756 .               { yymore(); }
 757
 758 %%
 759
 760 void
 761 yyerror(char *s, ...)
 762 {
 763         char fmt[512];
 764
 765         va_list ap;
 766 #ifdef HAVE_STDARG_H
 767         va_start(ap, s);
 768 #else
 769         va_start(ap);
 770 #endif
 771         snprintf(fmt, sizeof(fmt), "%s:%d: \"%s\" %s\n",
 772                 incstack[incstackp].path, incstack[incstackp].lineno,
 773                 yytext, s);
 774         plogv(LLV_ERROR, LOCATION, NULL, fmt, &ap);
 775         va_end(ap);
 776
 777         yyerrorcount++;
 778 }
 779
 780 void
 781 yywarn(char *s, ...)
 782 {
 783         char fmt[512];
 784
 785         va_list ap;
 786 #ifdef HAVE_STDARG_H
 787         va_start(ap, s);
 788 #else
 789         va_start(ap);
 790 #endif
 791         snprintf(fmt, sizeof(fmt), "%s:%d: \"%s\" %s\n",
 792                 incstack[incstackp].path, incstack[incstackp].lineno,
 793                 yytext, s);
 794         plogv(LLV_WARNING, LOCATION, NULL, fmt, &ap);
 795         va_end(ap);
 796 }
 797
 798 int
 799 yycf_switch_buffer(path)
 800         char *path;
 801 {
 802         char *filepath = NULL;
 803
 804         /* got the include file name */
 805         if (incstackp >= MAX_INCLUDE_DEPTH) {
 806                 plog(LLV_ERROR, LOCATION, NULL,
 807                         "Includes nested too deeply");
 808                 return -1;
 809         }
 810
 811         if (glob(path, GLOB_TILDE, NULL, &incstack[incstackp].matches) != 0 ||
 812             incstack[incstackp].matches.gl_pathc == 0) {
 813                 plog(LLV_WARNING, LOCATION, NULL,
 814                         "glob found no matches for path \"%s\"\n", path);
 815                 return 0;
 816         }
 817         incstack[incstackp].matchon = 0;
 818         incstack[incstackp].prevstate = YY_CURRENT_BUFFER;
 819
 820     nextmatch:
 821         if (incstack[incstackp].matchon >= incstack[incstackp].matches.gl_pathc)
 822                 return -1;
 823         filepath =
 824             incstack[incstackp].matches.gl_pathv[incstack[incstackp].matchon];
 825         incstack[incstackp].matchon++;
 826         incstackp++;
 827
 828         if (yycf_set_buffer(filepath) != 0) {
 829               incstackp--;
 830               goto nextmatch;
 831         }
 832
 833         yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
 834
 835         BEGIN(S_INI);
 836
 837         return 0;
 838 }
 839
 840 int
 841 yycf_set_buffer(path)
 842         char *path;
 843 {
 844         yyin = fopen(path, "r");
 845         if (yyin == NULL) {
 846                 fprintf(stderr, "failed to open file %s (%s)\n",
 847                         path, strerror(errno));
 848                 plog(LLV_ERROR, LOCATION, NULL,
 849                         "failed to open file %s (%s)\n",
 850                         path, strerror(errno));
 851                 return -1;
 852         }
 853
 854         /* initialize */
 855         if (incstack[incstackp].path != NULL) {
 856                 fclose(incstack[incstackp].fp);
 857                 racoon_free(incstack[incstackp].path);
 858         }
 859         incstack[incstackp].fp = yyin;
 860         incstack[incstackp].path = racoon_strdup(path);
 861         STRDUP_FATAL(incstack[incstackp].path);
 862         incstack[incstackp].lineno = 1;
 863         plog(LLV_DEBUG, LOCATION, NULL,
 864                 "reading config file %s\n", path);
 865
 866         return 0;
 867 }
 868
 869 void
 870 yycf_init_buffer()
 871 {
 872         int i;
 873
 874         for (i = 0; i < MAX_INCLUDE_DEPTH; i++)
 875                 memset(&incstack[i], 0, sizeof(incstack[i]));
 876         incstackp = 0;
 877 }
 878
 879 void
 880 yycf_clean_buffer()
 881 {
 882         int i;
 883
 884         for (i = 0; i < MAX_INCLUDE_DEPTH; i++) {
 885                 if (incstack[i].path != NULL) {
 886                         fclose(incstack[i].fp);
 887                         racoon_free(incstack[i].path);
 888                         incstack[i].path = NULL;
 889                 }
 890         }
 891 }
 892