tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4 # Copyright (C) 2003 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  19 # 02111-1307, USA.
  20
  21
  22 ## ------------------------------- ##
  23 ## Macros decoding Bison options.  ##
  24 ## ------------------------------- ##
  25
  26
  27 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  28 # -----------------------------------------
  29 m4_define([AT_BISON_OPTION_PUSHDEFS],
  30 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  31
  32
  33 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  34 # --------------------------------------------------
  35 # This macro works around the impossibility to define macros
  36 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  37 # This sucks hard, GNU M4 should really provide M5 like $$1.
  38 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  39 [m4_if([$1$2], $[1]$[2], [],
  40        [m4_fatal([$0: Invalid arguments: $@])])dnl
  41 m4_pushdef([AT_LALR1_CC_IF],
  42 [m4_bmatch([$3], ["lalr1.cc"], [$1], [$2])])
  43 m4_pushdef([AT_GLR_IF],
  44 [m4_bmatch([$3], [%glr-parser], [$1], [$2])])
  45 # Using yacc.c?
  46 m4_pushdef([AT_YACC_IF],
  47 [m4_bmatch([$3], [%glr-parser\|%skeleton], [$2], [$1])])
  48 m4_pushdef([AT_PARAM_IF],
  49 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
  50 m4_pushdef([AT_LOCATION_IF],
  51 [m4_bmatch([$3], [%locations], [$1], [$2])])
  52 m4_pushdef([AT_PURE_IF],
  53 [m4_bmatch([$3], [%pure-parser], [$1], [$2])])
  54 m4_pushdef([AT_PURE_AND_LOC_IF],
  55 [m4_bmatch([$3], [%locations.*%pure-parser\|%pure-parser.*%locations],
  56            [$1], [$2])])
  57 m4_pushdef([AT_GLR_OR_PARAM_IF],
  58 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
  59
  60 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
  61 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
  62 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
  63                     [$2])])
  64 # yyerror always sees the locations (when activated), except if
  65 # yacc & pure & !param.
  66 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
  67 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
  68                                         [$1])],
  69                             [$1])],
  70                 [$2])])
  71
  72 # The interface is pure: either because %pure-parser, or because we
  73 # are using the C++ parsers.
  74 m4_pushdef([AT_PURE_LEX_IF],
  75 [AT_PURE_IF([$1],
  76             [AT_LALR1_CC_IF([$1], [$2])])])
  77
  78 AT_PURE_LEX_IF(
  79 [m4_pushdef([AT_LOC], [(*yylloc)])
  80  m4_pushdef([AT_VAL], [(*yylval)])
  81  m4_pushdef([AT_LEX_FORMALS],
  82             [YYSTYPE *yylval[]AT_LOCATION_IF([, YYLTYPE *yylloc])])
  83  m4_pushdef([AT_LEX_ARGS],
  84             [yylval[]AT_LOCATION_IF([, yylloc])])
  85  m4_pushdef([AT_USE_LEX_ARGS],
  86             [(void) yylval;AT_LOCATION_IF([(void) yylloc])])
  87  m4_pushdef([AT_LEX_PRE_FORMALS],
  88             [AT_LEX_FORMALS, ])
  89  m4_pushdef([AT_LEX_PRE_ARGS],
  90             [AT_LEX_ARGS, ])
  91 ],
  92 [m4_pushdef([AT_LOC], [(yylloc)])
  93  m4_pushdef([AT_VAL], [(yylval)])
  94  m4_pushdef([AT_LEX_FORMALS],     [void])
  95  m4_pushdef([AT_LEX_ARGS],        [])
  96  m4_pushdef([AT_USE_LEX_ARGS],    [])
  97  m4_pushdef([AT_LEX_PRE_FORMALS], [])
  98  m4_pushdef([AT_LEX_PRE_ARGS],    [])
  99 ])
 100 ])# _AT_BISON_OPTION_PUSHDEFS
 101
 102
 103 # AT_BISON_OPTION_POPDEFS
 104 # -----------------------
 105 m4_define([AT_BISON_OPTION_POPDEFS],
 106 [m4_popdef([AT_LEX_PRE_ARGS])
 107 m4_popdef([AT_LEX_PRE_FORMALS])
 108 m4_popdef([AT_USE_LEX_ARGS])
 109 m4_popdef([AT_LEX_ARGS])
 110 m4_popdef([AT_LEX_FORMALS])
 111 m4_popdef([AT_VAL])
 112 m4_popdef([AT_LOC])
 113 m4_popdef([AT_PURE_LEX_IF])
 114 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 115 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 116 m4_popdef([AT_GLR_OR_PARAM_IF])
 117 m4_popdef([AT_PURE_AND_LOC_IF])
 118 m4_popdef([AT_LOCATION_IF])
 119 m4_popdef([AT_PARAM_IF])
 120 m4_popdef([AT_YACC_IF])
 121 m4_popdef([AT_GLR_IF])
 122 m4_popdef([AT_LALR1_CC_IF])
 123 ])# AT_BISON_OPTION_POPDEFS
 124
 125
 126
 127 ## -------------------------- ##
 128 ## Generating Grammar Files.  ##
 129 ## -------------------------- ##
 130
 131
 132 # AT_DATA_GRAMMAR_PROLOGUE
 133 # ------------------------
 134 # The prologue that should be included in any grammar which parser is
 135 # meant to be compiled.
 136 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 137 [[%{
 138 #if HAVE_CONFIG_H
 139 # include <config.h>
 140   /* We don't need perfect functions for these tests. */
 141 # undef malloc
 142 # undef memcmp
 143 # undef realloc
 144 #endif
 145 %}]
 146 ])
 147
 148
 149 # AT_DATA_GRAMMAR(NAME, CONTENT)
 150 # ------------------------------
 151 # Generate the file NAME, which CONTENT is preceded by
 152 # AT_DATA_GRAMMAR_PROLOGUE.
 153 m4_define([AT_DATA_GRAMMAR],
 154 [AT_DATA([$1],
 155 [AT_DATA_GRAMMAR_PROLOGUE
 156 $2])
 157 ])
 158
 159
 160 ## ------------------------ ##
 161 ## Compiling C, C++ Files.  ##
 162 ## ------------------------ ##
 163
 164
 165 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 166 # ----------------------------------------
 167 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 168 # assume that we are linking too; this is a hack.
 169 m4_define([AT_COMPILE],
 170 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])m4_default([$2], [$1.c]) m4_bmatch([$1], [[.]], [], [$LIBS ])-o $1],
 171            0, [], [ignore])])
 172
 173 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.c])
 174 # --------------------------------------------
 175 # If the C++ compiler is not defined, ignore the test.
 176 m4_define([AT_COMPILE_CXX],
 177 [AT_KEYWORDS(c++)
 178 AT_CHECK([$CXX --version || exit 77], 0, ignore, ignore)
 179 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_default([$2], [$1.c]) -o $1],
 180          0, [], [ignore])])
 181
 182
 183
 184 ## ---------------------------- ##
 185 ## Running a generated parser.  ##
 186 ## ---------------------------- ##
 187
 188 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR)
 189 # -----------------------------------------------------
 190 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 191 m4_define([AT_PARSER_CHECK],
 192 [AT_CHECK([$PREPARSER $1], [$2], [$3], [$4])])