configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2012 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.  We need Autoconf 2.68 or
  21 # better to avoid a typo in the `configure --help' entry for the YACC
  22 # environment variable.
  23 AC_PREREQ([2.68])
  24 m4_pattern_forbid([^gl_[A-Z]])
  25
  26 AC_INIT([GNU Bison],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-bison@gnu.org])
  29 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2012])
  30 AC_DEFINE_UNQUOTED([PACKAGE_COPYRIGHT_YEAR], [$PACKAGE_COPYRIGHT_YEAR],
  31                    [The copyright year for this package])
  32
  33 AC_CONFIG_AUX_DIR([build-aux])
  34 AC_CONFIG_MACRO_DIR([m4])
  35
  36 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  37 #
  38 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  39 #
  40 # To avoid 1.11, we make 1.11.1 the minimum version.
  41 #
  42 # We want gnits strictness only when rolling a stable release.  For
  43 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  44 # doesn't like that, so we let the underscore disable gnits.  Between
  45 # releases, we want to be able run make dist without being required to
  46 # add a bogus NEWS entry.  In that case, the version string
  47 # automatically contains a dash, which we also let disable gnits.
  48 AM_INIT_AUTOMAKE([1.11.1 dist-xz silent-rules]
  49                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  50                            [gnu], [gnits]))
  51 AM_SILENT_RULES([yes])
  52 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  53
  54 # Checks for the compiler.
  55 AC_PROG_CC_STDC
  56
  57 # Gnulib (early checks).
  58 gl_EARLY
  59
  60 AC_ARG_ENABLE(gcc-warnings,
  61 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  62 [case "${enableval}" in
  63    yes|no) ;;
  64    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  65  esac],
  66               [enableval=no])
  67 if test "${enableval}" = yes; then
  68   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  69   AC_SUBST([WERROR_CFLAGS])
  70   gl_WARN_ADD([-Wall])
  71   gl_WARN_ADD([-Wextra -Wno-sign-compare])
  72   gl_WARN_ADD([-Wcast-align])
  73   gl_WARN_ADD([-Wcast-qual])
  74   gl_WARN_ADD([-Wformat])
  75   gl_WARN_ADD([-Wpointer-arith])
  76   gl_WARN_ADD([-Wwrite-strings])
  77   AC_SUBST([WARN_CXXFLAGS], [$WARN_CFLAGS])
  78   # The following warnings are not suitable for C++.
  79   gl_WARN_ADD([-Wbad-function-cast])
  80   gl_WARN_ADD([-Wmissing-declarations])
  81   gl_WARN_ADD([-Wmissing-prototypes])
  82   gl_WARN_ADD([-Wshadow])
  83   gl_WARN_ADD([-Wstrict-prototypes])
  84   AC_SUBST([WARN_CFLAGS])
  85   # Warnings for the test suite only.
  86   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
  87   gl_WARN_ADD([-pedantic], [WARN_CFLAGS_TEST])
  88   AC_SUBST([WARN_CXXFLAGS_TEST], ["$WARN_CXXFLAGS $WARN_CFLAGS_TEST"])
  89   AC_SUBST([WARN_CFLAGS_TEST], ["$WARN_CFLAGS $WARN_CFLAGS_TEST"])
  90 fi
  91
  92 BISON_TEST_FOR_WORKING_C_COMPILER
  93
  94 AC_ARG_ENABLE([yacc],
  95   [AC_HELP_STRING([--disable-yacc],
  96      [do not build a yacc command or an -ly library])],
  97   , [enable_yacc=yes])
  98 case $enable_yacc in
  99 yes)
 100   YACC_SCRIPT=yacc
 101   YACC_LIBRARY=liby.a;;
 102 *)
 103   YACC_SCRIPT=
 104   YACC_LIBRARY=;;
 105 esac
 106 AC_SUBST([YACC_SCRIPT])
 107 AC_SUBST([YACC_LIBRARY])
 108
 109 # Checks for programs.
 110 AC_PROG_LEX
 111 AC_PROG_YACC
 112 AC_PROG_RANLIB
 113 AC_PROG_GNU_M4
 114 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 115 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 116 supports -g, otherwise to "".])
 117 AM_MISSING_PROG([HELP2MAN], [help2man])
 118 AC_PATH_PROG([XSLTPROC], [xsltproc])
 119 AC_SUBST([XSLTPROC])
 120
 121 # Checks for header files.
 122 AC_CHECK_HEADERS_ONCE([locale.h])
 123
 124 # Checks for compiler characteristics.
 125 AC_C_INLINE
 126
 127 # Gnulib (later checks).  Putting them here rather than right after
 128 # gl_EARLY avoids some redundant checks.
 129 gl_INIT
 130
 131 # Checks for library functions.
 132 AC_CHECK_FUNCS_ONCE([setlocale])
 133 AM_WITH_DMALLOC
 134 BISON_PREREQ_SUBPIPE
 135 BISON_PREREQ_TIMEVAR
 136
 137 # Gettext.
 138 # We use gnulib, which is only guaranteed to work properly with the
 139 # latest Gettext.
 140 AM_GNU_GETTEXT([external], [need-ngettext])
 141 AM_GNU_GETTEXT_VERSION([0.18])
 142 BISON_I18N
 143
 144 # Internationalized parsers.
 145 AC_CONFIG_FILES([runtime-po/Makefile.in])
 146 # Autoconf macros for packages using internationalized parsers.
 147 aclocaldir='${datadir}/aclocal'
 148 AC_SUBST([aclocaldir])
 149
 150 # Create the benchmark script.
 151 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 152
 153 # Initialize the test suite.
 154 AC_CONFIG_TESTDIR(tests)
 155 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 156 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 157 AC_CHECK_PROGS([VALGRIND], [valgrind])
 158 AC_PROG_CXX
 159 BISON_TEST_FOR_WORKING_CXX_COMPILER
 160 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 161 # Needed by tests/atlocal.in.
 162 AC_SUBST([GCC])
 163 AC_SUBST([O0CFLAGS],   [`echo $CFLAGS   | sed 's/-O[[0-9]] *//'`])
 164 AC_SUBST([O0CXXFLAGS], [`echo $CXXFLAGS | sed 's/-O[[0-9]] *//'`])
 165
 166 gt_JAVACOMP([1.3])
 167 gt_JAVAEXEC
 168
 169 AC_CONFIG_FILES([Makefile
 170                  build-aux/Makefile
 171                  po/Makefile.in
 172                  data/Makefile
 173                  etc/Makefile
 174                  examples/Makefile
 175                     examples/calc++/Makefile
 176                  lib/Makefile src/Makefile
 177                  doc/Makefile
 178                    doc/yacc.1])
 179 AC_OUTPUT