/* Scan Bison Skeletons.                                       -*- C -*-

   Copyright (C) 2001-2012 Free Software Foundation, Inc.

   This file is part of Bison, the GNU Compiler Compiler.

   This program is free software: you can redistribute it and/or modify
   it under the terms of the GNU General Public License as published by
   the Free Software Foundation, either version 3 of the License, or
   (at your option) any later version.

   This program is distributed in the hope that it will be useful,
   but WITHOUT ANY WARRANTY; without even the implied warranty of
   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   GNU General Public License for more details.

   You should have received a copy of the GNU General Public License
   along with this program.  If not, see <http://www.gnu.org/licenses/>.  */

%option nodefault noyywrap noinput nounput never-interactive debug
%option prefix="skel_" outfile="lex.yy.c"

%{
/* Work around a bug in flex 2.5.31.  See Debian bug 333231
   <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=333231>.  */
#undef skel_wrap
#define skel_wrap() 1

#define FLEX_PREFIX(Id) skel_ ## Id
#include <src/flex-scanner.h>

#include <dirname.h>
#include <error.h>
#include <quotearg.h>

#include <src/complain.h>
#include <src/getargs.h>
#include <src/files.h>
#include <src/scan-skel.h>

#define YY_DECL static int skel_lex (void)
YY_DECL;

static void at_directive_perform (int argc, char *argv[],
                                  char **outnamep, int *out_linenop);
static void fail_for_at_directive_too_many_args (char const *at_directive_name);
static void fail_for_at_directive_too_few_args (char const *at_directive_name);
static void fail_for_invalid_at (char const *at);
%}

%x SC_AT_DIRECTIVE_ARGS
%x SC_AT_DIRECTIVE_SKIP_WS

%%

%{
  int out_lineno PACIFY_CC (= 0);
  char *outname = NULL;

  /* Currently, only the @warn, @complain, @fatal, @warn_at, @complain_at, and
     @fatal_at directives take multiple arguments, and the last three already
     can't take more than 7.  argv[0] is the directive name.  */
  #define ARGC_MAX 8
  int argc = 0;
  char *argv[ARGC_MAX];
%}

"@@" fputc ('@', yyout);
"@{" fputc ('[', yyout);
"@}" fputc (']', yyout);
"@`" continue;  /* Used by b4_cat in ../data/bison.m4.  */
@\n  continue;

"@oline@"  fprintf (yyout, "%d", out_lineno + 1);
"@ofile@"  fputs (quotearg_style (c_quoting_style, outname), yyout);

@[a-z_]+"(" {
  yytext[yyleng-1] = '\0';
  obstack_grow (&obstack_for_string, yytext, yyleng);
  argv[argc++] = obstack_finish (&obstack_for_string);
  BEGIN SC_AT_DIRECTIVE_ARGS;
}

  /* This pattern must not match more than the previous @ patterns. */
@[^@{}`(\n]* fail_for_invalid_at (yytext);
\n         out_lineno++; ECHO;
[^@\n]+    ECHO;

<INITIAL><<EOF>> {
  if (outname)
    {
      free (outname);
      xfclose (yyout);
    }
  return EOF;
}

<SC_AT_DIRECTIVE_ARGS>
{
  [^@]+  STRING_GROW;

  "@@"   obstack_1grow (&obstack_for_string, '@');
  "@{"   obstack_1grow (&obstack_for_string, '[');
  "@}"   obstack_1grow (&obstack_for_string, ']');
  "@`"   continue; /* For starting an argument that begins with whitespace. */
  @\n    continue;

  @[,)] {
    if (argc >= ARGC_MAX)
      fail_for_at_directive_too_many_args (argv[0]);

    argv[argc++] = obstack_finish0 (&obstack_for_string);

    /* Like M4, skip whitespace after a comma.  */
    if (yytext[1] == ',')
      BEGIN SC_AT_DIRECTIVE_SKIP_WS;
    else
      {
        at_directive_perform (argc, argv, &outname, &out_lineno);
        obstack_free (&obstack_for_string, argv[0]);
        argc = 0;
        BEGIN INITIAL;
      }
  }

  @.?  fail_for_invalid_at (yytext);
}

<SC_AT_DIRECTIVE_SKIP_WS>
{
  [ \t\r\n]    continue;
  .            yyless (0); BEGIN SC_AT_DIRECTIVE_ARGS;
}

<SC_AT_DIRECTIVE_ARGS,SC_AT_DIRECTIVE_SKIP_WS>
{
  <<EOF>>  complain (NULL, fatal, _("unclosed %s directive in skeleton"), argv[0]);
}

%%

/*------------------------.
| Scan a Bison skeleton.  |
`------------------------*/

void
scan_skel (FILE *in)
{
  static bool initialized = false;
  if (!initialized)
    {
      initialized = true;
      obstack_init (&obstack_for_string);
    }
  skel_in = in;
  skel__flex_debug = trace_flag & trace_skeleton;
  skel_lex ();
}

void
skel_scanner_free (void)
{
  obstack_free (&obstack_for_string, 0);
  /* Reclaim Flex's buffers.  */
  yylex_destroy ();
}

static inline warnings
flag (const char *arg)
{
  switch (arg[1])
    {
    case 'w': return Wother;
    case 'c': return complaint;
    case 'f': return fatal;
    default: aver (false); break;
    }
}

static void
at_directive_perform (int argc, char *argv[], char **outnamep, int *out_linenop)
{
  if (STREQ (argv[0], "@basename"))
    {
      if (argc > 2)
        fail_for_at_directive_too_many_args (argv[0]);
      fputs (last_component (argv[1]), yyout);
    }
  else if (STREQ (argv[0], "@warn") || STREQ (argv[0], "@warn_at")
           || STREQ (argv[0], "@complain") || STREQ (argv[0], "@complain_at")
           || STREQ (argv[0], "@fatal") || STREQ (argv[0], "@fatal_at"))
    {
      warnings w = flag (*argv);
      location loc;
      location *locp = NULL;
      if (STREQ (*argv + strlen (*argv) - 3, "_at"))
        {
          if (argc < 4)
            fail_for_at_directive_too_few_args (argv[0]);
          boundary_set_from_string (&loc.start, argv[1]);
          boundary_set_from_string (&loc.end, argv[2]);
          argc -= 2;
          argv += 2;
          locp = &loc;
        }
      else if (argc < 2)
        fail_for_at_directive_too_few_args (argv[0]);
      complain_args (locp, w, argc, argv);
    }
  else if (STREQ (argv[0], "@output"))
    {
      if (argc > 2)
        fail_for_at_directive_too_many_args (argv[0]);
      if (*outnamep)
        {
          free (*outnamep);
          xfclose (yyout);
        }
      *outnamep = xstrdup (argv[1]);
      output_file_name_check (outnamep);
      yyout = xfopen (*outnamep, "w");
      *out_linenop = 1;
    }
  else
    fail_for_invalid_at (argv[0]);
}

static void
fail_for_at_directive_too_few_args (char const *at_directive_name)
{
  complain (NULL, fatal, _("too few arguments for %s directive in skeleton"),
            at_directive_name);
}

static void
fail_for_at_directive_too_many_args (char const *at_directive_name)
{
  complain (NULL, fatal, _("too many arguments for %s directive in skeleton"),
            at_directive_name);
}

static void
fail_for_invalid_at (char const *at)
{
  complain (NULL, fatal, "invalid @ in skeleton: %s", at);
}