src/osx/cocoa/nonownedwnd.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/nonownedwnd.mm
   3 // Purpose:     non owned window for cocoa
   4 // Author:      DavidStefan Csomor
   5 // Modified by:
   6 // Created:     2008-06-20
   7 // RCS-ID:      $Id: nonownedwnd.mm 48805 2007-09-19 14:52:25Z SC $
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13 #ifndef WX_PRECOMP
  14     #include "wx/nonownedwnd.h"
  15     #include "wx/frame.h"
  16 #endif
  17
  18 #include "wx/osx/private.h"
  19
  20 NSRect wxToNSRect( NSView* parent, const wxRect& r )
  21 {
  22     NSRect frame = parent ? [parent bounds] : [[NSScreen mainScreen] frame];
  23     int y = r.y;
  24     int x = r.x ;
  25     if ( parent == NULL || ![ parent isFlipped ] )
  26         y = (int)(frame.size.height - ( r.y + r.height ));
  27     return NSMakeRect(x, y, r.width , r.height);
  28 }
  29
  30 wxRect wxFromNSRect( NSView* parent, const NSRect& rect )
  31 {
  32     NSRect frame = parent ? [parent bounds] : [[NSScreen mainScreen] frame];
  33     int y = (int)rect.origin.y;
  34     int x = (int)rect.origin.x;
  35     if ( parent == NULL || ![ parent isFlipped ] )
  36         y = (int)(frame.size.height - (rect.origin.y + rect.size.height));
  37     return wxRect( x, y, (int)rect.size.width, (int)rect.size.height );
  38 }
  39
  40 NSPoint wxToNSPoint( NSView* parent, const wxPoint& p )
  41 {
  42     NSRect frame = parent ? [parent bounds] : [[NSScreen mainScreen] frame];
  43     int x = p.x ;
  44     int y = p.y;
  45     if ( parent == NULL || ![ parent isFlipped ] )
  46         y = (int)(frame.size.height - ( p.y ));
  47     return NSMakePoint(x, y);
  48 }
  49
  50 wxPoint wxFromNSPoint( NSView* parent, const NSPoint& p )
  51 {
  52     NSRect frame = parent ? [parent bounds] : [[NSScreen mainScreen] frame];
  53     int x = (int)p.x;
  54     int y = (int)p.y;
  55     if ( parent == NULL || ![ parent isFlipped ] )
  56         y = (int)(frame.size.height - ( p.y ));
  57     return wxPoint( x, y);
  58 }
  59
  60 bool shouldHandleSelector(SEL selector)
  61 {
  62     if (selector == @selector(noop:)
  63             || selector == @selector(complete:)
  64             || selector == @selector(deleteBackward:)
  65             || selector == @selector(deleteForward:)
  66             || selector == @selector(insertNewline:)
  67             || selector == @selector(insertTab:)
  68             || selector == @selector(keyDown:)
  69             || selector == @selector(keyUp:)
  70             || selector == @selector(scrollPageUp:)
  71             || selector == @selector(scrollPageDown:)
  72             || selector == @selector(scrollToBeginningOfDocument:)
  73             || selector == @selector(scrollToEndOfDocument:))
  74         return false;
  75
  76     return true;
  77
  78 }
  79
  80 //
  81 // wx native implementation classes
  82 //
  83
  84 typedef void (*wxOSX_NoResponderHandlerPtr)(NSView* self, SEL _cmd, SEL selector);
  85
  86 @interface wxNSWindow : NSWindow
  87 {
  88     wxNonOwnedWindowCocoaImpl* impl;
  89 }
  90
  91 - (void)setImplementation: (wxNonOwnedWindowCocoaImpl *) theImplementation;
  92 - (wxNonOwnedWindowCocoaImpl*) implementation;
  93 - (void)noResponderFor: (SEL) selector;
  94 @end
  95
  96 @implementation wxNSWindow
  97
  98 - (void)setImplementation: (wxNonOwnedWindowCocoaImpl *) theImplementation
  99 {
 100     impl = theImplementation;
 101 }
 102
 103 - (wxNonOwnedWindowCocoaImpl*) implementation
 104 {
 105     return impl;
 106 }
 107
 108 - (void)doCommandBySelector:(SEL)selector
 109 {
 110     if (shouldHandleSelector(selector) &&
 111         !(selector == @selector(cancel:) || selector == @selector(cancelOperation:)) )
 112         [super doCommandBySelector:selector];
 113 }
 114
 115
 116 // NB: if we don't do this, all key downs that get handled lead to a NSBeep
 117 - (void)noResponderFor: (SEL) selector
 118 {
 119     if (selector != @selector(keyDown:) && selector != @selector(keyUp:))
 120     {
 121         [super noResponderFor:selector];
 122 //        wxOSX_NoResponderHandlerPtr superimpl = (wxOSX_NoResponderHandlerPtr) [[self superclass] instanceMethodForSelector:@selector(noResponderFor:)];
 123 //        superimpl(self, @selector(noResponderFor:), selector);
 124     }
 125 }
 126
 127 @end
 128
 129 @interface wxNSPanel : NSPanel
 130
 131 {
 132     wxNonOwnedWindowCocoaImpl* impl;
 133 }
 134
 135 - (void)setImplementation: (wxNonOwnedWindowCocoaImpl *) theImplementation;
 136 - (wxNonOwnedWindowCocoaImpl*) implementation;
 137 - (void)noResponderFor: (SEL) selector;
 138 @end
 139
 140 @implementation wxNSPanel
 141
 142 - (void)setImplementation: (wxNonOwnedWindowCocoaImpl *) theImplementation
 143 {
 144     impl = theImplementation;
 145 }
 146
 147 - (BOOL)canBecomeKeyWindow
 148 {
 149     return YES;
 150 }
 151
 152 - (wxNonOwnedWindowCocoaImpl*) implementation
 153 {
 154     return impl;
 155 }
 156
 157 - (void)doCommandBySelector:(SEL)selector
 158 {
 159     if (shouldHandleSelector(selector))
 160         [super doCommandBySelector:selector];
 161 }
 162
 163 // NB: if we don't do this, it seems that all events that end here lead to a NSBeep
 164 - (void)noResponderFor: (SEL) selector
 165 {
 166     if (selector != @selector(keyDown:) && selector != @selector(keyUp:))
 167     {
 168         [super noResponderFor:selector];
 169 //        wxOSX_NoResponderHandlerPtr superimpl = (wxOSX_NoResponderHandlerPtr) [[self superclass] instanceMethodForSelector:@selector(noResponderFor:)];
 170 //        superimpl(self, @selector(noResponderFor:), selector);
 171     }
 172 }
 173
 174 @end
 175
 176
 177 //
 178 // controller
 179 //
 180
 181 @interface wxNonOwnedWindowController : NSObject
 182 {
 183 }
 184
 185 - (void)windowDidResize:(NSNotification *)notification;
 186 - (NSSize)windowWillResize:(NSWindow *)window toSize:(NSSize)proposedFrameSize;
 187 - (void)windowDidResignKey:(NSNotification *)notification;
 188 - (void)windowDidBecomeKey:(NSNotification *)notification;
 189 - (void)windowDidMove:(NSNotification *)notification;
 190 - (BOOL)windowShouldClose:(id)window;
 191
 192 @end
 193
 194 @implementation wxNonOwnedWindowController
 195
 196 - (id) init
 197 {
 198     [super init];
 199     return self;
 200 }
 201
 202 - (BOOL)windowShouldClose:(id)nwindow
 203 {
 204     wxNSWindow* window = (wxNSWindow*) nwindow;
 205     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 206     if ( windowimpl )
 207     {
 208         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 209         if ( wxpeer )
 210             wxpeer->Close();
 211     }
 212     return NO;
 213 }
 214
 215 - (NSSize)windowWillResize:(NSWindow *)win
 216                     toSize:(NSSize)proposedFrameSize
 217 {
 218     NSRect frame = [win frame];
 219     wxRect wxframe = wxFromNSRect( NULL, frame );
 220     wxframe.SetWidth( (int)proposedFrameSize.width );
 221     wxframe.SetHeight( (int)proposedFrameSize.height );
 222     wxNSWindow* window = (wxNSWindow*) win;
 223     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 224     if ( windowimpl )
 225     {
 226         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 227         if ( wxpeer )
 228         {
 229             wxpeer->HandleResizing( 0, &wxframe );
 230             NSSize newSize = NSMakeSize(wxframe.GetWidth(), wxframe.GetHeight());
 231             return newSize;
 232         }
 233     }
 234
 235     return proposedFrameSize;
 236 }
 237
 238 - (void)windowDidResize:(NSNotification *)notification
 239 {
 240     wxNSWindow* window = (wxNSWindow*) [notification object];
 241     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 242     if ( windowimpl )
 243     {
 244         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 245         if ( wxpeer )
 246             wxpeer->HandleResized(0);
 247     }
 248 }
 249
 250 - (void)windowDidMove:(NSNotification *)notification
 251 {
 252     wxNSWindow* window = (wxNSWindow*) [notification object];
 253     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 254     if ( windowimpl )
 255     {
 256         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 257         if ( wxpeer )
 258             wxpeer->HandleMoved(0);
 259     }
 260 }
 261
 262 - (void)windowDidBecomeKey:(NSNotification *)notification
 263 {
 264     wxNSWindow* window = (wxNSWindow*) [notification object];
 265     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 266     if ( windowimpl )
 267     {
 268         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 269         if ( wxpeer )
 270             wxpeer->HandleActivated(0, true);
 271     }
 272 }
 273
 274 - (void)windowDidResignKey:(NSNotification *)notification
 275 {
 276     wxNSWindow* window = (wxNSWindow*) [notification object];
 277     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 278     if ( windowimpl )
 279     {
 280         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 281         if ( wxpeer )
 282         {
 283             wxpeer->HandleActivated(0, false);
 284             // Needed for popup window since the firstResponder
 285             // (focus in wx) doesn't change when this
 286             // TLW becomes inactive.
 287             wxFocusEvent event( wxEVT_KILL_FOCUS, wxpeer->GetId());
 288             event.SetEventObject(wxpeer);
 289             wxpeer->HandleWindowEvent(event);
 290         }
 291     }
 292 }
 293
 294 - (id)windowWillReturnFieldEditor:(NSWindow *)sender toObject:(id)anObject
 295 {
 296     wxUnusedVar(sender);
 297
 298     if ([anObject isKindOfClass:[wxNSTextField class]])
 299     {
 300         wxNSTextField* tf = (wxNSTextField*) anObject;
 301         wxNSTextFieldEditor* editor = [tf fieldEditor];
 302         if ( editor == nil )
 303         {
 304             editor = [[wxNSTextFieldEditor alloc] init];
 305             [editor setFieldEditor:YES];
 306             [tf setFieldEditor:editor];
 307         }
 308         return editor;
 309     }
 310
 311     return nil;
 312 }
 313
 314 @end
 315
 316 IMPLEMENT_DYNAMIC_CLASS( wxNonOwnedWindowCocoaImpl , wxNonOwnedWindowImpl )
 317
 318 wxNonOwnedWindowCocoaImpl::wxNonOwnedWindowCocoaImpl( wxNonOwnedWindow* nonownedwnd) :
 319     wxNonOwnedWindowImpl(nonownedwnd)
 320 {
 321     m_macWindow = NULL;
 322     m_macFullScreenData = NULL;
 323 }
 324
 325 wxNonOwnedWindowCocoaImpl::wxNonOwnedWindowCocoaImpl()
 326 {
 327     m_macWindow = NULL;
 328     m_macFullScreenData = NULL;
 329 }
 330
 331 wxNonOwnedWindowCocoaImpl::~wxNonOwnedWindowCocoaImpl()
 332 {
 333     [m_macWindow setImplementation:nil];
 334     [m_macWindow setDelegate:nil];
 335     [m_macWindow release];
 336 }
 337
 338 void wxNonOwnedWindowCocoaImpl::Destroy()
 339 {
 340     wxPendingDelete.Append( new wxDeferredObjectDeleter( this ) );
 341 }
 342
 343 void wxNonOwnedWindowCocoaImpl::Create( wxWindow* WXUNUSED(parent), const wxPoint& pos, const wxSize& size,
 344 long style, long extraStyle, const wxString& WXUNUSED(name) )
 345 {
 346     static wxNonOwnedWindowController* controller = NULL;
 347
 348     if ( !controller )
 349         controller =[[wxNonOwnedWindowController alloc] init];
 350
 351
 352     int windowstyle = NSBorderlessWindowMask;
 353
 354     if ( style & wxFRAME_TOOL_WINDOW || ( style & wxPOPUP_WINDOW ) ||
 355             GetWXPeer()->GetExtraStyle() & wxTOPLEVEL_EX_DIALOG )
 356     {
 357         m_macWindow = [wxNSPanel alloc];
 358     }
 359     else
 360         m_macWindow = [wxNSWindow alloc];
 361
 362     CGWindowLevel level = kCGNormalWindowLevel;
 363
 364     if ( style & wxFRAME_TOOL_WINDOW )
 365     {
 366         windowstyle |= NSUtilityWindowMask;
 367         if ( ( style & wxMINIMIZE_BOX ) || ( style & wxMAXIMIZE_BOX ) ||
 368             ( style & wxCLOSE_BOX ) || ( style & wxSYSTEM_MENU ) )
 369         {
 370             windowstyle |= NSTitledWindowMask ;
 371         }
 372     }
 373     else if ( ( style & wxPOPUP_WINDOW ) )
 374     {
 375         level = kCGPopUpMenuWindowLevel;
 376         /*
 377         if ( ( style & wxBORDER_NONE ) )
 378         {
 379             wclass = kHelpWindowClass ;   // has no border
 380             attr |= kWindowNoShadowAttribute;
 381         }
 382         else
 383         {
 384             wclass = kPlainWindowClass ;  // has a single line border, it will have to do for now
 385         }
 386         */
 387     }
 388     else if ( ( style & wxCAPTION ) )
 389     {
 390         windowstyle |= NSTitledWindowMask ;
 391     }
 392     else if ( ( style & wxFRAME_DRAWER ) )
 393     {
 394         /*
 395         wclass = kDrawerWindowClass;
 396         */
 397     }
 398     else
 399     {
 400         // set these even if we have no title, otherwise the controls won't be visible
 401         if ( ( style & wxMINIMIZE_BOX ) || ( style & wxMAXIMIZE_BOX ) ||
 402             ( style & wxCLOSE_BOX ) || ( style & wxSYSTEM_MENU ) )
 403         {
 404             windowstyle |= NSTitledWindowMask ;
 405         }
 406         /*
 407         else if ( ( style & wxNO_BORDER ) )
 408         {
 409             wclass = kSimpleWindowClass ;
 410         }
 411         else
 412         {
 413             wclass = kPlainWindowClass ;
 414         }
 415         */
 416     }
 417
 418     if ( windowstyle & NSTitledWindowMask )
 419     {
 420         if ( ( style & wxMINIMIZE_BOX ) )
 421             windowstyle |= NSMiniaturizableWindowMask ;
 422
 423         if ( ( style & wxMAXIMIZE_BOX ) )
 424             windowstyle |= NSResizableWindowMask ; // TODO showing ZOOM ?
 425
 426         if ( ( style & wxRESIZE_BORDER ) )
 427             windowstyle |= NSResizableWindowMask ;
 428
 429         if ( ( style & wxCLOSE_BOX) )
 430             windowstyle |= NSClosableWindowMask ;
 431     }
 432     if ( extraStyle & wxFRAME_EX_METAL)
 433         windowstyle |= NSTexturedBackgroundWindowMask;
 434
 435     if ( ( style & wxFRAME_FLOAT_ON_PARENT ) || ( style & wxFRAME_TOOL_WINDOW ) )
 436         level = kCGFloatingWindowLevel;
 437
 438     if ( ( style & wxSTAY_ON_TOP ) )
 439         level = kCGUtilityWindowLevel;
 440
 441     NSRect r = wxToNSRect( NULL, wxRect( pos, size) );
 442
 443     [m_macWindow setImplementation:this];
 444
 445     [m_macWindow initWithContentRect:r
 446         styleMask:windowstyle
 447         backing:NSBackingStoreBuffered
 448         defer:NO
 449         ];
 450
 451     [m_macWindow setLevel:level];
 452
 453     [m_macWindow setDelegate:controller];
 454
 455     [m_macWindow setAcceptsMouseMovedEvents: YES];
 456 }
 457
 458
 459 WXWindow wxNonOwnedWindowCocoaImpl::GetWXWindow() const
 460 {
 461     return m_macWindow;
 462 }
 463
 464 void wxNonOwnedWindowCocoaImpl::Raise()
 465 {
 466     [m_macWindow orderWindow:NSWindowAbove relativeTo:0];
 467 }
 468
 469 void wxNonOwnedWindowCocoaImpl::Lower()
 470 {
 471     [m_macWindow orderWindow:NSWindowBelow relativeTo:0];
 472 }
 473
 474 bool wxNonOwnedWindowCocoaImpl::Show(bool show)
 475 {
 476     if ( show )
 477     {
 478         wxNonOwnedWindow* wxpeer = GetWXPeer();
 479         if (wxpeer && !(wxpeer->GetWindowStyle() & wxFRAME_TOOL_WINDOW))
 480             [m_macWindow makeKeyAndOrderFront:nil];
 481         else
 482             [m_macWindow orderFront:nil];
 483
 484         [[m_macWindow contentView] setNeedsDisplay:YES];
 485     }
 486     else
 487         [m_macWindow orderOut:nil];
 488     return true;
 489 }
 490
 491 bool wxNonOwnedWindowCocoaImpl::ShowWithEffect(bool show, wxShowEffect WXUNUSED(effect), unsigned WXUNUSED(timeout))
 492 {
 493     return Show(show);
 494 }
 495
 496 void wxNonOwnedWindowCocoaImpl::Update()
 497 {
 498     [m_macWindow displayIfNeeded];
 499 }
 500
 501 bool wxNonOwnedWindowCocoaImpl::SetTransparent(wxByte alpha)
 502 {
 503     [m_macWindow setAlphaValue:(CGFloat) alpha/255.0];
 504     return true;
 505 }
 506
 507 bool wxNonOwnedWindowCocoaImpl::SetBackgroundColour(const wxColour& WXUNUSED(col) )
 508 {
 509     return true;
 510 }
 511
 512 void wxNonOwnedWindowCocoaImpl::SetExtraStyle( long exStyle )
 513 {
 514     if ( m_macWindow )
 515     {
 516         bool metal = exStyle & wxFRAME_EX_METAL ;
 517         int windowStyle = [ m_macWindow styleMask];
 518         if ( metal && !(windowStyle & NSTexturedBackgroundWindowMask) )
 519         {
 520             wxFAIL_MSG( wxT("Metal Style cannot be changed after creation") );
 521         }
 522         else if ( !metal && (windowStyle & NSTexturedBackgroundWindowMask ) )
 523         {
 524             wxFAIL_MSG( wxT("Metal Style cannot be changed after creation") );
 525         }
 526     }
 527 }
 528
 529 bool wxNonOwnedWindowCocoaImpl::SetBackgroundStyle(wxBackgroundStyle WXUNUSED(style))
 530 {
 531     return true;
 532 }
 533
 534 bool wxNonOwnedWindowCocoaImpl::CanSetTransparent()
 535 {
 536     return true;
 537 }
 538
 539 void wxNonOwnedWindowCocoaImpl::MoveWindow(int x, int y, int width, int height)
 540 {
 541     NSRect r = wxToNSRect( NULL, wxRect(x,y,width, height) );
 542     // do not trigger refreshes upon invisible and possible partly created objects
 543     [m_macWindow setFrame:r display:GetWXPeer()->IsShownOnScreen()];
 544 }
 545
 546 void wxNonOwnedWindowCocoaImpl::GetPosition( int &x, int &y ) const
 547 {
 548     wxRect r = wxFromNSRect( NULL, [m_macWindow frame] );
 549     x = r.GetLeft();
 550     y = r.GetTop();
 551 }
 552
 553 void wxNonOwnedWindowCocoaImpl::GetSize( int &width, int &height ) const
 554 {
 555     NSRect rect = [m_macWindow frame];
 556     width = (int)rect.size.width;
 557     height = (int)rect.size.height;
 558 }
 559
 560 void wxNonOwnedWindowCocoaImpl::GetContentArea( int& left, int &top, int &width, int &height ) const
 561 {
 562     NSRect outer = NSMakeRect(100,100,100,100);
 563     NSRect content = [NSWindow contentRectForFrameRect:outer styleMask:[m_macWindow styleMask] ];
 564     NSRect rect = [[m_macWindow contentView] frame];
 565     left = (int)rect.origin.x;
 566     top = (int)rect.origin.y;
 567     width = (int)rect.size.width;
 568     height = (int)rect.size.height;
 569 }
 570
 571 bool wxNonOwnedWindowCocoaImpl::SetShape(const wxRegion& WXUNUSED(region))
 572 {
 573     return false;
 574 }
 575
 576 void wxNonOwnedWindowCocoaImpl::SetTitle( const wxString& title, wxFontEncoding encoding )
 577 {
 578     [m_macWindow setTitle:wxCFStringRef( title , encoding ).AsNSString()];
 579 }
 580
 581 bool wxNonOwnedWindowCocoaImpl::IsMaximized() const
 582 {
 583     return [m_macWindow isZoomed];
 584 }
 585
 586 bool wxNonOwnedWindowCocoaImpl::IsIconized() const
 587 {
 588     return [m_macWindow isMiniaturized];
 589 }
 590
 591 void wxNonOwnedWindowCocoaImpl::Iconize( bool iconize )
 592 {
 593     if ( iconize )
 594         [m_macWindow miniaturize:nil];
 595     else
 596         [m_macWindow deminiaturize:nil];
 597 }
 598
 599 void wxNonOwnedWindowCocoaImpl::Maximize(bool WXUNUSED(maximize))
 600 {
 601     [m_macWindow zoom:nil];
 602 }
 603
 604
 605 // http://cocoadevcentral.com/articles/000028.php
 606
 607 typedef struct
 608 {
 609     int m_formerLevel;
 610     NSRect m_formerFrame;
 611 } FullScreenData ;
 612
 613 bool wxNonOwnedWindowCocoaImpl::IsFullScreen() const
 614 {
 615     return m_macFullScreenData != NULL ;
 616 }
 617
 618 bool wxNonOwnedWindowCocoaImpl::ShowFullScreen(bool show, long WXUNUSED(style))
 619 {
 620     if ( show )
 621     {
 622         FullScreenData *data = (FullScreenData *)m_macFullScreenData ;
 623         delete data ;
 624         data = new FullScreenData();
 625
 626         m_macFullScreenData = data ;
 627         data->m_formerLevel = [m_macWindow level];
 628         data->m_formerFrame = [m_macWindow frame];
 629         CGDisplayCapture( kCGDirectMainDisplay );
 630         [m_macWindow setLevel:CGShieldingWindowLevel()];
 631         [m_macWindow setFrame:[[NSScreen mainScreen] frame] display:YES];
 632     }
 633     else if ( m_macFullScreenData != NULL )
 634     {
 635         FullScreenData *data = (FullScreenData *) m_macFullScreenData ;
 636         CGDisplayRelease( kCGDirectMainDisplay );
 637         [m_macWindow setLevel:data->m_formerLevel];
 638         [m_macWindow setFrame:data->m_formerFrame display:YES];
 639         delete data ;
 640         m_macFullScreenData = NULL ;
 641     }
 642
 643     return true;
 644 }
 645
 646 void wxNonOwnedWindowCocoaImpl::RequestUserAttention(int WXUNUSED(flags))
 647 {
 648 }
 649
 650 void wxNonOwnedWindowCocoaImpl::ScreenToWindow( int *x, int *y )
 651 {
 652     wxPoint p((x ? *x : 0), (y ? *y : 0) );
 653     NSPoint nspt = wxToNSPoint( NULL, p );
 654     nspt = [m_macWindow convertScreenToBase:nspt];
 655     nspt = [[m_macWindow contentView] convertPoint:nspt fromView:nil];
 656     p = wxFromNSPoint([m_macWindow contentView], nspt);
 657     if ( x )
 658         *x = p.x;
 659     if ( y )
 660         *y = p.y;
 661 }
 662
 663 void wxNonOwnedWindowCocoaImpl::WindowToScreen( int *x, int *y )
 664 {
 665     wxPoint p((x ? *x : 0), (y ? *y : 0) );
 666     NSPoint nspt = wxToNSPoint( [m_macWindow contentView], p );
 667     nspt = [[m_macWindow contentView] convertPoint:nspt toView:nil];
 668     nspt = [m_macWindow convertBaseToScreen:nspt];
 669     p = wxFromNSPoint( NULL, nspt);
 670     if ( x )
 671         *x = p.x;
 672     if ( y )
 673         *y = p.y;
 674 }
 675
 676 wxNonOwnedWindowImpl* wxNonOwnedWindowImpl::CreateNonOwnedWindow( wxNonOwnedWindow* wxpeer, wxWindow* parent, const wxPoint& pos, const wxSize& size,
 677     long style, long extraStyle, const wxString& name )
 678 {
 679     wxNonOwnedWindowImpl* now = new wxNonOwnedWindowCocoaImpl( wxpeer );
 680     now->Create( parent, pos, size, style , extraStyle, name );
 681     return now;
 682 }