data/java.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Java language support for Bison
   4
   5 # Copyright (C) 2007, 2008 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 # b4_comment(TEXT)
  22 # ----------------
  23 m4_define([b4_comment], [/* m4_bpatsubst([$1], [
  24 ], [
  25    ])  */])
  26
  27
  28 # b4_list2(LIST1, LIST2)
  29 # --------------------------
  30 # Join two lists with a comma if necessary.
  31 m4_define([b4_list2],
  32           [$1[]m4_ifval(m4_quote($1), [m4_ifval(m4_quote($2), [[, ]])])[]$2])
  33
  34
  35 # b4_percent_define_get3(DEF, PRE, POST, NOT)
  36 # -------------------------------------------
  37 # Expand to the value of DEF surrounded by PRE and POST if it's %define'ed,
  38 # otherwise NOT.
  39 m4_define([b4_percent_define_get3],
  40           [m4_ifval(m4_quote(b4_percent_define_get([$1])),
  41                 [$2[]b4_percent_define_get([$1])[]$3], [$4])])
  42
  43
  44
  45 # b4_flag_value(BOOLEAN-FLAG)
  46 # ---------------------------
  47 m4_define([b4_flag_value], [b4_flag_if([$1], [true], [false])])
  48
  49
  50 # b4_public_if(TRUE, FALSE)
  51 # -------------------------
  52 b4_percent_define_default([[public]], [[false]])
  53 m4_define([b4_public_if],
  54 [b4_percent_define_flag_if([public], [$1], [$2])])
  55
  56
  57 # b4_abstract_if(TRUE, FALSE)
  58 # ---------------------------
  59 b4_percent_define_default([[abstract]], [[false]])
  60 m4_define([b4_abstract_if],
  61 [b4_percent_define_flag_if([abstract], [$1], [$2])])
  62
  63
  64 # b4_final_if(TRUE, FALSE)
  65 # ---------------------------
  66 b4_percent_define_default([[final]], [[false]])
  67 m4_define([b4_final_if],
  68 [b4_percent_define_flag_if([final], [$1], [$2])])
  69
  70
  71 # b4_strictfp_if(TRUE, FALSE)
  72 # ---------------------------
  73 b4_percent_define_default([[strictfp]], [[false]])
  74 m4_define([b4_strictfp_if],
  75 [b4_percent_define_flag_if([strictfp], [$1], [$2])])
  76
  77
  78 # b4_lexer_if(TRUE, FALSE)
  79 # ------------------------
  80 m4_define([b4_lexer_if],
  81 [b4_percent_code_ifdef([[lexer]], [$1], [$2])])
  82
  83
  84 # b4_identification
  85 # -----------------
  86 m4_define([b4_identification],
  87 [  /** Version number for the Bison executable that generated this parser.  */
  88   public static final String bisonVersion = "b4_version";
  89
  90   /** Name of the skeleton that generated this parser.  */
  91   public static final String bisonSkeleton = b4_skeleton;
  92 ])
  93
  94
  95 ## ------------ ##
  96 ## Data types.  ##
  97 ## ------------ ##
  98
  99 # b4_int_type(MIN, MAX)
 100 # ---------------------
 101 # Return the smallest int type able to handle numbers ranging from
 102 # MIN to MAX (included).
 103 m4_define([b4_int_type],
 104 [m4_if(b4_ints_in($@,   [-128],   [127]), [1], [byte],
 105        b4_ints_in($@, [-32768], [32767]), [1], [short],
 106                                                [int])])
 107
 108 # b4_int_type_for(NAME)
 109 # ---------------------
 110 # Return the smallest int type able to handle numbers ranging from
 111 # `NAME_min' to `NAME_max' (included).
 112 m4_define([b4_int_type_for],
 113 [b4_int_type($1_min, $1_max)])
 114
 115 # b4_null
 116 # -------
 117 m4_define([b4_null], [null])
 118
 119
 120 ## ------------------------- ##
 121 ## Assigning token numbers.  ##
 122 ## ------------------------- ##
 123
 124 # b4_token_enum(TOKEN-NAME, TOKEN-NUMBER)
 125 # ---------------------------------------
 126 # Output the definition of this token as an enum.
 127 m4_define([b4_token_enum],
 128 [    /** Token number, to be returned by the scanner.  */
 129     static final int $1 = $2;
 130 ])
 131
 132
 133 # b4_token_enums(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
 134 # -----------------------------------------------------
 135 # Output the definition of the tokens (if there are) as enums.
 136 m4_define([b4_token_enums],
 137 [m4_if([$#$1], [1], [],
 138 [/* Tokens.  */
 139 m4_map([b4_token_enum], [$@])])
 140 ])
 141
 142 # b4-case(ID, CODE)
 143 # -----------------
 144 # We need to fool Java's stupid unreachable code detection.
 145 m4_define([b4_case], [  case $1:
 146   if (yyn == $1)
 147     $2;
 148   break;
 149     ])
 150
 151
 152 ## ---------------- ##
 153 ## Default values.  ##
 154 ## ---------------- ##
 155
 156 m4_define([b4_yystype], [b4_percent_define_get([[stype]])])
 157 b4_percent_define_default([[stype]], [[Object]])
 158
 159 # %name-prefix
 160 m4_define_default([b4_prefix], [[YY]])
 161
 162 b4_percent_define_default([[parser_class_name]], [b4_prefix[]Parser])
 163 m4_define([b4_parser_class_name], [b4_percent_define_get([[parser_class_name]])])
 164
 165 b4_percent_define_default([[lex_throws]], [[java.io.IOException]])
 166 m4_define([b4_lex_throws], [b4_percent_define_get([[lex_throws]])])
 167
 168 b4_percent_define_default([[throws]], [])
 169 m4_define([b4_throws], [b4_percent_define_get([[throws]])])
 170
 171 b4_percent_define_default([[init_throws]], [])
 172 m4_define([b4_init_throws], [b4_percent_define_get([[init_throws]])])
 173
 174 b4_percent_define_default([[location_type]], [Location])
 175 m4_define([b4_location_type], [b4_percent_define_get([[location_type]])])
 176
 177 b4_percent_define_default([[position_type]], [Position])
 178 m4_define([b4_position_type], [b4_percent_define_get([[position_type]])])
 179
 180
 181 ## ----------------- ##
 182 ## Semantic Values.  ##
 183 ## ----------------- ##
 184
 185
 186 # b4_lhs_value([TYPE])
 187 # --------------------
 188 # Expansion of $<TYPE>$.
 189 m4_define([b4_lhs_value], [yyval])
 190
 191
 192 # b4_rhs_value(RULE-LENGTH, NUM, [TYPE])
 193 # --------------------------------------
 194 # Expansion of $<TYPE>NUM, where the current rule has RULE-LENGTH
 195 # symbols on RHS.
 196 #
 197 # In this simple implementation, %token and %type have class names
 198 # between the angle brackets.
 199 m4_define([b4_rhs_value],
 200 [(m4_ifval($3, [($3)])[](yystack.valueAt ($1-($2))))])
 201
 202 # b4_lhs_location()
 203 # -----------------
 204 # Expansion of @$.
 205 m4_define([b4_lhs_location],
 206 [(yyloc)])
 207
 208
 209 # b4_rhs_location(RULE-LENGTH, NUM)
 210 # ---------------------------------
 211 # Expansion of @NUM, where the current rule has RULE-LENGTH symbols
 212 # on RHS.
 213 m4_define([b4_rhs_location],
 214 [yystack.locationAt ($1-($2))])
 215
 216
 217 # b4_lex_param
 218 # b4_parse_param
 219 # --------------
 220 # If defined, b4_lex_param arrives double quoted, but below we prefer
 221 # it to be single quoted.  Same for b4_parse_param.
 222
 223 # TODO: should be in bison.m4
 224 m4_define_default([b4_lex_param], [[]])
 225 m4_define([b4_lex_param], b4_lex_param)
 226 m4_define([b4_parse_param], b4_parse_param)
 227
 228 # b4_lex_param_decl
 229 # -------------------
 230 # Extra formal arguments of the constructor.
 231 m4_define([b4_lex_param_decl],
 232 [m4_ifset([b4_lex_param],
 233           [b4_remove_comma([$1],
 234                            b4_param_decls(b4_lex_param))],
 235           [$1])])
 236
 237 m4_define([b4_param_decls],
 238           [m4_map([b4_param_decl], [$@])])
 239 m4_define([b4_param_decl], [, $1])
 240
 241 m4_define([b4_remove_comma], [m4_ifval(m4_quote($1), [$1, ], [])m4_shift2($@)])
 242
 243
 244
 245 # b4_parse_param_decl
 246 # -------------------
 247 # Extra formal arguments of the constructor.
 248 m4_define([b4_parse_param_decl],
 249 [m4_ifset([b4_parse_param],
 250           [b4_remove_comma([$1],
 251                            b4_param_decls(b4_parse_param))],
 252           [$1])])
 253
 254
 255
 256 # b4_lex_param_call
 257 # -------------------
 258 # Delegating the lexer parameters to the lexer constructor.
 259 m4_define([b4_lex_param_call],
 260           [m4_ifset([b4_lex_param],
 261                     [b4_remove_comma([$1],
 262                                      b4_param_calls(b4_lex_param))],
 263                     [$1])])
 264 m4_define([b4_param_calls],
 265           [m4_map([b4_param_call], [$@])])
 266 m4_define([b4_param_call], [, $2])
 267
 268
 269
 270 # b4_parse_param_cons
 271 # -------------------
 272 # Extra initialisations of the constructor.
 273 m4_define([b4_parse_param_cons],
 274           [m4_ifset([b4_parse_param],
 275                     [b4_constructor_calls(b4_parse_param)])])
 276
 277 m4_define([b4_constructor_calls],
 278           [m4_map([b4_constructor_call], [$@])])
 279 m4_define([b4_constructor_call],
 280           [this.$2 = $2;
 281           ])
 282
 283
 284
 285 # b4_parse_param_vars
 286 # -------------------
 287 # Extra instance variables.
 288 m4_define([b4_parse_param_vars],
 289           [m4_ifset([b4_parse_param],
 290                     [
 291     /* User arguments.  */
 292 b4_var_decls(b4_parse_param)])])
 293
 294 m4_define([b4_var_decls],
 295           [m4_map_sep([b4_var_decl], [
 296 ], [$@])])
 297 m4_define([b4_var_decl],
 298           [    protected final $1;])
 299
 300
 301
 302 # b4_maybe_throws(THROWS)
 303 # -----------------------
 304 # Expand to either an empty string or "throws THROWS".
 305 m4_define([b4_maybe_throws],
 306           [m4_ifval($1, [throws $1])])