[bison.git] / tests / local.at

# Process this -*- Autotest -*- file with autom4te.

# Macros for the GNU Bison Test suite.
# Copyright (C) 2003, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.

# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

# We want a recent Autotest.
m4_version_prereq([2.58])


## ------------------------------- ##
## Macros decoding Bison options.  ##
## ------------------------------- ##


# AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
# -----------------------------------------
m4_define([AT_BISON_OPTION_PUSHDEFS],
[_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])


# _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
# --------------------------------------------------
# This macro works around the impossibility to define macros
# inside macros, because issuing `[$1]' is not possible in M4 :(.
# This sucks hard, GNU M4 should really provide M5 like $$1.
m4_define([_AT_BISON_OPTION_PUSHDEFS],
[m4_if([$1$2], $[1]$[2], [],
       [m4_fatal([$0: Invalid arguments: $@])])dnl
m4_pushdef([AT_SKEL_CC_IF],
[m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
m4_pushdef([AT_GLR_IF],
[m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
m4_pushdef([AT_LALR1_CC_IF],
[AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
m4_pushdef([AT_GLR_CC_IF],
[AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
# Using yacc.c?
m4_pushdef([AT_YACC_IF],
[m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
m4_pushdef([AT_LEXPARAM_IF],
[m4_bmatch([$3], [%lex-param], [$1], [$2])])
m4_pushdef([AT_PARAM_IF],
[m4_bmatch([$3], [%parse-param], [$1], [$2])])
m4_pushdef([AT_LOCATION_IF],
[m4_bmatch([$3], [%locations], [$1], [$2])])
m4_pushdef([AT_PURE_IF],
[m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
           [m4_bmatch([$3], [%define  *api\.pure *"false"], [$2], [$1])],
           [$2])])
m4_pushdef([AT_PURE_AND_LOC_IF],
[m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
m4_pushdef([AT_GLR_OR_PARAM_IF],
[m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
m4_pushdef([AT_NAME_PREFIX],
[m4_bmatch([$3], [%name-prefix ".*"],
           [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
           [yy])])
# yyerror receives the location if %location & %pure & (%glr or %parse-param).
m4_pushdef([AT_YYERROR_ARG_LOC_IF],
[AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
		    [$2])])
# yyerror always sees the locations (when activated), except if
# (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
m4_pushdef([AT_YYERROR_SEES_LOC_IF],
[AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
					[$1])],
			    [$1])],
		[$2])])

# The interface is pure: either because %define api.pure, or because we
# are using the C++ parsers.
m4_pushdef([AT_PURE_LEX_IF],
[AT_PURE_IF([$1],
	    [AT_SKEL_CC_IF([$1], [$2])])])

AT_PURE_LEX_IF(
[m4_pushdef([AT_LOC], [(*llocp)])
 m4_pushdef([AT_VAL], [(*lvalp)])
 m4_pushdef([AT_LEX_FORMALS],
	    [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 m4_pushdef([AT_LEX_ARGS],
	    [lvalp[]AT_LOCATION_IF([, llocp])])
 m4_pushdef([AT_USE_LEX_ARGS],
	    [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 m4_pushdef([AT_LEX_PRE_FORMALS],
	    [AT_LEX_FORMALS, ])
 m4_pushdef([AT_LEX_PRE_ARGS],
	    [AT_LEX_ARGS, ])
],
[m4_pushdef([AT_LOC], [(yylloc)])
 m4_pushdef([AT_VAL], [(yylval)])
 m4_pushdef([AT_LEX_FORMALS],     [void])
 m4_pushdef([AT_LEX_ARGS],        [])
 m4_pushdef([AT_USE_LEX_ARGS],    [])
 m4_pushdef([AT_LEX_PRE_FORMALS], [])
 m4_pushdef([AT_LEX_PRE_ARGS],    [])
])
])# _AT_BISON_OPTION_PUSHDEFS


# AT_BISON_OPTION_POPDEFS
# -----------------------
m4_define([AT_BISON_OPTION_POPDEFS],
[m4_popdef([AT_LEX_PRE_ARGS])
m4_popdef([AT_LEX_PRE_FORMALS])
m4_popdef([AT_USE_LEX_ARGS])
m4_popdef([AT_LEX_ARGS])
m4_popdef([AT_LEX_FORMALS])
m4_popdef([AT_VAL])
m4_popdef([AT_LOC])
m4_popdef([AT_PURE_LEX_IF])
m4_popdef([AT_YYERROR_SEES_LOC_IF])
m4_popdef([AT_YYERROR_ARG_LOC_IF])
m4_popdef([AT_NAME_PREFIX])
m4_popdef([AT_GLR_OR_PARAM_IF])
m4_popdef([AT_PURE_AND_LOC_IF])
m4_popdef([AT_LOCATION_IF])
m4_popdef([AT_PARAM_IF])
m4_popdef([AT_LEXPARAM_IF])
m4_popdef([AT_YACC_IF])
m4_popdef([AT_GLR_IF])
m4_popdef([AT_SKEL_CC_IF])
m4_popdef([AT_GLR_CC_IF])
m4_popdef([AT_LALR1_CC_IF])
])# AT_BISON_OPTION_POPDEFS


## -------------------------- ##
## Generating Grammar Files.  ##
## -------------------------- ##


# AT_DATA_GRAMMAR_PROLOGUE
# ------------------------
# The prologue that should be included in any grammar which parser is
# meant to be compiled.
m4_define([AT_DATA_GRAMMAR_PROLOGUE],
[[%{
#include <config.h>
/* We don't need perfect functions for these tests. */
#undef malloc
#undef memcmp
#undef realloc
%}]
])


# AT_DATA_GRAMMAR(NAME, CONTENT)
# ------------------------------
# Generate the file NAME, which CONTENT is preceded by
# AT_DATA_GRAMMAR_PROLOGUE.
m4_define([AT_DATA_GRAMMAR],
[AT_DATA([$1],
[AT_DATA_GRAMMAR_PROLOGUE
$2])
])

# AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
# -------------------------------------------------
# Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
# usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
#
# This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
# Bison in the test suite.  For now it ensures that:
#
#   1. Valgrind doesn't report reachable memory when Bison is expected to have
#      a non-zero exit status since Bison doesn't always try to free all memory
#      in that case.
#
#   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
#      --graph and --report=all output for every working grammar.
m4_define([AT_BISON_CHECK],
[m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
       m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
AT_BISON_CHECK_NO_XML($@)])

# AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
# --------------------------------------------------------
# Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
# when a tortured grammar's XML is known to be too large for xsltproc to
# handle.
m4_define([AT_BISON_CHECK_NO_XML],
[AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
                [AT_QUELL_VALGRIND ])[[bison ]]$@)])

# AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
# -----------------------------------------------------
# Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
# defined.  It doesn't make sense to invoke this macro if Bison is expected to
# have a non-zero exit status.
m4_define([AT_BISON_CHECK_XML],
[[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
  mkdir xml-tests]
  m4_pushdef([AT_BISON_ARGS],
             [m4_bpatsubsts([[$1]],
                            [--report(-file)?=[^][ ]*], [],
                            [--graph=[^][ ]*], [],
                            [--xml=[^][ ]*], [])])dnl
  # Don't combine these Bison invocations since we want to be sure that
  # --report=all isn't required to get the full XML file.
  AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
             --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
           [[0]], [ignore], [ignore])
  AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
           [[0]], [ignore], [ignore])
  m4_popdef([AT_BISON_ARGS])dnl
  [cp xml-tests/test.output expout]
  AT_CHECK([[$XSLTPROC \
             `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
             xml-tests/test.xml]], [[0]], [expout])
  [cp xml-tests/test.dot expout]
  AT_CHECK([[$XSLTPROC \
             `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
             xml-tests/test.xml]], [[0]], [expout])
  [rm -rf xml-tests expout
fi]])

# AT_QUELL_VALGRIND
# -----------------
# Put this before a Bison invocation to keep Valgrind from complaining about
# reachable memory.
#
# Do not quote invocations of this macro within the first argument of AT_CHECK.
# The triple quoting below will cause test cases to fail if you do.  If you do
# so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
# will then fail to shell-escape its contents when attempting to print them.
# The testsuite verbose output, at least, will be incorrect, but nothing may
# fail to make sure you notice.
m4_define([AT_QUELL_VALGRIND],
[[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])

## ------------------------ ##
## Compiling C, C++ Files.  ##
## ------------------------ ##


# AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
# ----------------------------------------
# Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
# assume that we are linking too; this is a hack.
m4_define([AT_COMPILE],
[AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
	   0, [ignore], [ignore])])

# AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
# --------------------------------------------
# Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
# assume that we are linking too; this is a hack.
# If the C++ compiler does not work, ignore the test.
m4_define([AT_COMPILE_CXX],
[AT_KEYWORDS(c++)
AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
	 0, [ignore], [ignore])])


## ---------------------------- ##
## Running a generated parser.  ##
## ---------------------------- ##

# AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
# ------------------------------------------------------------
# So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
m4_define([AT_PARSER_CHECK],
[AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])


## ----------------------- ##
## Launch the test suite.  ##
## ----------------------- ##

AT_INIT

AT_TESTED([bison])
Commit	Line	Data
67a25fed AD	1	# Process this -- Autotest -- file with autom4te.
	2
	3	# Macros for the GNU Bison Test suite.
279cabb6	4	# Copyright (C) 2003, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
67a25fed	5
f16b0819	6	# This program is free software: you can redistribute it and/or modify
67a25fed	7	# it under the terms of the GNU General Public License as published by
f16b0819 PE	8	# the Free Software Foundation, either version 3 of the License, or
	9	# (at your option) any later version.
	10	#
67a25fed AD	11	# This program is distributed in the hope that it will be useful,
	12	# but WITHOUT ANY WARRANTY; without even the implied warranty of
	13	# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	14	# GNU General Public License for more details.
f16b0819	15	#
67a25fed	16	# You should have received a copy of the GNU General Public License
f16b0819	17	# along with this program. If not, see <http://www.gnu.org/licenses/>.
67a25fed	18
1f7a61ff	19	# We want a recent Autotest.
ce05140d	20	m4_version_prereq([2.58])
1f7a61ff	21
67a25fed AD	22
	23	## ------------------------------- ##
	24	## Macros decoding Bison options. ##
	25	## ------------------------------- ##
	26
	27
	28	# AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
	29	# -----------------------------------------
	30	m4_define([AT_BISON_OPTION_PUSHDEFS],
	31	[_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
	32
	33
	34	# _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
	35	# --------------------------------------------------
	36	# This macro works around the impossibility to define macros
	37	# inside macros, because issuing `[$1]' is not possible in M4 :(.
	38	# This sucks hard, GNU M4 should really provide M5 like $$1.
	39	m4_define([_AT_BISON_OPTION_PUSHDEFS],
	40	[m4_if([$1$2], $[1]$[2], [],
	41	[m4_fatal([$0: Invalid arguments: $@])])dnl
8f7e3cf9	42	m4_pushdef([AT_SKEL_CC_IF],
0e021770	43	[m4_bmatch([$3], [%language "[Cc]\+\+"\\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
67a25fed	44	m4_pushdef([AT_GLR_IF],
0e021770 PE	45	[m4_bmatch([$3], [%glr-parser\\|%skeleton "glr\.], [$1], [$2])])
	46	m4_pushdef([AT_LALR1_CC_IF],
	47	[AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
	48	m4_pushdef([AT_GLR_CC_IF],
	49	[AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
67a25fed AD	50	# Using yacc.c?
67a25fed AD	51	m4_pushdef([AT_YACC_IF],
0e021770	52	[m4_bmatch([$3], [%language\\|%glr-parser\\|%skeleton], [$2], [$1])])
01b477c6 PB	53	m4_pushdef([AT_LEXPARAM_IF],
01b477c6 PB	54	[m4_bmatch([$3], [%lex-param], [$1], [$2])])
67a25fed AD	55	m4_pushdef([AT_PARAM_IF],
	56	[m4_bmatch([$3], [%parse-param], [$1], [$2])])
	57	m4_pushdef([AT_LOCATION_IF],
	58	[m4_bmatch([$3], [%locations], [$1], [$2])])
	59	m4_pushdef([AT_PURE_IF],
d9df47b6 JD	60	[m4_bmatch([$3], [%define *api\.pure\\|%pure-parser],
	61	[m4_bmatch([$3], [%define api\.pure "false"], [$2], [$1])],
	62	[$2])])
67a25fed	63	m4_pushdef([AT_PURE_AND_LOC_IF],
d9df47b6	64	[m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
67a25fed AD	65	m4_pushdef([AT_GLR_OR_PARAM_IF],
67a25fed AD	66	[m4_bmatch([$3], [%glr-parser\\|%parse-param], [$1], [$2])])
aa08666d	67	m4_pushdef([AT_NAME_PREFIX],
02975b9a JD	68	[m4_bmatch([$3], [%name-prefix ".*"],
02975b9a JD	69	[m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
5cf61e93	70	[yy])])
67a25fed AD	71	# yyerror receives the location if %location & %pure & (%glr or %parse-param).
	72	m4_pushdef([AT_YYERROR_ARG_LOC_IF],
	73	[AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
02650b7f	74	[$2])])
67a25fed	75	# yyerror always sees the locations (when activated), except if
94ebeba5	76	# (yacc & pure & !param). FIXME: This is wrong. See the manual.
67a25fed	77	m4_pushdef([AT_YYERROR_SEES_LOC_IF],
7d596384 JD	78	[AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
	79	[$1])],
	80	[$1])],
94ebeba5	81	[$2])])
67a25fed	82
d9df47b6	83	# The interface is pure: either because %define api.pure, or because we
67a25fed AD	84	# are using the C++ parsers.
67a25fed AD	85	m4_pushdef([AT_PURE_LEX_IF],
94ebeba5	86	[AT_PURE_IF([$1],
aa08666d	87	[AT_SKEL_CC_IF([$1], [$2])])])
67a25fed AD	88
67a25fed AD	89	AT_PURE_LEX_IF(
ebc3737e PE	90	[m4_pushdef([AT_LOC], [(*llocp)])
ebc3737e PE	91	m4_pushdef([AT_VAL], [(*lvalp)])
67a25fed	92	m4_pushdef([AT_LEX_FORMALS],
02650b7f	93	[YYSTYPE lvalp[]AT_LOCATION_IF([, YYLTYPE llocp])])
67a25fed	94	m4_pushdef([AT_LEX_ARGS],
02650b7f	95	[lvalp[]AT_LOCATION_IF([, llocp])])
67a25fed	96	m4_pushdef([AT_USE_LEX_ARGS],
02650b7f	97	[(void) lvalp;AT_LOCATION_IF([(void) llocp])])
67a25fed	98	m4_pushdef([AT_LEX_PRE_FORMALS],
02650b7f	99	[AT_LEX_FORMALS, ])
67a25fed	100	m4_pushdef([AT_LEX_PRE_ARGS],
02650b7f	101	[AT_LEX_ARGS, ])
67a25fed AD	102	],
	103	[m4_pushdef([AT_LOC], [(yylloc)])
	104	m4_pushdef([AT_VAL], [(yylval)])
	105	m4_pushdef([AT_LEX_FORMALS], [void])
	106	m4_pushdef([AT_LEX_ARGS], [])
	107	m4_pushdef([AT_USE_LEX_ARGS], [])
	108	m4_pushdef([AT_LEX_PRE_FORMALS], [])
	109	m4_pushdef([AT_LEX_PRE_ARGS], [])
	110	])
	111	])# _AT_BISON_OPTION_PUSHDEFS
	112
	113
	114	# AT_BISON_OPTION_POPDEFS
	115	# -----------------------
	116	m4_define([AT_BISON_OPTION_POPDEFS],
	117	[m4_popdef([AT_LEX_PRE_ARGS])
	118	m4_popdef([AT_LEX_PRE_FORMALS])
	119	m4_popdef([AT_USE_LEX_ARGS])
	120	m4_popdef([AT_LEX_ARGS])
	121	m4_popdef([AT_LEX_FORMALS])
	122	m4_popdef([AT_VAL])
	123	m4_popdef([AT_LOC])
	124	m4_popdef([AT_PURE_LEX_IF])
	125	m4_popdef([AT_YYERROR_SEES_LOC_IF])
	126	m4_popdef([AT_YYERROR_ARG_LOC_IF])
aa08666d	127	m4_popdef([AT_NAME_PREFIX])
67a25fed AD	128	m4_popdef([AT_GLR_OR_PARAM_IF])
	129	m4_popdef([AT_PURE_AND_LOC_IF])
	130	m4_popdef([AT_LOCATION_IF])
	131	m4_popdef([AT_PARAM_IF])
01b477c6	132	m4_popdef([AT_LEXPARAM_IF])
67a25fed AD	133	m4_popdef([AT_YACC_IF])
67a25fed AD	134	m4_popdef([AT_GLR_IF])
8f7e3cf9 AD	135	m4_popdef([AT_SKEL_CC_IF])
8f7e3cf9 AD	136	m4_popdef([AT_GLR_CC_IF])
67a25fed AD	137	m4_popdef([AT_LALR1_CC_IF])
	138	])# AT_BISON_OPTION_POPDEFS
	139
	140
	141
	142	## -------------------------- ##
	143	## Generating Grammar Files. ##
	144	## -------------------------- ##
	145
	146
	147	# AT_DATA_GRAMMAR_PROLOGUE
	148	# ------------------------
	149	# The prologue that should be included in any grammar which parser is
	150	# meant to be compiled.
	151	m4_define([AT_DATA_GRAMMAR_PROLOGUE],
	152	[[%{
231ed89a PE	153	#include <config.h>
	154	/* We don't need perfect functions for these tests. */
	155	#undef malloc
	156	#undef memcmp
	157	#undef realloc
67a25fed AD	158	%}]
	159	])
	160
	161
	162	# AT_DATA_GRAMMAR(NAME, CONTENT)
	163	# ------------------------------
	164	# Generate the file NAME, which CONTENT is preceded by
	165	# AT_DATA_GRAMMAR_PROLOGUE.
	166	m4_define([AT_DATA_GRAMMAR],
	167	[AT_DATA([$1],
	168	[AT_DATA_GRAMMAR_PROLOGUE
	169	$2])
	170	])
	171
da730230 JD	172	# AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
	173	# -------------------------------------------------
	174	# Check Bison by invoking `bison BISON_ARGS'. OTHER_AT_CHECK_ARGS are the
	175	# usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
	176	#
	177	# This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
	178	# Bison in the test suite. For now it ensures that:
	179	#
	180	# 1. Valgrind doesn't report reachable memory when Bison is expected to have
	181	# a non-zero exit status since Bison doesn't always try to free all memory
	182	# in that case.
	183	#
	184	# 2. In the case of maintainer-xml-check, XML/XSLT output is compared with
	185	# --graph and --report=all output for every working grammar.
	186	m4_define([AT_BISON_CHECK],
	187	[m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
	188	m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
	189	AT_BISON_CHECK_NO_XML($@)])
	190
	191	# AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
	192	# --------------------------------------------------------
	193	# Same as AT_BISON_CHECK except don't perform XML/XSLT checks. This is useful
	194	# when a tortured grammar's XML is known to be too large for xsltproc to
	195	# handle.
	196	m4_define([AT_BISON_CHECK_NO_XML],
	197	[AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
	198	[AT_QUELL_VALGRIND ])[[bison ]]$@)])
	199
	200	# AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
	201	# -----------------------------------------------------
	202	# Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
	203	# defined. It doesn't make sense to invoke this macro if Bison is expected to
	204	# have a non-zero exit status.
	205	m4_define([AT_BISON_CHECK_XML],
247b8c21 JD	206	[[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
247b8c21 JD	207	mkdir xml-tests]
da730230 JD	208	m4_pushdef([AT_BISON_ARGS],
	209	[m4_bpatsubsts([[$1]],
	210	[--report(-file)?=[^][ ]*], [],
	211	[--graph=[^][ ]*], [],
	212	[--xml=[^][ ]*], [])])dnl
	213	# Don't combine these Bison invocations since we want to be sure that
	214	# --report=all isn't required to get the full XML file.
	215	AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
	216	--graph=xml-tests/test.dot ]]AT_BISON_ARGS,
	217	[[0]], [ignore], [ignore])
	218	AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
	219	[[0]], [ignore], [ignore])
	220	m4_popdef([AT_BISON_ARGS])dnl
247b8c21	221	[cp xml-tests/test.output expout]
da730230 JD	222	AT_CHECK([[$XSLTPROC \
	223	`]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
	224	xml-tests/test.xml]], [[0]], [expout])
247b8c21	225	[cp xml-tests/test.dot expout]
da730230 JD	226	AT_CHECK([[$XSLTPROC \
	227	`]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
	228	xml-tests/test.xml]], [[0]], [expout])
247b8c21 JD	229	[rm -rf xml-tests expout
247b8c21 JD	230	fi]])
da730230 JD	231
	232	# AT_QUELL_VALGRIND
	233	# -----------------
	234	# Put this before a Bison invocation to keep Valgrind from complaining about
	235	# reachable memory.
	236	#
	237	# Do not quote invocations of this macro within the first argument of AT_CHECK.
	238	# The triple quoting below will cause test cases to fail if you do. If you do
	239	# so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
	240	# will then fail to shell-escape its contents when attempting to print them.
	241	# The testsuite verbose output, at least, will be incorrect, but nothing may
	242	# fail to make sure you notice.
	243	m4_define([AT_QUELL_VALGRIND],
	244	[[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
67a25fed AD	245
	246	## ------------------------ ##
	247	## Compiling C, C++ Files. ##
	248	## ------------------------ ##
	249
	250
	251	# AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
	252	# ----------------------------------------
	253	# Compile SOURCES into OUTPUT. If OUTPUT does not contain '.',
	254	# assume that we are linking too; this is a hack.
	255	m4_define([AT_COMPILE],
72d848c2	256	[AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
006d217d	257	0, [ignore], [ignore])])
67a25fed	258
07971983	259	# AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
67a25fed	260	# --------------------------------------------
51f4735e PE	261	# Compile SOURCES into OUTPUT. If OUTPUT does not contain '.',
51f4735e PE	262	# assume that we are linking too; this is a hack.
209ea708	263	# If the C++ compiler does not work, ignore the test.
67a25fed AD	264	m4_define([AT_COMPILE_CXX],
67a25fed AD	265	[AT_KEYWORDS(c++)
209ea708	266	AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
e6efa9da	267	AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
02650b7f	268	0, [ignore], [ignore])])
67a25fed AD	269
	270
	271
	272	## ---------------------------- ##
	273	## Running a generated parser. ##
	274	## ---------------------------- ##
	275
e0ac9b4b JD	276	# AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
e0ac9b4b JD	277	# ------------------------------------------------------------
67a25fed AD	278	# So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
67a25fed AD	279	m4_define([AT_PARSER_CHECK],
e0ac9b4b	280	[AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
1f7a61ff AD	281
	282
	283
	284
	285	## ----------------------- ##
	286	## Launch the test suite. ##
	287	## ----------------------- ##
	288
	289	AT_INIT
	290
	291	AT_TESTED([bison])