osfmk/i386/cswitch.s

   1 /*
   2  * Copyright (c) 2000-2006 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_OSREFERENCE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. The rights granted to you under the License
  10  * may not be used to create, or enable the creation or redistribution of,
  11  * unlawful or unlicensed copies of an Apple operating system, or to
  12  * circumvent, violate, or enable the circumvention or violation of, any
  13  * terms of an Apple operating system software license agreement.
  14  *
  15  * Please obtain a copy of the License at
  16  * http://www.opensource.apple.com/apsl/ and read it before using this file.
  17  *
  18  * The Original Code and all software distributed under the License are
  19  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  20  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  21  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  22  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  23  * Please see the License for the specific language governing rights and
  24  * limitations under the License.
  25  *
  26  * @APPLE_OSREFERENCE_LICENSE_HEADER_END@
  27  */
  28 /*
  29  * @OSF_COPYRIGHT@
  30  */
  31 /*
  32  * Mach Operating System
  33  * Copyright (c) 1991,1990 Carnegie Mellon University
  34  * All Rights Reserved.
  35  *
  36  * Permission to use, copy, modify and distribute this software and its
  37  * documentation is hereby granted, provided that both the copyright
  38  * notice and this permission notice appear in all copies of the
  39  * software, derivative works or modified versions, and any portions
  40  * thereof, and that both notices appear in supporting documentation.
  41  *
  42  * CARNEGIE MELLON ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS"
  43  * CONDITION.  CARNEGIE MELLON DISCLAIMS ANY LIABILITY OF ANY KIND FOR
  44  * ANY DAMAGES WHATSOEVER RESULTING FROM THE USE OF THIS SOFTWARE.
  45  *
  46  * Carnegie Mellon requests users of this software to return to
  47  *
  48  *  Software Distribution Coordinator  or  Software.Distribution@CS.CMU.EDU
  49  *  School of Computer Science
  50  *  Carnegie Mellon University
  51  *  Pittsburgh PA 15213-3890
  52  *
  53  * any improvements or extensions that they make and grant Carnegie Mellon
  54  * the rights to redistribute these changes.
  55  */
  56 /*
  57  */
  58
  59 #include <platforms.h>
  60
  61 #include <i386/asm.h>
  62 #include <i386/proc_reg.h>
  63 #include <assym.s>
  64
  65 #ifdef  SYMMETRY
  66 #include <sqt/asm_macros.h>
  67 #endif
  68
  69 #if     AT386
  70 #include <i386/mp.h>
  71 #endif  /* AT386 */
  72
  73 #define CX(addr, reg)   addr(,reg,4)
  74
  75         .text
  76 /*
  77  * Context switch routines for i386.
  78  */
  79
  80 Entry(Load_context)
  81         movl    S_ARG0,%ecx                     /* get thread */
  82         movl    TH_KERNEL_STACK(%ecx),%ecx      /* get kernel stack */
  83         lea     KERNEL_STACK_SIZE-IKS_SIZE-IEL_SIZE(%ecx),%edx
  84                                                 /* point to stack top */
  85         movl    %ecx,%gs:CPU_ACTIVE_STACK       /* store stack address */
  86         movl    %edx,%gs:CPU_KERNEL_STACK       /* store stack top */
  87
  88         movl    %edx,%esp
  89         movl    %edx,%ebp
  90
  91         xorl    %eax,%eax                       /* return zero (no old thread) */
  92         pushl   %eax
  93         call    EXT(thread_continue)
  94
  95 /*
  96  *      This has to save registers only
  97  *      when there is no explicit continuation.
  98  */
  99
 100 Entry(Switch_context)
 101         popl    %eax                            /* pop return PC */
 102
 103         /* Test for a continuation and skip all state saving if so... */
 104         cmpl    $0,4(%esp)
 105         jne     5f
 106         movl    %gs:CPU_ACTIVE_STACK,%ecx       /* get old kernel stack */
 107         movl    %ebx,KSS_EBX(%ecx)              /* save registers */
 108         movl    %ebp,KSS_EBP(%ecx)
 109         movl    %edi,KSS_EDI(%ecx)
 110         movl    %esi,KSS_ESI(%ecx)
 111         movl    %eax,KSS_EIP(%ecx)              /* save return PC */
 112         movl    %esp,KSS_ESP(%ecx)              /* save SP */
 113 5:
 114         movl    0(%esp),%eax                    /* return old thread */
 115         movl    8(%esp),%ebx                    /* get new thread */
 116         movl    %ebx,%gs:CPU_ACTIVE_THREAD      /* new thread is active */
 117         movl    TH_KERNEL_STACK(%ebx),%ecx      /* get its kernel stack */
 118         lea     KERNEL_STACK_SIZE-IKS_SIZE-IEL_SIZE(%ecx),%ebx
 119                                                 /* point to stack top */
 120
 121         movl    %ecx,%gs:CPU_ACTIVE_STACK       /* set current stack */
 122         movl    %ebx,%gs:CPU_KERNEL_STACK       /* set stack top */
 123
 124
 125         movl    KSS_ESP(%ecx),%esp              /* switch stacks */
 126         movl    KSS_ESI(%ecx),%esi              /* restore registers */
 127         movl    KSS_EDI(%ecx),%edi
 128         movl    KSS_EBP(%ecx),%ebp
 129         movl    KSS_EBX(%ecx),%ebx
 130         jmp     *KSS_EIP(%ecx)                  /* return old thread */
 131
 132 Entry(Thread_continue)
 133         pushl   %eax                            /* push the thread argument */
 134         xorl    %ebp,%ebp                       /* zero frame pointer */
 135         call    *%ebx                           /* call real continuation */
 136
 137 /*
 138  * thread_t Shutdown_context(thread_t thread,
 139  *                       void (*routine)(processor_t),
 140  *                       processor_t processor)
 141  *
 142  * saves the kernel context of the thread,
 143  * switches to the interrupt stack,
 144  * continues the thread (with thread_continue),
 145  * then runs routine on the interrupt stack.
 146  *
 147  */
 148 Entry(Shutdown_context)
 149         movl    %gs:CPU_ACTIVE_STACK,%ecx /* get old kernel stack */
 150         movl    %ebx,KSS_EBX(%ecx)              /* save registers */
 151         movl    %ebp,KSS_EBP(%ecx)
 152         movl    %edi,KSS_EDI(%ecx)
 153         movl    %esi,KSS_ESI(%ecx)
 154         popl    KSS_EIP(%ecx)                   /* save return PC */
 155         movl    %esp,KSS_ESP(%ecx)              /* save SP */
 156
 157         movl    0(%esp),%eax                    /* get old thread */
 158         movl    %ecx,TH_KERNEL_STACK(%eax)      /* save old stack */
 159         movl    4(%esp),%ebx                    /* get routine to run next */
 160         movl    8(%esp),%esi                    /* get its argument */
 161
 162         movl    %gs:CPU_INT_STACK_TOP,%esp      /* switch to interrupt stack */
 163
 164         pushl   %esi                            /* push argument */
 165         call    *%ebx                           /* call routine to run */
 166         hlt                                     /* (should never return) */