osfmk/x86_64/bzero.s

   1 /*
   2  * Copyright (c) 2000 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_OSREFERENCE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. The rights granted to you under the License
  10  * may not be used to create, or enable the creation or redistribution of,
  11  * unlawful or unlicensed copies of an Apple operating system, or to
  12  * circumvent, violate, or enable the circumvention or violation of, any
  13  * terms of an Apple operating system software license agreement.
  14  *
  15  * Please obtain a copy of the License at
  16  * http://www.opensource.apple.com/apsl/ and read it before using this file.
  17  *
  18  * The Original Code and all software distributed under the License are
  19  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  20  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  21  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  22  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  23  * Please see the License for the specific language governing rights and
  24  * limitations under the License.
  25  *
  26  * @APPLE_OSREFERENCE_LICENSE_HEADER_END@
  27  */
  28  /*
  29  * @OSF_COPYRIGHT@
  30  */
  31 /*
  32  * Mach Operating System
  33  * Copyright (c) 1991,1990 Carnegie Mellon University
  34  * All Rights Reserved.
  35  *
  36  * Permission to use, copy, modify and distribute this software and its
  37  * documentation is hereby granted, provided that both the copyright
  38  * notice and this permission notice appear in all copies of the
  39  * software, derivative works or modified versions, and any portions
  40  * thereof, and that both notices appear in supporting documentation.
  41  *
  42  * CARNEGIE MELLON ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS"
  43  * CONDITION.  CARNEGIE MELLON DISCLAIMS ANY LIABILITY OF ANY KIND FOR
  44  * ANY DAMAGES WHATSOEVER RESULTING FROM THE USE OF THIS SOFTWARE.
  45  *
  46  * Carnegie Mellon requests users of this software to return to
  47  *
  48  *  Software Distribution Coordinator  or  Software.Distribution@CS.CMU.EDU
  49  *  School of Computer Science
  50  *  Carnegie Mellon University
  51  *  Pittsburgh PA 15213-3890
  52  *
  53  * any improvements or extensions that they make and grant Carnegie Mellon
  54  * the rights to redistribute these changes.
  55  */
  56 /*
  57  */
  58
  59 #include <i386/asm.h>
  60
  61 /*
  62  * void *memset(void * addr, int pattern, size_t length)
  63  */
  64
  65 ENTRY(memset)
  66         movq    %rdi, %r8
  67         movq    %rsi, %rax              /* move pattern (arg2) to rax */
  68         movb    %al,%ah                 /* fill out pattern */
  69         movw    %ax,%cx
  70         shll    $16,%eax
  71         movw    %cx,%ax
  72         mov             %eax, %ecx
  73         shlq    $32,%rax
  74         orq             %rcx, %rax
  75         cld                                             /* reset direction flag */
  76         movq    %rdx, %rcx              /* mov quads first */
  77         shrq    $3, %rcx
  78         rep
  79         stosq
  80         movq    %rdx,%rcx               /* mov bytes */
  81         andq    $7,%rcx
  82         rep
  83         stosb
  84         movq    %r8 ,%rax               /* returns its first argument */
  85         ret
  86
  87 /*
  88  * void bzero(char * addr, size_t length)
  89  */
  90 Entry(blkclr)
  91 ENTRY2(bzero,__bzero)
  92         movq    %rsi,%rcx
  93         xorq    %rax,%rax
  94         shrq    $3,%rcx
  95         cld
  96         rep
  97         stosq
  98         movq    %rsi,%rcx
  99         andq    $7,%rcx
 100         rep
 101         stosb
 102         ret