doc/docbook-text-style.xsl.cmake.in

   1 <?xml version="1.0" encoding="UTF-8"?>
   2 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
   3
   4   <xsl:import href="@DOCBOOK_XSL@/xhtml-1_1/docbook.xsl" />
   5
   6   <!-- Parameters for optimal text output. -->
   7   <xsl:param name="callout.graphics" select="0"/>
   8   <xsl:param name="callout.unicode" select="0"/>
   9   <xsl:param name="section.autolabel" select="1"/>
  10   <xsl:param name="section.label.includes.component.label" select="1"/>
  11
  12   <!-- Centering and aligning title elements. -->
  13   <xsl:template match="/*/title[position()=1]" mode="titlepage.mode">
  14     <br/>
  15     <center>
  16       <xsl:apply-imports/>
  17     </center>
  18     <br/>
  19     <hr/> <!-- No underline, but at least something. -->
  20   </xsl:template>
  21   <xsl:template match="author|editor" mode="titlepage.mode">
  22     <center>
  23       <xsl:apply-imports/>
  24     </center>
  25   </xsl:template>
  26
  27   <xsl:template match="releaseinfo" mode="titlepage.mode">
  28     <center>
  29       <xsl:apply-imports/>
  30     </center>
  31     <hr/>
  32   </xsl:template>
  33
  34   <!-- Dirty hack to get a left margin for paragraphs etc. -->
  35   <xsl:template match="legalnotice/*
  36         |chapter/*[not(name(.)='section') and not(name(.)='title')]
  37         |section/*[not(name(.)='section') and not(name(.)='title')]
  38         |appendix/*[not(name(.)='section') and not(name(.)='title')]
  39         |footnote/*">
  40     <xsl:copy><table><tr><td>&#xa0;&#xa0;&#xa0;</td><td>
  41     <xsl:apply-imports/>
  42     </td></tr></table></xsl:copy>
  43   </xsl:template>
  44
  45   <!-- Skip URLs if it has something to print. -->
  46   <xsl:template match="ulink[.!='']">
  47     <xsl:copy-of select="."/>
  48   </xsl:template>
  49   <!-- Print URLs if nothing to print. -->
  50   <xsl:template match="ulink[.='']">
  51     <xsl:value-of select="@url"/>
  52   </xsl:template>
  53
  54   <!-- Make clear where notes etc. begin and end. -->
  55   <xsl:template match="caution|important|note|tip|warning">
  56     <table width="80%" border="1">
  57       <colgroup>
  58         <col align="justify"/>
  59       </colgroup>
  60       <tbody>
  61         <tr>
  62           <td align="justify">
  63             <xsl:apply-imports/>
  64           </td>
  65         </tr>
  66       </tbody>
  67     </table>
  68   </xsl:template>
  69
  70 </xsl:stylesheet>