build-aux/update-b4-copyright

   1 #!/usr/bin/perl -0777 -pi
   2
   3 # Update b4_copyright invocations or b4_copyright_years definitions to
   4 # include the current year.
   5
   6 # Copyright (C) 2009, 2010 Free Software Foundation, Inc.
   7
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3, or (at your option)
  11 # any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 use strict;
  22 use warnings;
  23
  24 my $margin = 72;
  25
  26 my $this_year = $ENV{UPDATE_COPYRIGHT_YEAR};
  27 if (!$this_year || $this_year !~ m/^\d{4}$/)
  28   {
  29     my ($sec, $min, $hour, $mday, $month, $year) = localtime (time ());
  30     $this_year = $year + 1900;
  31   }
  32 my $old_re = <<'EOF'
  33   (
  34     (?:^|\n)
  35     #BEFORE
  36     (?:
  37       b4_copyright\(\[[^][]*]
  38       | m4_(?:push|pop)def\(\[b4_copyright_years]
  39     )
  40     #AFTER
  41   )
  42   (?:
  43     ,\s*
  44     (
  45       \[\s* (?:\d{4}(?:,\s*|-))* (\d{4}) \s*]
  46     )
  47   )?
  48   \)
  49 EOF
  50   ;
  51
  52 while (/($old_re)/gx)
  53   {
  54     my $start = pos() - length ($1);
  55     my $b4_copyright_line = $2;
  56     my $year_lines = $3;
  57     my $final_year = $4;
  58     $year_lines .= ')';
  59
  60     # If there was a second argument, it contains years, so update them.
  61     if ($final_year)
  62       {
  63         $b4_copyright_line .= ',';
  64         if ($final_year != $this_year)
  65           {
  66             # Update the year.
  67             $year_lines =~ s/$final_year/$final_year, $this_year/;
  68           }
  69
  70         # Normalize all whitespace.
  71         $year_lines =~ s/\s+/ /g;
  72
  73         # Put spaces after commas.
  74         $year_lines =~ s/, ?/, /g;
  75
  76         # Do not compress to intervals; for example, do not replace
  77         # "2008, 2009, 2010" with "2008-2010".  See the Copyright
  78         # Notices section in Information for Maintainers of GNU Software, at:
  79         # http://www.gnu.org/prep/maintain/maintain.html#Copyright-Notices
  80
  81         # Format within margin.
  82         my $year_lines_new;
  83         my $indent = index ($b4_copyright_line, '[');
  84         --$indent if ($b4_copyright_line =~ m/^\n/);
  85         while (length $year_lines)
  86           {
  87             my $text_margin = $margin - $indent;
  88             if (($year_lines =~ s/^(.{1,$text_margin})(?: |$)//)
  89                 || ($year_lines =~ s/^([\S]+)(?: |$)//))
  90               {
  91                 my $line = "\n" . (' 'x$indent) . $1;
  92                 ++$indent if (!$year_lines_new);
  93                 $year_lines_new .= $line;
  94               }
  95             else
  96               {
  97                 # Should be unreachable, but we don't want an infinite
  98                 # loop if it can be reached.
  99                 die;
 100               }
 101           }
 102
 103         # Replace the old invocation.  Should never die.
 104         die if (!s/$old_re\G/$b4_copyright_line$year_lines_new/x);
 105
 106         # Prepare for the next search.
 107         pos () = $start + length ("$b4_copyright_line$year_lines_new");
 108       }
 109   }
 110
 111 while (/(\bb4_copyright\()/g)
 112   {
 113     my $start = pos () - length ($1);
 114     my $end = pos ();
 115     my $re = $old_re;
 116     pos () = $start;
 117     $re =~ s/\#BEFORE/\\G/;
 118     if (!/$re/x)
 119       {
 120         my $line = (substr ($_, 0, $start) =~ s/\n/\n/g) + 1;
 121         print STDERR
 122           "$ARGV:$line: warning: failed to update a b4_copyright\n";
 123       }
 124     pos () = $end;
 125   }
 126
 127 while (/(\[b4_copyright_years])/g)
 128   {
 129     my $start = pos () - length ($1);
 130     my $end = pos ();
 131     my $re = $old_re;
 132     $re =~ s/\#AFTER/\\G/;
 133     if (!/$re/x)
 134       {
 135         # The substr operation blows away pos (), so restoring pos ()
 136         # at the end is necessary.
 137         my $line = (substr ($_, 0, $start) =~ s/\n/\n/g) + 1;
 138         print STDERR
 139           "$ARGV:$line: warning: failed to update a"
 140           . " b4_copyright_years\n";
 141       }
 142     pos () = $end;
 143   }