/* -*- Mode: C; tab-width: 4 -*-
 *
 * Copyright (c) 2007 Apple Inc. All rights reserved.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.

    Change History (most recent first):

$Log: helpermsg.defs,v $
Revision 1.6  2007/09/07 22:44:03  mcguire
<rdar://problem/5448420> Move CFUserNotification code to mDNSResponderHelper

Revision 1.5  2007/09/04 22:32:58  mcguire
<rdar://problem/5453633> BTMM: BTMM overwrites /etc/racoon/remote/anonymous.conf

Revision 1.4  2007/08/23 21:53:13  cheshire
Added $Log header

Revision 1.3  2007/08/18 01:02:03  mcguire
<rdar://problem/5415593> No Bonjour services are getting registered at boot

Revision 1.2  2007/08/15 23:20:28  mcguire
<rdar://problem/5408105> BTMM: racoon files can get corrupted if autotunnel is listening on port > 32767

Revision 1.1  2007/08/08 22:34:58  mcguire
<rdar://problem/5197869> Security: Run mDNSResponder as user id mdnsresponder instead of root
 */

#include <mach/std_types.defs>
#include <mach/mach_types.defs>

import "helpermsg-types.h";

type v6addr_t = array [16] of uint8_t;
type v4addr_t = array [4] of uint8_t;
type string_t = c_string[*:1024];

subsystem helper 1833193043;
serverprefix do_;
userprefix proxy_;

simpleroutine mDNSIdleExit(
				port		: mach_port_t;
	ServerAuditToken	token		: audit_token_t);

routine mDNSDynamicStoreSetConfig(
				port		: mach_port_t;
				key		: int;
				value		: pointer_t;
	out			err		: int;
	ServerAuditToken	token		: audit_token_t);

routine mDNSPreferencesSetName(
						port	: mach_port_t;
 						key		: int;
 						old		: string_t;
 						new		: string_t;
	out					err		: int;
	ServerAuditToken	token	: audit_token_t);

routine mDNSKeychainGetSecrets(
				port		: mach_port_t;
	out			numsecrets	: unsigned;
	out			secrets		: pointer_t;
	out			err		: int;
	ServerAuditToken	token		: audit_token_t);

routine mDNSAutoTunnelInterfaceUpDown(
				port		: mach_port_t;
				updown		: int;
				address		: v6addr_t;
	out			err		: int;
	ServerAuditToken	token		: audit_token_t);

routine mDNSConfigureServer(
				port		: mach_port_t;
				updown		: int;
				keydata		: string_t;
	out			err		: int;
	ServerAuditToken	token		: audit_token_t);

routine mDNSAutoTunnelSetKeys(
				port		: mach_port_t;
				replacedelete	: int;
				local_inner	: v6addr_t;
				local_outer	: v4addr_t;
				local_port	: uint16_t;
				remote_inner	: v6addr_t;
				remote_outer	: v4addr_t;
				remote_port	: uint16_t;
				keydata		: string_t;
	out			err		: int;
	ServerAuditToken	token		: audit_token_t);