src/osx/cocoa/nonownedwnd.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/nonownedwnd.mm
   3 // Purpose:     non owned window for cocoa
   4 // Author:      DavidStefan Csomor
   5 // Modified by:
   6 // Created:     2008-06-20
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13 #ifndef WX_PRECOMP
  14     #include "wx/nonownedwnd.h"
  15     #include "wx/frame.h"
  16     #include "wx/app.h"
  17     #include "wx/dialog.h"
  18     #include "wx/menuitem.h"
  19     #include "wx/menu.h"
  20 #endif
  21
  22 #include "wx/osx/private.h"
  23
  24 NSScreen* wxOSXGetMenuScreen()
  25 {
  26     if ( [NSScreen screens] == nil )
  27         return [NSScreen mainScreen];
  28     else
  29     {
  30         return [[NSScreen screens] objectAtIndex:0];
  31     }
  32 }
  33
  34 NSRect wxToNSRect( NSView* parent, const wxRect& r )
  35 {
  36     NSRect frame = parent ? [parent bounds] : [wxOSXGetMenuScreen() frame];
  37     int y = r.y;
  38     int x = r.x ;
  39     if ( parent == NULL || ![ parent isFlipped ] )
  40         y = (int)(frame.size.height - ( r.y + r.height ));
  41     return NSMakeRect(x, y, r.width , r.height);
  42 }
  43
  44 wxRect wxFromNSRect( NSView* parent, const NSRect& rect )
  45 {
  46     NSRect frame = parent ? [parent bounds] : [wxOSXGetMenuScreen() frame];
  47     int y = (int)rect.origin.y;
  48     int x = (int)rect.origin.x;
  49     if ( parent == NULL || ![ parent isFlipped ] )
  50         y = (int)(frame.size.height - (rect.origin.y + rect.size.height));
  51     return wxRect( x, y, (int)rect.size.width, (int)rect.size.height );
  52 }
  53
  54 NSPoint wxToNSPoint( NSView* parent, const wxPoint& p )
  55 {
  56     NSRect frame = parent ? [parent bounds] : [wxOSXGetMenuScreen() frame];
  57     int x = p.x ;
  58     int y = p.y;
  59     if ( parent == NULL || ![ parent isFlipped ] )
  60         y = (int)(frame.size.height - ( p.y ));
  61     return NSMakePoint(x, y);
  62 }
  63
  64 wxPoint wxFromNSPoint( NSView* parent, const NSPoint& p )
  65 {
  66     NSRect frame = parent ? [parent bounds] : [wxOSXGetMenuScreen() frame];
  67     int x = (int)p.x;
  68     int y = (int)p.y;
  69     if ( parent == NULL || ![ parent isFlipped ] )
  70         y = (int)(frame.size.height - ( p.y ));
  71     return wxPoint( x, y);
  72 }
  73
  74 bool shouldHandleSelector(SEL selector)
  75 {
  76     if (selector == @selector(noop:)
  77             || selector == @selector(complete:)
  78             || selector == @selector(deleteBackward:)
  79             || selector == @selector(deleteForward:)
  80             || selector == @selector(insertNewline:)
  81             || selector == @selector(insertTab:)
  82             || selector == @selector(insertBacktab:)
  83             || selector == @selector(keyDown:)
  84             || selector == @selector(keyUp:)
  85             || selector == @selector(scrollPageUp:)
  86             || selector == @selector(scrollPageDown:)
  87             || selector == @selector(scrollToBeginningOfDocument:)
  88             || selector == @selector(scrollToEndOfDocument:))
  89         return false;
  90
  91     return true;
  92
  93 }
  94
  95 //
  96 // wx category for NSWindow (our own and wrapped instances)
  97 //
  98
  99 @interface NSWindow (wxNSWindowSupport)
 100
 101 - (wxNonOwnedWindowCocoaImpl*) WX_implementation;
 102
 103 - (bool) WX_filterSendEvent:(NSEvent *) event;
 104
 105 @end
 106
 107 @implementation NSWindow (wxNSWindowSupport)
 108
 109 - (wxNonOwnedWindowCocoaImpl*) WX_implementation
 110 {
 111     return (wxNonOwnedWindowCocoaImpl*) wxNonOwnedWindowImpl::FindFromWXWindow( self );
 112 }
 113
 114 // TODO in cocoa everything during a drag is sent to the NSWindow the mouse down occurred,
 115 // this does not conform to the wx behaviour if the window is not captured, so try to resend
 116 // or capture all wx mouse event handling at the tlw as we did for carbon
 117
 118 - (bool) WX_filterSendEvent:(NSEvent *) event
 119 {
 120     bool handled = false;
 121     if ( ([event type] >= NSLeftMouseDown) && ([event type] <= NSMouseExited) )
 122     {
 123         WXEVENTREF formerEvent = wxTheApp == NULL ? NULL : wxTheApp->MacGetCurrentEvent();
 124         WXEVENTHANDLERCALLREF formerHandler = wxTheApp == NULL ? NULL : wxTheApp->MacGetCurrentEventHandlerCallRef();
 125
 126         wxWindow* cw = wxWindow::GetCapture();
 127         if ( cw != NULL )
 128         {
 129             if (wxTheApp)
 130                 wxTheApp->MacSetCurrentEvent(event, NULL);
 131             ((wxWidgetCocoaImpl*)cw->GetPeer())->DoHandleMouseEvent( event);
 132             handled = true;
 133         }
 134         if ( handled )
 135         {
 136             if (wxTheApp)
 137                 wxTheApp->MacSetCurrentEvent(formerEvent , formerHandler);
 138         }
 139     }
 140     return handled;
 141 }
 142 @end
 143
 144 //
 145 // wx native implementation
 146 //
 147
 148 @interface wxNSWindow : NSWindow
 149 {
 150 }
 151
 152 - (void) sendEvent:(NSEvent *)event;
 153 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen;
 154 - (void)noResponderFor: (SEL) selector;
 155 @end
 156
 157 @implementation wxNSWindow
 158
 159 - (void)sendEvent:(NSEvent *) event
 160 {
 161     if ( ![self WX_filterSendEvent: event] )
 162     {
 163         WXEVENTREF formerEvent = wxTheApp == NULL ? NULL : wxTheApp->MacGetCurrentEvent();
 164         WXEVENTHANDLERCALLREF formerHandler = wxTheApp == NULL ? NULL : wxTheApp->MacGetCurrentEventHandlerCallRef();
 165
 166         if (wxTheApp)
 167             wxTheApp->MacSetCurrentEvent(event, NULL);
 168
 169         [super sendEvent: event];
 170
 171         if (wxTheApp)
 172             wxTheApp->MacSetCurrentEvent(formerEvent , formerHandler);
 173     }
 174 }
 175
 176 // The default implementation always moves the window back onto the screen,
 177 // even when the programmer explicitly wants to hide it.
 178 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen
 179 {
 180     wxUnusedVar(screen);
 181     return frameRect;
 182 }
 183
 184 - (void)doCommandBySelector:(SEL)selector
 185 {
 186     if (shouldHandleSelector(selector) &&
 187         !(selector == @selector(cancel:) || selector == @selector(cancelOperation:)) )
 188         [super doCommandBySelector:selector];
 189 }
 190
 191
 192 // NB: if we don't do this, all key downs that get handled lead to a NSBeep
 193 - (void)noResponderFor: (SEL) selector
 194 {
 195     if (selector != @selector(keyDown:) && selector != @selector(keyUp:))
 196     {
 197         [super noResponderFor:selector];
 198     }
 199 }
 200
 201 // We need this for borderless windows, i.e. shaped windows or windows without
 202 // a title bar. For more info, see:
 203 // http://lists.apple.com/archives/cocoa-dev/2008/May/msg02091.html
 204 - (BOOL)canBecomeKeyWindow
 205 {
 206     return YES;
 207 }
 208
 209 @end
 210
 211 @interface wxNSPanel : NSPanel
 212 {
 213 }
 214
 215 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen;
 216 - (void)noResponderFor: (SEL) selector;
 217 - (void)sendEvent:(NSEvent *)event;
 218 @end
 219
 220 @implementation wxNSPanel
 221
 222 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen
 223 {
 224     wxNonOwnedWindowCocoaImpl* impl = (wxNonOwnedWindowCocoaImpl*) wxNonOwnedWindowImpl::FindFromWXWindow( self );
 225     if (impl && impl->IsFullScreen())
 226         return frameRect;
 227     else
 228         return [super constrainFrameRect:frameRect toScreen:screen];
 229 }
 230
 231 - (BOOL)canBecomeKeyWindow
 232 {
 233     return YES;
 234 }
 235
 236 - (void)doCommandBySelector:(SEL)selector
 237 {
 238     if (shouldHandleSelector(selector))
 239         [super doCommandBySelector:selector];
 240 }
 241
 242 // NB: if we don't do this, it seems that all events that end here lead to a NSBeep
 243 - (void)noResponderFor: (SEL) selector
 244 {
 245     if (selector != @selector(keyDown:) && selector != @selector(keyUp:))
 246     {
 247         [super noResponderFor:selector];
 248     }
 249 }
 250
 251 - (void)sendEvent:(NSEvent *) event
 252 {
 253     if ( ![self WX_filterSendEvent: event] )
 254     {
 255         WXEVENTREF formerEvent = wxTheApp == NULL ? NULL : wxTheApp->MacGetCurrentEvent();
 256         WXEVENTHANDLERCALLREF formerHandler = wxTheApp == NULL ? NULL : wxTheApp->MacGetCurrentEventHandlerCallRef();
 257
 258         if (wxTheApp)
 259             wxTheApp->MacSetCurrentEvent(event, NULL);
 260
 261         [super sendEvent: event];
 262
 263         if (wxTheApp)
 264             wxTheApp->MacSetCurrentEvent(formerEvent , formerHandler);
 265     }
 266 }
 267
 268 @end
 269
 270
 271 //
 272 // controller
 273 //
 274
 275 @interface wxNonOwnedWindowController : NSObject wxOSX_10_6_AND_LATER(<NSWindowDelegate>)
 276 {
 277 }
 278
 279 - (void)windowDidResize:(NSNotification *)notification;
 280 - (NSSize)windowWillResize:(NSWindow *)window toSize:(NSSize)proposedFrameSize;
 281 - (void)windowDidResignKey:(NSNotification *)notification;
 282 - (void)windowDidBecomeKey:(NSNotification *)notification;
 283 - (void)windowDidMove:(NSNotification *)notification;
 284 - (BOOL)windowShouldClose:(id)window;
 285 - (BOOL)windowShouldZoom:(NSWindow *)window toFrame:(NSRect)newFrame;
 286
 287 @end
 288
 289 extern int wxOSXGetIdFromSelector(SEL action );
 290
 291 @implementation wxNonOwnedWindowController
 292
 293 - (id) init
 294 {
 295     self = [super init];
 296     return self;
 297 }
 298
 299 - (BOOL) triggerMenu:(SEL) action
 300 {
 301     wxMenuBar* mbar = wxMenuBar::MacGetInstalledMenuBar();
 302     if ( mbar )
 303     {
 304         wxMenu* menu = NULL;
 305         wxMenuItem* menuitem = mbar->FindItem(wxOSXGetIdFromSelector(action), &menu);
 306         if ( menu != NULL && menuitem != NULL)
 307             return menu->HandleCommandProcess(menuitem);
 308     }
 309     return NO;
 310 }
 311
 312 - (BOOL)validateMenuItem:(NSMenuItem *)menuItem
 313 {
 314     SEL action = [menuItem action];
 315
 316     wxMenuBar* mbar = wxMenuBar::MacGetInstalledMenuBar();
 317     if ( mbar )
 318     {
 319         wxMenu* menu = NULL;
 320         wxMenuItem* menuitem = mbar->FindItem(wxOSXGetIdFromSelector(action), &menu);
 321         if ( menu != NULL && menuitem != NULL)
 322         {
 323             menu->HandleCommandUpdateStatus(menuitem);
 324             return menuitem->IsEnabled();
 325         }
 326     }
 327     return YES;
 328 }
 329
 330 - (void)undo:(id)sender
 331 {
 332     wxUnusedVar(sender);
 333     [self triggerMenu:_cmd];
 334 }
 335
 336 - (void)redo:(id)sender
 337 {
 338     wxUnusedVar(sender);
 339     [self triggerMenu:_cmd];
 340 }
 341
 342 - (void)cut:(id)sender
 343 {
 344     wxUnusedVar(sender);
 345     [self triggerMenu:_cmd];
 346 }
 347
 348 - (void)copy:(id)sender
 349 {
 350     wxUnusedVar(sender);
 351     [self triggerMenu:_cmd];
 352 }
 353
 354 - (void)paste:(id)sender
 355 {
 356     wxUnusedVar(sender);
 357     [self triggerMenu:_cmd];
 358 }
 359
 360 - (void)delete:(id)sender
 361 {
 362     wxUnusedVar(sender);
 363     [self triggerMenu:_cmd];
 364 }
 365
 366 - (void)selectAll:(id)sender
 367 {
 368     wxUnusedVar(sender);
 369     [self triggerMenu:_cmd];
 370 }
 371
 372 - (BOOL)windowShouldClose:(id)nwindow
 373 {
 374     wxNonOwnedWindowCocoaImpl* windowimpl = [(NSWindow*) nwindow WX_implementation];
 375     if ( windowimpl )
 376     {
 377         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 378         if ( wxpeer )
 379             wxpeer->Close();
 380     }
 381     return NO;
 382 }
 383
 384 - (NSSize)windowWillResize:(NSWindow *)window
 385                     toSize:(NSSize)proposedFrameSize
 386 {
 387     NSRect frame = [window frame];
 388     wxRect wxframe = wxFromNSRect( NULL, frame );
 389     wxframe.SetWidth( (int)proposedFrameSize.width );
 390     wxframe.SetHeight( (int)proposedFrameSize.height );
 391
 392     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 393     if ( windowimpl )
 394     {
 395         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 396         if ( wxpeer )
 397         {
 398             wxpeer->HandleResizing( 0, &wxframe );
 399             NSSize newSize = NSMakeSize(wxframe.GetWidth(), wxframe.GetHeight());
 400             return newSize;
 401         }
 402     }
 403
 404     return proposedFrameSize;
 405 }
 406
 407 - (void)windowDidResize:(NSNotification *)notification
 408 {
 409     NSWindow* window = (NSWindow*) [notification object];
 410     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 411     if ( windowimpl )
 412     {
 413         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 414         if ( wxpeer )
 415             wxpeer->HandleResized(0);
 416     }
 417 }
 418
 419 - (void)windowDidMove:(NSNotification *)notification
 420 {
 421     wxNSWindow* window = (wxNSWindow*) [notification object];
 422     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 423     if ( windowimpl )
 424     {
 425         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 426         if ( wxpeer )
 427             wxpeer->HandleMoved(0);
 428     }
 429 }
 430
 431 - (void)windowDidBecomeKey:(NSNotification *)notification
 432 {
 433     NSWindow* window = (NSWindow*) [notification object];
 434     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 435     if ( windowimpl )
 436     {
 437         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 438         if ( wxpeer )
 439             wxpeer->HandleActivated(0, true);
 440     }
 441 }
 442
 443 - (void)windowDidResignKey:(NSNotification *)notification
 444 {
 445     NSWindow* window = (NSWindow*) [notification object];
 446     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 447     if ( windowimpl )
 448     {
 449         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 450         if ( wxpeer )
 451         {
 452             wxpeer->HandleActivated(0, false);
 453             // as for wx the deactivation also means loosing focus we
 454             // must trigger this manually
 455             [window makeFirstResponder:nil];
 456
 457             // TODO Remove if no problems arise with Popup Windows
 458 #if 0
 459             // Needed for popup window since the firstResponder
 460             // (focus in wx) doesn't change when this
 461             // TLW becomes inactive.
 462             wxFocusEvent event( wxEVT_KILL_FOCUS, wxpeer->GetId());
 463             event.SetEventObject(wxpeer);
 464             wxpeer->HandleWindowEvent(event);
 465 #endif
 466         }
 467     }
 468 }
 469
 470 - (id)windowWillReturnFieldEditor:(NSWindow *)sender toObject:(id)anObject
 471 {
 472     wxUnusedVar(sender);
 473
 474     if ([anObject isKindOfClass:[wxNSTextField class]])
 475     {
 476         wxNSTextField* tf = (wxNSTextField*) anObject;
 477         wxNSTextFieldEditor* editor = [tf fieldEditor];
 478         if ( editor == nil )
 479         {
 480             editor = [[wxNSTextFieldEditor alloc] init];
 481             [editor setFieldEditor:YES];
 482             [tf setFieldEditor:editor];
 483             [editor release];
 484         }
 485         return editor;
 486     }
 487
 488     return nil;
 489 }
 490
 491 - (BOOL)windowShouldZoom:(NSWindow *)window toFrame:(NSRect)newFrame
 492 {
 493     wxUnusedVar(newFrame);
 494     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 495     if ( windowimpl )
 496     {
 497         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 498         wxMaximizeEvent event(wxpeer->GetId());
 499         event.SetEventObject(wxpeer);
 500         return !wxpeer->HandleWindowEvent(event);
 501     }
 502     return true;
 503 }
 504
 505 @end
 506
 507 IMPLEMENT_DYNAMIC_CLASS( wxNonOwnedWindowCocoaImpl , wxNonOwnedWindowImpl )
 508
 509 wxNonOwnedWindowCocoaImpl::wxNonOwnedWindowCocoaImpl( wxNonOwnedWindow* nonownedwnd) :
 510     wxNonOwnedWindowImpl(nonownedwnd)
 511 {
 512     m_macWindow = NULL;
 513     m_macFullScreenData = NULL;
 514 }
 515
 516 wxNonOwnedWindowCocoaImpl::wxNonOwnedWindowCocoaImpl()
 517 {
 518     m_macWindow = NULL;
 519     m_macFullScreenData = NULL;
 520 }
 521
 522 wxNonOwnedWindowCocoaImpl::~wxNonOwnedWindowCocoaImpl()
 523 {
 524     if ( !m_wxPeer->IsNativeWindowWrapper() )
 525     {
 526         [m_macWindow setDelegate:nil];
 527
 528         // make sure we remove this first, otherwise the ref count will not lead to the
 529         // native window's destruction
 530         if ([m_macWindow parentWindow] != 0)
 531             [[m_macWindow parentWindow] removeChildWindow: m_macWindow];
 532
 533         [m_macWindow release];
 534     }
 535 }
 536
 537 void wxNonOwnedWindowCocoaImpl::WillBeDestroyed()
 538 {
 539     if ( !m_wxPeer->IsNativeWindowWrapper() )
 540     {
 541         [m_macWindow setDelegate:nil];
 542     }
 543 }
 544
 545 void wxNonOwnedWindowCocoaImpl::Create( wxWindow* parent, const wxPoint& pos, const wxSize& size,
 546 long style, long extraStyle, const wxString& WXUNUSED(name) )
 547 {
 548     static wxNonOwnedWindowController* controller = NULL;
 549
 550     if ( !controller )
 551         controller =[[wxNonOwnedWindowController alloc] init];
 552
 553
 554     int windowstyle = NSBorderlessWindowMask;
 555
 556     if ( style & wxFRAME_TOOL_WINDOW || ( style & wxPOPUP_WINDOW ) ||
 557             GetWXPeer()->GetExtraStyle() & wxTOPLEVEL_EX_DIALOG )
 558     {
 559         m_macWindow = [wxNSPanel alloc];
 560     }
 561     else
 562         m_macWindow = [wxNSWindow alloc];
 563
 564     CGWindowLevel level = kCGNormalWindowLevel;
 565
 566     if ( style & wxFRAME_TOOL_WINDOW )
 567     {
 568         windowstyle |= NSUtilityWindowMask;
 569     }
 570     else if ( ( style & wxPOPUP_WINDOW ) )
 571     {
 572         level = kCGPopUpMenuWindowLevel;
 573     }
 574     else if ( ( style & wxFRAME_DRAWER ) )
 575     {
 576         /*
 577         wclass = kDrawerWindowClass;
 578         */
 579     }
 580
 581     if ( ( style & wxMINIMIZE_BOX ) || ( style & wxMAXIMIZE_BOX ) ||
 582         ( style & wxCLOSE_BOX ) || ( style & wxSYSTEM_MENU ) || ( style & wxCAPTION ) )
 583     {
 584         windowstyle |= NSTitledWindowMask ;
 585         if ( ( style & wxMINIMIZE_BOX ) )
 586             windowstyle |= NSMiniaturizableWindowMask ;
 587
 588         if ( ( style & wxMAXIMIZE_BOX ) )
 589             windowstyle |= NSResizableWindowMask ;
 590
 591         if ( ( style & wxCLOSE_BOX) )
 592             windowstyle |= NSClosableWindowMask ;
 593     }
 594
 595     if ( ( style & wxRESIZE_BORDER ) )
 596         windowstyle |= NSResizableWindowMask ;
 597
 598     if ( extraStyle & wxFRAME_EX_METAL)
 599         windowstyle |= NSTexturedBackgroundWindowMask;
 600
 601     if ( ( style & wxFRAME_FLOAT_ON_PARENT ) || ( style & wxFRAME_TOOL_WINDOW ) )
 602         level = kCGFloatingWindowLevel;
 603
 604     if ( ( style & wxSTAY_ON_TOP ) )
 605         level = kCGUtilityWindowLevel;
 606
 607     NSRect r = wxToNSRect( NULL, wxRect( pos, size) );
 608
 609     r = [NSWindow contentRectForFrameRect:r styleMask:windowstyle];
 610
 611     [m_macWindow initWithContentRect:r
 612         styleMask:windowstyle
 613         backing:NSBackingStoreBuffered
 614         defer:NO
 615         ];
 616
 617     // if we just have a title bar with no buttons needed, hide them
 618     if ( (windowstyle & NSTitledWindowMask) &&
 619         !(style & wxCLOSE_BOX) && !(style & wxMAXIMIZE_BOX) && !(style & wxMINIMIZE_BOX) )
 620     {
 621         [[m_macWindow standardWindowButton:NSWindowZoomButton] setHidden:YES];
 622         [[m_macWindow standardWindowButton:NSWindowCloseButton] setHidden:YES];
 623         [[m_macWindow standardWindowButton:NSWindowMiniaturizeButton] setHidden:YES];
 624     }
 625
 626     // If the parent is modal, windows with wxFRAME_FLOAT_ON_PARENT style need
 627     // to be in kCGUtilityWindowLevel and not kCGFloatingWindowLevel to stay
 628     // above the parent.
 629     wxDialog * const parentDialog = wxDynamicCast(parent, wxDialog);
 630     if (parentDialog && parentDialog->IsModal())
 631     {
 632         if (level == kCGFloatingWindowLevel)
 633         {
 634             level = kCGUtilityWindowLevel;
 635         }
 636
 637         // Cocoa's modal loop does not process other windows by default, but
 638         // don't call this on normal window levels so nested modal dialogs will
 639         // still behave modally.
 640         if (level != kCGNormalWindowLevel)
 641         {
 642             if ([m_macWindow isKindOfClass:[NSPanel class]])
 643             {
 644                 [(NSPanel*)m_macWindow setWorksWhenModal:YES];
 645             }
 646         }
 647     }
 648
 649     [m_macWindow setLevel:level];
 650     m_macWindowLevel = level;
 651
 652     [m_macWindow setDelegate:controller];
 653
 654     if ( ( style & wxFRAME_SHAPED) )
 655     {
 656         [m_macWindow setOpaque:NO];
 657         [m_macWindow setAlphaValue:1.0];
 658     }
 659
 660     if ( !(style & wxFRAME_TOOL_WINDOW) )
 661         [m_macWindow setHidesOnDeactivate:NO];
 662 }
 663
 664 void wxNonOwnedWindowCocoaImpl::Create( wxWindow* WXUNUSED(parent), WXWindow nativeWindow )
 665 {
 666     m_macWindow = nativeWindow;
 667 }
 668
 669 WXWindow wxNonOwnedWindowCocoaImpl::GetWXWindow() const
 670 {
 671     return m_macWindow;
 672 }
 673
 674 void wxNonOwnedWindowCocoaImpl::Raise()
 675 {
 676     [m_macWindow makeKeyAndOrderFront:nil];
 677 }
 678
 679 void wxNonOwnedWindowCocoaImpl::Lower()
 680 {
 681     [m_macWindow orderWindow:NSWindowBelow relativeTo:0];
 682 }
 683
 684 void wxNonOwnedWindowCocoaImpl::ShowWithoutActivating()
 685 {
 686     [m_macWindow orderFront:nil];
 687     [[m_macWindow contentView] setNeedsDisplay: YES];
 688 }
 689
 690 bool wxNonOwnedWindowCocoaImpl::Show(bool show)
 691 {
 692     if ( show )
 693     {
 694         wxNonOwnedWindow* wxpeer = GetWXPeer();
 695         if ( wxpeer )
 696         {
 697             // add to parent window before showing
 698             wxDialog * const dialog = wxDynamicCast(wxpeer, wxDialog);
 699             if ( wxpeer->GetParent() && dialog && dialog->IsModal())
 700             {
 701                 NSView * parentView = wxpeer->GetParent()->GetPeer()->GetWXWidget();
 702                 if ( parentView )
 703                 {
 704                     NSWindow* parentNSWindow = [parentView window];
 705                     if ( parentNSWindow )
 706                         [parentNSWindow addChildWindow:m_macWindow ordered:NSWindowAbove];
 707                 }
 708             }
 709
 710             if (!(wxpeer->GetWindowStyle() & wxFRAME_TOOL_WINDOW))
 711                 [m_macWindow makeKeyAndOrderFront:nil];
 712             else
 713                 [m_macWindow orderFront:nil];
 714         }
 715         [[m_macWindow contentView] setNeedsDisplay: YES];
 716     }
 717     else
 718     {
 719         // avoid propagation of orderOut to parent
 720         if ([m_macWindow parentWindow] != 0)
 721             [[m_macWindow parentWindow] removeChildWindow: m_macWindow];
 722         [m_macWindow orderOut:nil];
 723     }
 724     return true;
 725 }
 726
 727 bool wxNonOwnedWindowCocoaImpl::ShowWithEffect(bool show,
 728                                                wxShowEffect effect,
 729                                                unsigned timeout)
 730 {
 731     return wxWidgetCocoaImpl::
 732             ShowViewOrWindowWithEffect(m_wxPeer, show, effect, timeout);
 733 }
 734
 735 void wxNonOwnedWindowCocoaImpl::Update()
 736 {
 737     [m_macWindow displayIfNeeded];
 738 }
 739
 740 bool wxNonOwnedWindowCocoaImpl::SetTransparent(wxByte alpha)
 741 {
 742     [m_macWindow setAlphaValue:(CGFloat) alpha/255.0];
 743     return true;
 744 }
 745
 746 bool wxNonOwnedWindowCocoaImpl::SetBackgroundColour(const wxColour& col )
 747 {
 748     [m_macWindow setBackgroundColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
 749                                                              green:(CGFloat) (col.Green() / 255.0)
 750                                                               blue:(CGFloat) (col.Blue() / 255.0)
 751                                                              alpha:(CGFloat) (col.Alpha() / 255.0)]];
 752     return true;
 753 }
 754
 755 void wxNonOwnedWindowCocoaImpl::SetExtraStyle( long exStyle )
 756 {
 757     if ( m_macWindow )
 758     {
 759         bool metal = exStyle & wxFRAME_EX_METAL ;
 760         int windowStyle = [ m_macWindow styleMask];
 761         if ( metal && !(windowStyle & NSTexturedBackgroundWindowMask) )
 762         {
 763             wxFAIL_MSG( wxT("Metal Style cannot be changed after creation") );
 764         }
 765         else if ( !metal && (windowStyle & NSTexturedBackgroundWindowMask ) )
 766         {
 767             wxFAIL_MSG( wxT("Metal Style cannot be changed after creation") );
 768         }
 769     }
 770 }
 771
 772 void wxNonOwnedWindowCocoaImpl::SetWindowStyleFlag( long style )
 773 {
 774     if (m_macWindow)
 775     {
 776         CGWindowLevel level = kCGNormalWindowLevel;
 777
 778         if (style & wxSTAY_ON_TOP)
 779             level = kCGUtilityWindowLevel;
 780         else if (( style & wxFRAME_FLOAT_ON_PARENT ) || ( style & wxFRAME_TOOL_WINDOW ))
 781             level = kCGFloatingWindowLevel;
 782
 783         [m_macWindow setLevel: level];
 784         m_macWindowLevel = level;
 785     }
 786 }
 787
 788 bool wxNonOwnedWindowCocoaImpl::SetBackgroundStyle(wxBackgroundStyle style)
 789 {
 790     if ( style == wxBG_STYLE_TRANSPARENT )
 791     {
 792         [m_macWindow setOpaque:NO];
 793         [m_macWindow setBackgroundColor:[NSColor clearColor]];
 794     }
 795
 796     return true;
 797 }
 798
 799 bool wxNonOwnedWindowCocoaImpl::CanSetTransparent()
 800 {
 801     return true;
 802 }
 803
 804 void wxNonOwnedWindowCocoaImpl::MoveWindow(int x, int y, int width, int height)
 805 {
 806     NSRect r = wxToNSRect( NULL, wxRect(x,y,width, height) );
 807     // do not trigger refreshes upon invisible and possible partly created objects
 808     [m_macWindow setFrame:r display:GetWXPeer()->IsShownOnScreen()];
 809 }
 810
 811 void wxNonOwnedWindowCocoaImpl::GetPosition( int &x, int &y ) const
 812 {
 813     wxRect r = wxFromNSRect( NULL, [m_macWindow frame] );
 814     x = r.GetLeft();
 815     y = r.GetTop();
 816 }
 817
 818 void wxNonOwnedWindowCocoaImpl::GetSize( int &width, int &height ) const
 819 {
 820     NSRect rect = [m_macWindow frame];
 821     width = (int)rect.size.width;
 822     height = (int)rect.size.height;
 823 }
 824
 825 void wxNonOwnedWindowCocoaImpl::GetContentArea( int& left, int &top, int &width, int &height ) const
 826 {
 827     NSRect rect = [[m_macWindow contentView] frame];
 828     left = (int)rect.origin.x;
 829     top = (int)rect.origin.y;
 830     width = (int)rect.size.width;
 831     height = (int)rect.size.height;
 832 }
 833
 834 bool wxNonOwnedWindowCocoaImpl::SetShape(const wxRegion& WXUNUSED(region))
 835 {
 836     [m_macWindow setOpaque:NO];
 837     [m_macWindow setBackgroundColor:[NSColor clearColor]];
 838
 839     return true;
 840 }
 841
 842 void wxNonOwnedWindowCocoaImpl::SetTitle( const wxString& title, wxFontEncoding encoding )
 843 {
 844     [m_macWindow setTitle:wxCFStringRef( title , encoding ).AsNSString()];
 845 }
 846
 847 bool wxNonOwnedWindowCocoaImpl::IsMaximized() const
 848 {
 849     if (([m_macWindow styleMask] & NSResizableWindowMask) != 0)
 850     {
 851         return [m_macWindow isZoomed];
 852     }
 853     else
 854     {
 855         NSRect rectScreen = [[NSScreen mainScreen] visibleFrame];
 856         NSRect rectWindow = [m_macWindow frame];
 857         return (rectScreen.origin.x == rectWindow.origin.x &&
 858                 rectScreen.origin.y == rectWindow.origin.y &&
 859                 rectScreen.size.width == rectWindow.size.width &&
 860                 rectScreen.size.height == rectWindow.size.height);
 861     }
 862 }
 863
 864 bool wxNonOwnedWindowCocoaImpl::IsIconized() const
 865 {
 866     return [m_macWindow isMiniaturized];
 867 }
 868
 869 void wxNonOwnedWindowCocoaImpl::Iconize( bool iconize )
 870 {
 871     if ( iconize )
 872         [m_macWindow miniaturize:nil];
 873     else
 874         [m_macWindow deminiaturize:nil];
 875 }
 876
 877 void wxNonOwnedWindowCocoaImpl::Maximize(bool WXUNUSED(maximize))
 878 {
 879     [m_macWindow zoom:nil];
 880 }
 881
 882
 883 // http://cocoadevcentral.com/articles/000028.php
 884
 885 typedef struct
 886 {
 887     NSUInteger m_formerStyleMask;
 888     int m_formerLevel;
 889     NSRect m_formerFrame;
 890 } FullScreenData ;
 891
 892 bool wxNonOwnedWindowCocoaImpl::IsFullScreen() const
 893 {
 894     return m_macFullScreenData != NULL ;
 895 }
 896
 897 bool wxNonOwnedWindowCocoaImpl::ShowFullScreen(bool show, long WXUNUSED(style))
 898 {
 899     if ( show )
 900     {
 901         FullScreenData *data = (FullScreenData *)m_macFullScreenData ;
 902         delete data ;
 903         data = new FullScreenData();
 904
 905         m_macFullScreenData = data ;
 906         data->m_formerLevel = [m_macWindow level];
 907         data->m_formerFrame = [m_macWindow frame];
 908         data->m_formerStyleMask = [m_macWindow styleMask];
 909 #if 0
 910         // CGDisplayCapture( kCGDirectMainDisplay );
 911         //[m_macWindow setLevel:NSMainMenuWindowLevel+1/*CGShieldingWindowLevel()*/];
 912 #endif
 913         NSRect screenframe = [[NSScreen mainScreen] frame];
 914         NSRect frame = NSMakeRect (0, 0, 100, 100);
 915         NSRect contentRect;
 916
 917 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_6
 918         if ( [ m_macWindow respondsToSelector:@selector(setStyleMask:) ] )
 919             [m_macWindow setStyleMask:data->m_formerStyleMask & ~ NSResizableWindowMask];
 920 #endif
 921
 922         contentRect = [NSWindow contentRectForFrameRect: frame
 923                                 styleMask: [m_macWindow styleMask]];
 924         screenframe.origin.y += (frame.origin.y - contentRect.origin.y);
 925         screenframe.size.height += (frame.size.height - contentRect.size.height);
 926         [m_macWindow setFrame:screenframe display:YES];
 927
 928         SetSystemUIMode(kUIModeAllHidden,
 929                                 kUIOptionDisableAppleMenu
 930                         /*
 931                                 | kUIOptionDisableProcessSwitch
 932                                 | kUIOptionDisableForceQuit
 933                          */);
 934     }
 935     else if ( m_macFullScreenData != NULL )
 936     {
 937         FullScreenData *data = (FullScreenData *) m_macFullScreenData ;
 938 #if 0
 939         // CGDisplayRelease( kCGDirectMainDisplay );
 940         // [m_macWindow setLevel:data->m_formerLevel];
 941 #endif
 942
 943         [m_macWindow setFrame:data->m_formerFrame display:YES];
 944 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_6
 945         if ( [ m_macWindow respondsToSelector:@selector(setStyleMask:) ] )
 946             [m_macWindow setStyleMask:data->m_formerStyleMask];
 947 #endif
 948         delete data ;
 949         m_macFullScreenData = NULL ;
 950
 951         SetSystemUIMode(kUIModeNormal, 0);
 952     }
 953
 954     return true;
 955 }
 956
 957 void wxNonOwnedWindowCocoaImpl::RequestUserAttention(int flagsWX)
 958 {
 959     NSRequestUserAttentionType flagsOSX;
 960     switch ( flagsWX )
 961     {
 962         case wxUSER_ATTENTION_INFO:
 963             flagsOSX = NSInformationalRequest;
 964             break;
 965
 966         case wxUSER_ATTENTION_ERROR:
 967             flagsOSX = NSCriticalRequest;
 968             break;
 969
 970         default:
 971             wxFAIL_MSG( "invalid RequestUserAttention() flags" );
 972             return;
 973     }
 974
 975     [NSApp requestUserAttention:flagsOSX];
 976 }
 977
 978 void wxNonOwnedWindowCocoaImpl::ScreenToWindow( int *x, int *y )
 979 {
 980     wxPoint p((x ? *x : 0), (y ? *y : 0) );
 981     NSPoint nspt = wxToNSPoint( NULL, p );
 982     nspt = [m_macWindow convertScreenToBase:nspt];
 983     nspt = [[m_macWindow contentView] convertPoint:nspt fromView:nil];
 984     p = wxFromNSPoint([m_macWindow contentView], nspt);
 985     if ( x )
 986         *x = p.x;
 987     if ( y )
 988         *y = p.y;
 989 }
 990
 991 void wxNonOwnedWindowCocoaImpl::WindowToScreen( int *x, int *y )
 992 {
 993     wxPoint p((x ? *x : 0), (y ? *y : 0) );
 994     NSPoint nspt = wxToNSPoint( [m_macWindow contentView], p );
 995     nspt = [[m_macWindow contentView] convertPoint:nspt toView:nil];
 996     nspt = [m_macWindow convertBaseToScreen:nspt];
 997     p = wxFromNSPoint( NULL, nspt);
 998     if ( x )
 999         *x = p.x;
1000     if ( y )
1001         *y = p.y;
1002 }
1003
1004 bool wxNonOwnedWindowCocoaImpl::IsActive()
1005 {
1006     return [m_macWindow isKeyWindow];
1007 }
1008
1009 void wxNonOwnedWindowCocoaImpl::SetModified(bool modified)
1010 {
1011     [m_macWindow setDocumentEdited:modified];
1012 }
1013
1014 bool wxNonOwnedWindowCocoaImpl::IsModified() const
1015 {
1016     return [m_macWindow isDocumentEdited];
1017 }
1018
1019 void wxNonOwnedWindowCocoaImpl::SetRepresentedFilename(const wxString& filename)
1020 {
1021     [m_macWindow setRepresentedFilename:wxCFStringRef(filename).AsNSString()];
1022 }
1023
1024 void wxNonOwnedWindowCocoaImpl::RestoreWindowLevel()
1025 {
1026     if ( [m_macWindow level] != m_macWindowLevel )
1027         [m_macWindow setLevel:m_macWindowLevel];
1028 }
1029
1030 //
1031 //
1032 //
1033
1034 wxNonOwnedWindowImpl* wxNonOwnedWindowImpl::CreateNonOwnedWindow( wxNonOwnedWindow* wxpeer, wxWindow* parent, WXWindow nativeWindow)
1035 {
1036     wxNonOwnedWindowCocoaImpl* now = new wxNonOwnedWindowCocoaImpl( wxpeer );
1037     now->Create( parent, nativeWindow );
1038     return now;
1039 }
1040
1041 wxNonOwnedWindowImpl* wxNonOwnedWindowImpl::CreateNonOwnedWindow( wxNonOwnedWindow* wxpeer, wxWindow* parent, const wxPoint& pos, const wxSize& size,
1042     long style, long extraStyle, const wxString& name )
1043 {
1044     wxNonOwnedWindowImpl* now = new wxNonOwnedWindowCocoaImpl( wxpeer );
1045     now->Create( parent, pos, size, style , extraStyle, name );
1046     return now;
1047 }
1048