m4/ax_pthread.m4

   1 # ===========================================================================
   2 #        http://www.gnu.org/software/autoconf-archive/ax_pthread.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   This macro figures out how to build C programs using POSIX threads. It
  12 #   sets the PTHREAD_LIBS output variable to the threads library and linker
  13 #   flags, and the PTHREAD_CFLAGS output variable to any special C compiler
  14 #   flags that are needed. (The user can also force certain compiler
  15 #   flags/libs to be tested by setting these environment variables.)
  16 #
  17 #   Also sets PTHREAD_CC to any special C compiler that is needed for
  18 #   multi-threaded programs (defaults to the value of CC otherwise). (This
  19 #   is necessary on AIX to use the special cc_r compiler alias.)
  20 #
  21 #   NOTE: You are assumed to not only compile your program with these flags,
  22 #   but also link it with them as well. e.g. you should link with
  23 #   $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS $LIBS
  24 #
  25 #   If you are only building threads programs, you may wish to use these
  26 #   variables in your default LIBS, CFLAGS, and CC:
  27 #
  28 #     LIBS="$PTHREAD_LIBS $LIBS"
  29 #     CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  30 #     CC="$PTHREAD_CC"
  31 #
  32 #   In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute constant
  33 #   has a nonstandard name, defines PTHREAD_CREATE_JOINABLE to that name
  34 #   (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
  35 #
  36 #   Also HAVE_PTHREAD_PRIO_INHERIT is defined if pthread is found and the
  37 #   PTHREAD_PRIO_INHERIT symbol is defined when compiling with
  38 #   PTHREAD_CFLAGS.
  39 #
  40 #   ACTION-IF-FOUND is a list of shell commands to run if a threads library
  41 #   is found, and ACTION-IF-NOT-FOUND is a list of commands to run it if it
  42 #   is not found. If ACTION-IF-FOUND is not specified, the default action
  43 #   will define HAVE_PTHREAD.
  44 #
  45 #   Please let the authors know if this macro fails on any platform, or if
  46 #   you have any other suggestions or comments. This macro was based on work
  47 #   by SGJ on autoconf scripts for FFTW (http://www.fftw.org/) (with help
  48 #   from M. Frigo), as well as ac_pthread and hb_pthread macros posted by
  49 #   Alejandro Forero Cuervo to the autoconf macro repository. We are also
  50 #   grateful for the helpful feedback of numerous users.
  51 #
  52 #   Updated for Autoconf 2.68 by Daniel Richard G.
  53 #
  54 # LICENSE
  55 #
  56 #   Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu>
  57 #   Copyright (c) 2011 Daniel Richard G. <skunk@iSKUNK.ORG>
  58 #
  59 #   This program is free software: you can redistribute it and/or modify it
  60 #   under the terms of the GNU General Public License as published by the
  61 #   Free Software Foundation, either version 3 of the License, or (at your
  62 #   option) any later version.
  63 #
  64 #   This program is distributed in the hope that it will be useful, but
  65 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  66 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  67 #   Public License for more details.
  68 #
  69 #   You should have received a copy of the GNU General Public License along
  70 #   with this program. If not, see <http://www.gnu.org/licenses/>.
  71 #
  72 #   As a special exception, the respective Autoconf Macro's copyright owner
  73 #   gives unlimited permission to copy, distribute and modify the configure
  74 #   scripts that are the output of Autoconf when processing the Macro. You
  75 #   need not follow the terms of the GNU General Public License when using
  76 #   or distributing such scripts, even though portions of the text of the
  77 #   Macro appear in them. The GNU General Public License (GPL) does govern
  78 #   all other use of the material that constitutes the Autoconf Macro.
  79 #
  80 #   This special exception to the GPL applies to versions of the Autoconf
  81 #   Macro released by the Autoconf Archive. When you make and distribute a
  82 #   modified version of the Autoconf Macro, you may extend this special
  83 #   exception to the GPL to apply to your modified version as well.
  84
  85 #serial 21
  86
  87 AU_ALIAS([ACX_PTHREAD], [AX_PTHREAD])
  88 AC_DEFUN([AX_PTHREAD], [
  89 AC_REQUIRE([AC_CANONICAL_HOST])
  90 AC_REQUIRE([AC_PROG_CC])
  91 AC_LANG_PUSH([C])
  92 ax_pthread_ok=no
  93
  94 # We used to check for pthread.h first, but this fails if pthread.h
  95 # requires special compiler flags (e.g. on Tru64 or Sequent).
  96 # It gets checked for in the link test anyway.
  97
  98 # First of all, check if the user has set any of the PTHREAD_LIBS,
  99 # etcetera environment variables, and if threads linking works using
 100 # them:
 101 if test x"$PTHREAD_LIBS$PTHREAD_CFLAGS" != x; then
 102         save_CFLAGS="$CFLAGS"
 103         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 104         save_LIBS="$LIBS"
 105         LIBS="$PTHREAD_LIBS $LIBS"
 106         AC_MSG_CHECKING([for pthread_join using $CC $PTHREAD_CFLAGS $PTHREAD_LIBS])
 107         AC_LINK_IFELSE([AC_LANG_CALL([], [pthread_join])], [ax_pthread_ok=yes])
 108         AC_MSG_RESULT([$ax_pthread_ok])
 109         if test x"$ax_pthread_ok" = xno; then
 110                 PTHREAD_LIBS=""
 111                 PTHREAD_CFLAGS=""
 112         fi
 113         LIBS="$save_LIBS"
 114         CFLAGS="$save_CFLAGS"
 115 fi
 116
 117 # We must check for the threads library under a number of different
 118 # names; the ordering is very important because some systems
 119 # (e.g. DEC) have both -lpthread and -lpthreads, where one of the
 120 # libraries is broken (non-POSIX).
 121
 122 # Create a list of thread flags to try.  Items starting with a "-" are
 123 # C compiler flags, and other items are library names, except for "none"
 124 # which indicates that we try without any flags at all, and "pthread-config"
 125 # which is a program returning the flags for the Pth emulation library.
 126
 127 ax_pthread_flags="pthreads none -Kthread -kthread lthread -pthread -pthreads -mt -mthreads pthread --thread-safe pthread-config"
 128
 129 # The ordering *is* (sometimes) important.  Some notes on the
 130 # individual items follow:
 131
 132 # pthreads: AIX (must check this before -lpthread)
 133 # none: in case threads are in libc; should be tried before -Kthread and
 134 #       other compiler flags to prevent continual compiler warnings
 135 # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
 136 # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
 137 # lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
 138 # -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads), Tru64
 139 # -pthreads: Solaris/gcc
 140 # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
 141 #      doesn't hurt to check since this sometimes defines pthreads and
 142 #      -D_REENTRANT too), HP C (must be checked before -lpthread, which
 143 #      is present but should not be used directly)
 144 # -mthreads: Mingw32/gcc, Lynx/gcc
 145 # pthread: Linux, etcetera
 146 # --thread-safe: KAI C++
 147 # pthread-config: use pthread-config program (for GNU Pth library)
 148
 149 case $host_os in
 150
 151         hpux*)
 152
 153         # From the cc(1) man page: "[-mt] Sets various -D flags to enable
 154         # multi-threading and also sets -lpthread."
 155
 156         ax_pthread_flags="-mt -pthread pthread $ax_pthread_flags"
 157         ;;
 158
 159         openedition*)
 160
 161         # IBM z/OS requires a feature-test macro to be defined in order to
 162         # enable POSIX threads at all, so give the user a hint if this is
 163         # not set. (We don't define these ourselves, as they can affect
 164         # other portions of the system API in unpredictable ways.)
 165
 166         AC_EGREP_CPP([AX_PTHREAD_ZOS_MISSING],
 167             [
 168 #            if !defined(_OPEN_THREADS) && !defined(_UNIX03_THREADS)
 169              AX_PTHREAD_ZOS_MISSING
 170 #            endif
 171             ],
 172             [AC_MSG_WARN([IBM z/OS requires -D_OPEN_THREADS or -D_UNIX03_THREADS to enable pthreads support.])])
 173         ;;
 174
 175         solaris*)
 176
 177         # Newer versions of Solaris require the "-mt -lpthread" pair, and we
 178         # check that first.  On some older versions, libc contains stubbed
 179         # (non-functional) versions of the pthreads routines, so link-based
 180         # tests will erroneously succeed.  (We need to link with -pthreads/-mt/
 181         # -lpthread.)  (The stubs are missing pthread_cleanup_push, or rather
 182         # a function called by this macro, so we could check for that, but
 183         # who knows whether they'll stub that too in a future libc.)  So
 184         # we'll look for -pthreads and -lpthread shortly thereafter.
 185
 186         ax_pthread_flags="-mt,pthread -pthreads -pthread pthread $ax_pthread_flags"
 187         ;;
 188 esac
 189
 190 # Older versions of Clang only give a warning instead of an error for an
 191 # unrecognized option, unless we specify -Werror. (We throw in some extra
 192 # Clang warning flags for good measure.)
 193
 194 AC_CACHE_CHECK([if compiler needs certain flags to reject unknown flags],
 195     [ax_cv_PTHREAD_REJECT_UNKNOWN],
 196     [ax_cv_PTHREAD_REJECT_UNKNOWN=unknown
 197      save_CFLAGS="$CFLAGS"
 198      ax_pthread_extra_flags="-Wunknown-warning-option -Wunused-command-line-argument"
 199      CFLAGS="$CFLAGS $ax_pthread_extra_flags -Wfoobaz -foobaz"
 200      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int foo(void);],[foo()])],
 201                        [ax_cv_PTHREAD_REJECT_UNKNOWN="-Werror $ax_pthread_extra_flags"],
 202                        [ax_cv_PTHREAD_REJECT_UNKNOWN=no])
 203      CFLAGS="$save_CFLAGS"
 204     ])
 205 ax_pthread_extra_flags=
 206 AS_IF([test "x$ax_cv_PTHREAD_REJECT_UNKNOWN" != "xno"],
 207       [ax_pthread_extra_flags="$ax_cv_PTHREAD_REJECT_UNKNOWN"])
 208
 209 if test x"$ax_pthread_ok" = xno; then
 210 for flag in $ax_pthread_flags; do
 211
 212         case $flag in
 213                 none)
 214                 AC_MSG_CHECKING([whether pthreads work without any flags])
 215                 ;;
 216
 217                 -mt,pthread)
 218                 AC_MSG_CHECKING([whether pthreads work with -mt -lpthread])
 219                 PTHREAD_CFLAGS="-mt"
 220                 PTHREAD_LIBS="-lpthread"
 221                 ;;
 222
 223                 -*)
 224                 AC_MSG_CHECKING([whether pthreads work with $flag])
 225                 PTHREAD_CFLAGS="$flag"
 226                 ;;
 227
 228                 pthread-config)
 229                 AC_CHECK_PROG([ax_pthread_config], [pthread-config], [yes], [no])
 230                 if test x"$ax_pthread_config" = xno; then continue; fi
 231                 PTHREAD_CFLAGS="`pthread-config --cflags`"
 232                 PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
 233                 ;;
 234
 235                 *)
 236                 AC_MSG_CHECKING([for the pthreads library -l$flag])
 237                 PTHREAD_LIBS="-l$flag"
 238                 ;;
 239         esac
 240
 241         save_LIBS="$LIBS"
 242         save_CFLAGS="$CFLAGS"
 243         LIBS="$PTHREAD_LIBS $LIBS"
 244         CFLAGS="$CFLAGS $PTHREAD_CFLAGS $ax_pthread_extra_flags"
 245
 246         # Check for various functions.  We must include pthread.h,
 247         # since some functions may be macros.  (On the Sequent, we
 248         # need a special flag -Kthread to make this header compile.)
 249         # We check for pthread_join because it is in -lpthread on IRIX
 250         # while pthread_create is in libc.  We check for pthread_attr_init
 251         # due to DEC craziness with -lpthreads.  We check for
 252         # pthread_cleanup_push because it is one of the few pthread
 253         # functions on Solaris that doesn't have a non-functional libc stub.
 254         # We try pthread_create on general principles.
 255         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>
 256                         static void routine(void *a) { a = 0; }
 257                         static void *start_routine(void *a) { return a; }],
 258                        [pthread_t th; pthread_attr_t attr;
 259                         pthread_create(&th, 0, start_routine, 0);
 260                         pthread_join(th, 0);
 261                         pthread_attr_init(&attr);
 262                         pthread_cleanup_push(routine, 0);
 263                         pthread_cleanup_pop(0) /* ; */])],
 264                 [ax_pthread_ok=yes],
 265                 [])
 266
 267         LIBS="$save_LIBS"
 268         CFLAGS="$save_CFLAGS"
 269
 270         AC_MSG_RESULT([$ax_pthread_ok])
 271         if test "x$ax_pthread_ok" = xyes; then
 272                 break;
 273         fi
 274
 275         PTHREAD_LIBS=""
 276         PTHREAD_CFLAGS=""
 277 done
 278 fi
 279
 280 # Various other checks:
 281 if test "x$ax_pthread_ok" = xyes; then
 282         save_LIBS="$LIBS"
 283         LIBS="$PTHREAD_LIBS $LIBS"
 284         save_CFLAGS="$CFLAGS"
 285         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 286
 287         # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
 288         AC_CACHE_CHECK([for joinable pthread attribute],
 289             [ax_cv_PTHREAD_JOINABLE_ATTR],
 290             [ax_cv_PTHREAD_JOINABLE_ATTR=unknown
 291              for attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
 292                  AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>],
 293                                                  [int attr = $attr; return attr /* ; */])],
 294                                 [ax_cv_PTHREAD_JOINABLE_ATTR=$attr; break],
 295                                 [])
 296              done
 297             ])
 298         AS_IF([test "$ax_cv_PTHREAD_JOINABLE_ATTR" != unknown && \
 299                test "$ax_cv_PTHREAD_JOINABLE_ATTR" != PTHREAD_CREATE_JOINABLE],
 300               [AC_DEFINE_UNQUOTED([PTHREAD_CREATE_JOINABLE],
 301                                   [$ax_cv_PTHREAD_JOINABLE_ATTR],
 302                                   [Define to necessary symbol if this constant
 303                                    uses a non-standard name on your system.])])
 304
 305         AC_CACHE_CHECK([if more special flags are required for pthreads],
 306             [ax_cv_PTHREAD_SPECIAL_FLAGS],
 307             [ax_cv_PTHREAD_SPECIAL_FLAGS=no
 308              ax_pthread_special_flags_added=no
 309              AC_EGREP_CPP([AX_PTHREAD_NEED_SPECIAL_FLAG],
 310                  [
 311 #                 if !defined(_REENTRANT) && !defined(_THREAD_SAFE)
 312                   AX_PTHREAD_NEED_SPECIAL_FLAG
 313 #                 endif
 314                  ],
 315                  [case $host_os in
 316                   aix* | freebsd*)
 317                   ax_cv_PTHREAD_SPECIAL_FLAGS="-D_THREAD_SAFE"
 318                   ;;
 319                   darwin* | hpux* | osf* | solaris*)
 320                   ax_cv_PTHREAD_SPECIAL_FLAGS="-D_REENTRANT"
 321                   ;;
 322                   esac
 323                  ])
 324             ])
 325         AS_IF([test "x$ax_cv_PTHREAD_SPECIAL_FLAGS" != "xno" && \
 326                test "x$ax_pthread_special_flags_added" != "xyes"],
 327               [PTHREAD_CFLAGS="$ax_cv_PTHREAD_SPECIAL_FLAGS $PTHREAD_CFLAGS"
 328                ax_pthread_special_flags_added=yes])
 329
 330         AC_CACHE_CHECK([for PTHREAD_PRIO_INHERIT],
 331             [ax_cv_PTHREAD_PRIO_INHERIT],
 332             [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]],
 333                                              [[int i = PTHREAD_PRIO_INHERIT;]])],
 334                             [ax_cv_PTHREAD_PRIO_INHERIT=yes],
 335                             [ax_cv_PTHREAD_PRIO_INHERIT=no])
 336             ])
 337         AS_IF([test "x$ax_cv_PTHREAD_PRIO_INHERIT" = "xyes"],
 338             [AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], [1], [Have PTHREAD_PRIO_INHERIT.])])
 339
 340         LIBS="$save_LIBS"
 341         CFLAGS="$save_CFLAGS"
 342
 343         # More AIX lossage: compile with *_r variant
 344         if test "x$GCC" != xyes; then
 345             case $host_os in
 346                 aix*)
 347                 AS_CASE(["x/$CC"],
 348                   [x*/c89|x*/c89_128|x*/c99|x*/c99_128|x*/cc|x*/cc128|x*/xlc|x*/xlc_v6|x*/xlc128|x*/xlc128_v6],
 349                   [#handle absolute path differently from PATH based program lookup
 350                    AS_CASE(["x$CC"],
 351                      [x/*],
 352                      [AS_IF([AS_EXECUTABLE_P([${CC}_r])],[PTHREAD_CC="${CC}_r"])],
 353                      [AC_CHECK_PROGS([PTHREAD_CC],[${CC}_r],[$CC])])])
 354                 ;;
 355             esac
 356         fi
 357 fi
 358
 359 test -n "$PTHREAD_CC" || PTHREAD_CC="$CC"
 360
 361 AC_SUBST([PTHREAD_LIBS])
 362 AC_SUBST([PTHREAD_CFLAGS])
 363 AC_SUBST([PTHREAD_CC])
 364
 365 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
 366 if test x"$ax_pthread_ok" = xyes; then
 367         ifelse([$1],,[AC_DEFINE([HAVE_PTHREAD],[1],[Define if you have POSIX threads libraries and header files.])],[$1])
 368         :
 369 else
 370         ax_pthread_ok=no
 371         $2
 372 fi
 373 AC_LANG_POP
 374 ])dnl AX_PTHREAD