X-Git-Url: https://git.saurik.com/bison.git/blobdiff_plain/7c4399eda18fe3d5104a23b77d0844f1a41fb8e4..8adfa272f72683102c45cc6eaba00aaa5db2497a:/configure.in

diff --git a/configure.in b/configure.in
index a8eb98a2..b6788873 100644
--- a/configure.in
+++ b/configure.in
@@ -1,12 +1,108 @@
-dnl Process this file with autoconf to produce a configure script.
-AC_INIT(reduce.c)
+# Configure template for GNU Bison.                   -*-Autoconf-*-
+#
+# Copyright 2001  Free Software Foundation, Inc.
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+# 02111-1307  USA
+
+# We need a recent Autoconf to run a recent Autotest.
+AC_PREREQ(2.52g)
+
+AC_INIT([GNU Bison], [1.49a], [bug-bison@gnu.org])
+AC_CONFIG_AUX_DIR(config)
+
+AM_INIT_AUTOMAKE([bison], [1.49a])
+AM_CONFIG_HEADER(config.h:config.hin)
+
+# Initialize the test suite.
+AC_CONFIG_TESTDIR(tests)
+AC_CONFIG_FILES([tests/Makefile tests/atlocal])
+AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
+# Needed by tests/atlocal.in.
+AC_SUBST([GCC])
+
+# Checks for programs.
 AC_PROG_CC
-AC_PROG_CPP
-AC_PROG_INSTALL
 AC_MINIX
 AC_ISC_POSIX
-AC_STDC_HEADERS
-AC_HAVE_HEADERS(string.h stdlib.h memory.h)
-AC_HAVE_FUNCS(strerror)
-AC_ALLOCA
-AC_OUTPUT(Makefile)
+AM_PROG_CC_STDC
+AC_PROG_RANLIB
+AM_MISSING_PROG([AUTOM4TE], [autom4te])
+
+AC_ARG_ENABLE(gcc-warnings,
+[  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
+[case "${enableval}" in
+   yes|no) ;;
+   *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
+ esac],
+              [enableval=no])
+if test "${enableval}" = yes; then
+  BISON_WARNING(-Wall)
+  BISON_WARNING(-W)
+  BISON_WARNING(-Wbad-function-cast)
+  BISON_WARNING(-Wcast-align)
+  BISON_WARNING(-Wcast-qual)
+  BISON_WARNING(-Wformat)
+  BISON_WARNING(-Wmissing-declarations)
+  BISON_WARNING(-Wmissing-prototypes)
+  BISON_WARNING(-Wnested-externs)
+  BISON_WARNING(-Wshadow)
+  BISON_WARNING(-Wstrict-prototypes)
+  BISON_WARNING(-Wwrite-strings)
+  BISON_WARNING(-Werror)
+fi
+
+# Checks for libraries.
+AC_DEFINE([_GNU_SOURCE],1,[Define to 1 for GNU C library extensions.])
+
+# Checks for header files.
+AC_HEADER_STDC
+AC_CHECK_HEADERS(ctype.h locale.h memory.h stdlib.h string.h unistd.h)
+
+# Checks for typedefs.
+
+# Checks for structures.
+
+# Checks for compiler characteristics.
+AC_C_CONST
+AC_C_INLINE
+AM_C_PROTOTYPES
+
+# Checks for library functions.
+AC_FUNC_ALLOCA
+AC_FUNC_OBSTACK
+AC_FUNC_ERROR_AT_LINE
+AC_CHECK_FUNCS(mkstemp setlocale)
+AC_CHECK_DECLS([stpcpy, strndup, strnlen, memchr])
+AC_REPLACE_FUNCS(stpcpy strndup strnlen strspn memchr)
+jm_FUNC_MALLOC
+jm_FUNC_REALLOC
+jm_PREREQ_QUOTEARG
+jm_PREREQ_ERROR
+AM_WITH_DMALLOC
+
+ALL_LINGUAS="de es et fr ja nl ru sv tr"
+AM_GNU_GETTEXT(, need-ngettext)
+
+# This is necessary so that .o files in LIBOBJS are also built via
+# the ANSI2KNR-filtering rules.
+LIB@&t@OBJS=`echo $LIB@&t@OBJS|sed 's/\.o /\$U.o /g;s/\.o$/\$U.o/'`
+AC_SUBST(LIB@&t@OBJS)
+
+AC_OUTPUT([Makefile
+           config/Makefile
+           intl/Makefile po/Makefile.in
+           lib/Makefile src/Makefile doc/Makefile
+           m4/Makefile])